         TITLE 'IGE0010E - 3270 ERROR RECOVERY PROCEDURES'              00100000
IGE0010E CSECT                                                          00200000
*                                                                       00300000
* A231200-231400,A391050-391250,A391850-391900,A626500           S21122 00305021
* C665000                                                        A59081 00395021
*C273000,381000,435000,465000,478000,398000,A718600-71960        A59117 00397021
*D512000                                                         A60474 00399021
* D389000-399500,A239500-239940,A247500-247800,C374000,A710500SB A57064 00399421
*********************************************************************** 00400000
*              3270 ERROR RECOVERY PROCEDURES    FIRST LOAD           * 00500000
*********************************************************************** 00600000
*                                                                     * 00700000
* STATUS:                                                             * 00800000
*    CHANGE LEVEL 000         JUNE 15,1971                            * 00900000
*                                                                     * 01000000
* FUNCTION:                                                           * 01100000
*    THIS MODULE IS THE FIRST LOAD OF THE ERP FOR LOCALLY ATTACHED    * 01200000
*    DEVICES OF THE 3270 DISPAY SYSTEM. THE MODULE IS SCHEDULED BY IOS* 01300000
*    WHEN UNIT CHECK OR UNIT EXCEPTION STATUS IS DETECTED ON AN I/O   * 01400000
*    INTERRUPT OR ON ANY I/O INTERRUPT OCURRING FROM A DEVICE ON WHICH* 01500000
*    THE ERP IS IN CONTROL. THE FOLLOWING FUNCTIONS ARE PERFORMED BY  * 01600000
*    THIS MODULE:                                                     * 01700000
*      1. DETERMINES IF AN ERROR IS RETRYABLE BY THE ERP AND RETRIES  * 01800000
*         THOSE THAT ARE.                                             * 01900000
*      2. DETERMINES IF ERP RETRIES ARE SUCCESSFUL.                   * 02000000
*      3. MAINTAINS THE STATISTICS TABLE FOR THE DEVICE.              * 02100000
*      4. REQUESTS OBR LOGOUT WHEN REQUIRED.                          * 02200000
*      5. REQUESTS INT REQ OR PERM ERROR MESSAGES WHEN REQUIRED.      * 02300000
*      6. TRANSFER CONTROL TO THE SECOND LOAD OF THE 3270 ERP FOR     * 02400000
*         CHANNEL ERRORS OR DEVICE END ERRORS.                        * 02500000
*         NOTE: FOR CHANNEL ERRORS OTHER THAN CDC, THE SECOND LOAD    * 02510021
*         OF THE 3270 ERP WILL XCTL TO THE OPEN/IR/CHAN ERROR LOAD.   * 02530021
*      7. TRANSFER CONTROL TO THE OPEN/IR/CHAN ERROR LOAD             * 02550021
*         OF THE 3270 ERP FOR CCW TP-OP TYPE X'24' OR WHEN INTER-     * 02560021
*         VENTION REQUIRED SITUATIONS ARISE.                          * 02570021
*                                                                     * 02600000
* ENTRY:                                                              * 02700000
*         TO THE FIRST EXECUTABLE INSTRUCTION                         * 02800000
*                                                                     * 02900000
* INPUT:                                                              * 03000000
*    THE ADDRESS OF THE RQE IN REGISTER ONE.                          * 03100000
*                                                                     * 03200000
* OUTPUT:                                                             * 03300000
*    1. SUCCESSFUL RETRY - IOBFLAG1 BIT 2=0,BIT 5=0 WITH STATISTICS   * 03400000
*       TABLE UPDATE IF REQUIRED.                                     * 03500000
*                                                                     * 03600000
*                        - IOBERRCT+1 BIT 5,6 AND 7 = 000.THE ERROR   * 03700000
*                        HAS BEEN PROCESSED BY THE ERP AND RECOVERY   * 03800000
*                        HAS BEEN SUCCESSFUL.                         * 03900000
*                                                                     * 04000000
*    2. PERMENENT ERROR  - IOBFLAG1 BIT 2=0,BIT 5=1 WITH OBR LOGOUT   * 04100000
*                        IF REQUIRED.                                 * 04200000
*                                                                     * 04300000
*                        - IOBERRCT+1 BIT 5,6 AND 7 = 010.THE ERROR   * 04400000
*                        WAS NOT CORRECTABLE BY THE ERP AND           * 04500000
*                        RECONSTRUCTION OF THE DEVICE BUFFER IS       * 04600000
*                        REQUIRED BY THE REQUESTOR.                   * 04700000
*                                                                     * 04800000
*                        - IOBERRCT+1 BIT 5,6 AND 7 = 011.THE ERROR   * 04900000
*                        WAS PROCESSED BY THE ERP AND IT WAS          * 05000000
*                        DETERMINED THAT THE ERROR IS PERMENENT.      * 05100000
*                                                                     * 05200000
*                        - IOBERRCT+1 BIT 5,6 AND 7 = 110.THE ERROR   * 05300000
*                        WAS PROCESSED BY THE ERP AND IT WAS          * 05400000
*                        DETERMINED THAT THE ERROR IS USER CORRECTABLE* 05500000
*                        BY THE CHANNEL PROGRAM OR DATA STREAM BUILDER* 05600000
*                                                                     * 05700000
*    3. RETRY BY THE ERP - IOBFLAG1 BIT 2=1,BIT 5=1.                  * 05800000
*                                                                     * 05900000
*    4. CHANNEL ERROR - IOBCNT2 BIT 0=1.                              * 06000000
*                                                                     * 06100000
*    5. DEVICE END ERROR - IOBCNT2 BIT 4=1.                           * 06200000
*                                                                     * 06300000
* EXTERNAL REFERENCES:                                                * 06400000
*         NONE                                                        * 06500000
*                                                                     * 06600000
* EXITS,NORMAL:                                                       * 06700000
*         IOS VIA SVC 15.                                             * 06800000
*         SUPERVISOR VIA SVC 3.                                       * 06900000
*         STATISTICS UPDATE RTN (IGE0025D) VIA BRANCH ENTRY TO XCTL.  * 07000000
*         IOS-WTO ROUTINE (IGE0025C) VIA BRANCH ENTRY TO XCTL.        * 07100000
*         3270 ERP SECOND LOAD (IGE0110E) VIA BRANCH ENTRY TO XCTL    * 07200000
*         3270 ERP OPEN/IR/CHAN ERROR LOAD (IGE0210E) VIA BRANCH      * 07250021
*         ENTRY TO XCTL                                               * 07270021
*                                                                     * 07300000
* EXITS,ERROR:                                                        * 07400000
*         NONE                                                        * 07500000
*                                                                     * 07600000
* TABLES/WORKAREAS:                                                   * 07700000
*    IOB OF THE I/O REQUEST IN PROCESS.                               * 07800000
*                                                                     * 07900000
* ATTRIBUTES:                                                         * 08000000
*    TRANSIENT,ENABLED,REENTRANT AND IS EXECUTED IN THE IOS TRANSIENT * 08100000
*    AREA WITH A SUPERVISOR PROTECT KEY.                              * 08200000
*                                                                     * 08300000
* CHARACTER CODE DEPENDENCY:                                          * 08400000
*    NONE                                                             * 08500000
*                                                                     * 08600000
* NOTES:                                                              * 08700000
*    SOME OF THE CHANNEL COMMANDS FOR THE 3270 DEVICES RESULT IN      * 08800000
*    SEPARATE I/O INTERRUPTS FOR CE AND DE. WHEN THIS OCCURS,THE      * 08900000
*    GRAPHICS TRAP CODE ROUTINE IN IOS WILL CAUSE THE CE TO BE        * 09000000
*    IGNORED. THAT IS,THE CE APPENDAGE IS NOT ENTERED AND THE UCBPST  * 09100000
*    BIT,IN THE UCB FOR THE DEVICE,IS NOT TURNED OFF. WHEN THE        * 09200000
*    SUBSEQUENT DE IS RECEIVED,THE RQE OF THE I/O OPERATION IS STILL  * 09300000
*    VALID.THE UCBPST BIT IS RESET AND THE CE APPENDAGE ENTERED AT    * 09400000
*    THIS TIME. THIS PROVIDES DE POSTING OF THOSE OPERATIONS THAT     * 09500000
*    RESULT IN SEPARATE PRESENTATION OF CE/DE AND ALLOWS ERROR        * 09600000
*    RECOVERY TO BE ATTEMPTED,BY ANALYSIS OF THE CHANNEL PROGRAM,IF   * 09700000
*    DE,UC IS RECEIVED.                                               * 09800000
*                                                                     * 09900000
*********************************************************************** 10000000
         EJECT                                                          10100000
