         TITLE 'LOGIC FOR TPEDIT MACRO'                                 00100019
IECTEDIT CSECT                                                          00200019
*********************************************************************** 00300019
* FUNCTION     PROVIDES PROGRAM LOGIC FOR TPEDIT MACRO. EDITS DATA      00400019
*              FROM 50 MDI                                              00500019
*                                                                       00600019
* INPUT        REGISTER 1 CONTAINS A POINTER TO A PARAMETER LIST        00700019
*              PROVIDED BY THE USER                                     00800019
*                                                                       00900019
*              REGISTER 0 CONTAINS A POINTER TO THE EDIT OPTIONS        01000019
*              SPECIFIED IN THE TPEDIT MACRO                            01100019
*                                                                       01200019
*              REGISTER 13 CONTAINS A POINTER TO A 72 BYTE SAVE AREA    01300019
*                                                                       01400019
*              REGISTER 14 CONTAINS THE RETURN ADDRESS                  01500019
*                                                                       01600019
* OUTPUT       REGISTER 1 CONTAINS A POINTER TO A PARAMETER LIST WHICH  01700019
*              CONTAINS THE RECORD ADDRESS AND ADDRESS OF THE RECORD    01800019
*              LENGTH                                                   01900019
*                                                                       02000019
* ENTRY        THE FIRST EXECUTABLE INSTRUCTION                         02100019
*                                                                       02200019
* EXITS        USER ERROR EXIT ROUTINE IF ONE IS SPECIFIED              02300019
*                                                                       02400019
* ATTRIBUTES   REENTRANT                                                02500019
*                                                                       02600019
*********************************************************************** 02700019
         SR    RTCDRG,RTCDRG       ZERO REG 15                          02800019
         STM   RETRNRG,BASERG,12(SAVERG) SAVE USERS REGISTERS           02900019
         BALR  BASERG,0            LOAD BASE REGISTER                   03000019
         USING *,BASERG                                                 03100019
         USING PARMLIST,PRMLSTRG   SET UP AND LOAD                      03200019
         LR    PRMLSTRG,PARMRG1    DSECT REG FOR USER PARM LIST         03300019
         USING EDITPARM,EDTPRMRG   SET UP AND LOAD                      03400019
         LR    EDTPRMRG,PARMRG0    DSECT REG FOR MACRO PARMS            03500019
         USING WORKSTOR,WRKSTRG    SET UP AND LOAD                      03600019
         SR    WRKRG2,WRKRG2       ZERO REG FOR COMPARE                 03700019
         CL    WRKRG2,PRMWRKAD     IS PTR TO WORK AREA ZERO             03800019
         BNE   LOADRG              BR IF NO TO LOAD REG FOR DSECT BASE  03900019
         L     WRKRG2,PRMMXRCL     GET MAX RCD LNG                      04000019
         LA    WRKRG2,96(WRKRG2)   ADD FIXED NO BYTES RQD               04100019
         TM    EDTTYPSW,HEX08      IS USER EXIT SPECIFIED               04200019
         BO    NOEXIT              BR IF NO                             04300019
         LA    WRKRG2,76(WRKRG2)                                        04400019
NOEXIT   TM    EDTTYPSW,HEX40      DOES RECFM = V                       04500019
         BZ    RECFMNTU            BR IF NO                             04600019
         LA    WRKRG2,4(WRKRG2)                                         04700019
RECFMNTU SRL   WRKRG2,3            DIVIDE BY 8                          04800019
         SLL   WRKRG2,3            MULTIPLY BY 8                        04900019
         LR    PARMRG0,WRKRG2      PUT CORE RQMT IN REG 0 FOR GETMAIN   05000019
         GETMAIN R,LV=(0)                                               05100019
         ST    PARMRG1,PRMWRKAD    SAVE PTR TO CORE OBTAINED            05200019
         OI    PRMMXRCL,HEX40      INDICATE GETMAIN ISSUED              05300019
LOADRG   L     WRKSTRG,PRMWRKAD    LOAD DSECT REG FOR WORK STORAGE      05400019
         TM    PRMMXRCL,HEX80      IS THIS THE BEGINING OF CARTRIDGE    05500019
         BO    NOFORMAT            BR IF NO                             05600019
*                                                                       05700019
* * *  FORMAT WORKING STORAGE  * * *                                    05800019
*                                                                       05900019
FORMAT   XC    WRKADRRC(84),WRKADRRC ZERO OUT CONSTANT AREA             06000019
         OI    PRMMXRCL,HEX80      IND NOT BEG OF CARTRIDGE             06100019
         ST    WRKRG2,WRKLNGSV     SAVE LENGTH OF CORE OBTAINED         06200019
         MVI   WRKLEVST,CHAR0      RESET LEVEL STATUS                   06300019
         LA    PARMRG1,WRKSVLZJ+8  GET ADDR OF RCD LNG                  06400019
         ST    PARMRG1,WRKSVLZJ+4  SAVE ADDR OF RCD LNGTH               06500019
         LA    PARMRG1,WRKMACSV    POINT TO END OF RCD LENGTH           06600019
         TM    EDTTYPSW,HEX08      IS USER EXIT SPECIFIED               06700019
         BO    HUITCLOS            BR IF NO                             06800019
         LA    PARMRG1,76(PARMRG1)                                      06900019
HUITCLOS TM    EDTTYPSW,HEX40      DOES RECFM = V                       07000019
         BZ    RECFMU              BR IF NO                             07100019
         LA    PARMRG1,4(PARMRG1)                                       07200019
RECFMU   ST    PARMRG1,WRKNXAVW    SAVE PTR TO NEXT AVAIL WORK          07300019
         AH    PARMRG1,PRMMXRCL+2  POINT TO END OF WORK + 1             07400019
         ST    PARMRG1,WRKENWRK    SAVE PTR TO END OF WORK              07500019
         SH    PARMRG1,PRMMXRCL+2  RESTORE PTR TO BEG OF WORK           07600019
         ST    PARMRG1,WRKADRRC    SAVE PTR TO RCD                      07700019
         OI    WRKEDSW1,HEX0A      EXPECT SOR AND DO NOT ALLOW DUP      07800019
         L     PARMRG1,PRMINPUT    GET PTR TO INPUT                     07900019
         ST    PARMRG1,WRKADNXB    SAVE PTR TO INPUT                    08000019
NOFORMAT TM    WRKEDSW2,HEX08      WAS INPUT EMPTY AFTER LAST REC       08100019
         BO    CKPARRCD            BR IF NO                             08200019
         TM    EDTTYPSW,HEX10          ARE USING BTAM BUFFER     A41120 08230021
         BZ    GETINPUT                BRANCH IF NO              A41120 08260021
         L     PARMRG1,WRKADNXB    GET PTR TO NEXT BUFFER               08300019
         LTR   PARMRG1,PARMRG1     ANY BUFFERS LEFT                     08400019
         BNZ   GETBUF              BR IF YES                            08500019
GETINPUT EQU   *                                                 A41120 08550021
         L     PARMRG1,PRMINPUT    GET POINTER TO INPUT                 08600019
         ST    PARMRG1,WRKADNXB    SAVE PTR TO NEXT BUFFER              08700019
