         TITLE ' IGE0004C  -  BSC ERP CONTROL MODULE '                  00100016
IGE0004C CSECT                                                          00200016
*72440015210000                                                    000C 00300016
*********************************************************************** 00400016
*              BINARY SYNCHRONOUS ERROR RECOVERY PROCEDURES           * 00500016
*                                                                     * 00600016
*              THE BINARY SYNCHRONOUS ERROR RECOVERY PROCEDURES       * 00700016
*        ROUTINES ARE A COMPOSITE SET OF ROUTINES DESIGNED TO         * 00800016
*        DIAGNOSE AND ATTEMPT RECOVERY FROM ALL ERRORS ENCOUNTERED    * 00900016
*        DURING TRANSMISSION OF BINARY SYNCHRONOUS DATA.              * 01000016
*********************************************************************** 01100016
*              WORK AREA ALLOCATION FOR BTAM BSC ERROR ROUTINES       * 01200016
*                                                                     * 01300016
*              THE WORK AREAS UTILIZED BY BTAM BSC ARE AS FOLLOWS:    * 01400016
*        1.IOBINCAM+1 USED TO DESIGNATE LINE ERROR RECORDING REQUIRED * 01500016
*              A VALUE OF 01=DATA CHECK ERROR                         * 01600016
*                         02 = INTERVENTION REQUIRED ERROR            * 01700016
*                         03=TIME OUT ERROR                           * 01800016
*                                                                     * 01900016
*        2.IOBERRCT USED TO MAINTAIN A COUNT OF ERP RETRIES ATTEMPTED * 02000016
*              FOR EACH OPERATION REQUESTED.                          * 02100016
*        3.IOBERRCT+1 LINK FIELD FOR SPECIAL RETURNS TO A PARTICULAR  * 02200016
*              ERP ROUTINE AFTER A RETRY HAS BEEN ATTEMPTED.          * 02300016
*        4.IOBWORK USED AS A WORK AND READ IN AREA FOR ERP            * 02400016
*                                                                     * 02500016
*        5.IOBERCCW HAS THREE CCW'S USE TO CREATE SPECIAL OPERATIONS  * 02600016
*              REQUIRED BY ERP TO EFFECT ERROR RECOVERY               * 02700016
*              LINKAGE  CONVENTIONS USED BY BTAM BSC ERP ROUTINES     * 02800016
*                                                                     * 02900016
*              STANDARD LINKAGE CONVENTIONS FOR ERP ROUTINES ARE      * 03000016
*        UTILIZED BY BTAM BSC ERP ROUTINES.                           * 03100016
*********************************************************************** 03200016
*              BTAM BSC ERROR RECOVERY CONTROL ROUTINE                * 03300016
*                                                                     * 03400016
*              THIS ROUTINE IS THE FIRST LOAD OF EACH ERP RETRY       * 03500016
*        ATTEMPT. THE ERRTAB BYTE IN THE ASSOCIATED UCB CONTAINS      * 03600016
*        THE NAME OF THIS ROUTINE AND IS ALWAYS REQUESTED BY IOS      * 03700016
*        WHEN ERP IS REQUIRED. THIS ROUTINE PERFORMS THE FOLLOWING    * 03800016
*        FUNCTIONS:                                                   * 03900016
*              1. PROVIDES LINKAGE TO PROPER ERP ROUTINE FOR TYPE OF  * 04000016
*                 ERROR ENCOUNTERED.                                  * 04100016
*              2. DETERMINES IF ERP RETRIES ARE SUCCESSFUL.           * 04200016
*              3. MAINTAINS SOR TABLE FOR TEMPORARY ERRORS.           * 04300016
*              4. GENERATES RETURN LINKAGE TO OTHER ERP ROUTINES.     * 04400016
*                                                                     * 04500016
*        ENTRY:    FIRST INSTRUCTION                                  * 04600016
*                                                                     * 04700016
*        INPUT:    REGISTER ONE POINTER TO IQE                        * 04800016
*                                                                     * 04900016
*        EXITS:    SUBSEQUENT LOADS OF ERP ROUTINES AND RESIDENT      * 05000016
*                  INTERPRETER ROUTINE.                               * 05100016
*        OUTPUT:   NONE                                               * 05200016
*                                                                     * 05300016
*                  THE ATTRIBUTES ARE; ENABELED, REENTRANT, TRANSIENT,* 05400016
*              AND A PROTECT KEY OF ZERO                              * 05500016
*********************************************************************** 05600016
         USING IECTDECB,DECBRG               START OF DECB DESECT       05700016
         USING IECTIOB,IOBRG                 START OF IOB DESECT        05800016
         USING IHADCB,DCBREG                 START OF DCB DESECT        05900016
         USING *,BASREG                                                 06000016
         SPACE 2                                                        06100016
         L     IOBRG,TSTIOB(TSTREG)          ADDRESSABILITY FOR IOB     06200016
         L     COMREG,CVTPTR                 ADDRESS OF CVT TABLE       06300016
         L     DECBRG,IOBECBPT               ADDRESSABILITY FOR DECB    06400016
         L     DCBREG,IOBDCBPT               ADDRESSABILITY FOR DCB     06500016
         LH    UCBREG,TSTUCB(TSTREG)         ADDRESS OF UCB             06600016
         L     ERRETR,VECTXL(COMREG)        XCTL ROUTINE ADDRESS        06700016
         SR    CRBREG,CRBREG                CLEAR WORK REGISTER         06800016
         LA    ERREG2,ERRRTCON         SET UP FOR INDEXING              06900016
         SR    ERREG1,ERREG1                 CLEAR LINKAGE REGISTER     07000016
         SR    ERREG3,ERREG3            ZERO ERROR IN CONTROL           07100016
         SPACE 2                                                        07200016
         TM    DCBOFLGS,X'11'           IS CLOSE IN PROCESS             07230016
         BO    BSCCT025                 IF SO, BRANCH                   07260016
         TM    IOBCSW+5,CSWCCK          CHAN OR INTERFACE CTL CHECK000C 07300016
         BZ    NOTCHAN                  BRANCH IF NOT              000C 07400016
         BCT   ERREG1,BSCCT016         LINK TO PROPER ROUTINE           07500016
