         TITLE 'IGE0004A - BTAM/QTAM ERP CONTROL MODULE'                00200013
IGE0004A CSECT                                                          00400013
*71660065462000-464000,576000-578000,626000                        000B 00600014
         SPACE 2                                                        00800013
* STATUS -          CHANGE LEVEL 002    JUNE 21, 1967              000B 01000014
         SPACE 2                                                        01200013
*********************************************************************** 01400013
*                                                                     * 01600013
*              BTAM ERROR RECOVERY PROCEDURES ROUTINES                * 01800013
*                                                                     * 02000013
*              THE ERROR RECOVERY PROCEDURES ROUTINES ARE A COMPOSITE * 02200013
*        SET OF ROUTINES DESIGNED TO DIAGNOSE AND RECOVER FROM ALL    * 02400013
*        ERRORS ENCOUNTERED DURING TRANSMISSION OF TELECOMMUNICATIONS * 02600013
*        DATA. THE ERROR ROUTINES OPERATE IN TWO MODES, BASIC AND     * 02800013
*        OPTIONAL FEATURES MODE.                                      * 03000013
*              THE BASIC ERROR RECOVERY ROUTINE PERFORMS THE FOLLOWING* 03200013
*        FUNCTIONS:                                                   * 03400013
*              1. AUTOMATIC RETRY OF ALL ERRORS NOT INVOLVING DATA    * 03600013
*                TRANSFER.                                            * 03800013
*              2. STATICSTICAL RECORDING OF UNIT CHECK ERRORS.        * 04000013
*              3. ERROR MESSAGES TO THE OPERATOR CONSOLE FOR ALL      * 04200013
*                 PERMANENT ERRORS.                                   * 04400013
*                                                                     * 04600013
*              THE ERROR RECOVERY ROUTINE OPTIONAL FEATURES INCLUDE:  * 04800013
*              1. LINE ERROR RECORDING FOR ALL DATA CHECKS, TIME OUTS,* 05000013
*                 AND INTERVENTION REQUIRED ERRORS.                   * 05200013
*              2. WRITE RETRIES FOR ERRORS OCCURING DURING TEXT       * 05400013
*                 TRANSFER.                                           * 05600013
*              3. READ RETRIES FOR ERRORS OCCURING DURING TEXT        * 05800013
*                 TRANSFERS.                                          * 06000013
*              NOTE: WRITE AND READ RETRIES WILL NOT BE ATTEMPTED FOR * 06200013
*              DEVICES NOT CAPABLE OF ACCEPTING THEM.                 * 06400013
*                                                                     * 06600013
*              THE ERROR RECOVERY ROUTINES OPERATE IN THE NUCLEUS     * 06800013
*        ERROR TRANSIENT AREA WITH A SUPERVISOR PROTECTION KEY. THE   * 07000013
*        ROUTINES HAVE THE FOLLOWING ATTRIBUTES; ENABELED,REENTRANT,  * 07200013
*        AND TRANSIENT.                                               * 07400013
*********************************************************************** 07600013
*              WORK AREA ALLOCATION FOR BTAM ERROR ROUTINES           * 07800013
*                                                                     * 08000013
*              WORK AREAS FOR THE BTAM ERROR ROUTINES ARE PROVIDED    * 08200013
*        WITHIN THE ASSOCIATED IOB FOR THE LINE THAT ENCOUNTERED      * 08400013
*        THE ERROR. THE FOLLOWING AREAS ARE DESCRIBED BY SYMBOLIC     * 08600013
*        NAME AND OFFSET WITHIN THE IOB CONTROL BLOCK.                * 08800013
*              1. IOBINCAM - THE SECOND BYTE OF THIS FIELD IS USED    * 09000013
*                 TO DESIGNATE THE TYPE OF ERROR ENCOUNTERED FOR      * 09200013
*                 THE LINE ERROR ROUTINE. A HEX VALUE OF 01 INDICATES * 09400013
*                 A DATA CHECK ERROR, 02 INDICATES INTERVENTION       * 09600013
*                 REQUIRED, AND 03 INDICATES A TIME OUT ERROR.  THE   * 09800013
*                 ERP SYMBOLIC REFERENCE IS IOBECT-1 OFFSET IS DEC. 29* 10000013
*              2. IOBERRCT - THE FIRST BYTE OF THIS FIELD CONTAINS THE* 10200013
*                 NUMBER OF RETRIES ATTEMPTED FOR A GIVEN FAILURE.    * 10400013
*                 THE ERP SYMBOLIC REFERENCE ID IOBECT OFFSET IS      * 10600013
*                 DEC 30                                              * 10800013
*              3. IOBWORK - THE SEVEN BYTES OF IOBWORK ARE USED       * 11000013
*                 BY ERP ROUTINES TO MODIFY CONTROL DATA FROM OTHER   * 11200013
*                 CONTROL BLOCKS CREATED FOR BTAM ERP SYMBOLIC        * 11400013
*                 REFERENCE IS IOBWRK OFFSET IS 33                    * 11600013
*              4. IOBERINF - THIS AREA IS USED TO SAVE FAILURE DATA   * 11800013
*                 FROM THE ORIGINAL ERROR WHEN SPECIAL CHANNEL PROGRAM* 12000013
*                 EXECUTION IS REQUIRED  OFFSET IS 48 DEC. LENGTH     * 12200013
*                 IS 16 BYTES                                         * 12400013
*                 BYTE1 = SENSE DATA                                  * 12600013
*                 BYTES 2 THRU 7 = LAST 7 BYTES OF CSW                * 12800013
*                 BYTES 8 THRU 15 = FAILING CCW                       * 13000013
*              5. IOBDCCW - AREA USED TO CREATE CHANNEL PROGRAMS      * 13200013
*                 OF ONE CCW LENGTH. USED FOR DISABLES TO SWITCHED    * 13400013
*                 LINE, AND FOR READ/SKIPS AND WRITE/BREAKS WHEN      * 13600013
*                 REQUIRED.                                           * 13800013
*                                                                     * 14000013
*              LINKAGE CONVENTIONS USED BETWEEN LOADS OF ERP          * 14200013
*                                                                     * 14400013
*              STANDARD LINKAGE CONVENTIONS FOR TRANSIENT ERROR       * 14600013
*        ROUTINES ARE UTILIZED BY BTAM ERROR ROUTINES. ALL LOADS      * 14800013
*        OF BTAM ERROR ROUTINES START WITH IGE0. THE FIRST LOAD IS    * 15000013
*        IGE0004A. SUBSEQUENT LOADS ARE NUMBERED 1000 HIGHER THAN     * 15200013
*        THE PREVIOUS LOAD. THE ELEVENTH LOAD IS IGE0004B AND ALL     * 15400013
*        SUBSEQUENT LOADS ARE 1000 GREATER. LINKAGE TO ANY LOAD OF    * 15600013
*        BTAM ERROR ROUTINES IS ACCOMPLISHED BY LOADING REGISTER 13   * 15800013
*        TO THE NUMERICAL VALUE OF THE DESIRED LOAD, LOADING REGISTER * 16000013
*        14 WITH THE CVT POINTER TO THE BRANCH ENTRY OF XCTL AND      * 16200013
*        BRANCHING VIA REGISTER 14. NO REGISTERS ARE SAVED BY THE     * 16400013
*        ERROR ROUTINES AND ONLY REGISTER 1 MAINTAINS TRANSPARENCY    * 16600013
*        BETWEEN LOADS OF ERROR ROUTINES.                             * 16800013
*                                                                     * 17000013
*              A SPECIAL ENTRY INDICATOR IS PROVIDED IN THE IOB WORK  * 17200013
*        AREA FOR LOADS OF ERP CONTAINING ONE OR MORE SPECIAL ROUTINES* 17400013
*        THE SYMBOLIC REFERENCE IS IOBECT+1 OFFSET IS 31. THIS        * 17600013
*        LOCATION IS NORMALLY 0. WHEN IOBECT+1 IS NOT ZERO IT         * 17800013
*        INDICATES A SPECIAL ROUTINE WITHIN A LOAD IS TO BE EXECUTED  * 18000013
*                                                                     * 18200013
*              REGISTER ASSIGNMENTS FOR BTAM ERROR ROUTINES           * 18400013
*                                                                     * 18600013
*              REGISTER  SYMBOLIC              USE                    * 18800013
*              ONE       TSTREG    CONTAINS POINTER TO THE REQUEST    * 19000013
*                                  BLOCK OF THE PROGRAM THAT INITIATED* 19200013
*                                  THE I/O REQUEST ATTRIBUTES: THIS   * 19400013
*                                  REGISTER MAINTAINS TRANSPARENCY    * 19600013
*                                  BETWEEN LOADS OF ERP ROUTINE       * 19800013
*                                                                     * 20000013
*              FOUR      CCWREG    CONTAINS POINTER TO THE FAILING    * 20200013
*                                  CHANNEL COMMAND WORD THIS REGISTER * 20400013
*                                  MUST BE INITIALIZED IN EACH LOAD   * 20600013
*                                  OF ERP                             * 20800013
*                                                                     * 21000013
*              FIVE      DECBRG    CONTAINS POINTER TO ASSOCIATED     * 21200013
*                                  DECB  REQUIRES INITIALIZATION IN   * 21400013
*                                  EACH LOAD OF ERP                   * 21600013
*              SIX       DCBREG    CONTAINS POINTER TO ASSOCIATED     * 21800013
*                                  DCB REQUIRES INITIALIZATION IN     * 22000013
*                                  EACH LOAD OF ERP                   * 22200013
*                                                                     * 22400013
*              SEVEN     UCBREG    CONTAINS POINTER TO ASSOCIATED     * 22600013
*                                  UCB REQUIRES INITIALIZATION IN     * 22800013
*                                  EACH LOAD OF ERP                   * 23000013
*                                                                     * 23200013
*              EIGHT     COMREG    CONTAINS POINTER TO NUCLEUS        * 23400013
*                                  COMMUNICATIONS VECTOR TABLE        * 23600013
*                                  REQUIRES INITIALIZATION IN EACH    * 23800013
*                                  LOAD OF ERP                        * 24000013
*                                                                     * 24200013
*              TEN       IOBRG     CONTAINS POINTER TO ASSOCIATED     * 24400013
*                                  IOB REQUIRES INITIALIZATION IN     * 24600013
*                                  EACH LOAD OF ERP                   * 24800013
*                                                                     * 25000013
*              TWELVE    ERRLNK    LINKAGE REGISTER USED IN           * 25200013
*                                  CONJUNCTION WITH RESIDENT STATUS   * 25400013
*                                  INTERPRETER ROUTINE                * 25600013
*                                                                     * 25800013
*              THIRTEEN  SAVREG    LINKAGE REGISTER FOR RESIDENT      * 26000013
*                                  XCTL ROUTINE CONTAINS LOW ORDER    * 26200013
*                                  NUMBER OF ERP LOAD TO BE LOADED    * 26400013
*                                                                     * 26600013
*              FOURTEEN            LINKAGE REGISTER FOR RESIDENT      * 26800013
*                                  XCTL ROUTINE CONTAINS CONTAINS     * 27000013
*                                  BRANCH ENTRY ADDRESS OF XCTL       * 27200013
*                                  ROUTINE                            * 27400013
*                                                                     * 27600013
*              FIFTEEN             BASE REGISTER FOR ALL BTAM ERP     * 27800013
*                                  ROUTINES                           * 28000013
*                                                                     * 28200013
*              THE REMAINING REGISTERS ARE USED AS WORK REGISTERS     * 28400013
*                                                                     * 28600013
*              BTAM/QTAM ERROR RECOVERY CONTROL ROUTINE               * 28800013
*                                                                     * 29000013
*              THE BTAM/QTAM ERROR RECOVERY CONTROL ROUTINE IS THE    * 29200013
*        FIRST LOAD OF THE ERROR RECOVERY PROCEDURS ROUTINE. THIS     * 29400013
*        ROUTINE PERFORMS THE FOLLOWING FUNCTIONS                     * 29600013
*              1. PROVIDES LINKAGE TO SUBSEQUENT LOADS OF EITHER BTAM * 29800013
*                 OR QTAM ACCESS METHODS ERROR ROUTINES               * 30000013
*              2. DETERMINES IF ENTRY IS DUE TO INITIAL ERROR OR AS   * 30200013
*                 A RESULT OF ERROR ROUTINE CHANNEL PROGRAM EXECUTION * 30400013
*              3. DETERMINES TYPE OF INITIAL ERROR ENCOUNTERED AND    * 30600013
*                 LINKS TO PROPER ROUTINE VIA CVT XCTL ROUTINE        * 30800013
*              4. GENERATES RETURN LINKAGE TO SUBSEQUENT LOADS OF     * 31000013
*                 ERROR ROUTINES WHEN REQUIRED DUE TO ERROR ROUTINE   * 31200013
*                 CHANNEL PROGRAM EXECUTION                           * 31400013
*                                                                     * 31600013
*        ENTRY:     ENTRY IS TO THE FIRST INSTRUCTION VIA XCTL        * 31800013
*                   RESIDENT ROUTINE                                  * 32000013
*                                                                     * 32200013
*        INPUT:     REGISTER ONE CONTAINS POINTER TO ASSOCIATED       * 32400013
*                   REQUEST BLOCK FOR PROGRAM REQUESTING BTAM/QTAM    * 32600013
*                   ACCESS ROUTINES                                   * 32800013
*                                                                     * 33000013
*        EXITS:     SUBSEQUENT LOADS OF ERROR RECOVERY ROUTINES AND   * 33200013
*                   RESIDENT ERROR INTERPRETER ROUTINE                * 33400013
*                                                                     * 33600013
*        NOTES:     IOBECT+1 DETERMINES TYPE OF EXIT TO BE PERFORMED  * 33800013
*                   IOBECT1+=0 INDICATES NORMAL EXIT DETERMINED BY    * 34000013
*                              ERROR CONDITION FOUND                  * 34200013
*                   IOBECT+1=4 OR 8 INDICATES RD/SKP OR WRT/BRT       * 34400013
*                              CHECK ROUTINE                          * 34600013
*                   IOBECT+1=16 OR MORE INDICATES RETURN TO           * 34800013
*                              ERROR POST ROUTINE                     * 35000013
*                                                                     * 35200013
*        OUTPUT     NONE                                              * 35400013
*********************************************************************** 35600013
         USING *,BASREG                                                 35800013