GETBUF   OI    WRKEDSW2,HEX08      INDICATE INPUT NOT EMPTY             08800019
         AH    PARMRG1,PRMIPTLN+2  POINT TO INPUT END + 1               08900019
         ST    PARMRG1,WRKENIPT    AND SAVE                             09000019
         SH    PARMRG1,PRMIPTLN+2  RESTORE PTR TO INPUT                 09100019
         TM    EDTTYPSW,HEX10      ARE USING BTAM BUFFERS               09200019
         BZ    NOBUF1              BR IF NO                             09300019
         L     WRKRG2,0(PARMRG1)   PICK UP PTR TO NEXT BUFFER           09400019
         LA    WRKRG2,0(WRKRG2)    ZERO HIGH ORDER BYTE                 09500019
         ST    WRKRG2,WRKADNXB     SAVE PTR TO NEXT AVAIL BUFFER        09600019
         LA    PARMRG1,4(PARMRG1)  INCR PAST CHAIN FIELD                09700019
NOBUF1   BCTR  PARMRG1,0           DECRE INPUT POINTER                  09800019
         ST    PARMRG1,WRKNXAVI    AND SAVE                             09900019
CKPARRCD TM    WRKEDSW2,HEX01      WAS LAST RCD A PARTIAL RCD           10000019
         BO    PTAGN               BR IF YES                            10100019
ZROTYPST MVI   WRKTYPST,HEX00      ZERO TYPE STATUS                     10200019
         SR    WRKRG2,WRKRG2                                            10300019
         STH   WRKRG2,WRKLZFCT     ZERO PREVIOUS COUNT OF LZF           10400019
PTAGN    BAL   LNKRG8,PTINPUT      GO POINT TO NEXT AVAIL IN INPUT      10500019
         NI    WRKEDSW2,HEXFE      RESET POSSIBLE PARTIAL RCD INDICATOR 10600019
         CLI   0(PARMRG1),HEX19    END OF DATA CODE                     10900019
         BE    ENDDATA             BR IF YES                            11000019
         CLI   0(PARMRG1),DLE      IS FIRST CHAR A DLE                  11100019
         BE    PTAGN               BR IF YES TO POINT TO NEXT BYTE      11200019
         CLI   0(PARMRG1),STX      IS FIRST CHAR A STX                  11300019
         BE    PTAGN               BR IF YES                            11400019
         CLI   0(PARMRG1),ETB      IS THIS BSC END CHAR                 11500019
         BE    BSCCHARS            BR IF YES                            11600019
         CLI   0(PARMRG1),HEX03    IS THIS BSC END CHAR                 11700019
         BE    BSCCHARS            BR IF YES                            11800019
         TM    WRKEDSW2,HEX10     IN LEFT ZERO MODE?             A65189 11850021
         BO    CMPRLZF            BR IF YES                      A65189 11860021
         TM    WRKEDSW1,HEX08 *    IS SOR EXPECTED                      11900019
         BZ    CONTSCAN            BR IF NO TO CONTINUE SCAN            12000019
         NI    WRKEDSW1,HEXF7      RESET EXPECTED SOR SW                12100019
         SR    WRKRG4,WRKRG4                                            12200019
         IC    WRKRG4,0(PARMRG1)   GET CHAR IN SOR LOCATION             12300019
         LA    WRKRG3,HEX78+1                                           12400019
         LA    WRKRG5,HEX71-1      INIT SCAN FOR PROGRAM LEVEL CODES    12500019
SCNPGMLV LA    WRKRG5,1(WRKRG5)                                         12600019
         CLR   WRKRG5,WRKRG4       IS THIS BYTE A PROG LEVEL CODE       12700019
         BE    PGMLVFND            BR IS YES                            12800019
         CLR   WRKRG5,WRKRG3       HAS SCAN EXCEEDER RANGE OF PL CODES  12900019
         BL    SCNPGMLV            BR IF NO TO CONT SCAN                13000019
         CLI   0(PARMRG1),HEXCAN   IS THIS A CANCEL CODE                13100019
         BE    CANFND              BR IF YES                            13200019
         CLI   0(PARMRG1),HEXGS    IS THIS A GS CODE                    13300019
         BE    GSFND               BR IF YES                            13400019
         OI    WRKTYPST,HEX01      INDICATE SOR/EOR ERROR IN TYPE STAT  13500019
         MVI   WRKSORSV,HEX0E      SET SOR ERROR IN ERROR DESCRIPTION   13600019
         B     CKKPSOR1                                                 13700019
CANFND   OI    WRKEDSW1,HEX82      SET ON DELET SW AND DO NOT ALLOW DUP 13800019
         MVI   WRKLEVST,HEXF0      RESET LEVEL STATUS                   13900019
         B     PTAGN               BR TO CONT SCAN                      14000019
GSFND    OI    WRKEDSW1,HEX08      SET EXPECT SOR SWITCH ON             14100019
         B     PTAGN                                                    14200019
CONTSCAN L     WRKRG3,WRKENIPT     GET INPUT END + 1                    14300019
         SR    WRKRG3,PARMRG1      GET LNG OF BUFFER REMAINING          14400019
         LTR   WRKRG3,WRKRG3       IS INPUT EMPTY                       14500019
         BP    L256CK              BR IF NO                             14600019
         BCTR  PARMRG1,0           DECR PTR TO NXT AVAIL IN IPT         14700019
         B     NOCDS1                                                   14800019
L256CK   C     WRKRG3,LGT256       ARE THERE MORE THAN 256 BYTES LEFT   14900019
         BNH   DECRRG              BR IF NO                             15000019
         L     WRKRG3,LGT256       SET LENGTH TO 256                    15100019
DECRRG   BCTR  WRKRG3,0            DECR LENGTH                          15200019
         LR    WRKRG5,PARMRG1      ADDR OF FIRST BYTE TO BE SCANNED     15300019
         AR    WRKRG5,WRKRG3       PLUS SCAN LNG - 1                    15400019
         ST    WRKRG5,WRKNXAVI     GIVES INPUT PTR IF NO SPECIAL CODES  15500019
         ST    WRKRG5,WRKENSCN     STORE AS END OF SCANNED              15600019
         SR    WRKRG2,WRKRG2       PREPARE FOR TRT                      15700019
         EX    WRKRG3,TRTTBL       TRANSLATE AND TEST                   15800019
         BC    8,NOSPECCD          BR IF NO SPECIAL CODES FOUND         15900019
         ST    PARMRG1,WRKNXAVI    SAVE LAST SCANNED AS INPUT PTR       16000019
         TM    WRKEDSW1,HEX80      IS THIS RECORD BEING DELETED         16100019
         BZ    BRTBL               BR IS NO                             16200019
         CH    WRKRG2,TWOOH        IS THIS END OF DELETED RECORD        16300019
         BL    PTAGN                                                    16400019
BRTBL    B     BRNCHTBL-4(WRKRG2)  BR TO BR TABLE TO HANDLE NONZERO     16500019
NOSPECCD L     PARMRG1,WRKENSCN    GET END OF SCANNED                   16600019
         L     WRKRG6,WRKENIPT     IS END OF SCANNED NOW                16700019
         BCTR  WRKRG6,0            POINTING AT LAST                     16800019
         CR    WRKRG6,PARMRG1      BYTE IN THIS BUFFER                  16900019
         BNE   CKCANRCD            BR IF NO                             17000019