NOTCHAN  TM    IOBSIOCC,IOBCC3         SIO COND CODE 1 OR 3        000C 07600016
         BNZ   BSCCT000                                            000C 07700016
         L     CCWREG,IOBCSW            ADDRESS OF CCW             000C 07800016
         LA    CCWREG,0(CCWREG)        CLEAR HI ORDER BYTE       A35723 07850020
         SH    CCWREG,ERRCON08          ADJUST TO FAILING CCW      000F 07900016
         BP    BSCCT001                      CSW GOOD                   08000016
BSCCT000 L     CCWREG,IOBSTART         GET ADDRESS OF CCW          000C 08100016
         LA    SAVREG,8(CCWREG)        ADDRESS OF NEXT CCW              08200016
         ST    SAVREG,IOBCSW           STORE  IN CSW                    08300016
BSCCT001 OI    IOBFLAG3,IOBMSG               INDICATE I/O ERR TO MSG WT 08400016
         MVC   IOBWORK(1),TPOPCODE(CCWREG) SETUP WORK AREA              08500016
         NI    IOBWORK,MASKALL-HIBIT   CLEAR UNUSED BITS                08600016
*                                            INDICATOR                  08700016
         TM    IOBFLAG1,IOBEXE               ERP ROUTINE IN CONTROL     08800016
         BNO   BSCSAVE                      NO,  SAVE SENSE, CSW INFO   08900016
         TM    IOBCSW+4,CSWUCK          UNIT CHECK OCCUR           000C 09000016
         BO    BSCCT003                 YES CONTINUE FLOW          000C 09100016
         STH   CRBREG,UCBSENS0(UCBREG)  CLEAR SENSE INFO           000C 09200016