ERRSTART L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  36000013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  36200013
         L     COMREG,LOC016            ADDRESS OF CVT                  36400013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 36600013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  36800013
         SR    ERREG1,ERREG1            CLEAR LINKAGE REGISTER          37000013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  37200021
         LA    CCWREG,0(CCWREG)     INSURE HIGH BYTE X'00'       A57370 37250021
         SH    CCWREG,ERRCN1            ADJUSTED TO FAILING CCW         37400013
         BP    ERRCK03                  CSW GOOD                        37600013
         L     ERREG4,IOBSTART(IOBRG)                            A33976 37700020
         LA    ERREG4,8(ERREG4)        ADDRESS OF DUMMY CCW             37800019
         XC    IOBCSW+1(3,IOBRG),IOBCSW+1(IOBRG) CLEAR ADDR OF CSW      38000013
ERRTOVR4 L     ERREG2,IOBCSW(IOBRG)     PICK UP FIRST WD OF CSW         38200013
         AR    ERREG2,ERREG4            ADJUST TO FAILING CCW           38400013
         ST    ERREG2,IOBCSW(IOBRG)     RESTORE TO CSW                  38600013
ERRCK03  TM    DCBMACRF(DCBREG),BTAMWRT IS THIS BTAM WRITE              38800013
         BO    ERRCK04                  YES SET UP FOR BTAM             39000013
         TM    DCBMACRF+1(DCBREG),BTAMRD IS THIS BTAM READ              39200013
         BO    ERRCK04                  YES SETUP FOR BTAM              39400013
         LA    CRBREG,QTAMLOD1          NO SET UP FOR QTAM              39600013
         B     ERRCK05A                 CONTINUE PROCESSING      A68735 39800021