NOCDS1   OI    WRKEDSW2,HEX01      IND PARTIAL RCD                      17100019
         NI    WRKEDSW2,HEXF7      INDICATE IPT EMPTY                   17200019
         TM    WRKEDSW1,HEX80      IS  RCD BEING DELETED                17300019
         BZ    SETRTURN            BR IF NO                             17400019
         TM    EDTTYPSW,HEX10      ARE USING BTAM BUFFERS               17500019
         BZ    DELETRCD            BR IF NO                             17600019
         L     PARMRG1,WRKADNXB    GET PTR TO NEXT BUFFER               17700019
         LTR   PARMRG1,PARMRG1     ARE ANY BUFFERS LEFT                 17800019
         BNZ   GETBUF              BR IF YES TO POINT TO NEXT BUFFE    17900019
DELETRCD MVI   19(SAVERG),HEX08    IND IPT EMPTY RCD NOT AVAIL          18000019
         B     RETURNX                                                  18100019
CKCANRCD TM    WRKEDSW1,HEX80      IS RECORD BEING DELETED              18200019
         BO    PTAGN               BR IF YES                            18300019
         B     SETRTURN            GO MOVE IT OUT                       18400019
*                                                                       18500019
* * *  BRANCH TABLE * * *                                               18600019
*                                                                       18700019
TRTTBL   TRT   0(0,PARMRG1),TRNSTBLE                                    18800019
BRNCHTBL B     LEFTZROF *          LEFT ZERO FILL                       18900019
         B     DUP      *          DUP                                  19000019
         B     LFTZROST *          LEFT ZERO START                      19100019
         B     CANCEL   *          CANCEL                               19200019
         B     PTAGN    *          GROUP SEPARATOR CODES                19300019
         B     BSCCHARS *          BCS CHARS                            19400019
         B     DATACK   *          DATA CHECK -2772 REPLACE CHARACTER   19500019
         B     ENDDATA             END OF DATA ON CARTRIDGE             19600019
         B     RMORVOK  *          RECORD MARK OR VERIFY OK             19700019
         B     PGMLEVEL *          PROGRAM LEVEL 1-8                    19800019
*                                                                       19900019
* * * END OF BRANCH TABLE * * *                                         20000019
*                                                                       20100019
* *  HANDLE LEFT ZERO FILL CODES                                        20200019
LEFTZROF TM    WRKEDSW1,HEX40      HAS A LEFT ZERO START BEEN FOUND     20300019
         BZ    NOLZSFND            BR IF NO                             20400019
LZFCNT   LH    WRKRG2,WRKLZFCT     PICK UP COUNT OF LA FIL CHARS        20500019
         LA    WRKRG2,1(WRKRG2)    INCR COUNT OF LZF                    20600019
         STH   WRKRG2,WRKLZFCT     AND SAVE                             20700019
         MVC   0(1,PARMRG1),EDTREPCR  MOVE IN REP CHAR IN CASE FLD      20800019
         OI    WRKEDSW2,HEX10      INDICATE LZF FOUND                   20900019
*                                     REMAINS UNJUSTIFIED               21000019
         BAL   LNKRG8,MOVERTN      GO MOVE IT OUT                       21100019
         BAL   LNKRG8,PTINPUT      GO POINT TO NEXT BYTE                21200019
         TM    WRKEDSW2,HEX08      IS INPUT EMPTY                       21300019
         BZ    RETURNX             BR IF YES                            21400019
         CLI   0(PARMRG1),ETB      IS THIS BSC END CHAR                 21500019
         BE    BSCCHARS            BR IF YES                            21600019
         CLI   0(PARMRG1),HEX03    IS THIS BSC END CHAR                 21700019
         BE    BSCCHARS            BR IF YES                            21800019
CMPRLZF  CLI   0(PARMRG1),HEXLZF   IS THIS ALSO A LEFT ZERO FILL        21900019
         BE    LZFCNT              BR IF YES TO CONT SCAN FOR LZF       22000019
         OI    WRKEDSW1,HEX20      INDICATE END OF LZ FIELD             22100019
         NI    WRKEDSW2,HEXEF      RESET LZ MODE SW                     22200019
         BCTR  PARMRG1,0           DECR INPUT POINTER                   22300019
         ST    PARMRG1,WRKNXAVI    STORE INPUT POINTER                  22400019
         B     SETRTURN            GO SET UP FOR ADJUST                 22500019
NOLZSFND MVC   0(1,PARMRG1),EDTREPCR REPLACE FIELD ERROR BYTE           22600019
         OI    WRKTYPST,HEX04      INDICATE FIELD ERROR IN TYPE STATUS  22700019
         B     SETRTURN            GO MOVE IT OUT                       22800019
         SPACE 1                                                        22900019
* * HANDLE DUP CODES                                                    23000019
DUP      NI    WRKEDSW1,HEX9F      RESET POSSIBLE LEFT ZERO             23100019
         BCTR  PARMRG1,0           DECR INPUT POINTER                   23200019
         ST    PARMRG1,WRKNXAVI    STORE PREV ADDR AS INPUT POINTER     23300019
         BAL   LNKRG8,MOVERTN      GO MOVE OUT ALL UP TO DUP            23400019
         BAL   LNKRG8,PTINPUT      POINT TO DUP AGAIN                   23500019
         OI    WRKEDSW1,HEX01      INDICATE DUP FOUND IN THIS RECORD    23600019
         TM    WRKEDSW1,HEX02      IS DUP ALLOWED                       23700019
         BO    NOLZSFND            BR IF NO                             23800019
         L     WRKRG5,WRKNXAVW     GET NEXT AVAIL IN WORK               23900019
         L     WRKRG6,WRKLDBPV     GET PTR TO LAST DATA BYTE PREV RCD   24000019
         TM    EDTTYPSW,HEX80      ARE TO KEEP SOR/EOR CHARS            24100019
         BZ    CMPR8               BR IF NO                             24200019
         BCTR  WRKRG6,0            DECR PTR TO LAST DATA BYTE PREV RCD  24300019
CMPR8    CR    WRKRG5,WRKRG6       IS DUP BEYOND END OF PREV RCD        24400019
         BH    NOLZSFND            BR IF YES TO INDICATE FIELD ERROR    24500019
         CLC   0(WRKRG5),EDTREPCR  IS BYTE TO BE DUPED A REPLACE CHAR   24600019
         BE    NOLZSFND            BR IS YES                            24700019
         MVC   0(1,PARMRG1),0(WRKRG5) PERFORM DUPLICATION               24800019
         B     SETRTURN            GO MOVE IT OUT                       24900019
         SPACE 1                                                        25000019
* *  HANDLE LEFT ZERO START CODES                                       25100019
LFTZROST BCTR  PARMRG1,0           DO NOT MOVE LEFT ZERO START          25200019
         BAL   LNKRG8,MOVERTN      MOVE OUT ALL UP TO LEFT ZERO START   25300019
         OI    WRKEDSW1,HEX40      INDICATE LZ START                    25400019
         MVC   WRKFBLZF,WRKNXAVW   SAVE ADDR OF START OF LZ FIELD       25500019
         B     PTAGN                                                    25600019
         SPACE 1                                                        25700019
* *  HANDLE VERIFY OK OR RECORD MARK                                    25800019
RMORVOK  NI    WRKEDSW1,HEX9F      RESET POSSIBLE LZ MODE               25900019
         OI    WRKEDSW1,HEX08      SET EXPECT SOR SWITCH ON             26000019
         TM    WRKEDSW1,HEX80      IS THIS RECORD BEING DELETED         26100019
         BO    RECDEL              BR IF YES                            26200019
         MVI   WRKEORSV,CVOK       SET VOK IND IN ERROR DESCRIPTION     26300019
         CLI   0(PARMRG1),HEXVOK   WAS EOR AN IRS(VOK) CODE             26400019
         BE    VOK                 BR IF YES                            26500019
         MVI   WRKEORSV,CRM        SAVE RM INDICATOR IN EDW             26600019
         TM    EDTTYPSW,HEX20      MUST EOR BE VOK                      26700019
         BZ    VOK                 BR IF NO                             26800019
         OI    WRKTYPST,HEX01      INDICATE SOR/EOR ERROR IN EDW        26900019