BSCCT003 EQU   *                                                   000C 09300016
         IC    CRBREG,IOBERRCT+1       BRANCH OFFSET TO LOADS           09400016
         LTR   CRBREG,CRBREG            ERROR RETURN                    09500016
         BP    BSCCT008(CRBREG)         YES, GO THERE                   09600016
         CLI   5(CCWREG),NONAME        IS THIS ERP CCW?          A43784 09610021
         BNE   BSCCT002                NO                        A43784 09620021
         TM    IOBCSW+4,X'F3'                                    A43784 09630021
         BNZ   BSCCT002                                          A43784 09640021
         TM    IOBCSW+4,X'0C'          CHECK FOR BOTH CE DE      A43784 09650021
         BNZ   SETMAX                  IF BOTH ON SET MAX RETRY  A43784 09660021
BSCCT002 OI    IOBFLAG1,IOBEXE               INDICATE ERP IN CONTROL    09700016
         TM    IOBSIOCC,IOBCC3               SIO COND CODE 3            09800016
         BO    BSCCT005                      YES, GO TO MSG WRITER      09900016
         BM    BSCCT016                 SIO COND CODE 1            000F 10000018
         TM    IOBCSW+4,CSWASCB              ATTEN, STATUS MOD, CONTROL 10200016
*                                            UNIT END OR BUSY INDICATED 10300016
         BNZ   BSCCT008                      YES, SNO & ERROR POST      10400016
BSCSA00  LR    ERREG1,BASREG           SAVE BASE                        10500016
         L     BASREG,VECTINT(COMREG)  LINK ADDRESS                     10600016
BSCS000  BALR  ERRLNK,BASREG           LINK TO INTERPRETER              10700016
         DC    X'16'                   UNIT CHECK INDICATOR             10800016
         DC    AL1(BSCCT009-BSCS000-2) INDEX TO UNIT CHECK ROUTINE      10900016
         DC    X'1F'                   CHAIN CHECK INDICATOR            11000016
         DC    AL1(BSCS001-BSCS000-4)  INDEX TO CHAIN CHECK ROUTINE     11100016
         DC    X'1A'                   PROGRAM CHECK INDICATOR          11200016
         DC    AL1(BSCS001-BSCS000-6)  INDEX TO PROGRAM CHECK ROUTINE   11300016
         DC    X'1B'                   PROTECTION CHECK INDICATOR       11400016
         DC    AL1(BSCS001-BSCS000-8)  INDEX TO PROTECTION CHECK RTN    11500016
         DC    X'17'                   UNIT EXCEPTION INDICATOR         11600016
         DC    AL1(BSCUE0AA-BSCS000-10) INDEX TO UNIT EXCEPTION ROUTINE 11700016
         DC    X'1C'                   CHANNEL DATA CHECK INDICATOR     11800016
         DC    AL1(BSCCT016-BSCS000-12) INDEX TO CHAN DATA CHK RTN      11900016
         DC    X'2F'                   SCAN END INDICATOR               12000016
         DC    AL1(BSCS002-BSCS000-14)  INDEX TO SCAN END ID            12100016
*   AT THE END OF STATUS CHECK YOU SHOULD HAVE ONLY CE OR DE OR SLI     12200016
*     IF SO, TEST ERREG4 -- IF ZERO--NTO FORST TIME THRU-- GO TO        12300016
*     BSCCT004  ///--  NORMAL                                           12400016
BSCS002  LTR   ERREG3,ERREG3            FIRST TIME THRU ERP             12500016
         BZ    BSCCT004                NO, POST  NORMAL RETURN          12600016
         OI    DECERRST,DECSNO                                          12700016
BSCS001  OI    IOBFLAG3,IOBLOG         INDICATE OBR RECORDING           12800016
         B     BSCCT022                LINK TO ERROR POST               12900016
SETMAX   MVI   IOBERRCT,ERRMAXCT       SET RETRY TO MAX          A43784 12920021
         OI    DECERRST,DECSNO         SET SHOULD NOT OCCUR      A43784 12940021
         B     BSCCT022                LINK TO ERROR POST        A43784 12960021