*/*IGE0010E: CHART*/                                                    10200000
*/* E IGE0010E*/                                                        10300000
*/* P INITIALIZE REGISTERS*/                                            10400000
*/* D (NO,,YES,CHKCLOS) FIRST TIME THRU ERP*/                           10500000
*/* M TURN ON IOB ERROR FLAGS*/                                         10600000
*/* M TURN ON ERP FLAGS*/                                               10700000
*/* D (YES,,NO,SNOEXIT) 3270 DEVICE*/                                   10800000
*/*CHKCLOS: D (NO,,YES,SNOEXIT) CLOSE IN PROGRESS*/                     10900000
*/* D (YES,,NO,CHKCSW) ICC OR CCC OR CDC*/                     SM0400K  10910021
*/* M INDICATE CHAN ERROR IOBCNT2 BIT0=1*/                     SM0400K  10920021
*/*NEXTLOAD: R XCTL TO LOAD TWO (IGE0110E)*/                   SM0400K  10930021
*/*CHKCSW: D (NO,,YES,GOTO210E) OPEN TP-OP IN CCW ? */         SM0400K  10950021
*/* D (NO,,YES,ANALINT) IOB INTERCEPTED*/                      SM0400K  11000021
*/*CHKUCK: D (NO,,YES,ANALUCK) UC*/                                     11400000
*/* D (NO,,YES,ANALUEX) UE*/                                            11500000
*/* D (NO,,YES,UNREC1) CC*/                                             11600000
*/* D (NO,,YES,UNREC1) PGM CHK*/                                        11700000
*/* D (NO,,YES,UNREC1) PROT CHK*/                                       11800000
*/* D (NO,,YES,UNREC1) IL*/                                             11900000
*/*NOERR: M RESET IOB ERROR FLAGS*/                                     12000000
*/* M RESET DCB ERROR FLAGS*/                                           12100000
*/* M RESET ERP FLAGS*/                                                 12200000
*/*STATEXIT: M RESET RETRY COUNT AND RETRY FLAGS*/                      12300000
*/* D (YES,,NO,RETEXIT) LOGOUT OR STAT UPDATE REQD*/                    12400000
*/* R XCTL TO STAT UPDATE (IGE0025D)*/                                  12500000
*/*PERMEXIT: D (NO,,YES,UNREC1) DEVICE AN OP CONSOLE*/                  12600000
*/* M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0*/                   12700000
*/* M RESET RETRY COUNT AND RETRY FLAGS*/                               12800000
*/* M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                             12900000
*/* M INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT7=1*/                      13000000
*/* M SET MSG FLG TO PERM ERR IOBFLAG3 BIT5=1*/                         13100000
*/*WTOEXIT: R XCTL TO IOS-WTO (IGE0025C)*/                              13200000
*/*UNREC1: M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                      13300000
*/*SNOEXIT: M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0*/           13400000
*/*SETPER: M (,STATEXIT) INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT5=1*/   13500000
*/*UNREC2: M (,SETPER) TURN OFF PERM ERROR ERP FLAG IOBCNT2 BIT7=0*/    13600000
*/*ANALINT: D (NO,,YES,SETEC) EC*/                                      13700000
*/* D (YES,,NO,SNOEXIT) DC,US*/                                         13800000
*/*SETDCUS: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                        13900000
*/* P (,SNOEXIT) UPDATE SENSE DATA IN STAT TABLE*/                      14000000
*/*SETEC: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                          14100000
*/* P UPDATE SENSE DATA IN STAT TABLE*/                                 14200000
*/* P (,RETEXIT) SET UP TO START INTCPT CHAN PGM*/                      14300000
*/*RTYCNT: D (NO,,YES,PERMEXIT) MAX RETRY COUNT*/                       14400000
*/* P INCR COUNT BY ONE*/                                               14500000
*/*RETEXIT: L SVC15 ERROR EXCP*/                                        14600000
*/* R RETURN SVC3*/                                                     14700000
*/*ANALUCK: D (YES,,NO,UNREC1) SENSE DATA VALID*/                       14800000
*/* D (NO,,YES,CHKCESNS) CE,DE*/                                        14900000
*/* D (NO,,YES,DENDERR) DE*/                                            15000000
*/* D (NO,,YES,GOTO210E) IR*/                                           15100021
*/* D (NO,,YES,PERMEXIT) DIAG RD OR WRT IN CHAN PGM*/                   15200000
*/* D (YES,,NO,CHKCR) BOC*/                                             15300000
*/* S FINDSTAT:LOCATE STAT TABLE ENTRY*/                                15400000
*/* P (,RTYCNT) UPDATE SENSE DATA IN STAT TABLE*/                       15500000
*/*CHKCR: D (YES,UNREC2,NO,SNOEXIT) CR*/                                15600000
*/*GOTO210E: R XCTL TO IGE0210E*/                                       15700021
*/*CHKCESNS: D (NO,,YES,PERMEXIT) DIAG RD OR WRT IN CHAN PGM*/          16400000
*/* P PICK UP CCW ADDR FROM IOBCSW*/                                    16500000
*/* P ADJUST ADDR TO FAILING CCW*/                                      16600000
*/* D (YES,,NO,SNOEXIT) ADDR VALID*/                                    16700000
*/* D (NO,,YES,BOCCMDS) BOC*/                                           16800000
*/* D (NO,,YES,CMDCHK) DC*/                                             16900000
*/* D (NO,,YES,CMDCHK) CC*/                                             17000000
*/* D (NO,,YES,CMDCHK) DC,US*/                                          17100000
*/* D (YES,,NO,SNOEXIT)OC*/                                             17200000
*/* D (NO,,YES,UNREC2) FAIL CMD WRT*/                                   17300000
*/* D (NO,SNOEXIT,YES,UNREC2) FAIL CMD ER/WRT*/                         17400000
*/*BOCCMDS: D (NO,,YES,UNREC1) FAIL CMD WRT*/                           17500000
*/* D (YES,,NO,SNOEXIT) FAIL CMD ER/WRT*/                               17600000
*/* S FINDSTAT:LOCATE STAT TABLE ENTRY*/                                17700000
*/* P (,RTYCNT) UPDATE SENSE DATA IN STAT TABLE*/                       17800000
*/*CMDCHK: D (NO,,YES,UNREC1) WRT*/                                     17900000
*/* D (NO,,YES,RECRTY) ER/WRT*/                                         18000000
*/* D (NO,,YES,RECRTY) SELECT*/                                         18100000
*/* D (NO,,YES,RECRTY) EUP*/                                            18200000
*/* D (NO,,YES,RDERR) DC,US*/                                           18300000
*/* D (NO,,YES,CHKWRCMD) RD MOD*/                                       18400000
*/* D (YES,,NO,SNOEXIT) RD BFR*/                                        18500000
*/*CHKWRCMD: D (NO,,YES,UNREC1) WRT IN CHAN PGM*/                       18600000
*/* S FINDSTAT:LOCATE STAT TABLE ENTRY*/                                18700000
*/* P (,RTYCNT) UPDATE SENSE DATA IN STAT TABLE*/                       18800000
*/*RECRTY: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                         18900000
*/* P (,RTYCNT) UPDATE SENSE DATA IN STAT TABLE*/                       19000000
*/*RDERR: D (NO,,YES,UNREC1) RD MOD*/                                   19100000
*/* D (NO,SNOEXIT,YES,UNREC1) RD BFR*/                                  19200000
*/*ANALUEX: D (NO,,YES,PERMEXIT) DIAG RD OR WRT IN CHAN PGM*/           19300000
*/* D (NO,,YES,CKCECMDS) CE,DE*/                                        19400000
*/* D (NO,SNOEXIT,YES,CKDECMDS) DE*/                                    19500000
*/*CKDECMDS: D (NO,,YES,UERETRY) SELECT*/                               19600000
*/* D (NO,SNOEXIT,YES,UERETRY) EUP*/                                    19700000
*/*CKCECMDS: D (NO,,YES,SNOEXIT) SENSE*/                                19800000
*/* D (NO,,YES,SNOEXIT) NO-OP*/                                         19900000
*/*UERETRY: M TURN ON UE RETRY FLAG IOBCNT2 BIT2=1*/                    20000000
*/* M (,RETEXIT) SET DEVICE NOT READY UCBFL1 BIT1=1*/                   20100000
*/*DENDERR: M (,NEXTLOAD) INDICATE DE ERROR IOBCNT2 BIT4=1*/            20200000
*/* E FINDSTAT*/                                                        20300000
*/* P PICK UP STAT TABLE ADDR FROM CVT*/                                20400000
*/* P PICK UP STAT TABLE INDEX FROM UCB*/                               20500000
*/*STATLOOP: D (NO,,YES,SECTFND) CORRECT TABLE SECTION*/                20600000
*/* P INCR STAT ADDR TO NEXT CTRL ENTRY*/                               20700000
*/* P (,STATLOOP) INCR INDEX TO NEXT SECTION*/                          20800000
*/*SECTFND: P RESOLVE ENTRY ADDR*/                                      20900000
*/* R RETURN TO CALLER*/                                                21000000
*/*IGE0010E: END*/                                                      21100000
         EJECT                                                          21200000
         USING IECTIOB,IOBREG           BASE FOR IOB DSECT              21300000
         USING IHADCB,DCBREG            BASE FOR DCB DSECT              21400000
         USING *,BASREG                 BASE FOR ERP MODULE             21500000
         L     IOBREG,TSTIOB(TSTREG)    ADDRESSABILITY FOR IOB          21600000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  21700000
         L     DCBREG,IOBDCBPT          ADDRESSABILITY FOR DCB          21800000
         L     CVTREG,CVTADR            ADDRESS OF CVT                  21900000
         L     RETREG,XCTLADR(CVTREG)   BRANCH ENTRY ADDR TO XCTL       22000000
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RETRY FLAGS               22100000
         TM    IOBFLAG1,IOBEXE          FIRST TIME THRU ERP   NG        22200000
         BO    CHKCLOS                  NO-CONTINUE           NG        22300000
         XC    IOBERRCT,IOBERRCT        CLEAR CNT AND FLAGS   NG        22400000
         OI    IOBFLAG1,IOBEXE          INDICATE ERP IN CONTROL         22500000
         OI    IOBCNT2,ERPFLGS          TURN ON ERP FLAGS     NG        22600000
