         TITLE ' IGC1306F - 3270 LOCAL/REMOTE EBCDIC TEST MODULE '      00400021
IGC1306F CSECT                                                          00800021
*********************************************************************** 00806021
*             3270 LOCAL/REMOTE EBCDIC TEST MODULE                    * 00812021
*********************************************************************** 00818021
*                                                                     * 00824021
* STATUS:                                                             * 00830021
*    CHANGE LEVEL 000         NOVEMBER 5, 1971                        * 00836021
*                                                                     * 00842021
* FUNCTION:                                                           * 00848021
*    THIS MODULE BUILDS PREDEFINED EBCDIC ON-LINE TEST MESSAGES       * 00854021
*    FOR THE 3270 DISPLAY SYSTEM - LOCAL OR REMOTE.                   * 00860021
*                                                                     * 00866021
* ENTRY:                                                              * 00872021
*         ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION VIA XCTL       * 00878021
*         FROM IGC0D06F(REMOTE) OR IGC1206F(LOCAL).                   * 00884021
*                                                                     * 00890021
* INPUT:                                                              * 00896021
*    REG 1 - ADDRESS OF THE IOB                                       * 00902021
*    REG 4 - TEST TYPE XX VALUE                                       * 00908021
*    IOBERINF - ADDRESS OF THE RFT                                    * 00914021
*    ON-LINE TEST CHANNEL PROGRAM IN IOB, BUILT BY IGC0D06F           * 00920021
*    (REMOTE) OR IGC1206F (LOCAL).                                    * 00926021
*                                                                     * 00932021
* OUTPUT:                                                             * 00938021
*    LOCAL--                                                          * 00944021
*                                                                     * 00950021
*    TEST MESSAGE (MINUS LINE CONTROL) BUILT IN USER'S AREA.          * 00956021
*    COUNT INSERTED IN ERASE/WRITE CCW.                               * 00962021
*    IF THE USER'S BUFFER IS NOT LONG ENOUGH (300) BYTES OR           * 00968021
*    THE TEST MESSAGE NUMBER IS INVALID, AN ERROR FLAG (IOBINCAM,     * 00974021
*    BYTE 0, BIT 6) IS TURNED ON, AND A NOP REPLACES THE ERASE/       * 00980021
*    WRITE CCW. THIS WILL CAUSE IGG019PI TO CANCEL THE TEST BY        * 00986021
*    RE-ISSUING THE USER'S READ INITIAL.                              * 00992021
*                                                                     * 00998021
*    REMOTE--                                                         * 01004021
*                                                                     * 01010021
*    TEST MESSAGE BUILT IN USER'S AREA.                               * 01016021
*    COUNT IN WRITE TEXT CCW.                                         * 01022021
*    IF AN ERROR IS FOUND, THE ERROR FLAG (SEE LOCAL) IS TURNED       * 01028021
*    ON TO CAUSE IGG019MR TO CANCEL THE TEST.                         * 01034021
*                                                                     * 01040021
*    TESTS BUILT BY THIS MODULE:                                      * 01046021
*                                                                     * 01052021
*    TEST 28 - 3270 NL/EOM PRINTER EBCDIC                               01058021
*                                                                     * 01064021
* EXTERNAL REFERENCES:                                                * 01070021
*         SVC 0 - EXECUTE CHANNEL PROGRAM                             * 01076021
*                                                                     * 01082021
* EXITS, NORMAL:                                                      * 01088021
*         SVC 3 - RETURN TO IOS                                       * 01094021
*                                                                     * 01100021
* EXITS, ERROR:                                                       * 01106021
*         NONE                                                        * 01112021
*                                                                     * 01118021
* TABLES/WORK AREAS:                                                  * 01124021
*         NONE                                                        * 01130021
*                                                                     * 01136021
* ATTRIBUTES:                                                         * 01142021
*    RE-ENTRANT                                                       * 01148021
*                                                                     * 01154021
* CHARACTER CODE DEPENDENCY:                                          * 01160021
*    NONE                                                             * 01166021
*                                                                     * 01172021
* NOTES:                                                              * 01172221
*    NONE                                                             * 01172421
*                                                                     * 01172621
*********************************************************************** 01178021
       EJECT                                                            01184021