VOK      TM    EDTTYPSW,HEX80      IS EOR TO BE RETAINED                27000019
         BO    EORRTAIN            BR IF YES                            27100019
         BCTR  PARMRG1,0           DECR INPUT PTR SO EOR NOT MOVED OUT  27200019
EORRTAIN B     SETRTURN            GO MOVE IT OUT                       27300019
RECDEL   NI    WRKEDSW1,HEX7F      SET OFF DELETE SWITCH                27400019
         B     PTAGN               GO CONT SCAN                         27500019
         SPACE 1                                                        27600019
* *  HANDLE PROGRAM LEVEL CODES                                         27700019
PGMLEVEL TM    WRKEDSW1,HEX80      IS THIS RECORD BEING DELETED         27800019
         BZ    CANCEL              BR IF NO TO FORCE END OF PREV RCD    27900019
         NI    WRKEDSW1,HEX7F      SET OFF DELETE SW                    28000019
PGMLVFND MVC   WRKSORSV(1),0(PARMRG1) SAVE IT AS SOR IN EDW             28100019
         NI    WRKSORSV,HEX0F      PUT IN FORM OF HEX 0X                28200019
CKKPSOR1 TM    EDTTYPSW,HEX80      SOR TO BE RETAINED                   28300019
         BZ    PTAGN               BR IF NO TO CONT SCAN                28400019
         ST    PARMRG1,WRKFBSCN    SAVE AS START                        28500019
         B     SETRTURN            GO MOVE IT OUT                       28600019
CANCEL   OI    WRKEDSW1,HEX08      SET EXPECT SOR SW ON                 28700019
         NI    WRKEDSW1,HEX9F      RESET POSSIBLE LZ MODE               28800019
         OI    WRKTYPST,HEX01      INDICATE SOR/EOR ERROR               28900019
         MVI   WRKEORSV,CHE        IND EOR ERROR IN EDW                 29000019
         BCTR  PARMRG1,0           DECR INPUT POINTER                   29100019
         ST    PARMRG1,WRKNXAVI    STORE INPUT POINTER                  29200019
         TM    EDTTYPSW,HEX80      EOR TO BE RETAINED                   29300019
         BO    NOEOR               BR IF YES                            29400019
         BCTR  PARMRG1,0           DECR INPUT PTR SO EOR NOT MOVED      29500019
NOEOR    OI    WRKEDSW1,HEX04      INDICATE EOR FORCED                  29600019
         B     SETRTURN            GO MOVE IT OUT                       29700019
         SPACE 1                                                        29800019
* *  HANDLE DATA CHECK  - 2772 REPLACE CHARS X'3F'                      29900019
DATACK   MVC   0(1,PARMRG1),EDTREPCR REPLACE DATA CK IND WITH REP CHAR  30000019
         OI    WRKTYPST,HEX08      IND DATA CHECK IN TYPE STATUS        30100019
         BAL   LNKRG8,MOVERTN      GO MOVE IT OUT                       30200019
         BAL   LNKRG8,PTINPUT      POINT TO NEXT BYTES                  30300019
         CLI   0(PARMRG1),HEX3F    IS THIS DATA CK BYTE ALSO            30400019
         BO    DBLDC               BR IF YES                            30500019
         BCTR  PARMRG1,0           DECR INPUT POINTER                   30600019
         ST    PARMRG1,WRKNXAVI    STORE INPUT POINTER                  30700019
         B     PTAGN                                                    30800019
DBLDC    MVC   0(1,PARMRG1),EDTREPCR REPLACE DATA CK IND WITH REP CHAR  30900019
         OI    WRKEDSW2,HEX02      INDICATE DOUBLE DATA CK              31000019
         B     SETRTURN            GO MOVE IT OUT                       31100019
         SPACE 1                                                        31200019
* *  HANDLE BSC CHARACTERS                                              31300019
BSCCHARS OI    WRKEDSW2,HEX04      INDICATE BSC END CHAR FOUND          31400019
         BCTR  PARMRG1,0           DECR PTR TO IPT                      31500019
         TM    WRKEDSW1,HEX08      IS SOR EXPECTED                      31600019
         BZ    NOCDS1                                                   31700019
         NI    WRKEDSW2,HEXF7      IND IPT EMPTY                        31800019
         MVI   19(SAVERG),HEX08    IND IPT EMPTY RCD NOT AVAIL          31900019
         B     RETURN                                                   32000019
         SPACE 1                                                        32100019
* * HANDLE END OF DATA CODE                                             32200019
ENDDATA  TM    WRKEDSW1,HEX08      IS SOR EXPECTED                      32300019
         BZ    CANCEL              BR IF NO TO FORCE END OF PREV RCD    32400019
         MVI   19(SAVERG),HEX0C    IND LAST RCD                         32500019
         NI    PRMMXRCL,HEX7F      IND BEG OF CARTRIDGE                 32600019
         TM    PRMMXRCL,HEX40      WAS GETMAIN ISSUED                   32700019
         BZ    RETRNZ              BR IF NO                             32800019
         L     PARMRG1,PRMWRKAD    GET PTR TO CORE OBTAINED VIA GETMAIN 32900019
         L     PARMRG0,WRKLNGSV    GET LNG OF CORE OBTAINED             33000019
         SR    WRKRG2,WRKRG2                                            33100019
         ST    WRKRG2,PRMWRKAD     ZERO PTR TO WORK STORAGE             33200019
         FREEMAIN R,LV=(0),A=(1)                                        33300019
RETRNZ   NI    PRMMXRCL,HEXBF      RESET GETMAIN SW                     33400019
         B     RETURNX             RETURN TO USER                       33500019
SETRTURN LA    LNKRG8,PTAGN        SET RETURN ADDR FROM MOVE RTN        33600019
*                                                                       33700019
* * *  MOVE ROUTINE  * * *                                              33800019
*                                                                       33900019
MOVERTN  L     WRKRG5,WRKNXAVW     GET ADDR OF NEXT AVAIL IN WORK       34000019
         L     WRKRG7,WRKFBSCN     GET ADDR OF FIRST BYTE SCANNED       34100019
         LR    WRKRG4,PARMRG1      ADDR OF LAST BYTE SCANNED            34200019
         LA    WRKRG4,1(WRKRG4)    GET END OF SCANNED +1                34300019
         SR    WRKRG4,WRKRG7       CALC LENGTH OF SCANNED               34400019
         BNP   NOBYTES             BR IF NO BYTES TO BE MOVED           34500019
         L     WRKRG6,WRKENWRK     GET END OF WORK AREA + 1             34600019
         SR    WRKRG6,WRKRG5       CALC NO BYTES AVAIL IN WORK AREA     34700019
         CR    WRKRG4,WRKRG6       WILL ALL SCANNED BYTES FIT IN WORK   34800019
         BNH   MVSCN               BR IF YES TO MOVE SCANNED            34900019
         OI    WRKEDSW1,HEX10      INDICATE NOT ALL FIT                 35000019
         NI    WRKEDSW2,HEXFE      RESET POSSIBLE PARTIAL RCD IND       35100019
         LTR   WRKRG4,WRKRG6       WILL ANY BYTES FIT                   35200019
         BNP   RCDTOOLG            BR IF NO                             35300019
