         TITLE 'IECTSVC - BTAM LOCAL 3270 SUPPORTING SVC LOGIC'         00100021
IECTSVC  CSECT                                                          00300021
         ENTRY IECTRDIL,IECTATRL,IECTCHSL,IECTCHAL,IECTRSTL             00600021
*                                                                       00900021
* STATUS- CHANGE LEVEL 000                                              01200021
*                                                                       01500021
* FUNCTION- 1. TEST FOR AN OUTSTANDING ATTENTION ON A LINE GROUP AND    01800021
*    QUEUE THE READ INITIAL IF NO ATTENTION EXISTS (IECTRDIL).          02100021
*                                                                       02400021
*         2. RESET ATTENTION STATUS FLAG FOR A DEVICE AND UPDATE THE    02700021
*    LINE GROUP'S ATTENTION COUNT (IECTATRL).                           03000021
*                                                                       03300021
*         3. SET THE SKIP FLAG FOR A DEVICE TO INHIBIT PERFORMING READ  03600021
*    INITIAL OPERATIONS ON THAT DEVICE (IECTCHSL).                      03900021
*                                                                       04200021
*         4. RESET THE SKIP FLAG FOR A DEVICE TO PERMIT PERFORMING READ 04500021
*    INITIAL OPERATIONS ON THAT DEVICE (IECTCHAL).                      04800021
*                                                                       05100021
*         5. DEQUEUE A QUEUED READ INITIAL OPERATION (IECTRSTL).        05400021
*                                                                       05700021
* ENTRY POINTS- 1. IECTRDIL FROM SVC 116 IF THE ROUTING CODE WAS 0.     06000021
*                                                                       06300021
*         2. IECTATRL FROM SVC 116 IF THE ROUTING CODE WAS 1.           06600021
*                                                                       06900021
*         3. IECTCHSL FROM SVC 116 IF THE ROUTING CODE WAS 2.           07200021
*                                                                       07500021
*         4. IECTCHAL FROM SVC 116 IF THE ROUTING CODE WAS 3.           07800021
*                                                                       08100021
*         5. IECTRSTL FROM SVC 116 IF THE ROUTING CODE WAS 4.           08400021
*                                                                       08700021
* INPUT-  1. REGISTER 15 CONTAINS THE ROUTING CODE ON ENTRY TO SVC 116. 09000021
*         2. REGISTER  0 CONTAINS THE ADDRESS OF THE DECB FOR IECTRSTL  09300021
*    AND ZERO IN ALL OTHER CASES                                        09600021
*         3. REGISTER  1 CONTAINS THE ADDRESS OF THE UCB FOR THE RLN    09900021
*    SPECIFIED OR IMPLIED                                               10200021
*         4. REGISTER 14 CONTAINS THE ADDRESS OF THE TYPE 1 SVC EXIT    10500021
*    ROUTINE.                                                           10800021
*                                                                       11100021
* OUTPUT- 1. UPDATED ATTENTION FLAGS IN THE UCB'S FOR THE DEVICE AND    11400021
*    LINE GROUP.                                                        11700021
*         2. A RETURN CODE IN REGISTER 15.                              12000021
*                                                                       12300021
* EXITS,NORMAL- BR 14 TO THE TYPE 1 SVC EXIT ROUTINE.                   12600021
*                                                                       12900021
* EXITS,ERROR-  BR 14 TO THE TYPE 1 SVC EXIT ROUTINE.                   13200021
*                                                                       13500021
* TABLES/WORK AREAS- NONE                                               13800021
*                                                                       14100021
* ATTRIBUTES- NUCLEUS RESIDENT, DISABLED, SUPERVISOR PROTECT KEY, READ  14400021
*    ONLY, TYPE 1 SVC INITIATED FUNCTION.                               14700021
*                                                                       15000021
         EJECT                                                          15003021
         EJECT                                                          15246021
* CHARACTER CODE DEPENDENCY- N/A                                        15300021
*                                                                       15600021
* NOTES- THIS ROUTINE MANIPULATES ATTENTION HANDLING FLAGS IN THE UCB'S 15900021
*    FOR LOCAL 3270 DEVICES SUPPORTED UNDER BTAM.  USER REGISTERS 2-14  16200021
*    ARE SAVED BY SVC FLIH AND RESTORED ON RETURN TO THE USER.          16500021
*                                                                       16800021
         EJECT                                                          16803021