*                                                                       13000016
BSCCT025 NI    IOBFLAG1,MASKALL-IOBERR  TURN OFF IOB EXCEPTION          13050016
BSCCT013 SVC   EXCPER                        RETRY CHANNEL PROGRAM      13100016
         SVC   RETURN                                                   13200016
*                                                                       13300016
BSCCT004 NI    IOBFLAG1,MASKALL-IOBEXE       TURN OFF ERP CONTROL INDS. 13400016
         MVI   IOBSENS0,NONAME                                          13500016
         BAL   ERREG3,BSCCT00A         GO SET UP STAT TABLE             13600016
         NI    ERRCN2(SAVREG),MASKALL-FIRSTBIT                          13700016
         BE    BSCCT013                      NO,  POST OPERATION COMP   13800016
         LA    SAVREG,STATUP                 STAT UPDATE ROUTINE NAME   13900016
         BR    ERRETR                        EXIT VIA XCTL              14000016
         SPACE 2                                                        14100016
BSCCT00A L     SAVREG,STATAB(COMREG)   SET STASTICS TABEL PTR           14200016
         SR    CRBREG,CRBREG                                            14300016
         IC    CRBREG,UCBSTI(UCBREG)         INDEX TO STATISTICS TABLE  14400016
         LR    CCWREG,SAVREG            SAVE STAT TBL START ADDR   000H 14420018
ERRLOOP1 CH    UCBREG,0(CCWREG)         DEVICE SUPPORTED THIS SECT 000H 14440018
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 14460018
         LA    CCWREG,2(CCWREG)         POINT TO NXT CTL ENTRY     000H 14480018
         LA    CRBREG,256(CRBREG)       POINT TO NXT STAT TBL SECT 000H 14500018
         B     ERRLOOP1                 LOOP TO CHECK THIS SECT    000H 14520018
ERRLOOP2 MH    CRBREG,ERRCON2           ADJUST FOR ENTRY LENGTH    000H 14540018
         AR    SAVREG,CRBREG           RESOLVE ACTUAL ADDRESS           14600016
         BR    ERREG3                  RETURN                           14700016
         SPACE 2                                                        14800016
BSCSAVE  MVC   IOBERCCW+16(1),IOBSENS0       MOVE SENSE INFO TO AREA    14900016
         MVC   IOBERCCW+17(7),IOBCSW+1       MOVE CSW TO AREA           15000016
         XC    IOBWORK+1(3),IOBWORK+1   CLEAR WORK AREA            000E 15050016
         XC    IOBERCCW(8),IOBERCCW   CLEAR ERP CCW AREA         A55974 15070021
         LR    ERREG3,IOBRG                                             15100016
         B     BSCCT002                      SET ERP IN CONTROL         15200016
         SPACE 2                                                        15300016
BSCCT005 LH    SAVREG,ERLOD16                INT REQ MSG WRITER ADDRESS 15400016
         BR    ERRETR                       LINK TO MSG WRITER          15500016
         SPACE 2                                                        15600016
BSCCT009 TM    IOBCSW+4,CSWCDE               BOTH CHAN AND DEV END OFF  15700016
         BZ    BSCCT016                INITIAL SELECTION                15800016
BSCCT012 LR    ERREG1,BASREG                 SAVE BASREG                15900016
         L     BASREG,VECTINT(COMREG)        LOAD INTERPRETER RTNE NAME 16000016