MVSCN    BCTR  WRKRG4,0            DECR LNG FOR EXECUTE                 35400019
         EX    WRKRG4,MOVESCND     MOVE SCANNED FROM INPUT TO WORK AREA 35500019
         LA    WRKRG4,1(WRKRG4)    RESTORE LNG                          35600019
         AR    WRKRG7,WRKRG4       CALC ADDR OF FIRST BYTE NOT MOVED    35700019
         ST    WRKRG7,WRKFBSCN     FROM INPUT TO WORK AREA              35800019
         TM    EDTTYPSW,HEX80      ARE TO KEEP SOR/EOR CHARS            35900019
         BZ    DONOTKP             BR IF NO                             36000019
         BCTR  WRKRG7,0            DECR POINTER TO NXT AV IPT           36100019
DONOTKP  AR    WRKRG5,WRKRG4       CALC NEXT AVAIL WORK                 36200019
         ST    WRKRG5,WRKNXAVW     SAVE ADDR OF NEXT AVAIL WORK         36300019
         TM    WRKEDSW1,HEX10      DID ALL SCANNED FIT                  36400019
         BO    RCDTOOLG            BR IF NO                             36500019
NOFCREOR TM    WRKEDSW1,HEX08      WAS END OF RECORD FOUND              36600019
         BO    ENDRCFND            BR IF YES                            36700019
         TM    WRKEDSW2,HEX01      IS THIS A PARTIAL RCD                36800019
         BO    ENDRCFND            BR IF YES                            36900019
         TM    WRKEDSW1,HEX20      WAS END OF LZ FIELD FOUND            37000019
         BCR   8,LNKRG8            BR IF NO TO CALLING RTN              37100019
         SPACE 1                                                        37200019
* * LEFT ZERO JUSTIFICATION                                             37300019
LZJSTRTN NI    WRKEDSW1,HEX9F      SET OFF LZ MODE                      37400019
         L     WRKRG4,WRKFBLZF     GET ADDR OF START OF LZ FIELD        37500019
         LH    WRKRG3,WRKLZFCT     GET COUNT OF LZ FILLS                37600019
         SR    WRKRG5,WRKRG4       CALC FIELD LNG                       37700019
         CH    WRKRG5,HLF15        DOES FIELD LNG EXCEED 15             37800019
         BNH   ADJUST              BR IF NO TO ADJUST                   37900019
         OI    WRKTYPST,HEX04      INDICATE FIELD ERROR                 38000019
         BR    LNKRG8              RETURN TO CALLING RTN                38100019
ADJUST   SR    WRKRG5,WRKRG3       GET NO OF SIGNIFICANT DIGITS         38200019
         BCTR  WRKRG5,0            DECR LNG FOR EXECUTE                 38300019
         LR    WRKRG6,WRKRG4       ADDR OF START OF LZ FIELD IN WORK    38400019
         AR    WRKRG6,WRKRG3       FIELD START + LZ FILL COUNT          38500019
         EX    WRKRG5,MVSIGDGT     MOVE SIGNIFICANT DIGITS TO HOLD AREA 38600019
         EX    WRKRG5,MVDGTWRK     MOVE SIGNIFICANT DIGITS TO RIGHT     38700019
MVZROFIL MVI   0(WRKRG4),HEXF0     MOVE ZERO FILL                       38800019
         LA    WRKRG4,1(WRKRG4)    INCR WORK ADDR                       38900019
         BCT   WRKRG3,MVZROFIL     BR IF NOT ALL FILLED                 39000019
         STH   WRKRG3,WRKLZFCT     ZERO COUNT FIELD                     39100019
         BR    LNKRG8              RETURN TO CALLING ROUTINE            39200019
MVSIGDGT MVC   WRKSVLZJ(0),0(WRKRG4) USED BY EXECUTE TO                 39300019
MVDGTWRK MVC   0(0,WRKRG6),WRKSVLZJ  RIGHT JUSTIFY FIELD                39400019
         SPACE 1                                                        39500019
* *  THIS ROUTINE IS ENTERED FOR RECORDS WHICH EXCEED USER SPECIFIED *  39600019
* *      RECORD  LENGTH                                                 39700019
RCDTOOLG OI    WRKTYPST,HEX03      INDICATE SOR/EOR AND LENGTH ERROR    39800019
         MVI   WRKEORSV,CHE        SET EOR ERROR IN ERROR DESCRIPTION   39900019
         OI    WRKEDSW1,HEX08      SET EXPECT SOR SW ON                 40000019
         OI    WRKEDSW2,HEX08      IND IPT NOT EMPTY                    40100019
         ST    WRKRG7,WRKNXAVI     SAVE ADDR AS INPUT POINTER           40200019
         TM    WRKEDSW1,HEX40      IN LZ MODE                           40300019
         BZ    ENDRCFND            BR IF NO                             40400019
         SR    PARMRG0,PARMRG0     ZERO REG FOR COMPARE                 40500019
         CH    PARMRG0,WRKLZFCT    ANY LZ FILLS FOUND                   40600019
         BE    ENDRCFND            BR IF NO                             40700019
         ST    PARMRG0,WRKLZFCT    SET CNT FIELD TO ZERO                40800019
         BCTR  WRKRG5,0            POINT TO LAST BYTE MOVED TO WORKAREA 40900019
         CLC   0(1,WRKRG5),EDTREPCR WAS LAST MOVED A FILL CHAR          41000019
         BNE   CKKPSOR             BR IF NO                             41100019
         OI    WRKTYPST,HEX04      INDICATE A FIELD ERROR IN TYPE STAT  41200019
CKKPSOR  TM    EDTTYPSW,HEX80      RETAIN SOR/EOR BYTES SPECIFIED       41300019
         BZ    SETUP               BR IF NO                             41400019
         BCTR  WRKRG5,0            POINT TO LAST MOVED TO WORK          41500019
         B     SETUP               GO SET UP TO OUTPUT RCD              41600019
NOBYTES  TM    EDTTYPSW,HEX80      PRE TO KEEP SOR/EOR CHARS            41700019
         BO    NOFCREOR            BR IF YES                            41800019
         TM    WRKEDSW1,HEX04      WAS EOR FORCED                       41900019
         BZ    NOFCREOR            BR IF NO                             42000019
         BCTR  WRKRG5,0            DECR ADDR NEXT WORK SO BAD           42100019
         ST    WRKRG5,WRKNXAVW     EOR NOT RETAINED AS PART OF RCD      42200019
ENDRCFND BCTR  WRKRG5,0            POINT TO LAST MOVED TO WORK          42300019
SETUP    L     PARMRG1,WRKNXAVI    GET POINTER TO INPUT                 42400019
         LA    PARMRG1,1(PARMRG1)  POINT NEXT AVAIL BYTE                42500019
BALROUT  BAL   LNKRG8,CKINPUT      GO SET STATUS OF INPUT               42600019
         TM    WRKEDSW2,HEX08      IS INPUT EMPTY                       42700019
         BZ    IPTNTEPT            BR IF NO                             42800019
         BCTR  PARMRG1,0           DECR POINTER TO INPUT                42900019
         ST    PARMRG1,WRKNXAVI    SAVE AS NEXT AVAIL IN INPUT          43000019