*/*IECTSVC: CHART */                                                    16806021
*/* HEADER                                                              16809021
*/*LOGIC MODULE FOR ESR ROUTING CODES 0 THROUGH 4                       16812021
*/*BTAM 3270 ATTENTION HANDLING SUPPORTING SVC                      */  16815021
*/*IECTRDIL: E ENTRY FROM ESR */                                        16818021
*/* M ESTABLISH ADDRESSABILITY AND SAVE RETURN ADDR */                  16821021
*/* S UCBCHK: CHECK UCB ADDRESS FOR VALIDITY */                         16824021
*/* D (YES,,NO,RC8) UCB VALID? */                                       16827021
*/* D (YES,,NO,RC0) ATTENTION COUNT IS ZERO? */                         16830021
*/* D (YES,,NO,CONTRDTI) BTAM READY PROCESSING ? */                     16832021
*/* D (YES,RDYPROC,NO,) READY IN LINE GROUP ? */                        16834021
*/*CONTRDTI: P SET READ INITIAL PENDING FLAG */                         16834421
*/* P (,RC4) SAVE RLN OF INITIALIZED IOB */                             16836021
*/*RDYPROC: P SET READ INITIAL PENDING FLAG */                          16838021
*/* P (,RCC) SAVE RLN IN MASTER, SET READY NOT DONE IN MASTER */        16838421
*/*IECTATRL: E ENTRY FROM ESR */                                        16839021
*/* M ESTABLISH ADDRESSABILITY AND SAVE RETURN ADDR */                  16842021
*/* S UCBCHK: CHECK UCB ADDRESS FOR VALIDITY */                         16845021
*/* D (YES,,NO,RC4) UCB VALID? */                                       16848021
*/* D (YE>,,NO,RDYCHKT) ATTN FLAG SET ? */                              16850021
*/* D (YES,RDYCHKT,NO,) PROCESSING READY ? */                           16852021
*/* P RESET THE ATTENTION FLAG */                                       16854021
*/* D (NO,,YES,RC0) SKIP FLAG SET? */                                   16857021
*/* P (,RC0) DECREMENT ATTENTION COUNT FOR LINE GROUP BY 1 */           16860021
*/*RDYCHKT: D (YES,,NO,RC4) USING BTAM'S READY ROUTINE ? */             16862021
*/*RDYCHK: D (YES,,NO,RC0) READY NOT DONE FLAG ON ? */                  16864021
*/* L (,RC0) INVOKE POST TO RESETPL THE READ */                         16866021
*/*IECTCHSL: E ENTRY FROM ESR */                                        16870621
*/* M ESTABLISH ADDRESSABILITY AND SAVE RETURN ADDR */                  16874321
*/* S UCBCHK: CHECK UCB ADDRESS FOR VALIDITY */                         16878021
*/* D (YES,,NO,RC8) UCB VALID? */                                       16881721
*/* D (NO,,YES,RC0) SKIP FLAG SET? */                                   16885421
*/* P SET THE SKIP FLAG */                                              16889121
*/* D (YES,,NO,RC0) ATTENTION FLAG SET */                               16892821
*/* P (,RC0) DECREMENT ATTENTION COUNT FOR LINE GROUP BY 1 */           16896521
*/*IECTCHAL: E ENTRY FROM ESR */                                        16900221
*/* M ESTABLISH ADDRESSABILITY AND SAVE RETURN ADDR */                  16903921
*/* S UCBCHK: CHECK UCB ADDRESS FOR VALIDITY */                         16907621
*/* D (YES,,NO,RC8) UCB VALID? */                                       16911321
*/* D (YES,,NO,RC0) SKIP FLAG SET? */                                   16915021
*/* P RESET THE SKIP FLAG */                                            16918721
*/* D (YES,,NO,RC0) ATTENTION FLAG SET? */                              16922421
*/* D (NO,,YES,SCHEDIQE) READ INITIAL PENDING? */                       16926121
*/* P (,RC0) INCREMENT ATTENTION COUNT FOR LINE GROUP BY 1 */           16929821
*/*SCHEDIQE: P RESET READ INITIAL PENDING AND ATTENTION FLAGS */        16933521
*/* P OBTAIN AND INITIALIZE IQE */                                      16937221
*/* L (,RC0) INVOKE AEE2 TO SCHEDULE READ */                            16940921
*/*IECTRSTL: E ENTRY FROM ESR */                                        16944621
*/* M ESTABLISH ADDRESSABILITY AND SAVE RETURN ADDR */                  16948321
*/* S UCBCHK: CHECK UCB ADDRESS FOR VALIDITY */                         16952021
*/* D (0,,4,RC8,8,RCC) TEST RETURN CODE */                              16955721
*/*RDTITST: D (YES,,NO,RC4) READ INITIAL PENDING? */                    16959421
*/* P RESET READ INITIAL PENDING FLAG */                                16963121
*/* P CLEAR INITIALIZED RLN FIELD */                                    16966821
*/* L (,RC0) POST USER'S ECB COMPLETE WITH X'48' CODE */                16970521
*/*RC0: P SET RETURN CODE OF 0 */                                       16974221
*/* R BR TO TYPE I SVC EXIT RTN */                                      16977921
*/*RC4: P SET RETURN CODE OF 4 */                                       16981621
*/* R BR TO TYPE I SVC EXIT RTN */                                      16985321
*/*RC8: P SET RETURN CODE OF 8 */                                       16989021
*/* R BR TO TYPE I SVC EXIT RTN */                                      16992721
*/*RCC: P SET RETURN CODE OF X'0C' */                                   16996421
*/* R BR TO TYPE I SVC EXIT RTN */                                      17000121
*/*IECTSVC: END */                                                      17003821
*/*UCBCHK: CHART */                                                     17007521
*/* HEADER                                                              17011221
*/*IECTSVC UCB VALIDITY CHECK SUBROUTINE                            */  17014921
*/*UCBCHK: E ENTRY */                                                   17018621
*/* M ESTABLISH ADDRESSABILITY FOR SUBROUTINE */                        17022321
*/* M ESTABLISH ADDRESSABILITY FOR DEVICE UCB */                        17026021
*/* D (YES,,NO,VCRC08) UCBID = X'FF'? */                                17029721
*/* D (YES,,NO,VCRC04) IS DEVICE A 3270 DEVICE? */                      17033421
*/* D (YES,,NO,VCRC08) IRB ADDRESS INITIALIZED? */                      17037121
*/* D (NO,,YES,RLNISONE) DEVICE UCB = MASTER UCB? */                    17040821
*/* M OBTAIN ADDRESS OF MASTER UCB FROM DEVICE UCB */                   17044521
*/*CHKMSTR: D (YES,,NO,VCRC08) UCBID OF MASTER UCB = X'FF'? */          17048221
*/* D (YES,,NO,VCRC04) IS MASTER DEVICE A 3270 DEVICE? */               17051921
*/* D (YES,,NO,VCRC08) IRB ADDR IN MASTER UCB NON-ZERO? */              17055621
*/* D (YES,,NO,VCRC08) BOTH UCB IRB ADDRESSES THE SAME? */              17059321
*/* D (YES,,NO,VCRC08) RLN IN MASTER UCB = 1? */                        17063021
*/*VCRC00:  P SET RETURN CODE OF ZERO */                                17066721
*/* R RETURN */                                                         17070421
*/*VCRC04: P SET RETURN CODE OF FOUR */                                 17074121
*/* R RETURN */                                                         17077821
*/*VCRC08: P SET RETURN CODE OF EIGHT */                                17081521
*/* R RETURN */                                                         17085221
*/*RLNISONE: P (,VCRC00) SET MASTER UCB = DEVICE UCB */                 17088921
*/*UCBCHK: END */                                                       17092621
         EJECT                                                          17096321
