         TITLE 'IGE0104A - BTAM ERP DATA CHECK MODULE'                  00500013
IGE0104A CSECT                                                          01000013
*125702201100                                                      000A 01500013
         SPACE 2                                                        02000013
*********************************************************************** 02500013
* STATUS -          CHANGE LEVEL 001    MAY 11, 1967                    03000013
*                                                                     * 03500013
* FUNCTION-        THIS MODULE IS ENTERED ON THE OCCURRENCE OF A      * 04000013
*                  DATA CHECK ERROR.  A CHECK IS MADE TO DETERMINE    * 04500013
*                  IF THE ERROR OCCURRED BEFORE, DURING, OR AFTER     * 05000013
*                  TEXT TRANSFER.  IF REQUIRED, A CHANNEL PROGRAM     * 05500013
*                  IS CONSTRUCTED AND EXECUTED.  LINKAGE IS PROVIDED  * 06000013
*                  TO DATA CHECK LOAD 2 AND THE DIAGNOSTIC WRITE/READ * 06500013
*                  ROUTINES.                                          * 07000013
*                                                                     * 07500013
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 08000013
*                                                                     * 08500013
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0104B AND      * 09000013
*                  IGE0204B.                                          * 09500013
*                                                                     * 10000013
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT.       * 10500013
*********************************************************************** 11000013
         SPACE 2                                                        11500013
*              DATA CHECK ERROR RECOVERY ROUTINE                        12000013
         USING *,BASREG                                                 12500013
         L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  13000013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  13500013
         L     COMREG,LOC016            ADDRESS OF CVT                  14000013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 14500013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  15000013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  15500013
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           16000013
         MVC   IOBWRK(1,IOBRG),5(CCWREG) MOVE TP OP CODE TO WORK AREA   16500013
         NI    IOBWRK(IOBRG),MASKALL-CCWMASK1 MASK OUT UNUSED BITS      17000013
         MVC   IOBWRK+1(1,IOBRG),DECTYPE+1(DECBRG) OPERATION TYPE       17500013
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT MASK OUT RESET BIT         18000013
         MVC   IOBWRK+2(1,IOBRG),UCBTYP+3(UCBREG)  ADAPTER TYPE         18500013
         NI    IOBWRK+2(IOBRG),MASK3    MASK OUT UNUSED HALF BYTE       19000013
         MVC   IOBWRK+3(1,IOBRG),UCBTYP+3(UCBREG)  CONTROL UNIT TYPE    19500013
         NI    IOBWRK+3(IOBRG),MASK15   MASK OUT UNUSED HALF BYTE       20000013
         CLI   0(CCWREG),CCWAPOLL       POLL COMMAND               000A 20500013
         BE    ERRDCD09                 YES CALL IN SECOND LOAD    000A 21000013
         CLI   0(CCWREG),CCWINCMD       INHIBIT COMMAND                 21100019
         BE    READ                                                     21200019
         CLI   0(CCWREG),CCWRDCMD       READ COMMAND                    21500013
         BNE   ERRDCD09                 NO CALL IN SECOND LOAD          22000013
READ     EQU   *                                                        22200019
         TM    IOBWRK(IOBRG),CCWPTXFR   READ PRIOR TO TEXT TRANSFER     22500013
         BZ    ERRDCD09                 YES CALL IN SECOND LOAD         23000013
         TM    DCBBFTEK(DCBREG),X'08'  IS DYNAMIC BUFFERING SPEC.  1264 23100018
         BZ    ERRDCD14                NO, TEST FOR DATA TRANS   A28615 23200019
         NI    IOBFL1(IOBRG),MASKALL-IOBERR TURN ERP CONTROL OFF A28615 23300019
         B     ERRDCD01                POST ERROR                A28615 23400019
