         TITLE 'IGE0104B - BTAM ERP DIAGNOSTIC WRITE/READ MODULE'       00020000
IGE0104B CSECT                                                          00040000
         SPACE 2                                                        00060000
*********************************************************************** 00080000
* STATUS -          CHANGE LEVEL 000    JANUARY 25, 1967                00100000
*                                                                     * 00120000
* FUNCTION-        THIS MODULE GENERATES A DIAGNOSTIC WRITE/READ      * 00140000
*                  PROGRAM.  IT SAVES INFORMATION FROM THE CCW AND    * 00160000
*                  CSW.  DISABLE IS EXECUTED IF REQUIRED.             * 00180000
*                                                                     * 00200000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 00220000
*                  TO THE ASSOCIATED IO RB.                           * 00240000
*                                                                     * 00260000
* OUTPUT-          SETS INDICATOR IN DECERRST FOR DISABLE EXECUTED.   * 00280000
*                                                                     * 00300000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 00320000
*                                                                     * 00340000
* EXITS-           EXITS THROUGH RETURN SVC.                          * 00360000
*                                                                     * 00380000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 00400000
*********************************************************************** 00420000
         SPACE 2                                                        00440000
         USING *,15                                                     00460000
         L     IOBRG,TSTIOB-1(TSTREG)   GET ADDR OF IOB                 00480000
        LH    UCBREG,TSTUCB(TSTREG)    GET ADDR OF UCB                  00500000
         L     CCWREG,IOBCSW(IOBRG)     GET ADDR OF CSW                 00520000
         SH    CCWREG,ERRCN1            BACK UP ONE CCW                 00540000
         L     COMREG,LOC016            GET ADDR OF CVT                 00560000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 00580000
ERE5C1   EQU   *    ISSUE DIAGNOSTIC WRITE/READ HERE                    00600000
         MVC   IOBERINF(1,IOBRG),IOBSNS(IOBRG)    SAVE SENSE BYTE       00620000
         MVC   IOBERINF+1(7,IOBRG),IOBCSW+1(IOBRG)     SAVE 7 LOW       00640000
*                                  ORDER BYTES OF CHANNEL STATUS WORD   00660000
         MVC   IOBERINF+8(8,IOBRG),0(CCWREG) SAVE FAILING CCW           00680000
         XC    IOBSNS(2,IOBRG),IOBSNS(IOBRG) CLEAR SENSE BYTES          00700000
         MVI   IOBECT+1(IOBRG),RTRNCDE  INDICATE DIAG W/R               00720000
         LA    ERREG1,IOBCPA(IOBRG)     START OF CHANNEL PROGRAM        00740000
         ST    ERREG1,IOBSTART(IOBRG)   POINTER LOC FOR CCW             00760000
         MVC   IOBCPA(32,IOBRG),ERRSKEL1 PUT CHAN PROG IN IOB           00780000
         TM    UCBTYP+3(UCBREG),M2702   CHECK 2702/2703                 00785017
         BO    T27023                   BRANCH IF 2702 OR 3             00790017
         MVC   IOBWRK(1,IOBRG),UCBTYP+3(UCBREG)   MOVE ADAPTER          00795017
         NI    IOBWRK(IOBRG),MASK3      TYPE TO IOBWORK CLEAR BITS      00800017
         CLI   IOBWRK(IOBRG),MOD2260    CHECK FOR TYPE III ADAPTER      00805017
         BNE   T27023                   BRANCH IF NOT                   00810017
         MVI   IOBCPA+16(IOBRG),RDCMD2  DIAG READ CMND IN CCW           00815017
         B     T2701                                                    00820017
T27023   MVI   IOBCPA+16(IOBRG),RDCMD   DIAG READ CMND IN CCW           00825017
T2701    MVI   IOBCPA+21(IOBRG),DIAGTPRD     MOVE IN TPOP CODE          00830017
         LA    ERREG3,8                 SET UP TO                       00840000
         LA    ERREG1,4                  GENERATE CORRECT               00860000
         LA    ERREG2,24                  DATA ADDRESS IN               00880000
         LA    ERREG4,33(IOBRG)            CCW'S FOR DIAG WR/RD         00900000
ERERPT   L     SAVREG,IOBCPA(ERREG2,IOBRG) FIRST WORD OF CCW            00920000
         AR    SAVREG,ERREG4           ADD DATA ADDR                    00940000
         ST    SAVREG,IOBCPA(ERREG2,IOBRG) STORE IN CCW                 00960000
         SR    ERREG2,ERREG3            DETERMINE NEXT CCW              00980000
         BCT   ERREG1,ERERPT            REPEAT IF MORE CCW'S            01000000
         MVC   IOBWRK(1,IOBRG),UCBTYP+3(UCBREG) PICK UP DEV TYPE IND    01020000
         NI    IOBWRK(IOBRG),MASK3      CLEAR UNUSED BITS               01040000
         CLI   IOBWRK(IOBRG),MOD2260    IS THIS A 2260                  01060000
         BNE   ERECK01                  NO CHECK FOR SWITCHED LINE      01080000
         L     ERREG1,IOBSTART(IOBRG)   PICK UP CPA POINTER             01100000
         AH    ERREG1,ERRCN1            BUMP PAST DISABLE               01120000
         ST    ERREG1,IOBSTART(IOBRG)   RESTORE POINTER                 01140000
         B     ERECLNP                  EXECUTE CHAN PROGRAM            01160000
ERECK01  EQU   *                                                        01180000
         TM    UCBTYP+1(UCBREG),SWLINE  THIS A SWITCHED LINE            01200000
         BNZ   ERECLNP                  YES CHAN PROG IS COMPLETE       01220000
         MVI   IOBCPA+20(IOBRG),CHAINCDE CHAIN IN ENABLE COMMAND        01240000
