         TITLE 'IECTLERP - BTAM LINE ERROR PRINT ROUTINE'               00020000
IECTLERP CSECT                                                          00040000
         SPACE 2                                                        00060000
* STATUS -          CHANGE LEVEL 000    JANUARY 16, 1967                00080000
         SPACE 2                                                        00100000
*********************************************************************** 00120000
*                                                                     * 00140000
*        LINE ERROR RECORDING PRINT ROUTINE (LERPRT)                  * 00160000
*                                                                     * 00180000
* FUNCTION -        THIS ROUTINE PRINTS LINE ERROR DATA FOR THE       * 00190021
*                   FOLLOWING -                                       * 00200021
*                                                                     * 00210021
*                     1. DATA CHECK ERRORS                            * 00220021
*                     2. INTERVENTION REQUIRED ERRORS                 * 00230021
*                     3. TIME OUT ERRORS                              * 00240021
*                                                                     * 00250021
* ENTRY -           FIRST EXECUTABLE INSTRUCTION                      * 00260021
*                                                                     * 00270021
* INPUT -           1. REGISTER 0 CONTAINS THE RELATIVE LINE NUMBER.  * 00280021
*                      IF REGISTER 0=0,ALL LINES ASSOCIATED WITH THE  * 00290021
*                      LINE GROUP WILL BE PRINTED.                    * 00300021
*                   2. REGISTER 1 CONTAINS A POINTER TO THE ASSOCIATED* 00310021
*                      LINE GROUP DATA CONTROL BLOCK.                 * 00320021
*                                                                     * 00330021
* OUTPUT -          LINE ERROR MESSAGES TO THE OPERATOR CONSOLE       * 00340021
*                                                                     * 00350021
* EXTERNAL ROUTINE - SVC 35 - WRITE TO OPERATOR                       * 00360021
*                                                                     * 00370021
* EXIT -            RETURN TO USER VIA REGISTER 14                    * 00380021
*                                                                     * 00390021
* ATTRIBUTES -      THIS ROUTINE IS REENTRANT.                        * 00400021
*                                                                     * 00500000
*********************************************************************** 00520000
         USING *,BASREG                                                 00540000
         STM   LNKREG,CLRREG,12(SAVREG) SAVE PROBLEM PROG REGS          00560000
         SR    CLRREG,CLRREG           CLEAR REGISTER            A27630 00570019
         LTR   PARRG1,PARRG1           TEST REGISTER U FOR POS   A27630 00580019
         BP    NOCOMPL                 BRANCH IF YES             A27630 00590019
         LA    CLRREG,1                IF NO, CLEAR=YES          A27630 00600019
         LCR   PARRG1,PARRG1           CONVERT TO POSITIVE ADDRESS27630 00610019
NOCOMPL  TM    DCBERROP(PARRG1),DCBLECT LINE ERROR RECORDING SPECA27630 00620019
         BZ    LERPRT11                NO EXIT                   A27630 00630019
         L     DEBREG,DCBDEBAD(PARRG1)  ADDRESS OF DEB                  00700000
         LA    PTRREG,DEBUCBAD-4(DEBREG) ADDRESS OF FIRST UCB POINTER-4 00720000
         SR    LERBRG,LERBRG            INITIALIZE LERB REGISTER        00740000
         LTR   RLNREG,PARRG0            CHECK FOR RELATIVE LINE PRINT   00760000
         BZ    LERPRT00                 LINE GROUP PRINT REQUIRED       00780000
         BCTR  RLNREG,PARRG0            ADJUST RLN FOR FACTORING        00800000
         LR    LERBRG,RLNREG            FACTOR TO MULTIPLY REG          00820000
         MH    LERBRG,LERPCN20          RESOLVE LERB INDEX              00840000
         SLL   RLNREG,2                 RESOLVE UCB INDEX               00860000
         LA    LNCTRG,1                 SET TO PRINT ONE LINE           00880000
         B     LERPRT01                 PRINT RELATIVE LINE             00900000
LERPRT00 SR    LNCTRG,LNCTRG            LINE GROUP PRINT ROUTINE SETUP  00920000
         IC    LNCTRG,DEBNMEXT(DEBREG)  NUMBER OF LINES TO BE PRINTED   00940000
