         TITLE 'IGE0004D BSC SPECIAL CHECK ERP ROUTINE'                 00500015
IGE0004D CSECT                                                          01000015
*72790002025000,445000                                             000C 01200015
         SPACE 2                                                        01500015
*********************************************************************** 02000015
* STATUS            CHANGE LEVEL 001    NOVEMBER 13, 1967             * 02500015
*                                                                     * 03000015
* FUNCTION         THIS ROUTINE CHECKS THE RESULTS OF SPECIAL         * 03500015
*                  I/O OPERATIONS INITIATED BY OTHER BSC ERP          * 04000015
*                  ROUTINES. IF THE RESULT IS THE DESIRED ONE,        * 04500015
*                  THIS ROUTINE RESTARTS THE CHANNEL PROGRAM          * 05000015
*                  WHERE THE INITIATING ERP ROUTINE HAS               * 05500015
*                  INDICATED FOR PROPER ERROR RECOVERY.               * 06000015
*                                                                     * 06500015
* INPUT            REGISTER ONE CONTAINS POINTER TO IO RB.            * 07000015
*                  IOBERRCT+1 CONTAINS A HEX VALUE FROM '80'          * 07500015
*                  TO X'FF'. THIS VALUE INDICATES THE TYPE OF         * 08000015
*                  OPERATION INITIATED AND THE RESPONSE ACTION        * 08500015
*                  OF THIS ROUTINE FOR A CORRECT ENDING. THE          * 09000015
*                  FOLLOWING TABLE DESCRIBES THE INITIATED            * 09500015
*                  OPERATION AND THE RESPONSE ACTION                  * 10000015
*                    VALUE  INITIATED OP   RESPONSE ACTION            * 10500015
*                    X'80'  READ ENQUIRY   RESTART FAILING CCW        * 11000015
*                    X'81'  READ ENQUIRY   WRITE NAK,RESTART FAIL CCW * 11500015
*                    X'82'  READ SKIP      WRITE NAK,RESTART FAIL CCW * 12000015
*                    X'83'  READ SKIP      WRITE ENQ,RESTART FAIL CCW * 12500015
*                    X'84'  READ ENQUIRY   CONTENTION CHECK           * 13000015
*                    X'85'  WRITE ENQUIRY  READ RESPONSE, CHECK ACK   * 13500015
*                    X'86'  WRITE TEXT     READ RESPONSE, CHECK ACK   * 14000015
*                  THE FAILING CCW POINTER IS IN LOCATION IOBERCCW+8  * 14500015
*                  FOR RESTART PURPOSES.                              * 15000015
*                                                                     * 15500015
* OUTPUT           ERROR INDICATORS IN DECERRST FOR PERMANENT ERRORS  * 16000015
*                                                                     * 16500015
* ENTRY            FIRST INSTRUCTION                                  * 17000015
*                                                                     * 17500015
* EXITS            RESIDENT INTERPRETER, IGE0504C, IGE0604C           * 18000015
*                                                                     * 18500015
* ATTRIBUTES       TRANSIENT, ENABLED, REENTRANT, OCCUPIES ERP        * 19000015
*                  TRANSIENT AREA AND A SUPERVISOR PROTECT KEY        * 19500015
*********************************************************************** 20000015
         SPACE 2                                                        20500015
         USING IECTIOB,IOBRG                                            21000015
         USING IECTDECB,DECBRG                                          21500015
         USING IHADCB,DCBREG                                            22000015
         USING *,BASREG                                                 22500015
         L     IOBRG,TSTIOB(TSTREG)    ADDRESS OF IOB                   23000015
         LH    UCBREG,TSTUCB(TSTREG)   ADDRESS OF UCB                   23500015
         L     COMREG,CVTPTR           ADDRESS OF CVT                   24000015
         L     DCBREG,IOBDCBPT         ADDRESS OF DCB                   24500015
         L     DECBRG,IOBECBPT         ADDRESS OF DECB                  25000015
         L     ERRETR,VECTXL(COMREG)   ADDRESS OF LINK ROUTINE          25500015
         L     CCWREG,IOBCSW           ADDRESS OF NEXT CCW              26000015
         SH    CCWREG,ERRCON08         ADDRESS OF FAILING CCW           26500015
         SR    CRBREG,CRBREG           INITIALIZE IC REGISTER           27000015
         LA    ERREG1,FLIPBIT          ACK FLIP BIT                     27500015
         MVC   IOBWORK+1(1),IOBERRCT+1 SET UP TO DETERMINE ENTRY        28000015
         NI    IOBWORK+1,MASKALL-HIGHBIT0 ZIP UNSED BIT                 28500015
         IC    CRBREG,IOBWORK+1        PICK UP INDEX FACTOR             29000015
         TM    UCBSENS0(UCBREG),TOERROR TIME OUT ERROR OCCUR            29500015
         BNZ   BSCSP073                 RETRY ERROR CCW            000C 30000015
         SLL   CRBREG,2                DOUBLE TWICE                     30500015
         B     BSCSP00(CRBREG)         BRANCH TO ROUTINE VIA BR TABLE   31000015