PARMREG2 EQU   0                    SECOND PARAMETER REGISTER           17100021
PARMREG1 EQU   1                    FIRST PARAMETER REGISTER            17400021
CVTREG   EQU   3                    POINTER TO CVT                      17700021
TCBREG   EQU   4                   POINTER TO TCB                       18000021
RTNREG   EQU   14                   RETURN POINT REGISTER               18300021
EPREG    EQU   15                   ENTRY POINT REGISTER                18600021
*                                                                       18900021
BASEREG  EQU   5                    BASE REGISTER FOR MAIN ROUTINE      19200021
SUBASREG EQU   10                   BASE REGISTER FOR SUB-ROUTINE       19500021
UCBREG   EQU   9                    BASE REGISTER FOR DEVICE UCB        19800021
MSTREG   EQU   8                    BASE REGISTER FOR MASTER UCB        20100021
IRBREG   EQU   7                    POINTER TO IRB                      20400021
IQEREG   EQU   6                    POINTER TO IQE                      20700021
*                                                                       21000021
SAVEREG  EQU   12                   SAVE REGISTER FOR REGISTER 14       21300021
WORKREG  EQU   2                    WORK REGISTER                       21600021
POSTCODE EQU   10                  COMPLETION CODE REG FOR POST         21900021
POSTECB  EQU   11                  ECB ADDR REG FOR POST                22200021
POSTTCB  EQU   12                  TCB ADDR REG FOR POST                22500021
*                                                                       22800021
XFF      EQU   X'FF'                VALID UCB ID BYTE                   23100021
GRPHCDVC EQU   X'10'                GRAPHICS DEVICE CLASS               23400021
DVC3277  EQU   X'09'                DEVICE TYPE FOR 3277 DISPLAY        23700021
DVC3286  EQU   X'0B'               DEVICE TYPE FOR 3286 PRINTER         24000021
*              X'0A'               DEVICE TYPE FOR 3284 PRINTER         24300021
ATTN     EQU   X'01'                ATTENTION FLAG                      24600021
SKIP     EQU   X'02'                SKIP FLAG                           24900021
READTI   EQU   X'04'                READ INITIAL PENDING FLAG           25200021
READY    EQU   X'20'               HAS COME READY FLAG        SB A57064 25210021
LINERDY  EQU   X'01'               MTR DEVICE IN GROUP READY  SB A57064 25220021
RDTIACTV EQU   X'08'                READ INITIAL REQUEST         A55715 25250021
*                                   OUTSTANDING                  A55715 25300021
RDYNDONE EQU   X'04'               INDICATE READY NOT DONE    SB A57064 25350021
RLN1     EQU   X'01'                RLN FOR RLN 1 OF LINE GROUP         25500021
AEE2AD   EQU   4                    DISP TO AEE2 EP IN CVT (CVT0EF00)   25800021
RBNEXAV  EQU   96                   DISP TO IQE POINTER IN IRB          26100021
IQEPARAM EQU   4                    DISP TO PARAMETER FIELD IN IQE      26400021
IGG019UP EQU   X'10'               USING BTAM EXIT ROUT       SB A57064 26450021
POSTAD   EQU   152                  DISP TO POST BR ENTRY IN CVT        26700021
DCBADDR  EQU   24                      DISP.TO DCBADDR           A61871 26800021
IOBADDR  EQU   28                      DISP.TO IOBADDR           A61871 26900021
*                                   (CVT0PT01)                          27000021
ZERO     EQU   X'00'                COMPARE VALUE OF 0                  27300021
ONE      EQU   X'01'                INCREMENT VALUE OF 1                27600021
FOUR     EQU   X'04'                RETURN CODE OF 4                    27900021
EIGHT    EQU   X'08'                RETURN CODE OF 8                    28200021
TWELVE   EQU   X'0C'                RETURN CODE OF X'0C'                28500021
SIXTEEN  EQU   X'10'               RETURN CODE X'10'          SB A57064 28550021
*                                                                       28800021
         USING UCB,UCBREG           ADDRESSABILITY FOR DEVICE UCB       29100021
         USING MSTRUCB,MSTREG       AND MASTER UCB                      29400021