*                                                                       22700000
         CLI   DEVCLS(UCBREG),GRTYPE    IS DEVICE GRAPHICS              22800000
         BNE   SNOEXIT                  NO-EXIT WITH ERROR    NG        22900000
         CLI   DEVTYP(UCBREG),DEV3277   IS DEVICE A 3277                23000000
         BE    CHKCLOS                  IF YES-CONTINUE                 23100000
         CLI   DEVTYP(UCBREG),DEV3158   IS DEVICE A 3158         S21122 23120021
         BE    CHKCLOS                  IF-YES-CONTINUE          S21122 23140021
         CLI   DEVTYP(UCBREG),DEV3284   IS DEVICE A 3284                23200000
         BE    CHKCLOS                  IF YES-CONTINUE                 23300000
         CLI   DEVTYP(UCBREG),DEV3286   IS DEVICE A 3286                23400000
         BNE   SNOEXIT                  NO-EXIT WITH ERROR    NG        23500000
*                                                                       23600000
CHKCLOS  EQU   *                                                        23700000
         TM    DCBOFLGS,DCBCLOS         IS CLOSE IN PROGRESS            23800000
         BO    SNOEXIT                  IF YES-EXIT WITH ERROR          23900000
         TM    IOBCSW+5,CATCHAN         ANY CHANNEL ERRORS     SM0400K  23910021
         BZ    CHKCSW                   IF NOT-CONTINUE        SM0400K  23920021
         OI    IOBCNT2,CHANERR          INDICATE CHAN ERROR    SM0400K  23930021
NEXTLOAD EQU   *                                               SM0400K  23940021
         LA    LDNAMREG,LOADTWO         SECOND 3270 ERP LOAD   SM0400K  23942021
         BR    RETREG                   EXIT VIA XCTL BR EP    SM0400K  23944021
*                                       GO TO OPEN'S ERP       SM0400K  23946021
GOTO210E EQU   *                        SPECIAL ERP FOR OPEN   SM0400K  23948021
         LA    LDNAMREG,LOAD210E        NAME OF SPECIAL ERP    SM0400K  23948421
         BR    RETREG                   EXIT VIA XCTL BR EP    SM0400K  23948821