ERRCK04  LA    CRBREG,ERLOD1            BTAM ERROR ROUTINE SETUP        40000013
ERRCK05  EQU   *                                                 A68735 40050021
         CLI   DECTYP(DECBRG),X'01'       READ INITIAL ?         A65145 40250021
         BNE   ERRCK05A           NO CONTINUE                    A65145 40300021
         TM    IOBFL2(IOBRG),IOBRESP    RESETPL ISSUED?          A65145 40400021
         BNO   ERRCK05A            NO, CONTINUE                  A65145 40450021
         MVI   IOBECT(IOBRG),X'02'  SET ERROR COUNT TO MAX TO    A65145 40500021
*                     PREVENT RETRIES SO RESETPL CAN TAKE EFFECT A65145 40550021
ERRCK05A OI    IOBFL3(IOBRG),IOBMSG     SET I/O ERR FOR MSG WTR  A68735 40552021
         TM    IOBFL1(IOBRG),IOBEXE  ERP IN CONTROL?             A68735 40560021
         BNO   ERRCK02                  NO CONTINUE PROCESSING          40600013
         CLI   IOBECT+1(IOBRG),NONAME   NORMAL RETRY                    40800013
         BE    ERRCK01                  YES, CONTINUE RETRY CHECKING    41000013
         CLI   IOBECT+1(IOBRG),X'01'    SPECIAL RETURN FOR INTREQA35750 41060020
         BE    ERRM38                   YES, BRANCH              A35750 41120020
         CLI   IOBECT+1(IOBRG),MASK15   LINK ROUTINE SPECIFIED          41200013
         BL    EREXCTL1                 YES RETURN VIA LINK MOCULE      41400013
         B     ERRWTO                   RETURN VIA ERROR POST           41600013