*        READ INITIAL ATTENTION TEST                                    29700021
IECTRDIL LR    SAVEREG,RTNREG       SAVE RETURN ADDRESS                 30000021
         BALR  BASEREG,0            ESTABLISH BASE REGISTER             30300021
         USING *,BASEREG            AND ADDRESSABILITY                  30600021
*                                                                       30900021
         BAL   RTNREG,UCBCHK        CHECK UCB ADDRESS FOR VALIDITY      31200021
         LTR   EPREG,EPREG          UCB VALID                           31500021
         BNZ   RC8                  NO, RETURN WITH RETURN CODE OF 8    31800021
*                                                                       32100021
         OI    MTRGCB,RDTIACTV      NOTE READ INITIAL REQUEST    A55715 32150021
*                                    OUTSTANDING                 A55715 32200021
         CLI   MTRATNCT,ZERO        IS ATTENTION COUNT ZERO             32400021
         BNE   RC0                  NO, RETURN WITH RETURN CODE OF 0    32700021
*                                                                       33000021
         TM    UCBGRAF,IGG019UP    BTAM READY PROCESSING ?    SB A57064 33050021
         BNO   CONTRDTI            NO, DO READ TI             SB A57064 33100021
         TM    MTRGRAF,LINERDY     COME READY ?               SB A57064 33150021
         BO    RDYPROC             YES, PROCESS READY         SB A57064 33200021
CONTRDTI EQU   *                   COMPLETE RDTI              SB A57064 33250021
         OI    MTRGCB,READTI        SET READ INITIAL PENDING FLAG       33300021
         MVC   MTRINRLN(ONE),UCBRLN  MOVE RLN OF INITIALIZED LINE       33600021
         B     RC4                  RETURN WITH RETURN CODE OF 4        33900021
RDYPROC  EQU   *                   DEVICE READY               SB A57064 33950021
         OI    MTRGCB,READTI       SET PENDING FLAG           SB A57064 34000021
         MVC   MTRINRLN(ONE),UCBRLN MOVE RLN OF INIT LINE     SB A57064 34050021
         OI    MTRGRAF,RDYNDONE    SET NOT DONE IN UCB        SB A57064 34100021
         B     RCC                 GIVE RETURN 0C             SB A57064 34150021
         DROP  BASEREG                                                  34200021