ERRDCD14 TM    IOBWRK(IOBRG),CCWTXTDT  DURING TEXT TRANSFER      A28615 23500019
         BZ    ERRDCD00                 NO CHECK FOR READ RESPONSE TEXT 24000013
         TM    DCBERROP(DCBREG),DCBRDTRY READ RETRY SPECIFIED           24500013
         BZ    ERRDCD01                 NO CHECK FOR LERB               25000013
         CLI   IOBECT(IOBRG),ERTRYCT    MORE RETRIES NECESSARY          25500013
         BNL   ERRDCD08                 NO SET TO CALL SECOND LOAD      26000013
         CLI   IOBWRK+1(IOBRG),DECRDRPT OPERATION TYPE READ REPEAT      26500013
         BE    ERRDCD03                 YES REEXECUTE CHAN PROG         27000013
         CLI   IOBWRK+1(IOBRG),DECWRTTV OPERATION WRITE TTV             27050019
         BNE   ERRDCD13                                                 27100019
         LA    ERREG2,IOBCPA(IOBRG)     POINT TO FIRST CCW              27150019
         LA    ERREG2,8(ERREG2)         POINT TO NEXT CCW               27200019
         CLI   5(ERREG2),RESET          FIND READ TV PART OF WRITE TTV  27250019
         BNE   *-8                                                      27300019
         ST    ERREG2,IOBSTART(IOBRG)   SET RESTART ADDRESS             27350019
         B     ERRDCD03                 EXECUTE CHANNEL PROGRAM         27400019
ERRDCD13 EQU   *                                                        27450019
         NI    DECTYPE+1(DECBRG),HIBIT  CLEAR LOW ORDER 6 BITS OF TYPE. 27500013
         OI    DECTYPE+1(DECBRG),DECRDRPT SET OPERATION TYPE READ TP.   28000013
ERRDCD10 TM    DECTYPE(DECBRG),AUTOPOLL IS AN AUTOPOLL OPERATION   000A 28500013
         BZ    ERRDCD07            IN PROGRESS.  IF NOT, BRANCH.   000A 29000013
         L     ERREG4,DECAREA(DECBRG)   LOAD MESSAGE AREA ADDRESS  000A 29500013
         MVC   DECPOLPT(1,DECBRG),0(ERREG4) AND SAVE INDEX BYTE.   000A 30000013
ERRDCD07 LR    ERREG4,BASREG            SAVE BASE REGISTER              30500013
         LR    ERREG2,TSTREG            SAVE RB POINTER                 31000013
         OI    IOBINCAM(IOBRG),ERPBIT   ERP IN CONTROL BIT       A30774 31200020
         LA    SAVREG,SAVEAREA-12       REGISTER SAVE AREA ADDRESS      31500013
         LR    TSTREG,DECBRG            DECB ADDRESS IN PARAMETER REG   32000013
         READ  (1),T,MF=E               CONSTRUCT CHAN PROG             32500013
         LR    BASREG,ERREG4            RESTORE BASE                    33000013
         LR    TSTREG,ERREG2            RESTORE RB REG                  33500013
         NI    IOBINCAM(IOBRG),MASKALL-ERPBIT TURN OFF ERP BIT   A30774 33700020
ERRDCD03 IC    ERREG2,IOBECT(IOBRG)     RETRY COUNT UPDATE              34000013
         LA    ERREG2,1(ERREG2)         BUMP COUNT BY ONE               34500013
         STC   ERREG2,IOBECT(IOBRG)     STORE BACK                      35000013
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                36500013
         TM    DCBERROP(DCBREG),DCBLERB  IS LERB REQUIRED               36600018
         BO    ERRDCD04                                                 36700018
         SVC   EXCPER                   EXECUTE CHAN PROG               37000013
         SVC   RETURN                   NO RETURN                       39500013
ERRDCD04 LA    SAVREG,ERLOD12           ADDRESS OF  LERB ROUTINE        40000013
         MVI   IOBECT-1(IOBRG),LERBDC  INDICATE DATA CHECK ERROR        40500013
ERRDCD05 L     ERRETR,VECTXL(COMREG)    LINK ROUTINE                    41000013
         BR    ERRETR                   LINK                            41500013
ERRDCD00 CLI   IOBWRK(IOBRG),CCWRRTXT   READ RESPONSE TO TEXT           42000013
         BNE   ERRDCD01                 NO CHECK FOR LINE ERROR RECORDS 42500013
         TM    DCBERROP(DCBREG),CCWRTRT  LINE ERROR RECORDING REQUIRED  43000013
         BO    ERRDCD06                 YES CHECK COUNT                 43500013
ERRDCD01 TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQUIRED   44000013
         BO    ERRDCD02                 YES SET UP FOR LERB             44500013
         LH    SAVREG,ERLOD5            ADDRESS OF ERROR POST    A25661 45100018
         B     ERRDCD05                 BRANCH TO POST ROUTINE   A25661 45700018
ERRDCD02 MVI   IOBECT-1(IOBRG),LERBDC   INDICATE DATA CHECK TO LERB     46500013
         NI    IOBFL1(IOBRG),MASKALL-IOBERR    IND PERM ERROR    A26919 47000019
         B     ERRDCD04                 EXIT TO LERB PRINT ROUTINE      47500013