IPTNTEPT TM    WRKEDSW2,HEX01      IS THIS PARTIAL RCD                  43100019
         BO    RETURN              BR IF YES                            43200019
         L     PARMRG0,WRKADRRC    GET ADDR OF RCD                      43300019
         L     PARMRG1,WRKNXAVW    GET PTR TO NEXT AVAIL IN WORK        43400019
         ST    PARMRG0,WRKNXAVW    REINIT PTR TO NEXT AVAIL WORK        43500019
         SR    PARMRG1,PARMRG0     CAL LENGTH OF RCD                    43600019
         TM    EDTTYPSW,HEX80      ARE SOR/EOR CHARS TO BE RETAINED     43700019
         BO    CKLNFR3             BR IF YES                            43800019
         LTR   PARMRG1,PARMRG1     IS RCD LENGTH AT LEAST ONE           43900019
         BZ    CKPARRCD            BR IF NO                             44000019
         BP    SVLSTBYT            BR IF YES TO PASS IT                 44100019
DONTPASS OI    WRKEDSW1,HEX02      RESET EDT SW AND DO NOT ALLOW DUP    44200019
         NI    WRKEDSW1,HEX0A      RESET EDIT SW                        44300019
         NI    WRKEDSW2,HEX88                                           44400019
         MVI   WRKLEVST,CHAR0      RESET LEVEL STATUS                   44500019
         B     ZROTYPST            GO ZERO TYPE STATUS                  44600019
CKLNFR3  CH    PARMRG1,THREE       IS RCD LENGTH AT LEAST 3             44700019
         BL    DONTPASS            BR IF NO                             44800019
SVLSTBYT ST    WRKRG5,WRKLDBPV     SAVE LAST DATA BYTE IN RCD           44900019
         ST    PARMRG1,WRKSVLZJ+8  SAVE LNG OF RCD                      45000019
*                                                                       45100019
* * *  OUTPUT ROUTINE  * * *                                            45200019
OUTPUT   TM    WRKEDSW2,HEX01      IS THIS PARTIAL RCD                  45300019
         BO    RETURN              BR IF YES                            45400019
         CLI   WRKSORSV,HEX0E      WAS SOR IN ERROR                     45500019
         BO    WRNGLN              BR IF YES                            45600019
         SR    WRKRG4,WRKRG4       SET TO ZERO FOR COMPARE              45700019
         SR    WRKRG5,WRKRG5       SET TO ZERO FOR CALC                 45800019
         IC    WRKRG5,WRKSORSV     GET SOR CHAR                         45900019
         AR    WRKRG5,WRKRG5       DOUBLE IT TO INDEX TABL              46000019
         CH    WRKRG4,WRKSVPGL-2(WRKRG5) HAS LENGTH BEEN SAVED          46100019
         BNE   CKLNGPL             BE IF YES                            46200019
         TM    WRKTYPST,HEX0F      DOES RCD HAVE INDENTIFIABLE ERROR    46300019
         BNZ   IDENTER             BR IF YES                            46400019
         STH   PARMRG1,WRKSVPGL-2(WRKRG5) SAVE LNG FOR THIS LEVEL       46500019
         BO    IDENTER             BYPASS LNG CHECK                     46600019
CKLNGPL  CH    PARMRG1,WRKSVPGL-2(WRKRG5) CK LNG WITH SAVED LNG         46700019
         BE    IDENTER             BR IF LNG OK                         46800019
         OI    WRKTYPST,HEX02      INDICATE WRONG LNG RCD               46900019
IDENTER  TM    WRKTYPST,HEX02      WAS IT A WRONG LNG RCD               47000019
         BO    WRNGLN              BR IF YES                            47100019
         TM    WRKEDSW2,HEX02      WAS DOUBLE DATA CHECK FOUND          47200019
         BO    WRNGLN              BR IF YES                            47300019
         CLI   WRKLEVST,CHAR0      IS LEVEL STATUS ZERO                 47400019
         BE    RESETSW             BR IF YES                            47500019
         TM    WRKEDSW1,HEX01      WAS DUP ENCOUNTERED                  47600019
         BO    MKLEVST2            BR IF YES                            47700019
         MVI   WRKLEVST,CHAR0      RESET LEVEL STATUS                   47800019
         B     RESETSW             GO RESET EDIT SWITCHES               47900019
WRNGLN   CLI   WRKLEVST,CHAR0      IS LEVEL STATUS ZERO                 48000019
         BNE   MKLEVST2            BR IF NO                             48100019
         MVI   WRKLEVST,CHAR1      MAKE IT 1                            48200019
         B     RESETSW             GO RESET EDIT SWITCHES               48300019
MKLEVST2 MVI   WRKLEVST,CHAR2      MAKE IT 2                            48400019
RESETSW  NI    WRKEDSW1,HEX08      RESET EDIT SWITCHES                  48500019
         NI    WRKEDSW2,HEX88                                           48600019
         CH    PARMRG1,EDTMINLN    CHECK MINIMUM LENGTH                 48700019
         BNL   MINLNOK             BR IF NOT SHORT                      48800019
         OI    WRKTYPST,HEX02      INDICATE LENGTH ERROR                48900019
MINLNOK  TR    WRKTYPST(2),TREDW   MAKE TYPE AND LEVEL STATUS PRNTABLE  49000019
RETURN1  LR    WRKRG3,PARMRG0      PTR TO RCD                           49100019
         LA    PARMRG0,HEX04       SET UP REG FOR SUB                   49200019
         TM    EDTTYPSW,HEX08      USER ERROR EXIT SPECIFIED            49300019
         BO    CKVFRMT1            BR IF NO                             49400019
         CLC   WRKSVEDW(2),CHAR00  IS THIS AN ERROR RECORD              49500019
         BE    CKVFRMT1            BR IF NO                             49600019
         SR    WRKRG3,PARMRG0      DECR PTR TO RCD                      49700019
         MVC   0(4,WRKRG3),WRKSVEDW APPEND EDW TO BEG OF RCD            49800019
         LA    PARMRG1,4(PARMRG1)  INCR LENGTH OF RCD TO INCLUDE EDW    49900019
CKVFRMT1 TM    EDTTYPSW,HEX40      DOES RECFM=V                         50000019
         BZ    RECFMU1             BR IF NO                             50100019
         LA    PARMRG1,4(PARMRG1)  INCR RCD LENGTH TO INCLUDE V-FIELD   50200019
         SR    WRKRG3,PARMRG0      DECR PTR TO RCD                      50300019
         STH   PARMRG1,0(WRKRG3)   SAVE LENGTH IN V-FIELD               50400019
         XC    2(2,WRKRG3),2(WRKRG3) SET SECOND HALF TO ZERO            50500019