*/*IGC1306F: CHART*/                                                    01200021
*/* E IGC1306F*/                                                        01600021
*/* D (YES,,NO,SETERR) IS BUFFER LONG ENOUGH (300 BYTES)*/              02000021
*/* D (YES,,NO,SETERR) IS TEST NUMBER VALID (28)*/                      02400021
*/* P GET MESSAGE LENGTH AND ADDRESS*/                                  02800021
*/*TESTLCL: D (YES,LOCAL,NO,REMOTE) IS DEVICE A LOCAL 3270*/            03200021
*/*LOCAL: P GET ADDRESS OF CCW*/                                        03700021
*/* D (NO,,YES,ISSUENOP) IS ERROR FLAG ON*/                             04200021
*/* P (,MOVEIN) POINT MESSAGE ADDR PAST LINE CONTROL CHARS*/            04700021
*/*REMOTE: P GET ADDRESS OF CCW*/                                       05200021
*/* D (NO,,YES,REMOTERR) IS ERROR FLAG ON*/                             05700021
*/* P OVERLAY TRANSPARENT CCW*/                                         06200021
*/*MOVEIN: P (,STARTEST) MOVE MESSAGE INTO USER'S BUFFER*/              06800021
*/*SETERR: M (,TESTLCL) TURN ON ERROR FLAG*/                            07200021
*/*ISSUENOP: P SET COUNT TO ONE*/                                       07600021
*/* P (,STARTEST) MOVE NOP COMMAND INTO CCW*/                           08000021
*/*REMOTERR: P SET COUNT TO ONE*/                                       08400021
*/*STARTEST: P STORE COUNT IN CCW*/                                     08800021
*/* P SAVE THE ECB*/                                                    09200021
*/* L SVC 0*/                                                           09600021
*/* P RESTORE THE ECB*/                                                 10000021
*/* R SVC 3*/                                                           10400021
*/*IGC1306F: END*/                                                      10800021
       EJECT                                                            11000021
         SPACE 2                                                        11200021
*        ESTABLISH ADDRESSABILITY                                       11600021
         SPACE                                                          12000021
         BALR  BASEREG,ZEROREG     SET UP BASE REG                      12400021
         USING *,BASEREG                                                12800021
         USING IECTIOB,IOBREG      IOB DSECT                            13200021
         USING IECTDECB,DECBREG    DECB DSECT                           13600021
         USING IHADCB,DCBREG       DCB DSECT                            14000021
         USING IECTDEB,DEBREG      DEB DSECT                            14400021
         USING UCBDSECT,UCBREG     UCB DSECT                            14800021
         B     SETUP               BRANCH AROUND ID USED TO             15200021
         DC    C'IGC1306F'         FIND MODULE IN DUMP                  15600021
SETUP    EQU   *                                                        16000021
         L     DECBREG,IOBECBPT    GET DECB ADDR                        16400021
         L     DCBREG,IOBDCBPT     GET DCB ADDR                         16800021
         L     DEBREG,DCBDEBAD     GET DEB ADDR                         17200021
         L     DEBREG,PREFIX(DEBREG)  GO PAST PREFIX                    17500021
         L     RFTREG,IOBERINF     GET ADDR OF RFT                      17800021
         SPACE 2                                                        18000021
*        VALIDITY CHECK BUFFER LENGTH AND TEST NUMBER. IF               18400021
*        INVALID, SET UP NOP CCW AND TURN ON ERROR FLAG.                18800021
         SPACE                                                          19200021
         CLC   DECLNGTH(BUFFLNG),MINBUF  IS BUFFER LONG ENOUGH ?        19600021
         BL    SETERR              NO, SET UP FOR ERROR                 20000021
         C     TESTREG,TEST28      IS IT TEST # 28 ?                    20400021
         BNE   SETERR              NO, SET UP FOR ERROR                 20800021
         SPACE 2                                                        21200021