*                                                                       34500021
*        RESET ATTENTION FLAG                                           34800021
IECTATRL LR    SAVEREG,RTNREG       SAVE RETURN ADDRESS                 35100021
         BALR  BASEREG,0            ESTABLISH BASE REGISTER             35400021
         USING *,BASEREG            AND ADDRESSABILITY                  35700021
ATRLBASE EQU   *                   ALLOW ADDRESSABILITY       SB A57064 35750021
*                                                                       36000021
         BAL   RTNREG,UCBCHK        CHECK UCB ADDRESS FOR VALIDITY      36300021
         LTR   EPREG,EPREG          UCB VALID                           36600021
         BNZ   RC4                  NO, GIVE RETURN CODE OF 4           36900021
*                                                                       37200021
         TM    UCBGCB,ATTN          ATTENTION FLAG SET                  37500021
         BZ    RDYCHKT              NO, SEE IF READY          SB A57064 37800021
         TM    MTRGRAF,RDYNDONE    READY NOT DONE FLAG ?      SB A57064 37850021
         BO    RDYCHKT             YES, PROCESS READY         SB A57064 37900021
         XI    UCBGCB,ATTN          YES, RESET THE ATTENTION FLAG       38100021
*                                                                       38400021
         TM    UCBGCB,SKIP          SKIP FLAG SET                       38700021
         BO    RC0                  YES, GIVE RETURN CODE OF 0          39000021
         SR    WORKREG,WORKREG                                          39300021
         IC    WORKREG,MTRATNCT     DECREMENT ATTENTION COUNT           39600021
         BCTR  WORKREG,0            FOR LINE GROUP BY 1                 39900021
         STC   WORKREG,MTRATNCT                                         40200021
         B     RC0                  GIVE RETURN CODE OF 0               40500021
RDYCHKT  EQU   *                   SEE IF BTAM                SB A57064 40510021
         TM    UCBGRAF,IGG019UP    USE BTAMS ?                SB A57064 40520021
         BNO   RC0                 NO, GIVE RETURN CODE 0     SB A57064 40530021
RDYCHK   EQU   *                   CHECK FOR READY            SB A57064 40550021
         TM    MTRGRAF,RDYNDONE    NOT DONE FLAG ?            SB A57064 40600021
         BZ    RC0                 NO, GIVE RETURN CODE 0     SB A57064 40650021
         LR    SUBASREG,BASEREG    ESTABLISH NEW BASE         SB A57064 40752021
         DROP  BASEREG             RELEASE OLD BASE           SB A57064 40802021
         USING ATRLBASE,SUBASREG   AND USE NEW BASE           SB A57064 40852021
         LA    BASEREG,RSTLBASE    ESTABLISH NEW ADDRESSABILITY  A57064 40902021
         B     POST48              GO POST READ               SB A57064 41002021
         DROP  SUBASREG            DROP ADDRESSABILITY        SB A57064 41052021
*                                                                       41100021
*        INHIBIT READ INITIALS ON A DEVICE                              41400021
IECTCHSL LR    SAVEREG,RTNREG       SAVE RETURN ADDRESS                 41700021
         BALR  BASEREG,0            ESTABLISH BASE REGISTER             42000021
         USING *,BASEREG            AND ADDRESSABILITY                  42300021
*                                                                       42600021
         BAL   RTNREG,UCBCHK        CHECK UCB ADDRESS FOR VALIDITY      42900021
         LTR   EPREG,EPREG          UCB VALID                           43200021
         BNZ   RC8                  NO, GIVE RETURN CODE OF 8           43500021
*                                                                       43800021
         TM    UCBGCB,SKIP          SKIP FLAG SET                       44100021
         BO    RC0                  YES, GIVE RETURN CODE OF 0          44400021
         OI    UCBGCB,SKIP          NO, SET THE SKIP FLAG               44700021
*                                                                       45000021
         TM    UCBGCB,ATTN          ATTENTION FLAG SET                  45300021
         BZ    RC0                  NO, GIVE RETURN CODE OF 0           45600021
         SR    WORKREG,WORKREG                                          45900021
         IC    WORKREG,MTRATNCT     DECREMENT ATTENTION COUNT           46200021
         BCTR  WORKREG,0            FOR LINE GROUP BY 1                 46500021
         STC   WORKREG,MTRATNCT                                         46800021
         B     RC0                  GIVE RETURN CODE OF 0               47100021
         DROP  BASEREG                                                  47400021
*                                                                       47700021
*        PERMIT READ INITIALS ON A DEVICE                               48000021
IECTCHAL LR    SAVEREG,RTNREG       SAVE RETURN ADDRESS                 48300021
         BALR  BASEREG,0            ESTABLISH BASE REGISTER             48600021
         USING *,BASEREG            AND ADDRESSABILITY                  48900021
