         TITLE 'IGE0004B - BTAM ERR DATA CHECK LOAD TWO MODULE'         00400013
IGE0004B CSECT                                                          00800013
*71660066444000,468000                                             000B 01400014
*CC271800024000                                                    000G 01700017
         SPACE 2                                                        02000013
* STATUS -          CHANGE LEVEL 002    MAY 10, 1968               000G 02400017
         SPACE 2                                                        02800013
*********************************************************************** 03200013
*              ERROR RECOVERY DATA CHECK DIAGNOSTIC ROUTINE           * 03600013
*                                                                     * 04000013
* FUNCTION -      1.ATTEMPT ERROR RECOVERY OF DATA CHECK ERRORS       * 04400021
*                   OCCURING DURING OR AFTER TEXT TRANSFERS.          * 04800013
*                   ERRORS THAT OCCUR AFTER TEXT TRANSFER ARE         * 05200013
*                   RETRIED AUTOMATICALLY. ERRORS THAT OCCUR          * 05600013
*                   DURING TEXT TRANSFER ARE RETRIED ONLY IF          * 06000013
*                   DECERROP PARAMETER SPECIFIES READ RETRIES.        * 06400013
*                                                                     * 06800013
*                 2.PROVIDE LINKAGE TO LINE ERROR RECORDING           * 07200013
*                   ROUTINE IF LERB INDICATOR IS SPECIFIED IN         * 07600013
*                   DECERROP PARAMETER                                * 08000013
*                                                                     * 08400013
*                 3.PROVIDE LINKAGE TO POST ROUTINE IF ERROR          * 08800013
*                   IS DETERMINED PERMANENT OR IF DURING TEXT         * 09200013
*                   TRANSFER AND READ RETRIES ARE NOT SPECIFIED       * 09600013
*                                                                     * 10000013
* ENTRY POINTS -    ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION      * 10020021
*                                                                     * 10040021
* INPUT -           REGISTER ONE CONTAINS POINTER TO ASSOCIATED RB.   * 10060021
*                                                                     * 10080021
* OUTPUT -          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR   * 10100021
*                   ERROR. SETS INDICATOR FOR DISABLE REQUIRED IN     * 10120021
*                   DECERRST.                                         * 10140021
*                                                                     * 10160021
* EXITS -           EXITS THROUGH LINKAGE TO LERB IF ERROR COUNTS ARE * 10180021
*                   REQUIRED, TO DIAGNOSTIC WRITE/READ ROUTINE IF 2701* 10200021
*                   IS BEING USED, OR TO ERROR POST.                  * 10220021
*                                                                     * 10240021
* ATTRIBUTES -      MODULE IS TRANSIENT, ENABLED, AND REENTRANT       * 10260021
*              DATA CHECK ERROR RECOVERY ROUTINE LOAD TWO               10400013
*********************************************************************** 10800013
         USING *,BASREG                                                 11200013
         L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  11600013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  12000013
         L     COMREG,LOC016            ADDRESS OF CVT                  12400013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 12800013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  13200013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  13600013
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           14000013
         CLI   IOBECT+1(IOBRG),MASK3    ENTRY FROM 1ST LOAD FOR LERB CK 14400013
         BE    ERRDCD03                 YES CHECK FOR LERB REQUIRED     14800013
         CLI   0(CCWREG),CCWAPOLL       POLL COMMAND               000A 15200013
         BE    ERRDCD12                 YES TREAT AS READ          000A 15600013
         CLI   0(CCWREG),CCWINCMD       INHIBIT COMMAND                 15700019
         BE    READ                                                     15800019
         CLI   0(CCWREG),CCWRDCMD       READ COMMAND                    16000013
         BNE   ERRDCD00                 NO CHECK FOR WRITE              16400013
READ     EQU   *                                                        16600019
         CLI   IOBWRK(IOBRG),CCWTWXID   READ RESPONSE TWX ID            16800013
         BE    ERRDCD01                 YES INITIALIZE START            17200013
         CLI   IOBCPA(IOBRG),CCWDISAB   FIRST COMMAND A DISABLE         17600013
         BNE   ERRDCD01                 NO INITIALIZE START             18000013
         LA    ERREG1,IOBCMD3(IOBRG)    SET CPA TO THIRD CCW            18400013
         ST    ERREG1,IOBSTART(IOBRG)   STORE IN POINTER                18800013
         B     ERRDCD03                 CHECK FOR LINE ERROR RECORDING  19200013