*        GET TEST MESSAGE ADDRESS AND LENGTH                            21600021
         SPACE                                                          22000021
GETINFO  LR    WORKREG1,TESTREG    GET TEST #                           22400021
         S     WORKREG1,TEST28     SUBTRACT 28 TO GET INDEX             22800021
*                                  (28 IS LOWEST TEST NUMBER            23200021
*                                  THIS MODULE WILL HANDLE)             23600021
         SLL   WORKREG1,2          MULTIPLY BY 4                        24000021
         L     COUNTREG,COUNTAB(WORKREG1) GET MSG LENGTH                24400021
         B     ADDRTAB(WORKREG1)   GET MSG ADDR                         24800021
         SPACE 2                                                        25600021
*        MESSAGE ADDRESS AND LENGTH TABLES - (TEST MESSAGE              26000021
*        NUMBER - 28) X 4 = THE ARGUMENT USED TO OBTAIN VALUES          26400021
*        FROM THE TABLE.                                                26800021
         SPACE                                                          27200021
         DS    0F                                                       27600021
COUNTAB  EQU   *                   MESSAGE LENGTH IN BYTES              28000021
         DC    A(TST28SZ)          TEST 28                              28400021
         SPACE 2                                                        28800021
ADDRTAB  EQU   *                   ADDRESS OF TEST MESSAGE              29200021
         B     TEST28AD            00   GET TEST 28 ADDR                29600021
TEST28AD LA    ADDREG,IJLBOT28     GET ADDR                             30000021
         SPACE 2                                                        30400021
*        TEST FOR LOCAL OR REMOTE                                       30800021
         SPACE                                                          31200021
TESTLCL  EQU   *                                                        31600021
         SR    UCBREG,UCBREG       CLEAR REG FOR IC                     32000021
         IC    UCBREG,IOBUCBX      GET INDEX TO UCB                     32400021
         SLL   UCBREG,2            MULTIPLY BY FOUR                     32800021
         L     UCBREG,DEBUCBAD(UCBREG)  GET ADDR OF UCB                 33200021
         CLI   DVCLASS,GRAPHIC     IS DVC A GRAPHIC ?                   33600021
         BNE   REMOTE              NO, SET UP FOR REMOTE                34000021
         CLI   UNITYPE,A3277       IS DVC A 3277 ?                      34400021
         BE    LOCAL               YES, SET UP FOR LOCAL                34800021
         CLI   UNITYPE,A3284       IS DVC A 3284 ?                      35200021
         BE    LOCAL               YES, SET UP FOR LOCAL                35600021
         CLI   UNITYPE,A3286       IS DVC A 3286 ?                      36000021
         BNE   REMOTE              NO, SET UP FOR REMOTE                36400021
*        FOR LOCAL DEVICES, STRIP OFF STX, ESC, CMD CODE, AND           36800021
*        ETX OF MESSAGE                                                 37200021
         SPACE                                                          37600021
LOCAL    EQU   *                                                        38000021
          LA    CCWREG,IOBCPA       GET ADDR OF CCW                     38200021
         TM    IOBINCAM,ERFLAG     IS ERROR FLAG ON ?                   38400021
         BO    ISSUENOP            YES, GO ISSUE NOP                    38800021
         LA    WORKREG2,LCLNGTH    SUBTRACT 4 FROM LENGTH               39200021
         SR    COUNTREG,WORKREG2   OF MESSAGE                           39600021
         LA    ADDREG,LINECTL(ADDREG)  POINT MSG ADDR PAST              40000021
*                                  STX, ESC, CMD CODE                   40400021
         LA    RFTREG,TENCHARS(RFTREG)  ADJUST PTR PAST RFT             41200021
         B     MOVEIN              GO SET UP MSG                        42000021
         SPACE 2                                                        42400021