BSCSP00  B     BSCSP01                 ENTRY FOR RD ENQ,TIC FAIL CCW    31500015
         B     BSCSP02                 ENTRY FOR RD ENQ,WRT NAK,TIC     32000015
         B     BSCSP021                ENTRY FOR RD SKP,WRT NAK,TIC     32500015
         B     BSCSP03                 ENTRY FOR RD SKP,WRT ENQ,TIC     33000015
         B     BSCSP04                 ENTRY FOR CONTENTION CHECK       33500015
         B     BSCSP05                 ENTRY FOR WR ENQ,CHECK RESP      34000015
         B     BSCSP06                  ENTRY FOR WRT ENQ BOTH RESP000C 34050015
         CLC   IOBWORK+2(1),DCBBSENQ    ENQ RECEIVED               000C 34100015
         BE    BSCSP07                  YES RETRANSMIT             000C 34150015
         L     CCWREG,IOBERCCW+8        NO DISABLE CHECK           000C 34200015
         TM    TPCODE(CCWREG),HIGHBIT0 THIS THE LAST CCW           000C 34250015
         BO    BSCSP07                  RETRY                      000C 34300015
         LA    CCWREG,8(CCWREG)         BUMP TO NEXT CCW           000C 34350015
         B     BSCSP071                 CONTINUE FLOW              000C 34400015
BSCSP06  IC    CRBREG,IOBRCVPT         RECEIVE ACK PTR                  34500015
         LA    ERREG2,DCBBSAK0(CRBREG) ADDRESS OF EXPECTED ACK          35000015
         CLC   DECRESPN(1),DCBBSNAK    NAK RECEIVED                     35500015
         BE    BSCSP051                YES RETRANSMIT                   36000015
         CLC   DECRESPN(2),0(ERREG2)   EXPECTED RESPONSE                36500015
         BE    BSCSP053                YES INDICATE NORMAL COMP         37000015
         XR    ERREG2,ERREG1           FLIP TO WRONG ACK                37500015
         CLC   DECRESPN(2),0(ERREG2)   WRONG ACK RECEIVED               38000015
         BE    BSCSP051                YES RETRANSMIT                   38500015
         B     BSCSP073                NO RETRY WRITE ENQ               39000015
BSCSP01  CLC   IOBWORK+2,DCBBSENQ      WAS AN ENQ RECEIVED              39500015
         BNE   BSCSP073                NO RETRY RD ENQ                  39700015
         CLI   IOBCPA,CCWAPOLL         THIS AUTO POLL                   39900015
         BNE   BSCSP07                 NO RESTART FAIL CCW              40100015
         IC    CRBREG,IOBSNDPT         ACK OFFSET                       40300015
         LA    CCWREG,DCBBSAK0(CRBREG) LAST GOOD ACK                    40500015
         B     BSCSP074                SET UP RETRY                     40700015