CHKCSW   L     CCWREG,IOBCSW            GET CCW ADDR           SM0400K  23950021
         LA    CCWREG,0(CCWREG)         CLEAR HIGH BYTE        SM0400K  23960021
         SH    CCWREG,CONEIGHT          POINT TO FAILING CCW   SM0400K  23970021
         BNP   NOTOPN                   NOT VALID              SM0400K  23980021
         CLI   5(CCWREG),X'24'          OPEN TP-OP ?           SM0400K  23990021
         BE    GOTO210E                 YES, GET OPEN ERP      SM0400K  23992021
NOTOPN   EQU   *                        NOT OPEN'S TP-OP       SM0400K  23994021
         CLI   IOBECBCC,IOBINT          IS I/O REQ INTERCEPTED SM0400K  24000021
         BE    ANALINT                  IF YES-ANALYZE         SM0400K  24100021
*                                                                       24800000
CHKUCK   EQU   *                                                        24900000
         TM    IOBCSW+4,CSWUCK          UNIT CHECK                      25000000
         BO    ANALUCK                  IF YES-ANALYZE                  25100000
         TM    IOBCSW+4,CSWUEX          UNIT EXCEPTION                  25200000
         BO    ANALUEX                  IF YES-ANALYZE                  25300000
         TM    IOBCSW+5,CATERR          ANY OTHER STATUS ERRORS         25400000
         BZ    NOERR                    IF NOT-EXIT WITHOUT ERROR       25500000
         B     UNREC1                   IF YES-EXIT WITH ERROR          25600000
*                                                                       25700000
NOERR    EQU   *                                                        25800000
         NI    IOBFLAG1,ALLONE-IOBEXE   INDICATE NO ERROR               25900000
         NI    DCBIFLGS,ALLONE-DCBPER   CLEAR DCB ERROR FLAGS           26000000
         NI    IOBCNT2,ALLONE-ERPFLGS   CLEAR ERP FLAGS       NG        26100000
         XC    UCBSNS(TWOSNS,UCBREG),UCBSNS(UCBREG) CLEAR SENSE  A65162 26150021
         B     CHKSTAT                  EXIT TO STAT UPDATE OR RETURN   26200000
*                                                                       26300000
ANALINT  EQU   *                                                        26400000
         CLI   IOBSENS0,SENEC           EQUIP CHECK                     26500000
         BE    SETEC                    IF YES-STAT UPDATE              26600000
         CLI   IOBSENS0,SENDCUS         DATA CHK,UNIT SPECIFY           26700000
         BE    SETDCUS                  IF YES-STAT UPDATE              26800000
         B     SNOEXIT                  IF NOT-EXIT WITH ERROR          26900000
*                                                                       27000000
SETEC    EQU   *                                                        27100000
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   27200000
         OI    8(STABREG),STATEC        INDICATE EC IN STAT TBLE A59117 27300021
         MVI   IOBECBCC,GOODIO          CLEAR INTCPT INDICATOR          27400000
         NI    IOBFLAG1,ALLONE-IOBEXC   CLEAR PER FLAG                  27500000
         NI    IOBCNT2,ALLONE-ERPFLGS   CLEAR ERP FLAGS       NG        27600000
         MVI   IOBSENS0,ALLZERO         CLEAR SENSE                     27700000
         NI    DCBIFLGS,ALLONE-DCBPER   CLEAR DCB ERROR FLAGS           27800000
         B     RETEXIT                  EXIT TO RETRY                   27900000
*                                                                       28000000
SETDCUS  EQU   *                                                        28100000
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   28200000
         OI    9(STABREG),STDCUS        INDICATE DC,US IN STAT TABLE    28300000
         B     SNOEXIT                  EXIT WITH ERROR                 28400000
*********************************************************************** 28500000
*              FINDSTAT SUBROUTINE                                    * 28600000
*        THIS SUBROUTINE SEARCHS THE DEVICE STATISTICS TABLE FOR THE  * 28700000
*        ENTRY ASSIGNED TO THE I/O DEVICE THAT IS CURRENTLY BEING     * 28800000
*        HANDLED BY THE ERP. THE ADDRESS OF THE ENTRY IS RETURNED TO  * 28900000
*        THE CALLER IN STABREG.                                       * 29000000
*********************************************************************** 29100000
FINDSTAT EQU   *                                                        29200000
         L     STABREG,STATADR(CVTREG)  STAT TABLE ADDRESS              29300000
         LR    WKREG1,STABREG           SAVE STAT TABLE START ADDR      29400000
         SR    ICREG,ICREG              CLEAR FOR STAT TABLE INDEX      29500000
         IC    ICREG,UCBSTI(UCBREG)     PICK UP INDEX                   29600000
STATLOOP CH    UCBREG,0(WKREG1)         TEST FOR CORRECT TABLE SECT     29700000
         BL    SECTFND                  IF FOUND-RESOLVE ENTRY ADDR     29800000
         LA    WKREG1,2(WKREG1)         IF NOT-INCR TO NEXT CTRL ENTRY  29900000
         LA    ICREG,256(ICREG)         INCR INDEX TO NEXT SECT         30000000
         B     STATLOOP                 CHECK AGAIN                     30100000
SECTFND  EQU   *                                                        30200000
         MH    ICREG,CONTEN             ADJUST FOR ENTRY LENGTH         30300000
         AR    STABREG,ICREG            RESOLVE ENTRY ADDR              30400000
         BR    LNKREG                   RETURN TO CALLER                30500000
*********************************************************************** 30600000
*              EXITS                                                  * 30700000
*********************************************************************** 30800000
UNREC2   EQU   *                                                        30900000
         NI    IOBCNT2,ALLONE-PERMERR   INDICATE USER CORRECT NG        31000000
         B     SETPER                                                   31100000
*                                                                       31200000
UNREC1   EQU   *                                                        31300000
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             31400000
SNOEXIT  EQU   *                                                        31500000
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLAGS  NG        31600000
SETPER   EQU   *                                                        31700000
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       31800000
CHKSTAT  EQU   *                                                        31900000
         NI    IOBCNT1,ALLZERO          CLEAR RETRY COUNT     NG        32000000
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RETRY FLAGS     NG        32100000
         TM    IOBFLAG3,IOBLOG          OBR LOGOUT REQUIRED             32200000
         BO    STATEXIT                 IF YES-EXIT TO STAT UPDATE      32300000
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   32400000
         NI    8(STABREG),STMSK1        CHECK FOR SINGLE BIT ENTRIES    32500000
         BZ    CHKMULTI                 IF NONE-CHECK MULTI BIT         32600000
         B     STATEXIT                 IF PRESENT-EXIT TO STAT UPDATE  32700000
CHKMULTI EQU   *                                                        32800000
         NI    9(STABREG),STMSK2        CHECK FOR MULTI BIT ENTRIES     32900000
         BZ    RETEXIT                  IF NONE-STAT UPDATE NOT REQD    33000000