LERPRT01 A     LERBRG,DCBLERB(PARRG1)   ADDRESS OF LERB BLOCKS          00960000
         SH    LERBRG,LERPCN20          ADJUST FOR PRINT ROUTINE        00980000
         AR    PTRREG,RLNREG            ADJUST UCB POINTER TO FIRST ENT 01000000
LERPRT02 AH    LERBRG,LERPCN20          STEP LERB POINTER TO NEXT ENTRY 01020000
         LA    PTRREG,4(PTRREG)         STEP UCB POINTER TO NEXT ENTRY  01040000
         L     WRKREG,0(LERBRG)         TOTAL NUMBER OF TRANSMISSIONS   01060000
         SR    CNTREG,CNTREG            INITIALIZE IC REGISTER          01080000
         IC    CNTREG,LERBTHCT(LERBRG)  PICK UP THRESHOLD COUNT         01100000
         AR    WRKREG,CNTREG            NEW COUNT                       01120000
         ST    WRKREG,0(LERBRG)         UPDATE TOTAL COUNTER            01140000
         CVD   WRKREG,LERPDBWD                                          01160000
         UNPK  OUTMSG03+6(8),LERPDBWD+3(5) MOVE INTO MSG IN ZONE FORMAT 01180000
         OI    OUTMSG03+13,MASK3        MASK OUT SIGN                   01200000
         LH    WRKREG,LERBDCTC(LERBRG)  PICK UP TOTAL DATA CHECK COUNT  01220000
         IC    CNTREG,LERBDCNC(LERBRG)  PICK UP DATA CHECK NEW COUNT    01240000
         AR    WRKREG,CNTREG            NEW TOTAL                       01260000
         STH   WRKREG,LERBDCTC(LERBRG)  UPDATE TOTAL COUNTER            01280000
         CVD   WRKREG,LERPDBWD                                          01300000
         UNPK  OUTMSG04+3(5),LERPDBWD+5(3) MOVE MSG INTO  AREA W/ZONES  01320000
         OI    OUTMSG04+7,MASK3         MASK OUT SIGN                   01340000
LERPRT04 LH    WRKREG,LERBIRTC(LERBRG)  PICK UP OLD TOTAL COUNT         01360000
         IC    CNTREG,LERBIRNC(LERBRG)  PICK UP NEW COUNT               01380000
         AR    WRKREG,CNTREG            NEW TOTAL                       01400000
         STH   WRKREG,LERBIRTC(LERBRG)  UPDATE TOTAL COUNTER            01420000
         CVD   WRKREG,LERPDBWD                                          01440000
         UNPK  OUTMSG05+3(5),LERPDBWD+5(3) MOVE COUNT TO MSG WITH ZONES 01460000
         OI    OUTMSG05+7,MASK3         MASK OUT SIGN                   01480000
LERPRT06 LH    WRKREG,LERBTOTC(LERBRG)  TIME OUT TOTAL COUNT            01500000
         IC    CNTREG,LERBTONC(LERBRG)  TIME OUT NEW COUNT              01520000
         AR    WRKREG,CNTREG            NEW TOTAL                       01540000
         STH   WRKREG,LERBTOTC(LERBRG)  UPDATE TOTAL COUNTER            01560000
         CVD   WRKREG,LERPDBWD                                          01580000
         UNPK  OUTMSG06+3(5),LERPDBWD+5(3) PUT COUNT INTO MSG WITH ZONE 01600000
         OI    OUTMSG06+7,MASK3         MASK OUT SIGN                   01620000
         XC    LERBTHCT(4,LERBRG),LERBTHCT(LERBRG) CLEAR INTERIM CTRS   01640000
         L     WRKREG,0(PTRREG)         ADDRESS OF UCB                  01660000
         MVC   OUTMSG02(3),UCBNAME(WRKREG) MOVE IN LINE ADDRESS         01680000
         LR    WRKREG,BASREG            SAVE BASE                       01700000
         LR    CNTREG,PARRG1            SAVE PARAMETER REGISTER         01720000
         LR    PARRG0,PARRG1           CONSOLE ID TO R0          A29589 01722019
         SRL   PARRG0,24               NOW TO LOW ORDER BYTE     A29589 01724019
         LTR   PARRG0,PARRG0           SEE IF MCS FLAGS SHOULD   A29589 01726019