BSCCT014 BALR  ERRLNK,BASREG                 EXIT TO INTERPRETER RTNE   16100016
         DC    X'03'                         EQUIPMENT CHECK            16200016
         DC    AL1(BSCCT016-BSCCT014-2)                                 16300016
         DC    X'06'                         LOST DATA                  16400016
         DC    AL1(BSCCT018-BSCCT014-4)                                 16500016
         DC    X'07'                         TIME OUT                   16600016
         DC    AL1(BSCCT020-BSCCT014-6)                                 16700018
         DC    X'01'                         INTERVENTION REQUIRED      16800016
         DC    AL1(BSCCT021-BSCCT014-8)                                 16900016
         DC    X'02'                         BUS-OUT CHECK              17000016
         DC    AL1(BSCCT017-BSCCT014-10)                                17100016
         DC    X'04'                         DATA CHECK                 17200016
         DC    AL1(BSCCT023-BSCCT014-12)                                17300016
         DC    X'05'                         OVERRUN                    17400016
         DC    AL1(BSCCT017-BSCCT014-14)                                17500016
         DC    X'00'                         COMMAND REJECT             17600016
         DC    AL1(BSCCT016-BSCCT014-16)                                17700016
         DC    X'2F'                         END OF TEST                17800016
         DC    AL1(BSCCT008-BSCCT014-18)                                17900016
         SPACE 2                                                        18000016
*                   THE FOLLOWING TABLE OF LOAD ADDRESSES ARE         * 18100016
*                   DESIGNED TO PROVIDE THE PROPER LINKAGE TO         * 18200016
*                   THE ERROR ROUTINE REQUIRED, VIA XCTL RTNE         * 18300016
*                                                                       18400016
BSCCT008 OI    DECERRST,CSWSNO               SET SHOULD NOT OCCUR ERR   18500016
BSCCT016 AR    ERREG1,ERREG2           ENTRY EQUIP CHECK                18600016
BSCCT017 AR    ERREG1,ERREG2           ENTRY BUSOUT OVERRUN             18700016
BSCCT018 AR    ERREG1,ERREG2           ENTRY LOST DATA                  18800016
         BAL   ERREG3,BSCCT00A         FIND STATUP TBL                  18900016
         OC    ERRCN2(1,SAVREG),IOBSENS0                                19000016
BSCCT019 AR    ERREG1,ERREG2           ENTRY SPEC RETURN                19100016
BSCCT020 AR    ERREG1,ERREG2           ENTRY 2ND LOAD T/O RTN           19200016
BSCCT021 AR    ERREG1,ERREG2           ENTRY INTERVENTION REQ           19300016
BSCCT022 AR    ERREG1,ERREG2           ENTRY ERROR POST                 19400016
BSCCT023 LA    SAVREG,BSCLOD1(ERREG1)  ENTRY DATA CHECK                 19500016
         BR    ERRETR                       LINK TO NEXT ERP MODULE     19600016
*                                             NEXT ERP MODULE           19700016
         SPACE 2                                                        19800019
BSCUE0AA CLI   0(CCWREG),CCWREAD   IS THIS READ OPERATION               19900019
         BNE   BSCUE0TP                                                 20000019
         LTR   ERREG3,ERREG3       FIRST TIME THRU ERP                  20100019
         BZ    BSCEREAD                NO, CHECK TP-OP CODE      A26910 20200019
         CLI   IOBWORK,X'11'           READ TEXT                  M2826 20205019
         BNE   BSCUE0A1                NO, LOAD UNIT EXCEPTION    M2826 20210019
         LH    ERREG3,6(CCWREG)        PICK UP ORIG CT            M2826 20215019
         BCTR  ERREG3,0                SUBTRACT ONE               M2826 20220019
         CH    ERREG3,IOBCSW+6         THIS COUNT = RESIDUAL COUNTM2826 20225019
         BNE   CHKSOHR                 NO, CHK FOR SOH%R MSG            20230021
         L     ERREG3,0(CCWREG)        ENQ POINTER                M2826 20235019
         CLC   0(1,ERREG3),DCBBSENQ    ENQ RECEIVED               M2826 20240019
         BNE   BSCUE0A1                NO, LOAD UNIT EXCEPTION    M2826 20245019
         TM    DCBBFTEK,DYNBUF         DYNAMIC BUFFER             M2826 20250019
         BO    BSCUET09                YES, POST WITH ERROR       M2826 20255019
         CLI   DECTYPE+1,X'13'         RD CONT/GRAPHICS           M2826 20260019
         BE    BSCUETAB                YES, BRANCH                M2826 20265019
         CLI   DECTYPE+1,X'17'         RD REPEAT/GRAPHICS         M2826 20270019
         BNE   BSCUE0A1                NO, LOAD UNIT EXCEPTION    M2826 20275019