ERRDCD06 CLI   IOBECT(IOBRG),ERTRYCT    RETRY COUNT AT MAXIMUM          48000013
         BNL   ERRDCD08                 YES, CALL IN SECOND LOAD        48500013
         CLI   IOBWRK+1(IOBRG),CCWWRTCT OPERATION TYPE WRITE CONTINUE   49000013
         BE    ERRDCD03                 YES RETRY CHAN PROG             49500013
         CLI   IOBWRK+1(IOBRG),TTV      OPERATION TYPE WRITE TTV A30774 49503020
         BE    ERRDCD03                 YES, RETRY CHAN PROG     A30774 49506020
         TM    UCBTYP+3(UCBREG),NOTADAP1 IS THIS ADAPTER TYPE I  A27637 49510019
         BNZ   ERRDCD12                NO, BRANCH                A27637 49520019
         TM    UCBTYP(UCBREG),NOT2740  IS THIS 2740              A27637 49530019
         BNZ   ERRDCD12                IF NOT BRANCH             A27637 49540019
         TM    UCBTYP+1(UCBREG),VERIMAT  IS THIS 2760            A27637 49550019
         BNO   ERRDCD12                IF NOT, BRANCH             27637 49560019
         CLI   IOBWRK+1(IOBRG),TIO      WRITE TIO                  000K 49600018
         BE    ERRDCD11                 BRANCH IF YES              000K 49700018
         CLI   IOBWRK+1(IOBRG),TCO      WRITE TCO                  000K 49800018
         BE    ERRDCD11                 BRANCH IF YES              000K 49900018
         CLI   IOBWRK+1(IOBRG),TVO      WRITE TVO                  000K 50000018
         BE    ERRDCD11                 BRANCH IF YES              000K 50100018
ERRDCD12 CLI   IOBWRK+1(IOBRG),TCO     IS THIS A WRITE ERASE?    A43783 50200021
         BE    ERRDCD03                YES RETRY C P             A43783 50300021
         NI    DECTYPE+1(DECBRG),HIBIT  CLEAR OP TYPE CODE       A43783 50400021
         OI    DECTYPE+1(DECBRG),CCWRTRT  OPERATION WRITE CONTINUE      50500013
         B     ERRDCD07                 CONSTRUCT CHAN PROG             51000013
ERRDCD08 MVI   IOBECT+1(IOBRG),MASK3    INDICATE LERB CHECK ENTRY       51500013
ERRDCD09 LA    SAVREG,ERLOD10           ADDRESS OF DISABLE CHECK ROUTIN 52000013
         B     ERRDCD05                 LINK ROUTINE                    52500013
ERRDCD11 SH    CCWREG,TWENTY4           BACK UP TO WR D PRE O CCW  000K 52510018
         CLI   7(CCWREG),TWO            CHECK TO SEE IF A DATA     000K 52520018
*                                       CHECK ERROR HAS ALREADY    000K 52530018
*                                       BEEN HANDLED ON THIS       000K 52540018
*                                       OPERATION.                 000K 52550018
         BE    ERRDCD03                 IF COUNT IS TWO,BRANCH     000K 52560018
*                                       BECAUSE CCW HAS ALREADY    000K 52570018
*                                       BEEN PROPERLY ALTERED.     000K 52580018
         ST    CCWREG,IOBSTART(IOBRG)   RESTART ON THIS ONE        000K 52660018
         L     ERREG2,0(CCWREG)         DATA ADDRESS               000K 52700018
         AH    ERREG2,ONE               BUMP PAST EOA              000K 52740018
         ST    ERREG2,0(CCWREG)                                    000K 52780018
         L     ERREG2,4(CCWREG)         DATA LENGTH                000K 52820018
         BCTR  ERREG2,0                 SUBTRACT 1                 000K 52860018
         ST    ERREG2,4(CCWREG)                                    000K 52900018
         B     ERRDCD03                                            000K 52940018