BSCSP02  CLC   IOBWORK+2,DCBBSENQ      WAS AN ENQ RECEIVED              41000015
         BNE   BSCSP073                NO RETRY RD ENQ                  41500015
BSCSP021 LA    CCWREG,DCBBSNAK         ADDRESS OF NAK CHARACTER         42000015
         B     BSCSP074                COMPLETE WRT OPERATION           42500015
BSCSP03  LA    CCWREG,DCBBSENQ         ADDRESS OF ENQ CHARACTER         43000015
         B     BSCSP074                COMPLETE WRITE OPERATION         43500015
BSCSP04  CLC   IOBWORK+2,DCBBSENQ      ENQ RECEIVED                     44000015
         BNE   BSCSP07                  NO RETRY RD ENQ            000C 44500015
         MVI   IOBWORK+1,INITCONS      SET UP TO CHECK WRT INIT         45000015
         XC    IOBWORK+1(1),DECTYPE+1  CHECK VALUE                      45500015
         TM    IOBWORK+1,MASK15        THIS WRITE INITIAL OPERATION     46000015
         BM    BSCSP042                NO SET SNO                       46500015
         B     BSCSP041                YES CHECK POINT TO POINT         47000015
BSCSP042 OI    DECERRST,DECSNO         INDICATE SNO                     47500015
BSCSP043 LH    SAVREG,ERLOD25          ADDRESS OF ERROR POST ROUTINE    48000015
         BR    ERRETR                  LINK VIA XCTL ROUTINE            48500015
BSCSP041 TM    UCBTYPE+1(UCBREG),NOTPTPT AUTO-CALL,ANSR,POLL            49000015
         BNZ   BSCSP042                YES SET SNO                      49500015
         TM    DCBXCODE,DCBMASTA       THIS THE MASTER STATION          50000015
         BZ    BSCSP044                YES RESTART CHAN PROGRAM         50500015
         OI    DECFLAGS,SLVCONT        INDICATE CONTENTION              51000015
         NI    IOBFLAG1,MASKALL-IOBERR INDICATE ERROR POST              51500015
         B     BSCSP054                EXIT VIA IOS                     52000015
BSCSP044 LA    CCWREG,IOBCPA           SET TO RESTART CHAN PROGRAM      52500015
         ST    CCWREG,IOBSTART         SET START POINTER                53000015
         B     BSCSP072                COMPLETE OPERATION               53500015
BSCSP05  IC    CRBREG,IOBRCVPT         PICK UP RECEIVE PTR              54000015
BSCSP052 XR    CRBREG,ERREG1           FLIP TO WRONG ACK                54500015
         LA    ERREG2,DCBBSAK0(CRBREG) ADDRESS OF WRONG ACK             55000015
         CLC   DECRESPN(2),0(ERREG2)   THIS WRONG ACK                   55500015
         BE    BSCSP051                YES RE TRANSMIT MSG              56000015
BSCSP053 NI    IOBFLAG1,MASKALL-IOBEXE INDICATE NORMAL COMPLETION       56500015
BSCSP054 EQU   *                                                        57000015
         SVC   EREXCP                  EXIT VIA IOS                     57500015
         SVC   RETURN                  ADIOS                            58000015
BSCSP051 TM    DCBBFTEK,DYNBUF         THIS DYNAMIC BUFFERING           58500015
         BO    BSCSP043                YES POST WITH ERROR              59000015
BSCSP055 EQU   *                                                        59500015
         SH    CCWREG,ERRCON08         BACK UP ONE CCW                  60000015
         CLI   5(CCWREG),TPOPDTXT      THIS TEXT TRANSFER               60500015
         BNE   BSCSP055                NO BACK UP ANOTHER CCW           61000015
         B     BSCSP071                SET TO RESTART CHAN PROG         61500015
BSCSP07  L     CCWREG,IOBERCCW+8       ADDRESS OF FAILING CCW           62000015
BSCSP071 ST    CCWREG,IOBSTART         STORE IN START PTR               62500015
         B     BSCSP075                COMPLETE CHAN PROGRAM            63000015