BSCUETAB SH    CCWREG,ERRCON16         BACK UP TO WR GRAPHICS     M2826 20280019
         B     BSCUETA7                BRANCH TO EXECUTE          M2826 20285019
CHKSOHR  L     ERREG3,IOBERINF         GET ADDR OF INPUT AREAP          20285521
         TM    DCBXCODE,ASCII      IS IT ASCII XMISSION CODE            20286021
         BO    USEASCII            YES, TEST FOR SOH%R IN               20288021
*                                   ASCII                               20288521
         CLC   0(SOHRLNG,ERREG3),EBCSOHR IS IT AN EBCDIC SOH%R          20289021
*                                   MESSAGE                             20289221
         BNE   BSCUE0A1            NO, LOAD UNIT EXCEPTION              20289521
         ST    ERREG3,IOBERINF     SAVE ADDR OF SOH%R MSG               20290021
         B     XFERCTL             YES, SET UP TO TRANSFER              20290521
*                                   CONTROL TO ERROR POST               20291021
USEASCII CLC   0(SOHRLNG,ERREG3),ASCSOHR IS IT ASCII SOH%R MSG          20291521
         BNE   BSCUE0A1            NO, LOAD UNIT EXCEPTION              20292021
XFERCTL  L     SAVREG,LOAD3270         LOAD ADDR OF 3270 ERROR POST     20292521
         BR    ERRETR              EXIT VIA XCTL ROUTINE                20293021
BSCUE0A1 LH    SAVREG,ERLOD904                                          20300019
         BR    ERRETR                                                   20400019
BSCUE0TP CLI   IOBWORK,TPOPERP          THIS ERP WR CCW          A28618 20500019
         BNE   BSCUE0A1                NO, GO TO UNIT EXCEPTION         20600019
         L     ERREG3,0(CCWREG)         GET WR CHAR              A28618 20700019
         CLC   0(1,ERREG3),DCBBSENQ     IS THIS ERP WR ENQ       A28618 20800019
         BNE   BSCUE02G                 CHECK FOR NAK            A28618 20900019
         MVI   IOBWORK+1,RTRNCD3        SET SP RETURN            A28618 21000019
         B     BSCUET2A                 COMPLETE RD SKIP CHAN PROG28618 21100019
BSCUE02G CLC   0(1,ERREG3),DCBBSNAK     IS THIS ERP WR NAK       A28618 21200019
         BNE   BSCUE0A1                NO, GO TO UNIT EXCEPTION         21300019
         MVI   IOBWORK+1,RTRNCD2        SET SP RETURN            A28618 21400019
BSCUET2A LA    ERREG4,CCWNOP           SET 2ND COMMAND FOR NO-OP        21500019
BSCUE02B LA    ERREG2,IOBWORK+2        DATA ADDRESS                     21600019
         LA    ERREG3,CCWREAD          SET IS COMMAND FOR READ          21700019
BSCUET04 EQU   *                                                   000F 21800019
BSCUET05 ST    ERREG2,IOBERCCW         STORE DATA ADDR IN CHAN PROG     21900019
         STC   ERREG3,IOBERCCW         STORE COMMAND IN 1ST CCW         22000019
BSCUET06 ST    ERREG3,IOBERCCW+4        PUT COUNT IN CCW           000F 22100019
         CLI   IOBWORK+1,NONAME                                         22200019
         BE    BSCUETA6                                                 22300019
         MVI   IOBERRCT+1,RTRNSPCD                                      22400019
BSCUETA6 EQU   *                                                        22500019
         CLI   IOBWORK+1,RTRNCD2        SPEC RETURN OF 82        A28618 22600019
         BNE   BSCUE02H                BRANCH IF NOT             A28618 22700019