*                                                                       49200021
         BAL   RTNREG,UCBCHK        CHECK UCB ADDRESS FOR VALIDITY      49500021
         LTR   EPREG,EPREG          UCB VALID                           49800021
         BNZ   RC8                  NO, GIVE RETURN CODE OF 8           50100021
*                                                                       50400021
         TM    UCBGCB,SKIP          SKIP FLAG SET                       50700021
         BZ    RC0                  NO, GIVE RETURN CODE OF 0           51000021
         XI    UCBGCB,SKIP          YES, RESET THE SKIP FLAG            51300021
*                                                                       51600021
         TM    UCBGCB,ATTN          ATTENTION FLAG SET                  51900021
         BZ    RC0                  NO, GIVE RETURN CODE OF 0           52200021
*                                                                       52500021
         TM    MTRGCB,READTI        READ INITIAL PENDING                52800021
         BO    SCHEDIQE             YES, SCHEDULE 2ND LEVEL ATTN. RTN   53100021
*                                   TO DO READ                          53400021
         SR    WORKREG,WORKREG      NO, INCREMENT ATTENTION COUNT       53700021
         IC    WORKREG,MTRATNCT     FOR LINE GROUP BY 1                 54000021
         LA    WORKREG,ONE(WORKREG)                                     54300021
         STC   WORKREG,MTRATNCT                                         54600021
         B     RC0                  GIVE RETURN CODE OF ZERO            54900021
*                                                                       55200021
SCHEDIQE XI    MTRGCB,READTI        RESET READ INITIAL PENDING FLAG     55500021
         XI    UCBGCB,ATTN          RESET ATTENTION FLAG                55800021
         L     IQEREG,RBNEXAV(IRBREG) GET ADDRESS OF IQE                56100021
         XC    RBNEXAV(FOUR,IRBREG),RBNEXAV(IRBREG)  CLEAR IQE LINK     56400021
         ST    UCBREG,IQEPARAM(IQEREG) STORE UCB ADDRESS IN IQE         56700021
         LNR   PARMREG1,IQEREG      PARM = COMPLEMENT OF IQE ADDR       57000021
         L     EPREG,AEE2AD(CVTREG) EP = AEE2                           57300021
         BALR  RTNREG,EPREG         SCHEDULE IQE                        57600021
         B     RC0                  GIVE RETURN CODE OF 0               57900021
*                                                                       58200021
*        DEQUEUE PENDING READ INITIAL                                   58500021
IECTRSTL LR    SAVEREG,RTNREG       SAVE RETURN ADDRESS                 58800021
         DROP  BASEREG                                                  59100021
         BALR  BASEREG,0            ESTABLISH BASE REGISTER             59400021
         USING *,BASEREG            AND ADDRESSABILITY                  59700021
RSTLBASE EQU   *                   ALLOW ADDRESSABILITY       SB A57064 59750021
*                                                                       60000021
         BAL   RTNREG,UCBCHK        CHECK UCB ADDRESS FOR VALIDITY      60300021
         B     RCTABLE(EPREG)       TEST RETURN CODE                    60600021
RCTABLE  B     RFTTEST                N 0, TEST FOR RFT MSG.     A61871 60900021
         B     RC8                  4, INVALID DVC- GIVE RC OF 8        61200021
         B     RCC                  8, INVALID UCB- GIVE RC OF X'0C'    61500021
*                                                                       61800021
RFTTEST  EQU   *                                                 A61871 61830021
         L     WORKREG,MTRDEBAD        GET DEB ADDR              A61871 61860021
         L     WORKREG,DCBADDR(WORKREG) GET DCB ADDR             A61871 61890021
         L     WORKREG,IOBADDR(WORKREG) GET IOB ADDR             A61871 61920021
         LA    WORKREG,88(WORKREG)     POINT TO 1ST IOB          A61871 61950021
         TM    28(WORKREG),X'01'       RFT IN PROGRESS           A61871 61980021
         BZ    RDTITST                 NO CONTINUE               A61871 62010021
         OI    1(WORKREG),X'01'        SET RESETPL FLAG          A61871 62040021
         B     RC0                                               A61871 62070021
RDTITST  TM    MTRGCB,RDTIACTV      READ INITIAL REQUEST         A55715 62100021
*                                   OUTSTANDING                  A55715 62150021
         BZ    RC10                RC=10                      SB A57064 62200021
         TM    MTRGCB,READTI        READ INIT PENDING            A55715 62250021
         BZ    RC4                  NO, GIVE RETURN CODE OF 4           62400021