ERRCK01  TM    IOBCSW+4(IOBRG),CSWNORM1 NORMAL COMPLETION               41800013
         BNZ   ERRCK02                  NO NORMAL PROCESSING            42000013
         TM    IOBCSW+5(IOBRG),CSWNORM2 MORE NORMAL COMPLETION          42200013
         BNZ   ERRCK02                  NO NORMAL PROCESSING            42400013
         TM    IOBCSW+4(IOBRG),CSWUE    THIS UNIT EXCEPTION             42600013
         BZ    ERRUPDTE                 NO STASTICSTICS UPDATE OR POST  42800013
         CLI   0(CCWREG),CCWRDCMD       READ COMMAND                    43000013
         BNE   ERRCK01A                 IF NOT, CHECK FOR INHIBIT  000A 43200013
         TM    TPCODE(CCWREG),CCWRRTXT  READ RESPONSE TO TEXT BIT  000A 43400013
         BNO   ERRUPDTE            SET? IF NOT, BRANCH TO DO SDR   000A 43600013
*                                  OR POST.                        000A 43800013
         TM    TPCODE(CCWREG),MASKALL-CCWRRTXT-HIBIT ANY OTHER TP  000A 44000013
         BNZ   ERRUPDTE            OP CODE BITS SET?  IF SO, BRANCH000A 44200013