*        FOR REMOTE, LEAVE MSG ADDRESS AND LENGTH ALONE                 42800021
         SPACE                                                          43200021
REMOTE   EQU   *                                                        43600021
         LA    WORKREG2,IOBCPA     GET ADDR OF IOBCPA            S99245 43660021
         ST    WORKREG2,IOBSTART    AND STORE IN IOBSTART        S99245 43720021
         LA    CCWREG,IOBCPA+40    GET ADDR OF CCW                      43800021
         TM    IOBINCAM,ERFLAG     IS ERROR FLAG ON ?                   44000021
         BO    REMOTERR            YES, ISSUE CCW                       44400021
         MVC   IOBCPA+48(CCWLNGTH),IOBCPA+56  OVERLAY TRANS CCW         45000021
         CLI   NVALUE(RFTREG),NOADDR IS THIS A DIAL RFT          S99245 45100021
         BNE   BSC3RFT             NO, FOLLOW BSC3 PROCEDURE     S99245 45200021
         LA    RFTREG,CHARS7(RFTREG)  ADJUST PTR PAST RFT        S99245 45300021
         B     MOVEIN              GO SET UP MSG                 S99245 45400021
BSC3RFT  EQU   *                                                 S99245 45500021
         LA    RFTREG,CHARS11(RFTREG)  ADJUST PTR PAST RFT              45600021
         SPACE 2                                                        46400021
*        MOVE TEST MSG INTO USER'S BUFFER                               46800021
         SPACE                                                          47200021
MOVEIN   EQU   *                                                        47600021
         SR    WORKREG2,WORKREG2   CLEAR REG                            48400021
         C     COUNTREG,MAXLNGTH   IS MSG LNGTH OVER 256 ?              48800021
         BNH   LNGTHOK             NO, BRANCH                           49200021
         LR    WORKREG2,COUNTREG   GET EXCESS OVER 256                  49600021
         S     WORKREG2,MAXLNGTH                                        50000021
         L     COUNTREG,MAXLNGTH   SET COUNT TO 256                     50400021
LNGTHOK  EQU   *                                                        50800021
         BCTR  COUNTREG,ZEROREG    SUBTRACT 1 FROM LNGTH FOR            51200021
*                                  EXECUTE                              51600021
         EX    COUNTREG,MSGMOVE    MOVE TEST MSG INTO USER'S            52000021
*                                  BUFFER                               52400021
         LTR   WORKREG2,WORKREG2   ANY MORE TO MOVE ?                   52800021
         BZ    STARTEST            NO, BRANCH                           53200021
         A     RFTREG,MAXLNGTH     BUMP ADDRESS PAST 256                53600021
         A     ADDREG,MAXLNGTH     CHARS JUST MOVED                     54000021
         BCTR  WORKREG2,ZEROREG    SUBTRACT 1 FOR EXECUTE               54400021
         EX    WORKREG2,MSGMOVE    MOVE REMAINDER OF TEXT               54800021
         B     STARTEST            BRANCH AROUND EXECUTE                55200021
MSGMOVE  MVC   0(FILLIN,RFTREG),0(ADDREG)  MOVE TEST MSG TO             55600021
*                                  USER'S BUFFER, USING LENGTH          56000021
*                                  SPECIFIED IN COUNTREG                56400021
       SPACE 2                                                          56480021
*      IF AN ERROR WAS FOUND, TURN ON ERROR FLAG AND GO GET             56560021
*      ADDRESS OF CCW.                                                  56640021
       SPACE                                                            56720021
SETERR   EQU   *                                                        56800021
         OI    IOBINCAM,ERFLAG     TURN ON ERROR FLAG                   57200021
         B     TESTLCL             GO SEE IF LOCAL                      57600021
       SPACE 2                                                          57700021
*      FOR ERROR IN LOCAL, SET UP A NOP CCW                             57800021
       SPACE                                                            57900021