*                                   (OPERATION IN PROGRESS)             62700021
POST48   EQU   *                                                 A61882 62750021
         NI    MTRGCB,X'FF'-RDTIACTV-READTI   YES, RESET READ    A55715 63000021
*                                   INITIAL PENDING AND OUT-     A55715 63300021
*                                   STANDING FLAGS               A55715 63400021
         TM    MTRGRAF,IGG019UP    BTAM READY ?               SB A57064 63450021
         BNO   CONTPOST            NO, DON'T DO READY CHECK   SB A57064 63500021
         TM    MTRGRAF,RDYNDONE    READY PROCESSING           SB A57064 63550021
         BNO   CONTPOST            NO, DON'T RESET FLAGS      SB A57064 63560021
         NI    MTRGRAF,X'FB'       TURN OFF READY NOT DONE    SB A57064 63570021
         NI    UCBGRAF,X'DB'       TURN OFF READY FLAG        SB A57064 63580021
         L     EPREG,MTRDEBAD      GET DEB ADDRESS            SB A57064 63582021
         LA    EPREG,0(EPREG)      CLEAR HIGH BYTE            SB A57064 63584021
         XR    POSTECB,POSTECB     CLEAR RLN REG              SB A57064 63586021
         IC    POSTECB,16(EPREG)   GET NUMBER EXTENTS         SB A57064 63588021
         XR    POSTCODE,POSTCODE   CLEAR INDEX REGISTER       SB A57064 63588421
READYLP  EQU   *                   CHECK UCB'S FOR READY      SB A57064 63588521
         L     PARMREG1,32(POSTCODE,EPREG) POINT TO UCB       SB A57064 63588821
         TM    28(PARMREG1),READY  COME READY                 SB A57064 63589221
         BO    CONTPOST            YES, DON'T TURN OFF        SB A57064 63589621
*                                  LINE READY IN MASTER       SB A57064 63589721
         LA    POSTCODE,4(POSTCODE) BUMP INDEX                SB A57064 63589821
         BCT   POSTECB,READYLP     CHECK IF MORE TO DO        SB A57064 63593221
         NI    MTRGRAF,X'FE'       TURN OFF LINE READY        SB A57064 63595221
CONTPOST EQU   *                   CONTINUE THE POST          SB A57064 63596721
         MVI   MTRINRLN,ZERO        CLEAR INITIALIZED RLN               63600021
*        SAVE CONTENTS OF REG 12 ACROSS CALL TO POST                    63900021
         LR    PARMREG1,SAVEREG    REG 1 IS SAVED BY POST               64200021
*        SET UP LINKAGE TO POST -- NON-STANDARD                         64500021
         L     POSTCODE,COMPCODE   REG 10 = COMPLETION CODE             64800021
         LR    POSTECB,PARMREG2    REG 11 = ECB ADDR                    65100021
         LA    POSTECB,0(POSTECB)  CLEAR HIGH ORDER BYTE         A66452 65150021
         LR    POSTTCB,TCBREG      REG 12 = TCB ADDR                    65400021
         L     EPREG,POSTAD(CVTREG) EP = POST                           65700021
         BALR  RTNREG,EPREG         POST USER'S ECB COMPLETE            66000021
         LR    SAVEREG,PARMREG1    RESTORE REG 12                       66300021
         B     RC0                  GIVE RETURN CODE OF 0               66600021
         DROP  BASEREG                                                  66900021
*                                                                       67200021
RC0      SR    EPREG,EPREG          SET REGISTER 15 = 0                 67500021
         LR    RTNREG,SAVEREG       EXIT RTN ADDRESS IN 14              67800021
         BR    RTNREG               BRANCH TO TYPE 1 EXIT RTN.          68100021
*                                                                       68400021
RC4      LA    EPREG,FOUR           SET RC = 4                          68700021
         LR    RTNREG,SAVEREG       EXIT RTN ADDR TO REG 14             69000021
         BR    RTNREG               BRANCH TO TYPE 1 EXIT RTN.          69300021
*                                                                       69600021
RC8      LA    EPREG,EIGHT          SET RC = 8                          69900021
         LR    RTNREG,SAVEREG       EXIT RTN ADDR TO REG 14             70200021
         BR    RTNREG               BRANCH TO TYPE 1 EXIT RTN.          70500021
*                                                                       70800021
RCC      LA    EPREG,TWELVE         SET RC = X'0C'                      71100021
         LR    RTNREG,SAVEREG       EXIT RTN ADDR TO REG 14             71400021
         BR    RTNREG               BRANCH TO TYPE 1 EXIT RTN.          71700021
*                                                                       72000021
RC10     LA    EPREG,SIXTEEN       SET RC = X'10'             SB A57064 72050021
         LR    RTNREG,SAVEREG      EXIT RTN ADDR TO REG 14    SB A57064 72100021
         BR    RTNREG              BRANCH TYPE 1 EXIT RTN     SB A57064 72150021