ERRDCD00 CLI   0(CCWREG),CCWWRT         WRITE COMMAND                   19600013
         BE    ERRDCD02                                                 20000013
         OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 20400013
         B     ERRDCD05                 CHECK FOR SWITCHED LINE         20800013
ERRDCD02 CLI   IOBWRK+2(IOBRG),TTYADPT1 THIS TELETYPE ADAPTER 1         21200013
         BE    ERRDCD14                 IF SO, BRANCH              000A 21600013
         CLI   IOBWRK+2(IOBRG),TTYADPT2 THIS TELETYPE ADAPTER 2         22000013
         BE    ERRDCD14                 IF SO, BRANCH              000A 22400013
         MVI   IOBECT(IOBRG),ERTRYCT    SET RETRY COUNT TO 2            22800013
         TM    UCBTYP+3(UCBREG),X'90'   IS MAY BE A WTTA           000G 22880017
         BNZ   ERRDCD03                 BRANCH IF NOT              000G 22960017
         TM    UCBTYP+3(UCBREG),X'60'   IS A WTTA                  000G 23040017
         BO    ERRDCD16                 BRANCH IF YES              000G 23120017
         B     ERRDCD03                 CHECK FOR LINE ERROR RECORDING  23200013
ERRDCD01 EQU   *                                                        23600013
         CLI   IOBWRK(IOBRG),CCWRDIX    READ RESP TO POLL ID       000A 24000013
         BNE   ERRDCD13                 NO ALL COMMANDS GOOD       000A 24400013
ERRDCD12 EQU   *                                                   000A 24800013
         L     ERREG1,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FROM    000A 25200013
*    PREVIOUS POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).    000A 25600013
         MVC   IOBCPA+9(3,IOBRG),DECENTRY+1(DECBRG)    MOVE IN     000A 26000013
*    ADDRESS OF LAST ENTRY POLLED (TO BE USED AS RESTART ADDRESS). 000A 26400013
         L     ERREG4,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FOR     000A 26800013
*    NEXT POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).        000A 27200013
         SR    ERREG1,ERREG4            SUBTRACT NEW POLL ADDRESS  000A 27600013
*                                  FROM PREVIOUS POLL ADDRESS.     000A 28000013
         AH    ERREG1,IOBCPA+14(IOBRG)  IF THE NEW POLL ADDRESS    000A 28400013
*    WERE LESS THAN THE PREVIOUS POLL ADDRESS, THE EFFECT IS TO    000A 28800013
*    ADD THE ABSOLUTE DIFFERENCE TO THE PREVIOUS COUNT;  IF IT WERE000A 29200013
*    GREATER, THE EFFECT IS TO SUBTRACT THE ABSOLUTE DIFFERENCE    000A 29600013
*    FROM THE PREVIOUS COUNT.                                      000A 30000013
         STH   ERREG1,IOBCPA+14(IOBRG)  STORE ADJUSTED COUNT IN    000A 30400013
*                                  POLL COMMAND.                   000A 30800013
ERRDCD13 EQU   *                                                   000A 31200013
         LA    ERREG2,IOBCPA(IOBRG)     START OF CHANNEL PROGRAM        31600013
         ST    ERREG2,IOBSTART(IOBRG)   STORE CPA IN POINTER            32000013
ERRDCD03 MVI   IOBECT+1(IOBRG),NONAME   CLEAR SPECIAL ENTRY INDICATOR   32400013
         TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQUIRED   32800013
         BZ    ERRDCD04                 NO CHECK RETRIES                33200013
         MVI   IOBECT-1(IOBRG),LERBDC   INDICATE LERB DATA CHECK ERROR  33600013
ERRDCD04 CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED                  34000013
         BL    ERRDCD06                 YES UPDATE RETRY COUNT          34400013
         TM    DCBBFTEK(DCBREG),DYNBUF IS DYN BUF SPECIFIED?     A41129 34500021
         BO    ERRDCD05                YES, NO DIAG ISSUED       A41129 34600021
         CLI   IOBWRK+3(IOBRG),CTRL2701 THIS A 2701 CONTROL UNIT        34800013
         BE    ERRDCD10                 YES ISSUE DIAG WRITE/READ       35200013