ERRCK01A CLI   0(CCWREG),CCWINHCD  INHIBIT COMMAND                 000A 44400013
         BE    ERRUPDTE                 IF SO, BRANCH TO DO SDR    000A 44600013
*                                  OR POST.                        000A 44800013
ERRCK02 EQU    *                                                        44850019
*              LINES 448600 AND 448800 (APAR 60081) REMOVED      A65145 44860021
         CLI   IOBDECB(IOBRG),X'48'    HAS HIO BEEN ISSUED       A27856 44900021
         BE    ERRETRY1                YES, RETURN INTERRUPT TO APP     44950019
         OI    IOBFL1(IOBRG),IOBEXE    INDICATE ERP IN CONTROL   A27856 45000019
         TM    IOBCSW+5(IOBRG),X'06'    INTERFACE OR CONTROL CHECK      45060014
         BZ    CHKMORE                                                  45120014
         LA    ERREG1,1                                                 45180014
         B     ERRM43                                                   45240014
CHKMORE  TM    IOBCSW+5(IOBRG),X'20'   CHANNEL PGM CHECK OCCUR     1267 45280018
         BO    ERRM43                  YES, GO TO STATUS CHECK RTN 1267 45320018
         TM    IOBCC(IOBRG),IOBCC3     SIO CONDITION CODE = 3      1267 45360018
         BO    ERRPST03            IF SO, GO TO CONTROL UNIT       000A 45400013
*                             NOT OPERATIONAL MESSAGE WRITER.      000A 45600013
         BM    ERRSTA04                 IF SIO COND CODE 1, GO TO  000A 45800013
*    CONTROL LOAD 2 TO HANDLE INITIAL SELECTION ERROR.             000A 46000013
         TM    IOBCSW+5(IOBRG),CSWCDC   CHANNEL DATA CHECK?        000B 46100014
         BO    ERRM35              IF SO, GO TO SPECIAL ENTRY OF   000B 46200014
*                                  CONTROL LOAD 2                  000B 46300014
         TM    IOBCSW+4(IOBRG),CSWASCB  ATTEN, STATUS MOD, CTRL UNIT    46600013
*                                       END OR BUSY INDICATED           46800013
         BNZ   ERRSNO                   ENTRY TO ERROR POST             47000013
         TM    IOBCSW+4(IOBRG),CSWUCK   IS THIS UNIT CHECK              47200013
        BO    ERRSTA02                 YES CHECK FOR CHAN AND DEV END   47400013
         B     ERRM43                   ENTRY TO BRANCHING TABLE        47600013
ERRSTA02 TM    IOBCSW+4(IOBRG),CSWCDE   BOTH CHAN AND DEV END OFF       47800013
         BNZ   ERRSTA03                 NO EXAMINE SENSE BITS           48000013
         B     ERRSTA04                                                 48200013
ERRETRY1 SVC   EXCPER                                                   48400013
         SVC   RETURN                                                   48600013