*                                                                       72200021
*        UCB VALIDITY CHECK ROUTINE                                     72300021
UCBCHK   BALR  SUBASREG,0           ADDRESSABILITY FOR                  72600021
         USING *,SUBASREG           VALIDITY SUBROUTINE                 72900021
         LR    UCBREG,PARMREG1      ADDRESSABILITY FOR UCB              73200021
*                                                                       73500021
         CLI   UCBID,XFF            UCBID = X'FF'                       73800021
         BNE   VCRC08               NO, GIVE RETURN CODE OF 8           74100021
*                                                                       74400021
         CLI   UCBDVCLS,GRPHCDVC    IS DEVICE A GRAPHICS DEVICE         74700021
         BNE   VCRC04               NO, GIVE RETURN CODE OF 4           75000021
         CLI   UCBUNTYP,DVC3277     DEVICE 3277 DISPLAY                 75300021
         BL    VCRC04              NO, GIVE RETURN CODE OF 4            75600021
         CLI   UCBUNTYP,DVC3286    DEVICE ANY OTHER 3270 DEVICE         75900021
         BH    VCRC04              NO, GIVE RETURN CODE OF 4            76200021
*                                                                       76500021
CHKIRB   L     IRBREG,UCBIRB        GET IRB ADDRESS                     76800021
         LA    IRBREG,0(IRBREG)    CLEAR GRAF FLAGS           SB A57064 76850021
         LTR   IRBREG,IRBREG        IS IT ZERO                          77100021
         BZ    VCRC08               YES, GIVE RETURN CODE OF 8          77400021
         CLI   UCBRLN,RLN1          DEVICE UCB = MASTER UCB             77700021
         BE    RLNISONE             YES, SET MASTER UCB BASE            78000021
         L     MSTREG,UCBCTLNK      GET ADDRESS OF MASTER UCB           78300021
*                                                                       78600021
CHKMSTR  CLI   MTRUCBID,XFF         UCBID OF MASTER UCB = X'FF'         78900021
         BNE   VCRC08               NO, GIVE RETURN CODE OF 8           79200021
*                                                                       79500021
         CLI   MTRDVCLS,GRPHCDVC    DEVICE A GRAPHICS DEVICE            79800021
         BNE   VCRC04               NO, GIVE RETURN CODE OF 4           80100021
         CLI   MTRUNTYP,DVC3277     DEVICE 3277 DISPLAY                 80400021
         BL    VCRC04              NO, GIVE RETURN CODE OF 4            80700021
         CLI   MTRUNTYP,DVC3286    DEVICE ANY OTHER 3270 DEVICE         81000021
         BH    VCRC04              NO, GIVE RETURN CODE OF 4            81300021
*                                                                       81600021
CHKIRB1  L     WORKREG,MTRIRB       GET IRB ADDRESS                     81900021
         LA    WORKREG,0(WORKREG)  CLEAR GRAF FLAGS           SB A57064 81950021
         LTR   WORKREG,WORKREG      IS IT ZERO                          82200021
         BZ    VCRC08               YES, GIVE RETURN CODE OF 8          82500021
         CR    WORKREG,IRBREG       EQUAL TO ADDRESS FROM DEVICE UCB    82800021
         BNE   VCRC08               NO, GIVE RETURN CODE OF 8           83100021
         CLI   MTRRLN,RLN1          RLN = 1                             83400021
         BNE   VCRC08               NO, GIVE RETURN CODE OF 8           83700021
*                                                                       84000021
VCRC00   SR    EPREG,EPREG          YES, GIVE RETURN CODE OF 0          84300021
         BR    RTNREG               AND RETURN                          84600021
*        INVALID DEVICE TYPE                                            84900021
VCRC04   LA    EPREG,FOUR           GIVE RETURN CODE OF 4               85200021
         BR    RTNREG               AND RETURN                          85500021
*        INVALID CONTROL BLOCK                                          85800021
VCRC08   LA    EPREG,EIGHT          GIVE RETURN CODE OF 8               86100021
         BR    RTNREG              AND RETURN                           86400021
*                                                                       86700021
RLNISONE LR    MSTREG,UCBREG        SET MASTER UCB = DEVICE UCB         87000021
         B     VCRC00               MASTER UCB OK. GIVE RETURN CODE 0   87300021
*                                                                       87600021
         DS    0F                                                       87900021
COMPCODE DC    X'48000000'         COMPLETION CODE FOR RESETPL          88200021
*                                                                       88500021
         IECTUCBX                                                       88800021
         END                                                            89100021