SAVEAREA DS    15F                                                      53000013
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 53500013
ERRCN1   DC    H'8'                     DECIMAL 8                  000A 54000013
ERLOD5   DC    H'5041'                                           A25661 54050018
TWENTY4  DC    H'24'                    SIZE OF 3 CCWS             000K 54100018
ONE      DC    H'1'                                                000K 54200018
IOBINCAM EQU   X'1C'                                             A30774 54220020
ERPBIT   EQU   X'08'                                             A30774 54240020
NOTADAP1 EQU   X'E0'                                             A27637 54270019
NOT2740  EQU   X'0B'                                             A27637 54340019
VERIMAT  EQU   X'0C'                                             A27637 54410019
CCWAPOLL EQU   X'09'                                               000A 54500013
CCWMASK1 EQU   X'C0'                                                    55000013
CCWPTXFR EQU   X'30'                                                    55500013
CCWINCMD EQU   X'0A'                                                    55700019
CCWRDCMD EQU   X'02'                                                    56000013
CCWRRTXT EQU   X'20'                                                    56500013
CCWRTRT  EQU   X'04'                                                    57000013
CCWTXTDT EQU   X'10'                                                    57500013
CCWWRTCT EQU   X'04'                                                    58000013
DECWRTTV EQU   X'0F'                                                    58100019
DCBBFTEK EQU   X'20'                                                    58200018
DCBERROP EQU   33                                                       58500013
DCBLERB  EQU   X'08'                                                    59000013
DCBRDTRY EQU X'02'                                                      59500013
DECRDRPT EQU   X'07'                                                    60000013
DECTYPE  EQU   4                                                        60500013
DECAREA  EQU   12                                                  000A 61000013
DECPOLPT EQU   36                                                  000A 61500013
AUTOPOLL EQU   X'80'                                               000A 62000013
UCBTYP   EQU   16                                                  000A 62500013
ERLOD10  EQU   42                                                       63000013
ERLOD12  EQU   2042                                                     63500013
ERTRYCT  EQU   X'02'                                                    64000013
EXCPER   EQU   15                           EXCP ERROR ROUTINE          64500013
HIBIT    EQU   X'C0'                                                    65000013
IOBCSW   EQU   8                            CSW STORAGE                 65500013
IOBCPA   EQU   X'40'                                                    65700019
IOBDCBAD EQU   20                                                       66000013
IOBDECB  EQU   4                                                        66500013
IOBECT   EQU   30                      ERROR COUNTS                     67000013
IOBERR   EQU   X'20'                        IOB ERROR FLAG              67500013
IOBEX    EQU   X'04'                        EXCEPT FLAG                 68000013
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                68500013
IOBFL1   EQU 0                              FLAGS 1                     69000013
IOBSNS   EQU   2                                                        69500013
IOBSTART EQU   16                                                       69700018
IOBWRK   EQU   33                                                       70000013
LERBDC   EQU   X'01'                                                    70500013
LOC016   EQU   16                           COMMUNICATIONS TABLE        71000013
MASKALL  EQU   255                                                      71500013
MASK3    EQU   X'F0'                                                    72000013
MASK15   EQU   X'0F'                                                    72500013
NONAME   EQU   X'00'                                                    73000013
RESET    EQU   X'02'                                                    73200019
RETURN   EQU   3                       RETURN SVC                       73500013
TCO      EQU   14                       OPTYPE FOR WRITE TCO            73600018
TIO      EQU   12                       OPTYPE FOR WRITE TIO            73700018
TTV      EQU   X'0F'                                             A30774 73800020
TSTIOB   EQU   5                            IOB POINTER                 74000013
TSTUCB   EQU   2                            UCB POINTER                 74500013
TVO      EQU   18                       OPTYPE FOR WRITE TVO            74700018
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      75000013
TWO      EQU   2                                                   000K 75200018
*        REGISTER DEFINITION                                            75500013
TSTREG   EQU   1                             TWELVE STAR REG            76000013
ERREG3   EQU   0                             W69K REG                   76500013
ERREG2   EQU   2                             WORK REG                   77000013
CRBREG   EQU   3                             CURRENT RB REG             77500013
CCWREG   EQU   4                             CCW ADDRESS REG            78000013
DECBRG   EQU   5                        DECB REGISTER                   78500013
DCBREG   EQU   6                        DCB REGISTER                    79000013
UCBREG   EQU   7                             UCB ADDRESS  REG           79500013
COMREG   EQU   8                             COMMUNICATION TABLE REG    80000013
ERREG1   EQU   9                                                        80500013
IOBRG    EQU   10                            IOB ADDRESS REG            81000013
ERREG4   EQU   11                            WORK REG                   81500013
ERRLNK   EQU   12                            LINK REG                   82000013
SAVREG   EQU   13                                                       82500013
ERRETR   EQU   14                            RETURN REG                 83000013
BASREG   EQU   15                            BASE REG                   83500013
         END                                                            84000013