ISSUENOP EQU   *                                                        58000021
          LA   COUNTREG,ONECHAR    SET COUNT TO ONE                     58400021
         MVI   0(CCWREG),NOP       MOVE IN NOP COMMAND                  58800021
         B     STARTEST            GO ISSUE NOP                         59200021
       SPACE 2                                                          59300021
*      FOR REMOTE ERROR, SET COUNT IN WRITE TEXT CCW TO ONE             59400021
       SPACE                                                            59500021
REMOTERR EQU   *                                                        59600021
         LA    COUNTREG,ONECHAR    SET COUNT TO ONE                     60000021
         B     STARTEST            DO TEST                              60400021
         SPACE 2                                                        60800021
*        MOVE COUNT INTO CCW AND START TEST                             61200021
         SPACE                                                          61600021
STARTEST EQU   *                                                        62000021
         LA    COUNTREG,ONECHAR(COUNTREG)  RESTORE COUNT                62400021
         STH   COUNTREG,BYTECNT(CCWREG)  STORE COUNT IN CCW             62800021
         L     WORKREG1,DECSDECB   SAVE ECB                             63200021
         SVC   EXCP                DO TEST                              63600021
         ST    WORKREG1,DECSDECB   RESTORE ECB                          64000021
         SVC   RETURN              RETURN                               64400021
         SPACE 2                                                        64800021
         SPACE                                                          66000021
         SPACE 2                                                        66400021
*        REGISTER EQUATES                                               66800021
         SPACE                                                          67200021
IOBREG   EQU   1                   ADDR OF IOB                          67600021
DECBREG  EQU   2                   ADDR OF DECB                         68000021
DCBREG   EQU   3                   ADDR OF DCB                          68400021
TESTREG  EQU   4                   TEST #                               68800021
WORKREG1 EQU   5                   WORK REG                             69200021
WORKREG2 EQU   6                   WORK REG                             69600021
DEBREG   EQU   7                   ADDR OF DEB                          70000021
UCBREG   EQU   8                   ADDR OF UCB                          70400021
ADDREG   EQU   9                   TEST MSG ADDRESS                     70800021
COUNTREG EQU   10                  TEST MSG LENGTH                      71200021
CCWREG   EQU   11                  ADDR OF CCW TO WRITE TEST MSG        71600021
BASEREG  EQU   12                                                       72000021
RFTREG   EQU   13                  ADDR OF RFT                          72400021
ZEROREG  EQU   0                   REGISTER 0                           72600021
         SPACE 2                                                        72800021
*        MISCELLANEOUS EQUATES                                          73200021
         SPACE                                                          73600021
A3286    EQU   X'0B'               3286 DEVICE TYPE                     74000021
A3284    EQU   X'0A'               3284 DEVICE TYPE                     74400021
A3277    EQU   X'09'               3277 DEVICE TYPE                     74800021
GRAPHIC  EQU   X'10'               GRAPHICS DEVICE TYPE                 75200021
NOP      EQU   X'03'               NOP COMMAND CODE                     75600021
ERFLAG   EQU   X'02'               ERROR FLAG                           76000021
NVALUE   EQU   6                   DISP INTO RFT OF N VALUE      S99245 76001021
NOADDR   EQU   X'00'               IF N=0, IT IS A DIAL RFT      S99245 76002021
CHARS7   EQU   7                   LENGTHOF STANDARD DIAL RFT    S99245 76003021
PREFIX   EQU   28                  DISP IN DEB PAST PREFIX              76005021
BUFFLNG  EQU   2                   LENGTH OF DECLNGTH FIELD             76010021
LCLNGTH  EQU   4                   NO. OF LINE CONTROL CHARS            76015021
LINECTL  EQU   3                   # OF CONTROL CHARS                   76020021
*                                   PRECEDING MSG                       76025021
TENCHARS EQU   10                  LENGTH OF STD RFT - LOCAL            76030021
CCWLNGTH EQU   8                   LENGTH OF A CCW                      76035021
CHARS11  EQU   11                  LENGTH OF STD RFT - REMOTE           76040021
FILLIN   EQU   0                   LENGTH FILLED IN EX INSTR            76045021
ONECHAR  EQU   1                   ONE CHAR - USED TO INCREMENT         76050021
BYTECNT  EQU   6                   DISP IN CCW OF BYTE COUNT            76055021
EXCP     EQU   0                   EXCP SVC                             76060021
RETURN   EQU   3                   RETURN SVC                           76065021
         SPACE 2                                                        76400021