BSCUE02J MVI   IOBERCCW+4,X'70'        COM CH, SLI, SKIP         A28618 22800019
         B     BSCUE02F                                          A28618 22900019
BSCUE02H CLI   IOBWORK+1,RTRNCD3        SPEC RETURN OF 83        A28618 23000019
         BE    BSCUE02J                 BRANCH IF YES            A28618 23100019
         ST    CCWREG,IOBERCCW+8       STORE TIC ADDR                   23200019
         MVI   IOBERCCW+4,CHAINCDE     COM CH, SLI               A28618 23300019
BSCUE02F STC   ERREG4,IOBERCCW+8        STORE COMMAND IN 2ND CCW A28618 23400019
         ST    ERREG3,IOBERCCW+12      PUT COUNT IN CCW          A25698 23500019
         LA    CCWREG,IOBERCCW         ADDR OF NEW CHAN PROG            23600019
         B     BSCUETA7                RETRY ERROR                      23700019
BSCEREAD EQU   *                                                 A26910 23800019
         CLI   5(CCWREG),NONAME        IS THIS ERP CCW           A26910 23900019
         BNE   BSCCT004                NO, POST NORMAL           A26910 24000019
         L     CCWREG,IOBERCCW+8       ADDRESS FAILING CCW       A26910 24100019
         B     BSCUETA7                RETRY FAILING CCW         A26910 24200019
         SPACE 2                                                        24300019
BSCUETA7 ST    CCWREG,IOBSTART                                          26800016
BSCUET08 CLI   IOBERRCT,ERRMAXCT       RETRIES EXHAUSTED                26900016
         BNL   BSCUET09                YES SET PERM ERROR               27000016
         IC    ERREG1,IOBERRCT          PICK UP RETRY COUNT             27100016
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     27200016
         STC   ERREG1,IOBERRCT          RESTORE NEW COUNT               27300016
         SVC   EREXCP                   EXECUTE CHAN PROGRAM            27600016
         SVC   RETURN                   NO EXIT NORMALLY                28100016
BSCUET09 NI    IOBFLAG1,MASKALL-IOBERR  INDICATE PERM ERROR             28200016
BSCUET0A LA    SAVREG,BSCLOD2           ADDRESS OF ERROR POST           28460016
         BR    ERRETR                  EXIT VIA XCTL ROUTINE            28520016