STATEXIT EQU   *                                                        33100000
         LA    LDNAMREG,STATUP          ADDRESS OF STAT UPDATE ROUTINE  33200000
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      33300000
*                                                                       33400000
RTYCNT   EQU   *                                              NG        33500000
         CLI   IOBCNT1,THREE            RETRY COUNT AT MAX    NG        33600000
         BNL   PERMEXIT                 MAX CNT-PER ERR EXIT  NG        33700000
         SR    ICREG,ICREG              CLEAR REG             NG        33800000
         IC    ICREG,IOBCNT1            PICK UP COUNT         NG        33900000
         LA    ICREG,ONE(ICREG)         BUMP BY ONE           NG        34000000
         STC   ICREG,IOBCNT1            SAVE COUNT            NG        34100000
RETEXIT  EQU   *                                                        34200000
         SVC   EREXCP                   ERROR EXCP                      34300000
         SVC   RETURN                   RETURN TO SVPR                  34400000
*                                                                       34500000
PERMEXIT EQU   *                                                        34600000
         TM    SRTESTAT(UCBREG),OPCNSL  DEVICE AN ONLINE ACTIVE CONSOLE 34700000
         BO    UNREC1                   IF YES-LOG WITHOUT ERROR MSG    34800000
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLAGS  NG        34900000
         NI    IOBCNT1,ALLZERO          CLEAR RETRY COUNT     NG        35000000
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RETRY FLAGS     NG        35100000
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             35200000
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       35300000
         OI    IOBFLAG3,IOBMSG          PERM ERROR MSG REQUIRED         35400000
WTOEXIT  EQU   *                                                        35500000
         LA    LDNAMREG,IOSWTO          ADDRESS OF IOS WTO ROUTINE      35600000
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      35700000
*                                                                       35800000
DENDERR  EQU   *                                              NG        35900000
         OI    IOBCNT2,DEERR            INDICATE DVC END ERR  NG        36000000
         B     NEXTLOAD                 GO TO NEXT LOAD EXIT  NG        36100000
*                                                                       36200000
ANALUCK  EQU   *                                                        36300000
         CLI   IOBSENS1,BADSENS         CHECK FOR VALID SENSE           36400000
         BE    UNREC1                   IF NOT-EXIT WITH ERROR          36500000
         TM    IOBSENS0,SENIR     INTERVENTION REQ?              A66412 36550021
         BO    GOTO210E           YES, GO TO 3RD LOAD            A66412 36560021
         TM    IOBCSW+4,CSWCDE          CHAN END AND DEVICE END         36600000
         BO    CHKCESNS                 IF YES-CHECK CE SENSE COND      36700000
         TM    IOBCSW+4,CSWDVE          DEVICE END ALONE                36800000
         BO    DENDERR                  YES-GO TO SECOND LOAD NG        36900000
**********************************************************************  36950021
*           UNIT CHECK ALONE                                            37050021
**********************************************************************  37200021
         BAL   LNKREGB,CHKDIAG          CHECK FOR DIAG CMD    NG        37500000
         B     BRTAB3(IXREG)            DIAG CHK RTN BR TBL   NG        37600000
BRTAB3   B     PERMEXIT                 DIAG CMD-PER ERR EXIT NG        37700000
         CLI   IOBSENS0,SENBOC          BUS OUT CHECK         NG        37800000
         BNE   CHKCR                    NO-CHECK FOR CR       NG        37900000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        38000000
         OI    8(STABREG),STATBOC       SET BOC IN STAT TBL      A59117 38100021
         B     RTYCNT                   CHECK RETRY COUNT     NG        38200000
*                                                                       38300000
CHKCR    EQU   *                                              NG        38400000
         CLI   IOBSENS0,SENCR           COMMAND REJECT                  38500000
         BE    UNREC2                   EXIT WITH USER ERROR            38600000
         B     SNOEXIT                  NO-EXIT WITH SNO ERR  NG        38700000
*                                                                       38800000
*********************************************************************** 40200000
*        CHANNEL END - DEVICE END - UNIT CHECK                        * 40300000
*********************************************************************** 40400000
CHKCESNS EQU   *                                                        40500000
         BAL   LNKREGB,CHKDIAG          CHECK FOR DIAG CMD    NG        40600000
         B     BRTAB2(IXREG)            DIAG CMD RTN BR TBL   NG        40700000
BRTAB2   B     PERMEXIT                 DIAG CMD-PER ERR EXIT NG        40800000
         L     CCWREG,IOBCSW            ADDR OF CCW           NG        40900000
         LA    CCWREG,0(CCWREG)         CLEAR HI BYTE         NG        41000000
         SH    CCWREG,CONEIGHT          FAILING CCW ADDR      NG        41100000
         BNP   SNOEXIT                  EXIT IF ADDR INVALID  NG        41200000
         TM    IOBSENS0,SENBOC          BUS OUT CHECK         NG        41300000
         BO    BOCCMDS                  YES-CHECK CMDS        NG        41400000
         CLI   IOBSENS0,SENDC           DATA CHECK            NG        41500000
         BE    CMDCHK                   YES-CHECK CMDS        NG        41600000
         CLI   IOBSENS0,SENCC           CONTROL CHECK         NG        41700000
         BE    CMDCHK                   YES-CHECK CMDS        NG        41800000
         CLI   IOBSENS0,SENDCUS         DATA CHK,UNIT SPECIFY NG        41900000
         BE    CMDCHK                   YES-CHECK CMDS        NG        42000000
         CLI   IOBSENS0,SENOC           OPERATION CHECK       NG        42100000
         BNE   SNOEXIT                  NO-EXIT WITH SNO ERR  NG        42200000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        42300000
         BE    UNREC2                   YES-EXIT WITH USR ERR NG        42400000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        42500000
         BE    UNREC2                   YES-EXIT WITH USR ERR NG        42600000
         B     SNOEXIT                  EXIT WITH SNO ERROR   NG        42700000
*                                                                       42800000
BOCCMDS  EQU   *                                                        42900000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        43000000
         BE    UNREC1                   YES-UNREC EXIT        NG        43100000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        43200000
         BNE   SNOEXIT                  NO-EXIT WITH SNO ERR  NG        43300000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        43400000
         OI    8(STABREG),STATBOC       SET BOC IN STAT TBL      A59117 43500021
         B     RTYCNT                   RETRY CHAN PGM        NG        43600000
*                                                                       43700000
CMDCHK   EQU   *                                              NG        43800000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        43900000
         BE    UNREC1                   YES-UNREC EXIT        NG        44000000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        44100000
         BE    RECRTY                   YES-RETRY             NG        44200000
         CLI   CCWCMD(CCWREG),CCWSEL    SELECT                NG        44300000
         BE    RECRTY                   YES-RETRY             NG        44400000
         CLI   CCWCMD(CCWREG),CCWEUP    ERASE UNPROTECTED     NG        44500000
         BE    RECRTY                   YES-RETRY             NG        44600000
         CLI   IOBSENS0,SENDCUS         DATA CHK,UNIT SPECIFY NG        44700000
         BE    RDERR                    YES-CHK RD CMDS       NG        44800000
         CLI   CCWCMD(CCWREG),CCWRDM    READ MODIFIED         NG        44900000
         BE    CHKWRCMD                 YES-CHECK CHAN PGN    NG        45000000
         CLI   CCWCMD(CCWREG),CCWRDB    READ BUFFER           NG        45100000
         BNE   SNOEXIT                  NO-SNO EXIT           NG        45200000