ERRDCD05 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                35600013
         BZ    ERRDCD07                 NO INDICATE PERMANENT ERROR     36000013
         MVC   IOBSAV1+8(8,IOBRG),0(CCWREG) SAVE FAILING CCW            36400013
         MVC   IOBSAV1(1,IOBRG),IOBSNS(IOBRG) SAVE SENSE BYTE           36800013
         MVC   IOBSAV1+1(7,IOBRG),IOBCSW+1(IOBRG) SAVE CSW DATA         37200013
         MVC   IOBDCCW(8,IOBRG),DISABCMD GENERATE DISABLE CCW           37600013
         LA    ERREG1,IOBDCCW(IOBRG)    ADDRESS OF CCW                  38000013
         ST    ERREG1,IOBSTART(IOBRG)   CPA START IN POINTER            38400013
         MVI   IOBECT+1(IOBRG),DISABIND INDICATE DISABLE EXECUTED       38800013
         OI    DECERRST(DECBRG),DISABLOK INDICATE DISABLE EXECUTED      39200013
ERRDCD06 IC    ERREG1,IOBECT(IOBRG)     RETRY COUNT                     39600013
         LA    ERREG1,1(ERREG1)         BUMP COUNT                      40000013
         STC   ERREG1,IOBECT(IOBRG)     STORE NEW COUNT                 40400013
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                41600013
         CLI   IOBECT-1(IOBRG),NONAME  IS LERB SPECIFIED         A27639 42300019
         BNE   ERRDCD09                IF YES, BRANCH            A27639 43000019
         SVC   EXCPER                   ISSUE EXCP                      43800019
         SVC   RETURN                   RELEASE TRANSIENT AREA          44000013
ERRDCD07 NI    IOBFL1(IOBRG),MASKALL-IOBERR  INDICATE POST TO LERB 000B 44200014
         CLI   IOBECT-1(IOBRG),NONAME   LINE ERROR RECORDING       000B 44400014
         BNE   ERRDCD09                                                 44800013
         LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         45200013
ERRDCD08 L     ERRETR,VECTXL(COMREG)    LINK ROUTINE                    45600013
         BR    ERRETR                   LINK                            46000013
ERRDCD09 LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         46400013
         B     ERRDCD08                 EXIT VIA LINK                   47200013
ERRDCD10 CLI   IOBECT-1(IOBRG),NONAME   LINE ERROR RECORDING REQUIRED   47600013
         BE    ERRDCD11                 NO EXIT TO DIAG WRT/RD          48000013
         MVI   IOBECT+1(IOBRG),RTRNCDE  INDICATE DIAG WR/RD REQ         48400013
         LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         48800013
         B     ERRDCD08                 EXIT VIA LINK                   49200013
ERRDCD11 LA    SAVREG,ERLOD11           ADDRESS OF DIAG WR/RD ROUTINE   49600013
         B     ERRDCD08                                                 50000013
ERRDCD14 TM    5(CCWREG),CCWTXTDT       DURING TEXT TRANSFER       000A 50400013
         BZ    ERRDCD13                 IF NOT, GO TO RETRY        000A 50800013
         TM    DCBERROP(DCBREG),CCWRTRT WRITE RETRIES SPECIFIED    000A 51200013
         BO    ERRDCD13                 IF SO, GO TO RETRY         000A 51600013
ERRDCD16 EQU   *                                                   000G 51800017
         TM    DCBERROP(DCBREG),DCBLERB LINE ERROR COUNTS          000A 52000013
         BZ    ERRDCD15                 IF NOT, POST               000A 52400013
         MVI   IOBECT-1(IOBRG),LERBDC   INDICATE LERB DATA CHECK   000A 52800013
         NI    IOBFL1(IOBRG),MASKALL-IOBEXE  INDICATE POST WITH NO 000A 53200013
*                                  ERROR MESSAGE                   000A 53600013
         B     ERRDCD09                                            000A 54000013
ERRDCD15 NI    IOBFL1(IOBRG),MASKALL-IOBERR  INDICATE PERM ERROR   000A 54400013
         SVC   EXCPER                                              000A 54800013
         SVC   RETURN                                              000A 55200013