ERRUPDTE NI    IOBFL1(IOBRG),MASKALL-IOBEXE TURN OF ERP CONTROL INDS    48800013
ERRSTA01 L     ERREG2,STATAB(COMREG)    STASTISTICS TABLE POINTER       49000013
         SR    ERREG1,ERREG1            CLEAR REGISTER                  49200013
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY            49400013
         LR    ERREG4,ERREG2            SAVE STAT TABLE START ADDR 000H 49450017
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED THIS SECT 000H 49500017
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 49550017
         LA    ERREG4,2(ERREG4)         POINT TO NXT CTL ENTRY     000H 49600017
         LA    ERREG1,256(ERREG1)       POINT TO NXT STAT TBL SECT 000H 49650017
         B     ERRLOOP1                 LOOP TO CHECK THIS SECTION 000H 49700017
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR ENTRY LENGTH    000H 49750017
         AR    ERREG2,ERREG1            RESOLVE ACTUAL ADDRESS          49800013
         CLI   8(ERREG2),NONAME         STASTISTICS UPDATE REQUIRED     50000013
         BE    ERRETRY1                 NO POST OPERATION COMPLETE      50200013
         TM    9(ERREG2),X'01'         CHANNEL CHECK ERROR OCCUR        50260017
         BNO    ERRETRY1               NO, GO TO POST                   50320017
         LA    SAVREG,STATUP            UPDATE STATISTICS ROUTINE NAME  50400013
EREXCTL  L     ERRETR,VECTXL(COMREG)    XCTL ROUTINE ADDRESS            50600013
         BR    ERRETR                   EXIT VIA XCTL                   50800013
ERRPST03 CH    CRBREG,QTAMLOD           IS THIS QTAM                    51000013
         BE    ERRPST04                 YES  BRANCH                     51200013
         LH    SAVREG,ERLOD16           ADDRESS OF INT REQ MSG WRITER   51400013
         B     EREXCTL                  LINK TO MESSAGE WRITER          51600013
ERRPST04 LH    SAVREG,QTAMLOD2          ADDRESS OF QTAM ROUTINE         51800013
         B     EREXCTL                                                  52000013
ERRSTA03 LR    ERREG1,BASREG            SAVE BASE REGISTER              52200013
         L     BASREG,VECT68(COMREG)    LOAD NAME INTERPRETER RTNE      52400013
ERRM30   BALR  ERRLNK,BASREG            EXIT TO INTERPRETER             52600013
         DC    X'03'                         EQUIPMENT CHECK            52800013
         DC    AL1(ERRM35-ERRM30-2)                                     53000013
         DC    X'06'                         LOST DATA                  53200013
         DC    AL1(ERRM36-ERRM30-4)                                     53400013
         DC    X'07'                         TIME OUT                   53600013
         DC    AL1(ERRM37-ERRM30-6)                                     53800013
         DC    X'01'                         INTERVENTION REQUIRED      54000013
         DC    AL1(ERRM38-ERRM30-8)                                     54200013
         DC    X'02'                         BUS OUT CHECK              54400013
         DC    AL1(ERRM39-ERRM30-10)                                    54600013
         DC    X'04'                         DATA CHECK                 54800013
         DC    AL1(ERRM40-ERRM30-12)                                    55000013
         DC    X'05'                         OVERRUN                    55200013
         DC    AL1(ERRM41-ERRM30-14)                                    55400013
         DC    X'00'                         COMMAND REJECT             55600013
         DC    AL1(ERRM42-ERRM30-16)                                    55800013
         DC    X'2F'                         END OF TEST                56000013
         DC    AL1(ERRSNO-ERRM30-18)                                    56200013
ERRSNO   CH    CRBREG,QTAMLOD           IS THIS QTAM                    56400013
         BE    ERRM35                   YES  BRANCH                     56600013
         OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOUL NOT OCCUR ERROR  56800013
ERRM42   EQU   *                        ENTRY FOR COMMAND REJECT        57000013
ERRM35   MVI   IOBECT+1(IOBRG),MASK15   IND SPECIAL ENTRY LOAD 2        57200013
ERRSTA04 EQU   *                                                        57400013
         CH    CRBREG,QTAMLOD          IS THIS FOR QTAM?                57406019
         BE    ERSTA4Q                     YES  GO TO QTAM LOAD 8       57412019
         LR    ERREG1,BASREG            SAVE BASE                       57418019
         L     BASREG,VECT68(COMREG)    ADDRESS OF INTERPRETER          57424019