CHKWRCMD EQU   *                                              NG        45300000
         LA    CMDREG,CCWWRT            WRITE CMD             NG        45400000
         BAL   LNKREG,CHKCMD            LINK TO CHK CHAN PGM  NG        45500000
         B     BRTAB5(IXREG)            RETURN BRANCH TABLE   NG        45600000
BRTAB5   B     UNREC1                   WRT IN CHAN PGM-EXIT  NG        45700000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        45800000
         CLI   IOBSENS0,SENDC           DATA CHK IN SENSE     NG        45900000
         BE    SETRDDC                  YES-SET DATA CHK ERR  NG        46000000
         OI    8(STABREG),SENCC         SET CC IN STST TBL    NG        46100000
         B     RTYCNT                   RETRY CHAN PGM        NG        46200000
*                                                                       46300000
SETRDDC  EQU   *                                              NG        46400000
         OI    8(STABREG),STATDC        SET DC IN STAT TBL       A59117 46500021
         B     RTYCNT                   RETRY CHAN PGM        NG        46600000
*                                                                       46700000
RECRTY   EQU   *                                              NG        46800000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        46900000
         CLI   IOBSENS0,SENDC           DATA CHK IN SENSE     NG        47000000
         BE    SETDC                    YES-SET DATA CHK ERR  NG        47100000
         CLI   IOBSENS0,SENCC           CTRL CHK IN SENSE     NG        47200000
         BE    SETCC                    YES-SET CTRL CHK ERR  NG        47300000
         OI    9(STABREG),STDCUS        SET DC,US IN STAT TBL NG        47400000
         B     RTYCNT                   RETRY CHAN PGM        NG        47500000
*                                                                       47600000
SETDC    EQU   *                                              NG        47700000
         OI    8(STABREG),STATDC        SET DC IN STAT TBL       A50117 47800021
         B     RTYCNT                   RETRY CHAN PGM        NG        47900000
*                                                                       48000000
SETCC    EQU   *                                              NG        48100000
         OI    8(STABREG),SENCC         SET CC IN STAT TBL    NG        48200000
         B     RTYCNT                   RETRY CHAN PGM        NG        48300000
*                                                                       48400000
RDERR    EQU   *                                              NG        48500000
         CLI   CCWCMD(CCWREG),CCWRDM    READ MODIFIED         NG        48600000
         BE    UNREC1                   YES-EXIT WITH ERROR   NG        48700000
         CLI   CCWCMD(CCWREG),CCWRDB    READ BUFFER           NG        48800000
         BE    UNREC1                   YES-EXIT WITH ERROR   NG        48900000
         B     SNOEXIT                  EXIT WITH SNO ERROR   NG        49000000
*********************************************************************** 49100000
*        UNIT EXCEPTION                                               * 49200000
*********************************************************************** 49300000
ANALUEX  EQU   *                                                        49400000
         BAL   LNKREGB,CHKDIAG          CHECK FOR DIAG CMD    NG        49500000
         B     BRTAB4(IXREG)            DIAG CHK RTN BR TBL   NG        49600000
BRTAB4   B     PERMEXIT                 DIAG CMD-PER ERR EXIT NG        49700000
         TM    IOBCSW+4,CSWCDE          CHAN END AND DEVICE END         49800000
         BO    CKCECMDS                 YES-CHECK FIRST CMD ON CE/DE    49900000
         TM    IOBCSW+4,CSWDVE          DEVICE END ALONE                50000000
         BO    CKDECMDS                 YES-CHECK FIRST CMD ON DE       50100000
         B     SNOEXIT                  EXIT WITH SNO ERROR             50200000
*                                                                       50300000
CKCECMDS EQU   *                                                        50400000
         L     CCWREG,IOBSTART          FIRST CCW ADDR        NG        50500000
         CLI   CCWCMD(CCWREG),CCWSNS    SENSE                 NG        50600000
         BE    SNOEXIT                  EXIT WITH SNO ERROR   NG        50700000
         CLI   CCWCMD(CCWREG),CCWNOP    NO-OP                 NG        50800000
         BE    SNOEXIT                  EXIT WITH SNO ERROR   NG        50900000
UERETRY  EQU   *                                              NG        51000000
         OI    IOBCNT2,UEXRTY           INDICATE UE RETRY     NG        51100000
         B     RETEXIT                  EXIT TO RETRY         NG        51300000
*                                                                       51400000
CKDECMDS EQU   *                                                        51500000
         L     CCWREG,IOBSTART          FIRST CCW ADDR        NG        51600000
         CLI   CCWCMD(CCWREG),CCWSEL    SELECT                          51700000
         BE    UERETRY                  YES-RETRY                       51800000
         CLI   CCWCMD(CCWREG),CCWEUP    ERASE UNPROTECTED               51900000
         BE    UERETRY                  YES-RETRY                       52000000
         B     SNOEXIT                  EXIT WITH SNO ERROR   NG        52100000
*********************************************************************** 52200000
*              CHKDIAG SUBROUTINE                                     * 52300000
*        THIS  SUBROUTINE PLACES A DIAGNOSTIC WRITE / DIAGNOSTIC READ * 52400000
*        COMMAND CODE IN CMDREG AND LINKS TO THE CHKCMD SUBRTN. THE   * 52500000
*        CHKCMD SUBRTN CHECKS IF EITHER COMMAND IS CONTAINED IN THE   * 52600000
*        CHANNEL PROGRAM.THE RETURN CODE RETURNED BY THE CHKCMD SUBRTN* 52700000
*        IS PASSED BACK TO THE CALLER.                                * 52800000
*********************************************************************** 52900000
CHKDIAG  EQU   *                                                        53000000
         LA    CMDREG,CCWDWR            DIAG WRITE CMD                  53100000
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               53200000
         B     BRTABD(IXREG)            RETURN BRANCH TABLE             53300000
BRTABD   BR    LNKREGB                  DWR FOUND-RETURN      NG        53400000
         BCR   ZERO,ZERO                PAD FOR RET CODE IX   NG        53500000
         LA    CMDREG,CCWDRD            DIAG READ CMD                   53600000
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               53700000
         BR    LNKREGB                  RETURN WITH RET CODE  NG        53800000
*********************************************************************** 53900000
*              CHKCMD SUBROUTINE                                      * 54000000
*        THIS SUBROUTINE COMPARES THE COMMAND CODE OF EACH CCW IN A   * 54100000
*        CHANNEL PROGRAM TO THE COMMAND CODE CONTAINED IN CMDREG.     * 54200000
*        IF THE COMMAND IS FOUND,A RETURN CODE OF ZERO IS PLACED IN   * 54300000
*        IXREG. IF IT IS NOT FOUND,THE RETURN CODE IS FOUR.           * 54400000
*********************************************************************** 54500000
CHKCMD   EQU   *                                                        54600000
         L     CCWREG,IOBSTART          PICK UP FIRST CCW ADDR          54700000
         SR    ICREG,ICREG              CLEAR FOR CMD                   54800000