DISABCMD DC    X'2F00000020300001'                                      55600013
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 56000013
ERLOD5   DC    H'5041'                                             000A 56400013
ERRCN1   DC    H'8'                     DECIMAL 8                  000A 56800013
CCWAPOLL EQU   X'09'                                               000A 57200013
CCWINCMD EQU   X'0A'                                                    57400019
CCWDISAB EQU   X'2F'                                                    57600013
CCWRDCMD EQU   X'02'                                                    58000013
CCWRDIX  EQU   X'0A'                                               000A 58400013
CCWRTRT  EQU   X'04'                                               000A 58800013
CCWTXTDT EQU   X'10'                                               000A 59200013
CCWTWXID EQU   X'07'                                                    59600013
CCWWRT   EQU   X'01'                                                    60000013
CSWSNO   EQU   X'40'                                                    60400013
CTRL2701 EQU   X'02'                                                    60800013
DCBERROP EQU   33                                                       61200013
DCBBFTEK EQU   X'20'                                             A41129 61300021
DYNBUF   EQU   X'08'                                             A41129 61400021
DCBLERB  EQU   X'08'                                                    61600013
DECENTRY EQU   20                                                  000A 62000013
DECERRST EQU   29                                                       62400013
DISABIND EQU   X'80'                                                    62800013
DISABLOK EQU   X'08'                                                    63200013
ERLOD11  EQU   1042                                                     63600013
ERLOD12  EQU   2042                                                     64000013
ERTRYCT  EQU   X'02'                                                    64400013
EXCPER   EQU   15                           EXCP ERROR ROUTINE          64800013
IOBCPA   EQU   64                                                       65200013
IOBCMD3  EQU   IOBCPA+16                                                65600013
IOBCSW   EQU   8                            CSW STORAGE                 66000013
IOBDCBAD EQU   20                                                       66400013
IOBDCCW  EQU   40                                                       66800013
IOBDECB  EQU   4                                                        67200013
IOBECT   EQU   30                      ERROR COUNTS                     67600013
IOBERR   EQU   X'20'                        IOB ERROR FLAG              68000013
IOBEX    EQU   X'04'                        EXCEPT FLAG                 68400013
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                68800013
IOBFL1   EQU 0                              FLAGS 1                     69200013
IOBSAV1  EQU   48                                                       69600013
IOBSNS   EQU   2                                                        70000013
IOBSTART EQU   16                                                       70400013
IOBWRK   EQU   33                                                       70800013
LERBDC   EQU   X'01'                                                    71200013
LOC016   EQU   16                           COMMUNICATIONS TABLE        71600013
MASKALL  EQU   255                                                      72000013
MASK15   EQU   X'0F'                                                    72400013
MASK3    EQU   X'F0'                                                    72800013
NONAME   EQU   X'00'                                                    73200013
RETURN   EQU   3                       RETURN SVC                       73600013
RTRNCDE  EQU   X'C0'                                                    74000013
SWLINE   EQU   X'90'                                                    74400013
TSTIOB   EQU   5                            IOB POINTER                 74800013
TSTUCB   EQU   2                            UCB POINTER                 75200013
TTYADPT1 EQU   X'40'                                             A28602 75600019
TTYADPT2 EQU   X'50'                                             A28602 76000019
UCBTYP   EQU   16                      DEVICE TYPE CODE                 76400013
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      76800013
*        REGISTER DEFINITION                                            77200013
ERREG3   EQU   0                             WORK REG                   77600013
TSTREG   EQU   1                             TWELVE STAR REG            78000013
ERREG2   EQU   2                             WORK REG                   78400013
CRBREG   EQU   3                             CURRENT RB REG             78800013
CCWREG   EQU   4                             CCW ADDRESS REG            79200013
DECBRG   EQU   5                        DECB REGISTER                   79600013
DCBREG   EQU   6                        DCB REGISTER                    80000013
UCBREG   EQU   7                             UCB ADDRESS  REG           80400013
COMREG   EQU   8                             COMMUNICATION TABLE REG    80800013
ERREG1   EQU   9                                                        81200013
IOBRG    EQU   10                            IOB ADDRESS REG            81600013
ERREG4   EQU   11                            WORK REG                   82000013
ERRLNK   EQU   12                            LINK REG                   82400013
SAVREG   EQU   13                                                       82800013
ERRETR   EQU   14                            RETURN REG                 83200013
BASREG   EQU   15                            BASE REG                   83600013
         END                                                            84000013