TSTIOB   EQU   4                                                        43400016
TSTUCB   EQU   2                                                        43500016
CVTPTR   EQU   16                                                       43600016
VECTXL   EQU   44                                                       43700016
VECT68   EQU   68                                                       43800016
DYNBUF   EQU   X'08'                                              M2826 43830019
ERRCON16 DC    H'16'                                              M2826 43860019
ERRCON08 DC    H'8'                                                     43900016
DECSNO   EQU   X'40'                                                    44100016
IOBLOG   EQU   X'01'                                                    44200016
MASKALL  EQU   X'FF'                                                    44300016
EXCPER   EQU   15                                                       44400016
RETURN   EQU   3                                                        44500016
BSCLOD1  EQU   1043                         BSC ERP BASE IDENT          44700016
BSCLOD2  EQU   2043                    BSC ERROR POST IDENT             44750016
ERRCON2  DC    AL2(10)                       CONSTANT 10                44800016
ERLOD16  DC    H'6042'                       WTOR ERP I.D.              44900016
ERRCN2   EQU   8                                                        45100016
CSWASCB  EQU   X'F0'                         ATTEN,STATUS,CTL UNIT,BUSY 45300016
CSWCCK   EQU   6                        CHAN CTL AND INTF CTL CHECK000C 45400016
CCWREAD  EQU   2                                                        45460019
ERLOD904 DC    H'9043'                                                  45520019
CSWCDE   EQU   X'0C'                         CHANNEL AND DEVICE END     45600016
CSWSNO   EQU   X'40'                         SHOULD NOT OCCUR           45700016
CSWUCK   EQU   X'02'                         UNIT CHECK                 45800016
ERRRTCON EQU   1000                          ERP LOAD MODULE INCREMENT  45900016
UCBSENS0 EQU   22                                                  000C 46000016
FIRSTBIT  EQU  X'80'                                                    46100016
IOBCC1   EQU   X'10'                        START I/O CODE 1            46200016
IOBCC3   EQU   X'30'                         START I/O CODE 3           46300016
IOBERR   EQU   X'20'                         IOB ERROR FLAG             46400016
IOBEX    EQU   X'04'                         IOB EXCEPTION FLAG         46500016
IOBEXE   EQU   IOBERR+IOBEX                  ERROR AND EXCEPTION        46600016
IOBMSG   EQU   X'04'                         MESSAGE TYPE               46700016
NORMCOND EQU   X'0D'                         CE,DE,UE FLAGS ON          46800016
NONAME   EQU   X'00'                                                    46900016
CCWNOP   EQU   3                                                        46910019
ERREG4   EQU   0                                                        46920019
CHAINCDE EQU   X'60'                                                    46930019
RTRNSPCD EQU   X'14'                                                    46940019
RTRNCD3  EQU   X'83'                                             A28618 46950019
RTRNCD2  EQU   X'82'                                                    46960019
TPOPERP  EQU   X'00'                                                    46970019
STATAB   EQU   112                           INDEX TO STATISTICS TABLE  47000016
STATUP   EQU   254                           STAT UPDATE LOAD NAME      47100016
UCBSTI   EQU   9                             STATISTICS POINTER         47200016
VECTINT  EQU   68                            INTERPRETER ROUTINE PTR    47300016
WLR      EQU   X'40'                         SLI FLAG                   47400016
TPOPCODE EQU   5                                                        48100016
HIBIT    EQU   X'C0'                                                    48200016
ERRMAXCT EQU   X'07'                                                    49000016
IOBSNDEN EQU   X'80'                                                    51100016
LOAD3270 DC    F'7042'             3270 ERROR POST IDENT                51200021
RDINIT   EQU   X'01'               READ INIT OPTYPE CODE                51300021
ASCII    EQU   X'14'               BIT SETTING FOR ASCII                51400021
EBCSOHR  DC    X'016CD9'           SOH%R SEQUENCE - EBCDIC              51500021
ASCSOHR  DC    X'012552'           SOH%R SEQUENCE - ASCII               51600021
SOHRLNG  EQU   3                   3 CHARS ARE NEEDED TO RECOG-         51630021
*                                  NIZE SOH%R MSG                       51660021
EREXCP   EQU   15                                                       51700016
TSTREG   EQU   1                             TWELVE STAR REGISTER       52200016
ERREG2   EQU   2                             WORK REGISTER 2            52300016
ERREG3   EQU   3                             WORK REGISTER 3            52400016
CCWREG   EQU   4                             CCW ADDRESS REGISTER       52500016
DECBRG   EQU   5                             DECB ADDRESS REGISTER      52600016
DCBREG   EQU   6                             DCB  ADDRESS REGISTER      52700016
UCBREG   EQU   7                             UCB  ADDRESS REGISTER      52800016
COMREG   EQU   8                             COMMUNICATION VECTOR REG   52900016
ERREG1   EQU   9                                                        53000016
IOBRG    EQU   10                            IOB ADDRESS REGISTER       53100016
CRBREG   EQU   11                                                       53200016
ERRLNK   EQU   12                            LINK REGISTER              53300016
SAVREG   EQU   13                            SAVE REGISTER              53400016
ERRETR   EQU   14                            RETURN REGISTER            53500016
BASREG   EQU   15                            BASE REGISTER              53600016
         IECTDECB                                                       53700016
         IECTIOBX                                                       53800016
         DCBD  DSORG=BX,DEVD=BS              DCB DESECT MACRO           53900016
         END                                                            54000016