RECFMU1  ST    PARMRG1,WRKSVLZJ+8  SAVE RECORD LENGTH                   50600019
         ST    WRKRG3,WRKSVLZJ     SAVE RECORD ADDR                     50700019
         LA    WRKRG3,WRKSVLZJ+8                                        50800019
         ST    WRKRG3,WRKSVLZJ+4                                        50900019
         TM    EDTTYPSW,HEX08      IS USER ERROR EXIT SPEC              51000019
         BO    RETURN              BR IF NO                             51100019
         CLC   WRKSVEDW(2),CHAR00  IS THIS AN ERROR RECORD              51200019
         BE    RETURN              BR IF NO                             51300019
         LR    WRKRG2,SAVERG       SAVE PTR TO USER SAVE AREA           51400019
         LA    SAVERG,WRKMACSV     POINT TO SAVE AREA                   51500019
         L     RTCDRG,EDTUSRXT     GET ADDR OF USER EXIT RTN            51600019
         LA    PARMRG1,WRKSVLZJ    POINT TO PARM LIST                   51700019
         BALR  RETRNRG,RTCDRG      GO TO USER EXIT ROUTINE              51800019
         LR    SAVERG,WRKRG2       RESTORE PTR SAVE AREA                51900019
         L     PARMRG1,WRKSVLZJ+8  GET RCD LNG                          52000019
         LA    PARMRG0,HEX04       SET UP RG FOR SUB                    52100019
         SR    PARMRG1,PARMRG0     DECR RCD LNG                         52200019
         ST    PARMRG1,WRKSVLZJ+8  SAVE RCD LNG                         52300019
         L     WRKRG3,WRKSVLZJ                                    M4292 52400019
         LA    WRKRG3,4(WRKRG3)    INCR RCD ADDR                        52500019
         TM    EDTTYPSW,HEX40      RECFM=V                              52600019
         BZ    NORCFM3             BR IF NO                             52700019
         MVC   0(4,WRKRG3),0(WRKRG7) MOVE V FIELD                       52800019
         STH   PARMRG1,0(WRKRG3)   SAVE RCD LNG IN V-FIELD              52900019
NORCFM3  ST    WRKRG3,WRKSVLZJ     SAVE RCD ADDR IN PARM LIST           53000019
         LTR   RTCDRG,RTCDRG       ARE TO PASS RCD                      53100019
         BNZ   NOFORMAT            BYPASS RCD                           53200019
RETURN   LA    WRKRG3,WRKSVLZJ     POINT TO PARMLIST                    53300019
         ST    WRKRG3,24(SAVERG)   AND SAVE                             53400019
RETURNX  LM    RETRNRG,BASERG,12(SAVERG) RESTORE USERS REGS             53500019
         BR    RETRNRG                                                  53600019
PTINPUT  L     PARMRG1,WRKNXAVI    POINT TO                             53700019
         LA    PARMRG1,1(PARMRG1)  NEXT BYTE                            53800019
         ST    PARMRG1,WRKNXAVI    IN INPUT                             53900019
SVSCBST  ST    PARMRG1,WRKFBSCN    SAVE SCAN START ADDR                 54000019
CKINPUT  C     PARMRG1,WRKENIPT    ANY BYTES LEFT IN INPUT              54100019
         BNL   IPTBSC              BR IF NO                             54200019
         TM    WRKEDSW2,HEX04      WAS BSC END CHAR FOUND               54300019
         BO    IPTBSC              BR IF YES                            54400019
         OI    WRKEDSW2,HEX08           INPUT NOT EMPTY          A35755 54450020
         MVI   19(SAVERG),HEX04    INDICATE INPUT NOT EMPTY RCD AVAIL   54500019
         BR    LNKRG8              RETURN TO CALLING ROUTINE            54600019
IPTBSC   NI    WRKEDSW2,HEXFB      RESET BSC END CHAR FOUND SW          54700019
         TM    WRKEDSW1,HEX08      SOR EXPECTED                         54800019
         BO    CKBTAMBF                                                 54900019
         OI    WRKEDSW2,HEX01      IND PARTIAL RCD                      55000019
CKBTAMBF TM    EDTTYPSW,HEX10      ARE USING BTAM BUFFERS               55100019
         BZ    NOBUF2              BR IF NO                             55200019
         L     PARMRG1,WRKADNXB    GET PTR TO NEXT BUFFER IN CHAIN      55300019
         LTR   PARMRG1,PARMRG1     ARE ANY MORE BUFFERS IN CHAIN        55400019
         BZ    NOBUF2              BR IF NO                             55500019
         NI    WRKEDSW2,HEXF7      IND BUFFER EMPTY                     55600019
         TM    WRKEDSW2,HEX01      IS THIS A PARTIAL RCD                55700019
         BO    GETBUF              BR IF YES                            55800019
         MVI   19(SAVERG),HEX04    IND IPT NOT EMPTY RCD NOT AVAIL      55900019
         BR    LNKRG8              RETURN TO CALLING RTN                56000019
NOBUF2   NI    WRKEDSW2,HEXF7      INDICATE INPUT EMPTY                 56100019
         MVI   19(SAVERG),HEX00    IND IPT EMPTY RCD AVAIL              56200019
         TM    WRKEDSW1,HEX08      SOR EXPECTED                         56300019
         BCR   1,LNKRG8                                                 56400019
         MVI   19(SAVERG),HEX08    IND INPUT EMPTY RCD NOT AVAIL        56500019
         BR    LNKRG8              RETURN TO CALLING RTN                56600019
*                                                                       56700019
* * *  REGISTER EQUATES * * *                                           56800019
*                                                                       56900019
PARMRG0  EQU   0                                                        57000019
PARMRG1  EQU   1                                                        57100019
WRKRG2   EQU   2                                                        57200019
WRKRG3   EQU   3                                                        57300019
WRKRG4   EQU   4                                                        57400019
WRKRG5   EQU   5                                                        57500019
WRKRG6   EQU   6                                                        57600019
WRKRG7   EQU   7                                                        57700019
LNKRG8   EQU   8                                                        57800019
WRKSTRG  EQU   9                                                        57900019
EDTPRMRG EQU   10                                                       58000019
PRMLSTRG EQU   11                                                       58100019
BASERG   EQU   12                                                       58200019
SAVERG   EQU   13                                                       58300019
RETRNRG  EQU   14                                                       58400019
RTCDRG   EQU   15                                                       58500019
*                                                                       58600019
* * *  EQUATES USED AS CONSTANTS  * * *                                 58700019
*                                                                       58800019
HEX00    EQU   X'00'                                                    58900019
HEX01    EQU   X'01'                                                    59000019
HEX02    EQU   X'02'                                                    59100019
HEX03    EQU   X'03'                                                    59200019
HEX04    EQU   X'04'                                                    59300019
HEX08    EQU   X'08'                                                    59400019
HEX0A    EQU   X'0A'                                                    59500019
HEX0C    EQU   X'0C'                                                    59600019
HEX10    EQU   X'10'                                                    59700019
HEX20    EQU   X'20'                                                    59800019
HEX40    EQU   X'40'                                                    59900019
HEX80    EQU   X'80'                                                    60000019
DLE      EQU   X'10'                                                    60100019
STX      EQU   X'02'                                                    60200019
HEXF7    EQU   X'F7'                                                    60300019
HEX71    EQU   X'71'                                                    60400019
HEX78    EQU   X'78'                                                    60500019
HEXCAN   EQU   X'18'                                                    60600019
HEXGS    EQU   X'1D'                                                    60700019
HEX0E    EQU   X'0E'                                                    60800019
HEX82    EQU   X'82'                                                    60900019
HEXF0    EQU   X'F0'                                                    61000019
HEXLZF   EQU   X'00'                                                    61100019
HEX9F    EQU   X'9F'                                                    61200019
CRM      EQU   C'U'                                                     61300019
HEX7F    EQU   X'7F'                                                    61400019
CVOK     EQU   C'V'                                                     61500019
HEX0F    EQU   X'0F'                                                    61600019
CHE      EQU   C'E'                                                     61700019
HEX3F    EQU   X'3F'                                                    61800019
CHAR0    EQU   C'0'                                                     61900019
CHAR1    EQU   C'1'                                                     62000019
CHAR2    EQU   C'2'                                                     62100019
HEXFE    EQU   X'FE'                                                    62200019
HEXFB    EQU   X'FB'                                                    62300019
HEXDUP   EQU   X'11'                                                    62400019
ETB      EQU   X'26'                                                    62500019
HEX19    EQU   X'19'                                                    62600019
HEXVOK   EQU   X'1E'                                                    62700019
HEXRM    EQU   X'3C'                                                    62800019
HEX12    EQU   X'12'                                                    62900019
HEX88    EQU   X'88'                                                    63000019
HEX16    EQU   X'16'                                                    63100019
HEXBF    EQU   X'BF'                                                    63200019
HEXEF    EQU   X'EF'                                                    63300019
*                                                                       63400019
* * *  CONSTANTS  * * *                                                 63500019
*                                                                       63600019
LGT256   DC    F'256'                                                   63700019
TWOOH    DC    H'20'                                                    63800019
HLF15    DC    H'15'                                                    63900019
THREE    DC    H'3'                                                     64000019
TREDW    DC    C'01234567'         USED TO MAKE EDW                     64100019
         DC    C'89ABCDEF'         PRINTABLE                            64200019