ERRSCR00 BALR  ERRLNK,BASREG            LINK TO INTERPRETER             57430019
         DC    X'1F'                    CHAIN CHECK INDICATOR           57436019
         DC    AL1(ERRSCR01-ERRSCR00-2) INDEX TO CHAIN CHECK ROUTINE    57442019
         DC    X'1A'                    PROGRAM CHECK INDICATOR         57448019
         DC    AL1(ERRSCR02-ERRSCR00-4) INDEX TO PROGRAM CHECK ROUTINE  57454019
         DC    X'1B'                    PROTECTION CHECK INDICATOR      57460019
         DC    AL1(ERRSCR03-ERRSCR00-6) INDEX TO PROTECTION CHECK RTN   57466019
         DC    X'17'                    UNIT EXCEPTION INDICATOR        57472019
         DC    AL1(ERRSCR04-ERRSCR00-8) UNIT EXCEPTION ROUTINE POINTER  57478019
         DC    X'2F'                    SCAN END INDICATOR              57484019
         DC    AL1(ERRSCR05-ERRSCR00-10) SHOULD NOT OCCUR ERRORS        57490019
ERRSCR01 EQU   *                                                        57496019
ERRSCR02 EQU   *                                                        57502019
ERRSCR03 EQU   *                                                        57508019
         B     ERRSCR06                 CHECK FOR SWITCHED LINE         57514019
ERRSCR04 LA    SAVREG,ERLOD13           ADDRESS OF UNIT EXCEPTION RTN   57520019
         B     EREXCTL                  EXIT ROUTINE                    57526019
ERRSCR05 OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 57532019
ERRSCR06 TM    UCBTYP+1(UCBREG),SWLINE  IS A DISABLE REQUIRED           57538019
         BZ    ERRSCR07                 NO GO TO OBR ROUTINE            57544019
         MVI   IOBECT+1(IOBRG),MASK15   SPECIAL ENTRY INDICATOR         57550019
         LH    SAVREG,ERLOD9            ADDRESS OF DISABLE ROUTINE      57556019
         B     EREXCTL                  EXIT                            57562019
ERRSCR07 OI    IOBFL3(IOBRG),IOBLOG     INDICATE OUTBOARD RECORDING     57568019
         LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         57574019
         B     EREXCTL                  EXIT                            57580019
*                                                                       57586019
ERSTA4Q  EQU   *                                                        57592019
         LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR CHANNEL DATA     000B 57600014
*    CHECK, INITIAL SELECTION ERRORS, AND EQUIPMENT CHECK          000B 57800014
ERRM43   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR STATUS CHECK     000A 58000013
EREXCTL1 LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR A READ-SKIP OR   000A 58200013
*    BREAK WHICH WERE ISSUED TO RECOVER FROM LOST DATA ON A READ   000A 58400013
*    OR UNIT EXCEPTION ON A WRITE                                  000A 58600013
ERRM39   EQU   *                        ENTRY FOR BUS-OUT CHECK    000A 58800013
ERRM41   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR OVERRUN               59000013
ERRWTO   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR ERROR POST            59200013
ERRM36   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR LOST DATA             59400013
ERRM38   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR INTERVENTION REQUIRED 59600013
ERRM37   LA    ERREG1,ERRRTCON(ERREG1)  ENTRY FOR TIME OUT              59800013
ERRM40   AR    ERREG1,CRBREG            ADD QTAM/BTAM INTERFACE VALUE   60000013
         LR    SAVREG,ERREG1            SET UP LINK REGISTER            60200013
         B     EREXCTL                  EXIT VIA LINK MODULE            60400013