*        STORAGE                                                        76800021
         SPACE                                                          77200021
MINBUF   DC    X'012C'             MINIMUM BUFFER LENGTH                77600021
TEST28   DC    F'28'               ACCEPTABLE TEST NUMBER               78000021
MAXLNGTH DC    F'256'              MAX # OF CHARS FOR MVC               78400021
IJLBOT28 EQU   *                                                        78800021
         DC    X'0227F5'           STX-ESC-EWRT                         79200021
         DC    X'4F'               WCC- RSTRE KYBRD/SND ALRM/STRT PRNT  79600021
         DC    C'NEW LINE FUNCTION CHECK'                   DS LINE 1   80000021
         DC    X'15'               NEW LINE                             80400021
         DC    C'NEW LINE FUNCTION'                         DS LINE 2   80800021
         DC    X'15'               NEW LINE                             81200021
         DC    C'NEW LINE'                                  DS LINE 3   81600021
         DC    X'15'               NEW LINE                             82000021
         DC    C'NEW'                                       DS LINE 4   82400021
         DC    X'15'               NEW LINE                             82800021
         DC    C'NEW LINE'                                  DS LINE 5   83200021
         DC    X'15'               NEW LINE                             83600021
         DC    C'NEW LINE FUNCTION'                         DS LINE 6   84000021
         DC    X'15'               NEW LINE                             84400021
         DC    C'NEW LINE FUNCTION CHECK'                   DS LINE 7   84800021
         DC    X'15'               NEW LINE                             85200021
         DC    X'1D4C'             NON DISPLAY,NON PRINT,NON DETECTABLE 85600021
         DC    C'THIS DATA NOT VISIBLE/EOM AND N/L IGNORED'             86000021
         DC    X'1519'             NEW LINE EOM (IGNORED)               86400021
        DC    X'1D40'             SF/NORMAL INT/ UNPROTECTED            86800021
         DC    C'END-OF-MESSAGE-TERMINATES PRINT'                       87200021
         DC    X'19'               END OF MESSAGE                       87600021
         DC    X'15'               NEW LINE                 DS LINE 8   88000021
         DC    C'2ND EOM LINE NOT ON PRINTER OUTPUT'                    88400021
         DC    X'19'               END OF MESSAGE                       88800021
         DC    X'03'               ETX                                  89200021
TST28SZ  EQU   *-IJLBOT28          LENGTH OF TEST 28                    89400021
         ORG   IGC1306F+1024       MAKE MODULE 1024 BYTES LONG          89500021
         SPACE 2                                                        89600021
*        DSECTS                                                         90000021
         SPACE                                                          90400021
         IECTIOBX                                                       90800021
         EJECT                                                          91200021
         IECTDECB                                                       91600021
         EJECT                                                          92000021
         DCBD  DSORG=BX,DEVD=BS                                         92400021
         EJECT                                                          92800021
         IECTDEBX                                                       93200021
UCBDSECT DSECT                                                          93600021
         DS    0F                                                       94000021
         ORG   UCBDSECT+13         ORG TO UNIT ADDR                     94400021
CHARADDR DS    CL3                 UNIT ADDR (EBCDIC)                   94800021
     ORG   UCBDSECT+18             ORG TO DVC CLASS AND UNIT TYPE       95200021
DVCLASS  DS    CL1                 DEVICE CLASS                         95600021
UNITYPE  DS    CL1                 UNIT TYPE                            96000021
         ORG   UCBDSECT+36         OR G TO RLN                          96400021
RLN      DS    CL1                 RELATIVE LINE NUMBER                 96800021
         END                                                            97200021