CMDLOOP  IC    ICREG,CCWCMD(CCWREG)     PICK UP COMMAND                 54900000
         CLR   CMDREG,ICREG             CHECK FOR COMMAND               55000000
         BE    SETCFND                  YES-SET COMMAND FOUND RET CODE  55100000
         CLI   CCWCMD(CCWREG),CCWTIC         TIC COMMAND          M2523 55200021
         BE    ADJADR1                       YES-ADJUST ADDRESS   M2523 55260021
*                                                TO NEXT CCW      M2523 55320021
         TM    CCWFLGS(CCWREG),CCWCC+CCWCD CHAINING INDICATED           55400000
         BZ    SETCNFND                 NO-SET CMD NOT FOUND RET CODE   55500000
         LA    CCWREG,8(CCWREG)         YES-INCR TO NEXT CCW            55600000
         B     CMDLOOP                  CONTINUE CHECKING               55700000
*                                                                       55800000
ADJADR1  EQU   *                                                        55900000
         L     CCWREG,0(CCWREG)         PICK UP NEXT CCW ADDR           56000000
         B     CMDLOOP                  CONTINUE TO CHECK COMMAND       56100000
*                                                                       56200000
SETCNFND EQU   *                                                        56300000
         LA    IXREG,FOUR               SET CMD NOT FOUND RC  NG        56400000
         BR    LNKREG                   RETURN TO CALLER                56500000
*                                                                       56600000
SETCFND  EQU   *                                                        56700000
         LA    IXREG,ZERO               SET CMD FOUND RC      NG        56800000
         BR    LNKREG                   RETURN TO CALLER                56900000