ERECLNP  MVC   IOBWRK(1,IOBRG),UCBTYP+3(UCBREG) DEVICE DATA TO WORK FLD 01260000
         NI    IOBWRK(IOBRG),MASK3      MASK OUT EXTRA BITS             01280000
         TM    IOBWRK(IOBRG),MASK4      CHECK FOR 2260,83B3 OR 115A     01300000
         BZ    EREMV01                  YES SET UP FOR MOVE             01320000
         NI    IOBWRK(IOBRG),MASK5      CHECK FOR TWX ADAPTERS 1 OR 2   01340000
         BZ    EREMV02                  ADAPTERS 1,2,3 IF BRANCH        01360000
         OI    IOBWRK(IOBRG),MASK6      TWX SPACIFIED                   01380000
EREMV01  SR    ERREG1,ERREG1           CLEAR REGISTER                   01390017
         IC    ERREG1,IOBWRK(IOBRG)     PICK UP INDEX                   01400017
         SRL   ERREG1,3                 ADJUST FOR CHAR COUNT           01420000
EREMV02  LA    ERREG1,ERRDATA1(ERREG1)  RESOLVE DATA ADDRESS            01440000
         MVC   IOBWRK(7,IOBRG),0(ERREG1) MOVE DATA INTO BUFFER          01460000
         OI    IOBFL1(IOBRG),CHAININD   INDICATE CHAINED CHAN PROG      01480000
         TM    UCBTYP+1(UCBREG),SWLINE  THIS A SWITCHED LINE            01490017
         BZ    EXCP                     NO, DON'T SET FLAG              01500017
         OI    DECERRST(DECBRG),DISABLOK   SET DISABLE EXECUTED         01510017
EXCP     SVC   EXCPER                                                   01520017
         SVC   RETURN                                                   01540000
ERRCN1   DC    AL2(8)                        DECIMAL 8                  01560000
ERRSKEL1 EQU   *                                                        01580000
         DC    X'2F00000060300007'     DISABLE COMMAND                  01600000
         DC    X'0500000060340007'      DIAG WRITE COMMAND              01620000
         DC    X'0000000020000007'     DIAG READ COMMAND                01640000
         DC    X'27000000203C0007'      ENABLE COMMAND                  01660000
ERRDATA1 DC    X'16626467686B3D00'      MESSAGE FORMAT ONE 1050'> ETC   01680000
         DC    X'18130E121B051F00'      MESSAGE FORMAT TWO 115A, 83B3   01700000
         DC    X'02A1A2A3A3A40300'      MESSAGE FORMAT THREE 2260'S     01720017
         DC    X'8343C323A36321'        MESSAGE FORMAT FOUR TWX         01740000
CHAINCDE EQU   X'60'                                                    01760000
CHAININD EQU   X'40'                                                    01780000
DIAGTPRD EQU   X'38'                                                    01800000
DECERRST EQU   29                                                       01820000
DISABLOK EQU   X'08'                                                    01840000
EXCPER   EQU   15                           EXCP ERROR ROUTINE          01860000
LOC016   EQU   16                           COMMUNICATIONS TABLE        01880000
TSTUCB   EQU   2                            UCB POINTER                 01900000
TSTIOB   EQU   5                            IOB POINTER                 01920000
UCBTYP   EQU   16                      DEVICE TYPE CODE                 01940000
IOBFL1   EQU   0                            FLAGS 1                     01960000
IOBSNS   EQU   2                                                        01980000
IOBDECB  EQU   4                                                        02000000
IOBCSW   EQU   8                            CSW STORAGE                 02020000
IOBSTART EQU   16                                                       02040000
IOBECT   EQU   30                      ERROR COUNTS                     02060000
IOBWRK   EQU   33                                                       02080000
IOBERINF EQU   48                                                       02100000
IOBCPA   EQU   64                                                       02120000
IOBEX    EQU   X'04'                        EXCEPT FLAG                 02140000
IOBERR   EQU   X'20'                        IOB ERROR FLAG              02160000
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                02180000
MASK3    EQU   X'F0'                                                    02200000
MASK4    EQU   X'30'                                                    02220000
MASK5    EQU   X'40'                                                    02240000
MASK6   EQU   X'80'                                                     02260000
MOD2260  EQU   X'80'                                                    02280000
RDCMD    EQU   X'12'                                                    02300000
RETURN   EQU   3                       RETURN SVC                       02320000
RTRNCDE  EQU   X'C0'                                                    02340000
SWLINE   EQU   X'90'                                                    02360000
M2702    EQU   X'01'                                                    02366017
RDCMD2   EQU   X'06'                                                    02372017
*        REGISTER DEFINITION                                            02380000
ERREG3   EQU   0                             WORK REG                   02400000
TSTREG   EQU   1                             TWELVE STAR REG            02420000
ERREG2   EQU   2                             WORK REG                   02440000
CRBREG   EQU   3                             CURRENT RB REG             02460000
CCWREG   EQU   4                             CCW ADDRESS REG            02480000
DECBRG   EQU   5                        DECB REGISTER                   02500000
UCBREG   EQU   7                             UCB ADDRESS  REG           02520000
COMREG   EQU   8                             COMMUNICATION TABLE REG    02540000
ERREG1   EQU   9                                                        02560000
IOBRG    EQU   10                            IOB ADDRESS REG            02580000
ERREG4   EQU   11                            WORK REG                   02600000
ERRLNK   EQU   12                            LINK REG                   02620000
SAVREG   EQU   13                                                       02640000
ERRETR   EQU   14                            RETURN REG                 02660000
BASREG   EQU   15                            BASE REG                   02680000
         END                                                            02700000