CHAR00   DC    C'00'                                                    64300019
MOVESCND MVC   0(0,WRKRG5),0(WRKRG7) USED BY EXECUTE IN MOVE RTN        64400019
*                                                                       64500019
* * *  TRANSLATE AND TEST TABLE  * * *                                  64600019
*                                                                       64700019
TRNSTBLE DC    256X'00'                                                 64800019
         ORG   TRNSTBLE+HEXLZF                                          64900019
         DC    X'04' *             LEFT ZERO FILL                       65000019
         ORG   TRNSTBLE+HEXDUP                                          65100019
         DC    X'08'               DUP                                  65200019
         ORG   TRNSTBLE+HEX12                                           65300019
         DC    X'0C'               LEFT ZERO START                      65400019
         ORG   TRNSTBLE+HEXCAN                                          65500019
         DC    X'10'               CANCEL                               65600019
         ORG   TRNSTBLE+HEX0C                                           65700019
         DC    X'14'               GROUP SEPARATOR                      65800019
         ORG   TRNSTBLE+ETB                                             65900019
         DC    X'18'               ETB                                  66000019
         ORG   TRNSTBLE+HEX03                                           66100019
         DC    X'18'               ETX                                  66200019
         ORG   TRNSTBLE+HEX3F                                           66300019
         DC    X'1C'               DATA CHECK                           66400019
         ORG   TRNSTBLE+HEX19                                           66500019
         DC    X'20'               END DATA                             66600019
         ORG   TRNSTBLE+HEXVOK                                          66700019
         DC    X'24'               VERIFY OK                            66800019
         ORG   TRNSTBLE+HEXRM                                           66900019
         DC    X'24'               RECORD MARK                          67000019
         ORG   TRNSTBLE+HEX71                                           67100019
         DC    8X'28'              PROGRAM LEVEL 1-8                    67200019
         ORG                                                            67300019
PARMLIST DSECT                                                          67400019
PRMINPUT DS    A *                 ADDR OF INPUT                        67500019
PRMIPTLN DS    A *                 LENGTH OF INPUT                      67600019
PRMWRKAD DS    A *                 ADDR OF WORK AREA                    67700019
PRMMXRCL DS    A *                 MAXIMUM RECORD LENGTH                67800019
EDITPARM DSECT                                                          67900019
EDTTYPSW DS    B *                 EDIT SWS INDICATING USER OPTIONS     68000019
EDTREPCR DS    X *                 REPLACE CHARACTER                    68100019
EDTMINLN DS    H *                 MINIMUN ACCEPTABLE RECORD LENGTH     68200019
EDTUSRXT DS    V *                 USER ERROR EXIT ROUTINE              68300019
WORKSTOR DSECT                                                          68400019
WRKADRRC DS    A *                 ADDR OF RECORD                       68500019
WRKADNXB DS    A *                 POINTER TO NEXT BUFFER               68600019
WRKENWRK DS    A *                 PTR TO END OF WORK + 1               68700019
WRKNXAVW DS    A *                 PTR TO NEXT AVAIL IN WORK AREA       68800019
WRKNXAVI DS    A *                 PTR TO NEXT AVAIL IN INPUT           68900019
WRKENIPT DS    A *                 PTR TO END OF INPUT + 1              69000019
WRKFBSCN DS    A *                 PTR TO FIRST BYTE SCANNED            69100019
WRKENSCN DS    A *                 PTR TO LAST BYTE SCANNED             69200019
WRKLDBPV DS    A *                 PTR TO LAST DATA BYTE OF PREV RCD    69300019
WRKFBLZF DS    A *                 PTR TO FIRST BYTE OF LZ FIELD        69400019
WRKSVLZJ DS    4F *                SAVE AREA FOR LZ JUSTIFICATION RTN   69500019
WRKSVEDW DS    F *                 ERROR DESCRIPTION WORD               69600019
         ORG   WRKSVEDW *                                               69700019
WRKLEVST DS    C *                 LEVEL STATUS                         69800019
WRKTYPST DS    B *                 TYPE STATUS                          69900019
WRKSORSV DS    X *                 SOR                                  70000019
WRKEORSV DS    X *                 EOR                                  70100019
WRKSVPGL DS    8H *                SAVE AREA FOR LNG OF PGM LEVEL CODES 70200019
WRKLZFCT DS    H *                 COUNT OF LZ FILL CHARS               70300019
         SPACE 1                                                        70400019
*      THE BITS IN WRKEDSW1 ARE USED AS FOLLOWS                         70500019
*      BIT 0  ON INDICATES DELETE THIS RECORD                           70600019
*      BIT 1  ON INDICATES LEFT ZERO START CODE FOUND                   70700019
*      BIT 2  ON INDICATES END OF LEFT ZERO FIELD FOUND                 70800019
*      BIT 3  ON INDICATES ALL SCANNED NOT FIT IN WORK AREA             70900019
*      BIT 4  ON INDICATES SOR CHARACTER EXPECTED                       71000019
*      BIT 5  ON INDICATES END OF RECORD FORCED                         71100019
*      BIT 6  ON INDICATES DUP NOT ALLOWED IN THIS RECORD               71200019
*      BIT 7  ON INDICATES DUP FOUND IN THIS RECORD                     71300019
WRKEDSW1 DS    B *                 EDIT SWITCHES                        71400019
         SPACE 1                                                        71500019
*      THE BITS IN WRKEDSW2 ARE USED AS FOLLOWS                         71600019
*      BITS 0-3  RESERVED                                               71700019
*      BIT 4  ON INDICATES INPUT IS NOT EMPTY                           71800019
*     BIT 5 ON INDICATES BSC END CHARACTER FOUND                        71900019
*      BIT 6  ON INDICATES DOUBLE DATA CHECK FOUND IN THIS RECORD       72000019
*      BIT 7  ON INDICATES THIS RECORD IS A PARTIAL RECORD              72100019
WRKEDSW2 DS    B *                 EDIT SWITCH                          72200019
WRKLNGSV DS    F *                 SAVE FOR LENGTH OF WORK AREA         72300019
WRKMACSV DS    F *                 BEGIN OF SAVE AREA IF PRESENT        72400019
         END                                                            72500019