*                                                                       57000000
*        REGISTER DEFINITIONS                                           57100000
*                                                                       57200000
TEMPREG  EQU   0                        TEMPORARY SAVE REG    NG        57300000
TSTREG   EQU   1                        RQE ADDRESS                     57400000
IOBREG   EQU   2                        IOB ADDRESS                     57500000
DCBREG   EQU   3                        DCB ADDRESS                     57600000
UCBREG   EQU   4                        UCB ADDRESS                     57700000
CVTREG   EQU   5                        CVT ADDRESS                     57800000
CCWREG   EQU   6                        CCW ADDRESS                     57900000
STABREG  EQU   7                        STAT TABLE ADDRESS              58000000
WKREG1   EQU   8                        WORK REG                        58100000
CMDREG   EQU   WKREG1                   COMMAND REG                     58200000
ICREG    EQU   9                        CHAR REG                        58300000
LNKREG   EQU   10                       LINK REG                        58400000
IXREG    EQU   11                       INDEX REG                       58500000
LNKREGB  EQU   12                       SECOND LINK REG       NG        58600000
LDNAMREG EQU   13                       NEXT LOAD MODULE NAME           58700000
RETREG   EQU   14                       BRANCH ENTRY ADDR TO XCTL       58800000
BASREG   EQU   15                       ERP BASE REG                    58900000
*                                                                       59000000
*        IOB DEFINITIONS AND FLAGS                                      59100000
*                                                                       59200000
IOBDCH   EQU   X'80'                    DATA CHAIN FLAG       NG        59300000
IOBERR   EQU   X'20'                    ERP IN CONTROL                  59400000
IOBEXC   EQU   X'04'                    IOB EXCEPTION                   59500000
IOBEXE   EQU   IOBERR+IOBEXC            EXCEPTION AND ERP IN CONTROL    59600000
IOBINT   EQU   X'7E'                    INTERCEPT CODE                  59700000
GOODIO   EQU   X'7F'                    GOOD I/O CODE                   59800000
IOBMSG   EQU   X'04'                    PERMENENT ERROR MESSAGE         59900000
IOBLOG   EQU   X'01'                    OBR LOGOUT                      60000000
IOBCC1   EQU   X'10'                    SIO CC=1                        60100000
IOBCC3   EQU   X'30'                    SIO CC=3                        60200000
CHANERR  EQU   X'80'                    CHANNEL ERROR FLAG    NG        60300000
UEXRTY   EQU   X'20'                    UNIT EXCEPTION RETRY            60400000
IRERTY   EQU   X'10'                    INTERVENTION REQUIRED RETRY     60500000
DEERR    EQU   X'08'                    DEVICE END ERROR      NG        60600000
USRCRCT  EQU   X'04'                    USER CORRECTABLE                60700000
ERPCOMP  EQU   X'02'                    ERP COMPLETE                    60800000
PERMERR  EQU   X'01'                    PERMENENT ERROR                 60900000
ERPFLGS  EQU   USRCRCT+ERPCOMP+PERMERR  ERP FLAGS                       61000000
RTYFLD   EQU   X'F8'                    RETRY FLAGS FIELD     NG        61100000
*                                                                       61200000
*        UCB DEFINITIONS AND FLAGS                                      61300000
*                                                                       61400000
SRTESTAT EQU   3                        STATUS A                        61500000
UCBFL1   EQU   6                        FLAGS 1                         61600000
UCBSTI   EQU   9                        STATISTICS TABLE INDEX          61700000
UCBTYP   EQU   16                       DEVICE TYPE FIELD               61800000
UCBSNS   EQU   22                       UCB SENSE FIELD          A65162 61850021
DEVCLS   EQU   UCBTYP+2                 DEVICE CLASS BYTE               61900000
UCBNRY   EQU   X'40'                    DEVICE NOT READY                62000000
UCBITF   EQU   X'10'                    INTERCEPT FLAG                  62100000
OPCNSL   EQU   X'82'                    ONLINE ACTIVE CONSOLE           62200000
GRTYPE   EQU   X'10'                    GRAPHICS CLASS                  62300000
DEV3277  EQU   X'09'                    3277 DEVICE                     62400000
DEV3284  EQU   X'0A'                    3284 DEVICE                     62500000
DEV3286  EQU   X'0B'                    3286 DEVICE                     62600000
DEV3158  EQU   X'0C'                    3158 DEVICE              S21122 62650021
DEVTYP   EQU   UCBTYP+3                 DEVICE TYPE BYTE                62700000
*                                                                       62800000
*        DCB  FLAGS                                                     62900000
*                                                                       63000000
DCBPER   EQU   X'C0'                    PERMENENT ERROR                 63100000
DCBCLOS  EQU   X'11'                    CLOSE IN PROGRESS               63200000
*                                                                       63300000
*        RQE  DEFINITIONS                                               63400000
*                                                                       63500000
TSTUCB   EQU   2                        UCB ADDRESS                     63600000
TSTIOB   EQU   4                        IOB ADDRESS                     63700000
*                                                                       63800000
*        CSW  FLAGS                                                     63900000
*                                                                       64000000
CSWCHE   EQU   X'08'                    CHANNEL END                     64100000
CSWDVE   EQU   X'04'                    DEVICE END                      64200000
CSWCDE   EQU   CSWCHE+CSWDVE            CHANNEL END AND DEVICE END      64300000
CSWUCK   EQU   X'02'                    UNIT CHECK                      64400000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  64500000
CSWIL    EQU   X'40'                    INCORRECT LENGTH                64600000
CSWPGC   EQU   X'20'                    PROGRAM CHECK                   64700000
CSWPTC   EQU   X'10'                    PROTECTION CHECK                64800000
CSWCDC   EQU   X'08'                    CHANNEL DATA CHECK              64900000
CSWCCC   EQU   X'04'                    CHANNEL CONTROL CHECK           65000000
CSWICC   EQU   X'02'                    INTERFACE CONTROL CHECK         65100000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  65200000
CATCHAN  EQU   CSWCDC+CSWCCC+CSWICC     CATASTROPHIC CHANNEL ERRORS     65300000
CATERR   EQU   CSWIL+CSWPGC+CSWPTC+CSWCCK STATUS ERRORS                 65400000
*                                                                       65500000
*        SENSE FLAGS                                                    65600000
*                                                                       65700000
SENCR    EQU   X'80'                    COMMAND REJECT                  65800000
SENIR    EQU   X'40'                    INTERVENTION REQUIRED           65900000
SENBOC   EQU   X'20'                    BUS OUT CHECK                   66000000
SENEC    EQU   X'10'                    EQUIPMENT CHECK                 66100000
SENDC    EQU   X'08'                    DATA CHECK                      66200000
SENCC    EQU   X'02'                    CONTROL CHECK                   66300000
SENOC    EQU   X'01'                    OPERATION CHECK                 66400000
SENDCUS  EQU   X'0C'                    DATA CHECK,UNIT SPECIFY  A59081 66500021
SENIRUS  EQU   X'44'                    INT REQ,UNIT SPECIFY            66600000
SNIRECUS EQU   X'54'                    INT REQ,EQUIP CHK,UNIT SPECIFY  66700000
SENECUS  EQU   X'14'                    EQUIP CHECK,UNIT SPECIFY        66800000
*                                                                       66900000
*        STATISTICS TABLE MULTI BIT SENSE FLAGS                         67000000
*                                                                       67100000
STDCUS   EQU   X'10'                    DATA CHECK,UNIT SPECIFY         67200000
STIRUS   EQU   X'08'                    INT REQ,UNIT SPECIFY            67300000
STIRECUS EQU   X'04'                    INT REQ,EQUIP CHK,UNIT SPECIFY  67400000
STECUS   EQU   X'02'                    EQUIP CHECK,UNIT SPECIFY        67500000
STMSK1   EQU   X'7A'                    SINGLE BIT POS USED MASK        67600000
STMSK2   EQU   X'1F'                    MULTI BIT POS USED MASK         67700000
*                                                                       67800000
*        CCW COMMAND CODES , DEFINITIONS AND FLAGS                      67900000
*                                                                       68000000
CCWWRT   EQU   X'01'                    WRITE                           68100000
CCWEWR   EQU   X'05'                    ERASE WRITE                     68200000
CCWRDM   EQU   X'06'                    READ MODIFIED                   68300000
CCWSNS   EQU   X'04'                    SENSE                 NG        68400000
CCWNOP   EQU   X'03'                    NO-OP                 NG        68500000
CCWRDB   EQU   X'02'                    READ BUFFER                     68600000
CCWDWR   EQU   X'09'                    DIAGNOSTIC WRITE                68700000
CCWDRD   EQU   X'0A'                    DIAGNOSTIC READ                 68800000
CCWSEL   EQU   X'0B'                    SELECT                          68900000
CCWEUP   EQU   X'0F'                    ERASE ALL UNPROTECTED           69000000
CCWCC    EQU   X'40'                    COMMAND CHAINING                69100000
CCWCD    EQU   X'80'                    DATA CHAINING                   69200000
CCWTIC   EQU   X'08'                         TIC OP CODE          M2523 69300021
CCWCMD   EQU   0                        COMMAND FIELD                   69400000
CCWFLGS  EQU   4                        FLAGS FIELD                     69500000
CCWCNT   EQU   6                        COUNT FIELD                     69600000
*                                                                       69700000
*        MISC   DEFINITIONS,FLAGS AND CONSTANTS                         69800000
*                                                                       69900000
ZERO     EQU   0                        ZERO                  NG        70000000
TWOSNS   EQU   2                        TWO                      A65162 70050021
ONE      EQU   X'01'                    ONE                   NG        70100000
THREE    EQU   X'03'                    THREE                 NG        70200000
FOUR     EQU   4                        FOUR                  NG        70300000
CVTADR   EQU   16                       LOCATION OF CVT ADDRESS         70400000
XCTLADR  EQU   44                       ADDRESS OF BRANCH EP TO XCTL    70500000
STATADR  EQU   112                      ADDRESS OF STATISTICS TABLE     70600000
OPTFLGS  EQU   182                      ADDRESS OF OPTION FLAGS         70700000
IOSWTO   EQU   253                      IOS WTO ROUTINE ID              70800000
STATUP   EQU   254                      STATISTICS UPDATE ROUTINE ID    70900000
LOADTWO  EQU   1105                     3270 ERP SECOND LOAD  NG        71000000
LOAD210E EQU   2105                     OPEN INT REQ LOAD     SB A57064 71050021
CCHFLG   EQU   X'80'                    CCH IN SYSTEM                   71100000
RETURN   EQU   3                        RETURN SVC                      71200000
EREXCP   EQU   15                       ERROR SVC                       71300000
BADSENS  EQU   X'FE'                    SENSE NOT VALID                 71400000
ALLONE   EQU   X'FF'                    ALL ONES BYTE                   71500000
ALLZERO  EQU   X'00'                    ALL ZEROS BYTE                  71600000
CONTEN   DC    H'10'                    CONSTANT TEN          NG        71700000
CONEIGHT DC    H'8'                     CONSTANT EIGHT        NG        71800000
*                                                                       71850021
* THE FOLLOWING FLGS ARE USED TO SET THE PROPER BITS FOR EDITING A59117 71860021
* AND PRINTING DC,EC,BOC AND IR ERRORS WHEN SYS1.LOGREC IS       A59117 71870021
* PRINTED.                                                       A59117 71880021
STATEC   EQU   X'10'               EQUIPMENT CHECK               A65099 71890021
STATDC   EQU   X'08'               DATA CHECK                    A65099 71892021
STATBOC  EQU   X'20'               BUS OUT CHECK                 A65099 71894021
STATIR   EQU   X'40'               INTERVENTION REQUIRED         A65099 71896021
*                                                                       71900000
PATCHLEN EQU   IGE0010E+1024-*     LENGTH OF PATCH AREA          A68718 71950021
PATCH    DC    (PATCHLEN)X'00'     VARIABLE LENGTH PATCH AREA    A68718 71960021
         IECTIOBX                                                       72000000
IOBCNT1  EQU   IOBERRCT                                       NG        72100000
IOBCNT2  EQU   IOBERRCT+1                                     NG        72200000
         DCBD  DSORG=BX,DEVD=BS                                         72300000
         END                                                            72400000