QTAMLOD  DC    H'1045'                                                  60600013
ERRCN1   DC    AL2(8)                        DECIMAL 8                  60800013
QTAMLOD2 DC    H'4046'                                            M3178 61000019
ERRCN2   DC    AL2(10)                       MULTIPLIER CONSTANT        61200013
BTAMRD   EQU   X'20'                                                    61400013
BTAMWRT  EQU   X'20'                                                    61600013
CCWINHCD EQU X'0A'                                                      61800013
CCWRDCMD EQU X'02'                                                      62000013
CCWRRTXT EQU   X'20'     READ RESPONSE-TO-TEXT TP CODE             000A 62200013
CSWASCB  EQU   X'F0'                                                    62400013
CSWCDC   EQU   X'08'                         CHANNEL DATA CHECK    000B 62600014
CSWCDE   EQU   X'0C'                        CHANNEL AND DEVICE END      62800013
CSWSNO   EQU   X'40'                                                    63000013
CSWUCK   EQU   X'02'                        UNIT CHECK                  63200013
CSWUE    EQU   X'01'                                                    63400013
DCBMACRF EQU   42                                                       63600013
DECERRST EQU   29                                                       63800013
ERLOD1   EQU   1041                                                     64000013
ERLOD5   DC    AL2(5041)                                                64050019
ERLOD9   DC    AL2(9041)                                                64100019
ERLOD13  EQU   3042                                                     64150019
ERLOD16  DC    H'6042'                                                  64200013
ERRCN8   DC    AL2(8)                                                   64300019
ERRRTCON EQU   1000                                                     64400013
EXCPER   EQU   15                           EXCP ERROR ROUTINE          64600013
HIBIT    EQU   X'C0'     END OF CHANNEL PROG AND 1ST TIME PCI BITS 000A 64800013
IOBCC    EQU   16                           CONDITION CODE              65000013
IOBCC1   EQU   X'10'                        CONDITION CODE OF SIO       65200013
IOBCC3   EQU   X'30'                                                    65400013
IOBCPA   EQU   64                                                       65600013
IOBCSW   EQU   8                            CSW STORAGE                 65800013
IOBSTART EQU   16                                                       65900019
IOBDCBAD EQU   20                                                       66000013
IOBDCCW  EQU   40                                                       66200013
IOBDECB  EQU   4                                                        66400013
IOBECT   EQU   30                      ERROR COUNTS                     66600013
IOBERR   EQU   X'20'                        IOB ERROR FLAG              66800013
IOBEX    EQU   X'04'                        EXCEPT FLAG                 67000013
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                67200013
IOBFL1   EQU 0                              FLAGS 1                     67400013
IOBFL2   EQU   1                   FLAGS2                        A60081 67450021
IOBFL3   EQU   8                            FLAGS3                      67600013
IOBLOG   EQU   X'01'                                                    67700019
IOBRESP  EQU   X'01'               RESETPL ISSUED FLAG IN IOB    A60081 67750021
IOBMSG   EQU X'04'                     MESSAGE TYPE                     67800013
LOC016   EQU   16                           COMMUNICATIONS TABLE        68000013
MASKALL  EQU   255                                                      68200013
MASK15   EQU   X'0F'                                                    68400013
NONAME   EQU   X'00'                                                    68600013
NORMCOND EQU   X'0D'                                                    68800013
QTAMLOD1 EQU   1045                                                     69000013
RETURN   EQU   3                       RETURN SVC                       69200013
SIOCC3   EQU   X'80'                                                    69400013
STATAB   EQU  112                          INDEX TO STATISTICS TABLE    69600013
STATUP   EQU  254           LOAD NAME TO STATISTICS UPDATE ROUTINE      69800013
SWLINE   EQU   X'90'                                                    69900019
TPCODE   EQU   5                                                   000A 70000013
DECTYP   EQU   5        DECTYPE+1 FIELD OF DECB                  A65145 70050021
TSTIOB   EQU   5                            IOB POINTER                 70200013
TSTUCB   EQU   2                            UCB POINTER                 70400013
UCBSTI   EQU   9                            STATISTICS POINTER          70600013
UCBTYP   EQU   16                                                       70700019
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      70800013
VECT68   EQU   68                      INDEX TO INTERPRETER ROUTINE     71000013
WLR      EQU   X'40'                                                    71200013
CSWNORM1 EQU   MASKALL-NORMCOND                                         71400013
CSWNORM2 EQU   MASKALL-WLR                                              71600013
*        REGISTER DEFINITION                                            71800013
ERREG3   EQU   0                             WORK REG                   72000013
TSTREG   EQU   1                             TWELVE STAR REG            72200013
ERREG2   EQU   2                             WORK REG                   72400013
CRBREG   EQU   3                             CURRENT RB REG             72600013
CCWREG   EQU   4                             CCW ADDRESS REG            72800013
DECBRG   EQU   5                        DECB REGISTER                   73000013
DCBREG   EQU   6                        DCB REGISTER                    73200013
UCBREG   EQU   7                             UCB ADDRESS  REG           73400013
COMREG   EQU   8                             COMMUNICATION TABLE REG    73600013
ERREG1   EQU   9                                                        73800013
IOBRG    EQU   10                            IOB ADDRESS REG            74000013
ERREG4   EQU   11                            WORK REG                   74200013
ERRLNK   EQU   12                            LINK REG                   74400013
SAVREG   EQU   13                                                       74600013
ERRETR   EQU   14                            RETURN REG                 74800013
BASREG   EQU   15                            BASE REG                   75000013
         END                                                            75200013