BSCSP072 MVI   IOBERRCT+1,NONAME       SET NORMAL RETURN                63500015
BSCSP073 CLI   IOBERRCT,ERRMAXCT       CHECK RETRIES                    64000015
         BNL   BSCSP043                NONE LEFT                        64500015
         IC    ERREG1,IOBERRCT         PICK UP COUNT                    65000015
         LA    ERREG1,1(ERREG1)        BUMP ONCE                        65500015
         STC   ERREG1,IOBERRCT         RESTORE                          66000015
         MVI   UCBSENS0(UCBREG),NONAME  CLEAR SENSE BYTE                66200015
         SVC   EREXCP                  RESTART CHAN PROG                66500015
         SVC   RETURN                  EXIT                             67000015
BSCSP074 ST    CCWREG,IOBERCCW         NEW DATA ADDRESS                 67500015
         MVI   IOBERCCW,CCWWRITE       SET WRITE COMMAND                68000015
         MVI   IOBERCCW+8,CCWTIC       PUT TIC IN SECOND COMMANE        68500015
BSCSP075 MVI   IOBERRCT+1,NONAME       SET NORM RETURN                  69000015
         SVC   EREXCP                                                   69500015
         SVC   RETURN                                                   70000015
UCBSENS0 EQU  22                                                        70500015
TOERROR  EQU   3                                                   000C 71000015
TSTIOB   EQU   4                                                        71500015
TSTUCB   EQU   2                                                        72000015
CVTPTR   EQU   16                                                       72500015
VECTXL   EQU   44                                                       73000015
ERRCON08 DC    H'8'                                                     73500015
MASKALL  EQU   X'FF'                                                    74000015
NONAME   EQU   X'00'                                                    74500015
UCBTYPE  EQU   16                                                       75000015
TPOPDTXT EQU   X'11'                                                    75500015
IOBERR   EQU   X'20'                                                    76000015
HIGHBIT0 EQU   X'80'                                                    76500015
DYNBUF   EQU   X'08'                                                    77000015
CCWAPOLL EQU   9                                                        77500015
NORMCMP2 EQU   X'BF'                                                    78000015
INITCONS EQU   X'0D'                                                    78500015
MASK15   EQU   X'0F'                                                    79000015
TPOPWREN EQU   X'0C'                                                    79500015
TPOPWRTX EQU   X'25'                                                    80000015
TPCODE   EQU   5                                                        80200015
DECSNO   EQU   X'40'                                                    80500015
ERLOD25  DC    H'5043'                                                  81000015
ERRMAXCT EQU   7                                                        81500015
EREXCP   EQU   15                                                       82000015
RETURN   EQU   3                                                        82500015
SLVCONT  EQU   X'10'                                                    83000015
NOTPTPT  EQU   X'D0'                                                    83500015
DCBMASTA EQU   X'80'                                                    84000015
IOBEXE   EQU   X'24'                                                    84500015
CCWWRITE EQU   X'01'                                                    85000015
FLIPBIT  EQU   X'02'                                                    85500015
CCWTIC   EQU   X'08'                                                    86000015
ERREG3   EQU   0                                                        86500015
TSTREG   EQU   1                                                        87000015
ERREG2   EQU   2                                                        87500015
CRBREG   EQU   3                                                        88000015
CCWREG   EQU   4                                                        88500015
DECBRG   EQU   5                                                        89000015
DCBREG   EQU   6                                                        89500015
UCBREG   EQU   7                                                        90000015
COMREG   EQU   8                                                        90500015
ERREG1   EQU   9                                                        91000015
IOBRG    EQU   10                                                       91500015
ERREG4   EQU   11                                                       92000015
ERRLNK   EQU   12                                                       92500015
SAVREG   EQU   13                                                       93000015
ERRETR   EQU   14                                                       93500015
BASREG   EQU   15                                                       94000015
         IECTIOBX                                                       94500015
         IECTDECB                                                       95000015
         DCBD  DSORG=BX,DEVD=BS                                         95500015
         END                                                            96000015