*                                      BE CHANGED                A29589 01728019
         BZ    LERPRT12                NO                        A29589 01730019
         MVI   MSGAREA+2,X'40'         CHANGE MCS FLAGS SO THAT  A29589 01732019
*                                      LERB IS SENT TO REQUESTINGA29589 01734019
*                                      CONSOLE                   A29589 01736019
LERPRT12 EQU   *                                                 A29589 01738019
         LA    PARRG1,MSGAREA           WTO PARAMETER VALUE             01740000
         WTO   MF=(E,(1))               WRITE MESSAGE                   01760000
         LR    BASREG,WRKREG            RESTORE BASE                    01780000
         LR    PARRG1,CNTREG            RESTORE PARAMETER REG           01800000
LERPRT09 LTR   CLRREG,CLRREG            COUNTER CLEAR REQUIRED          01820000
         BZ    LERPRT10                 NO EXIT                         01840000
         MVI   0(LERBRG),NONAME         READY TO CLEAR COUNTERS         01860000
         MVC   1(13,LERBRG),0(LERBRG)   CLEAR}                          01880000
LERPRT10 BCT   LNCTRG,LERPRT02          BRANCH IF MORE LINES TO PROCESS 01900000
LERPRT11 EQU   *                                                        01920000
         LM    LNKREG,CLRREG,12(SAVREG) RESTORE PROBLEM PROG REGISTERS  01940000
         BR    LNKREG                   RETURN                          01960000
LERPDBWD DC    D'0'                                                     01980000
MSGAREA  WTO   'IEC802I     LINE TOTALS TRANS=         DC=      IR=    X02000018
                 TO=      ',MF=L,ROUTCDE=(8),DESC=(4)              000H 02020018
OUTMSG02 EQU   MSGAREA+12                                          000H 02040018
OUTMSG03 EQU   MSGAREA+28                                          000H 02060018
OUTMSG04 EQU   MSGAREA+43                                          000H 02080018
OUTMSG05 EQU   MSGAREA+52                                          000H 02100018
OUTMSG06 EQU   MSGAREA+61                                          000H 02120018
LERPCN20 DC    AL2(20)                                                  02140000
COUNTSW  DC    X'00'                                                    02160000
DCBDEBAD EQU   44                                                       02180000
DCBERROP EQU   33                                                       02200000
DCBLECT  EQU   X'08'                                                    02220000
DEBUCBAD EQU   32                                                       02240000
DEBNMEXT EQU   16                                                       02260000
DCBLERB  EQU   52                                                       02280000
LERBTHCT EQU   10                                                       02300000
LERBDCTC EQU   4                                                        02320000
UCBNAME  EQU   13                                                       02340000
LERBDCNC EQU   11                                                       02360000
LINEACT  EQU   X'10'                                                    02380000
MASK3    EQU   X'F0'                                                    02400000
LERBIRTC EQU   6                                                        02420000
LERBIRNC EQU   12                                                       02440000
LERBTOTC EQU   8                                                        02460000
LERBTONC EQU   13                                                       02480000
MASKALL  EQU   255                                                      02500000
NONAME   EQU   0                                                        02520000
PARRG0   EQU   0                                                        02540000
PARRG1   EQU   1                                                        02560000
DEBREG   EQU   2                                                        02580000
LNCTRG   EQU   3                                                        02600000
PTRREG   EQU   4                                                        02620000
UCBREG   EQU   5                                                        02640000
RLNREG   EQU   6                                                        02660000
LERBRG   EQU   7                                                        02680000
WRKREG   EQU   8                                                        02700000
CNTREG   EQU   9                                                        02720000
CLRREG   EQU   10                                                       02740000
SAVREG   EQU   13                                                       02760000
LNKREG   EQU   14                                                       02780000
BASREG   EQU   15                                                       02800000
         END                                                            02820000
