         TITLE 'IGE0104C BSC DATA CHECK ERP ROUTINE'                    00500014
IGE0104C CSECT                                                          01000014
*72420008025000,215000                                             000C 01200015
         SPACE 2                                                        01500014
*********************************************************************** 02000014
* STATUS            CHANGE LEVEL  001   NOVEMBER 14, 1967               02500015
*                                                                     * 03000014
* FUNCTION         THIS MODULE IS ENTERED FOR DATA CHECK ERRORS.      * 03500014
*                  THIS ROUTINE DETERMINES WHEN THE DATA CHECK        * 04000014
*                  OCCURRED WITHIN THE CHANNEL PROGRAM AND THEN       * 04500014
*                  EXECUTES THE APPROPRIATE ERROR RECOVERY ACTION     * 05000014
*                  TO ATTEMPT A RECOVERY. ALL READ TYPE CCW'S WILL    * 05500014
*                  RESULT IN A RECOVERY ATTEMPT EXCEPT FOR A READ     * 06000014
*                  DURING TEXT TRANSFER WITH DYNAMIC BUFFERING.       * 06500014
*                                                                     * 07000014
* INPUT -          REGISTER 1 CONTAINS A POINTER TO THE ASSOCIATED RB * 07500021
*                                                                     * 08000014
*                                                                     * 08500014
* OUTPUT           SETS ERROR INDICATORS IN DECERRST FIELD OF DECB    * 09000014
*                  FOR FAILING LINE                                   * 09500014
*                                                                     * 10000014
* ENTRY            FIRST EXECUTABLE INSTRUCTION OF LOAD MODULE        * 10500014
*                                                                     * 11000014
* EXITS            SUPERVISOR POST VIA RETURN IOS VIA EXCP ERROR      * 11500014
*                  POST VIA IGE0504C LERB VIA IGE0204C                * 12000014
*                                                                     * 12500014
* ATTRIBUTES       THIS MODULE IS TRANSIENT, ENABLED, REENTRANT       * 13000014
*                  AND OPERATES IN THE ERP TRANSIENT AREA OF THE      * 13500014
*                  NUCLEUS WITH A SUPERVISOR PROTECT KEY              * 14000014
*********************************************************************** 14500014
         SPACE 2                                                        15000014
         USING IECTDECB,DECBRG                                          15500014
         USING IECTIOB,IOBRG                                            16000014
         USING IHADCB,DCBREG                                            16500014
         USING *,BASREG                                                 17000014
         L     IOBRG,TSTIOB(TSTREG)     IOB ADDRESS                     17500014
         LH    UCBREG,TSTUCB(TSTREG)    UCB ADDRESS                     18000014
         L     COMREG,CVTPTR            CVT ADDRESS                     18500014
         L     DECBRG,IOBECBPT          DECB ADDRESS                    19000014
         L     DCBREG,IOBDCBPT          DCB ADDRESS                     19500014
         L     CCWREG,IOBCSW            DETERMINE ADDRESS               20000014
         SH    CCWREG,ERRCON08          FAILING CCW                     20500014
         MVC   IOBWORK(1),TPOPCODE(CCWREG) INITIALIZE WORK AREA         21000014
         NI    IOBWORK,MASKALL-HIBIT   CLEAR UNUSED BITS                21500014
         CLI   0(CCWREG),CCWREAD        ERROR ON A READ                 22000014
         BNE   BSCDCSNO                 NO GO TO SNO ROUTINE            22500014
         TM    IOBWORK,TPOPPTXT        ERROR PRIOR TO TEXT              23000014
         BZ    BSCDC03                  YES CHECK FURTHER               23500014
         TM    IOBWORK,TPOPDTXT        ERROR DURING TEXT                24000014
         BO    BSCDC04                 YES CHECK BUFFER TECHNIQUE       24500014
         TM    IOBWORK,TPOPATXT        ERROR AFTER TEXT                 25000014
         BO    BSCDC07                  YES GO TO WRT ENQ ROUTINE       25500014
BSCDCSNO OI    DECERRST,DECSNO         INDICATE SNO                     26000014
BSCDC00  MVI   IOBERRCT,ERRMAXCT       SET FOR NO RETRIES               26500014
BSCDC01  TM    DCBERROP,DCBLERBI        LERB REQUIRED                   27000014
         BNO   BSCDC02                  NO CHECK RETRIES                27500014
         MVI   IOBINCAM+1,LERBDCID      INDICATE LERB DATA CHECK        28000014
BSCDC02  CLI   IOBERRCT,ERRMAXCT       RETRY COUNT AT MAX               28500014
         BNL   BSCDC08                 YES GO TO PERM ERROR             29000014
         IC    ERREG1,IOBERRCT          ADJUST RETRY COUNT              29500014
         LA    ERREG1,1(ERREG1)         FOR NEXT RETRY ATTEMPT          30000014
         STC   ERREG1,IOBERRCT          STORE IT BACK                   30500014
         CLI   IOBINCAM+1,LERBDCID     IS LERB REQUIRED          A66468 31000021
         BE    BSCDC10                 YES, GO TO LERB ROUTINE   A66468 31500021
         SVC   EREXCP                   ISSUE RETRY SVC                 32000014
         SVC   RETURN                   NO EXIT VIA DISPATCHER          34500014
BSCDC03  CLI   IOBWORK,TPOPRENQ        READ ENQ                         35000014
         BE    BSCDC06                  YES SET TO RETRY                35500014
         CLI   IOBWORK,TPREADID        IS THIS READ ID CCW         2726 35600018
         BE    BSCDC0A                 YES, CHECK FURTHER          2726 35700018
         CLI   IOBWORK,TPOPRREN        READ RESP ENQ                    36000014
         BNE   BSCDCSNO                 NO INDICATE SNO ERROR           36500014
         SH    CCWREG,ERRCON08         SET CCWREG FOR RETRY             37000014
         B     BSCDC06                  GO TO RETRY                     37500014
BSCDC0A  SH    CCWREG,ERRCON08         BACK UP ONE CCW             2726 37580018
         CLI   5(CCWREG),TPWRITID      THIS WIRTE ID CCW           2726 37660018
         BE    BSCDC06                 YES, RESTART WITH THIS CCW  2726 37740018
         LA    CCWREG,8(CCWREG)        BUMP BY ONE CCW             2726 37820018
         B     BSCDC06                 RESTART WITH READ ID CCW    2726 37900018
BSCDC04  TM    DCBBFTEK,DYNBUF          DYNAMIC BUFFERING USED          38000014
         BO    BSCDC00                  YES GO TO PERM ERROR ROUTINE    38500014
         CLI   IOBCPA,CCWAPOLL          THIS A MULTIPOINT READ INITIAL  39000014
         BNE   BSCDC05                  NO CONTINUE FLOW                39500014
         LR    ERREG1,CCWREG            POINT TO CURRENT CCW            39800017
         SH    ERREG1,ERRCON08          BACK UP ONE                     40100017
         L     ERREG1,0(ERREG1)         GET AREA ADDRESS                40400017
         AH    ERREG1,ERRCON01          BUMP BY ONE (INDEX BYTE)        40700017
         C     ERREG1,0(CCWREG)         HAS COUNT BEEN ADJUSTED         41000017
         BE    BSCDC05                  YES, CONTINUE                   41300017
         ST    ERREG1,0(CCWREG)         NO, RESTORE READ                41600017
         LH    ERREG1,6(CCWREG)         PICK UP COUNT                   41900017
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     42200017
         STH   ERREG1,6(CCWREG)         STORE                           42500017
BSCDC05  TM    DCBXCODE,ITBMODE         ITB MODE                   000F 42800016
         BO    BSCDC11                  YES, CHECK RESID COUNT     000H 43200018
BSCDC12  LA    ERREG1,DCBBSNAK          ADDRESS OF NAK CHAR        000H 43600018
         MVI   IOBWORK+1,RTRNCDE2      SET SPECIAL RETURN BRANCH A66416 43700021
         MVI   IOBERRCT+1,RTRNSPCD     SET SPECIAL RETURN CODE   A26905 43800019
         MVI   IOBERCCW+7,NAKCOUNT      SET COUNT FOR NAK               44000014
BSCDC051 SH    CCWREG,ERRCON08         BACK UP ONE CCW             2728 44100018
         CLI   5(CCWREG),TPRDRESP      IS THIS READ RESPONSE       2728 44200018
         BE    BSCDC052                YES. RESTART WITH THIS CCW  2728 44300018
         LA    CCWREG,8(CCWREG)        NO, RESTART WITH TEXT CCW   2728 44400018
BSCDC052 ST    CCWREG,IOBERCCW+8       GENERATE TIC COMMAND        2728 44500018
         ST    ERREG1,IOBERCCW          SET UP DATA FIELD ADDR          45000014
         MVI   IOBERCCW,CCWWRITE       MOVE IN WRITE COMMAND            45500014
         MVI   IOBERCCW+4,CMDCHAIN      SET UP FOR COMMAND CHAINING     46000014
         MVI   IOBERCCW+8,CCWTIC        MOVE IN TIC COMMAND             46500014
         LA    CCWREG,IOBERCCW          SET UP CHAN START ADDRESS       47000014
BSCDC06  ST    CCWREG,IOBSTART          STORE IN RESTART ADDRESS        47500014
         B     BSCDC01                  CHECK RETRY COUNT               48000014
BSCDC07  LA    ERREG1,DCBBSENQ          ADDRESS OF ENQ CHAR             48500014
         ST    ERREG1,IOBERCCW          GENERATE CHAN PROG              49000014
         MVI   IOBERCCW+7,ENQCOUNT      SET UP COUNT                    49500014
         B     BSCDC051                 CONTINUE GENERATION             50000014
BSCDC08  NI    IOBFLAG1,MASKALL-IOBERR  INDICATE PERMANENT ERROR        50500014
         CLI   IOBINCAM+1,LERBDCID      LERB REQUIRED            A66468 51000021
         BE    BSCDC10                  YES EXIT VIA LERB               51500014
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            52000016
BSCDC09  L     ERRETR,VECTXL(COMREG)    ADDRESS OF XCTL ROUTINE         52500014
         BR    ERRETR                   EXIT VIA XCTL ROUTINE           53000014
BSCDC10  LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         53500014
         B     BSCDC09                  GO TO EXIT ROUTINE              54000014
BSCDC11  LH    ERREG3,IOBCSW+6          GET RESIDUAL COUNT         000H 54080018
         LA    ERREG3,1(ERREG3)         ADD ONE                    000H 54160018
         CH    ERREG3,6(CCWREG)         MORE THAN ONE CHARACTER    000H 54240018
         BL    BSCDC00                  YES, PERMANENT ERROR       000H 54320018
         B     BSCDC12                                             000H 54400018
CCWDIAL EQU    X'29'                                                    54500014
CCWDISAB EQU   47                                                       55000014
RTRNCDE EQU    1                                                        55500014
CCWRDSKP EQU   0                                                        56000014
CCWNOP   EQU   3                                                        56500014
TPREADID EQU   X'07'                                               2726 56600018
TPWRITID EQU   X'03'                                               2726 56700018
TPRDRESP EQU   X'25'                                               2728 56800018
TPOPDTXT EQU   X'11'                                                    57000014
LERBLDID EQU   X'00'                                                    57500014
TPOPRRTX EQU   X'25'                                                    58000014
READINIT EQU   X'01'                                                    58500014
RDINITEN EQU   X'15'                                                    59000014
CHAINCDE EQU   X'60'                                                    59500014
LERBTOID EQU   X'02'                                                    60000014
IOBSNDEN EQU   X'80'                                                    60500014
ERRCON01 DC    H'1'                                                     61000014
TPOPRRPL EQU   X'05'                                                    61500014
CHNDATCK EQU   X'08'                                                    62000014
LERBDCID EQU   X'01'                                                    62500014
TSTIOB   EQU   4                                                        63000014
TSTUCB   EQU   2                                                        63500014
CVTPTR   EQU   16                                                       64000014
ERRCON08 DC    H'8'                                                     64500014
TPOPCODE EQU   5                                                        65000014
MASKALL  EQU   X'FF'                                                    65500014
CCWREAD  EQU   X'02'                                                    66000014
TPOPPTXT EQU   X'30'                                                    66500014
HIBIT    EQU   X'C0'                                                    67000014
TPOPATXT EQU   X'20'                                                    67500014
DECSNO   EQU   X'40'                                                    68000014
ERRMAXCT EQU   7                                                        68500014
DCBLERBI EQU   X'08'                                                    69000014
NONAME   EQU   X'00'                                                    69500014
EREXCP   EQU   15                                                       70000014
RETURN   EQU   3                                                        70500014
TPOPRENQ EQU   X'0B'                                                    71000014
TPOPRREN EQU   X'0C'                                                    71500014
DYNBUF   EQU   X'08'                                                    72000014
CCWAPOLL EQU   X'09'                                                    72500014
CCWWRITE EQU   X'01'                                                    73000014
CMDCHAIN EQU   X'60'                                                    73500014
NAKCOUNT EQU   1                                                   7534 73800017
ITBMODE  EQU   X'40'                                                    74100016
RTRNSPCD EQU   X'14'                                             A26905 74200019
RTRNCDE2 EQU   X'82'                                             A66416 74300021
CCWTIC   EQU   X'08'                                                    74500014
ENQCOUNT EQU   X'01'                                                    75000014
IOBERR   EQU   X'20'                                                    75500014
ERLOD25  EQU   2043                                                     76000016
VECTXL   EQU   44                                                       76500014
ERLOD12  EQU   2042                                                     77000014
ERREG4   EQU   0                                                        77500014
TSTREG   EQU   1                             TWELVE STAR REGISTER       78000014
ERREG2   EQU   2                             WORK REGISTER 2            78500014
ERREG3   EQU   3                             WORK REGISTER 3            79000014
CCWREG   EQU   4                             CCW ADDRESS REGISTER       79500014
DECBRG   EQU   5                             DECB ADDRESS REGISTER      80000014
DCBREG   EQU   6                             DCB  ADDRESS REGISTER      80500014
UCBREG   EQU   7                             UCB  ADDRESS REGISTER      81000014
COMREG   EQU   8                             COMMUNICATION VECTOR REG   81500014
ERREG1   EQU   9                                                        82000014
IOBRG    EQU   10                            IOB ADDRESS REGISTER       82500014
ERRLNK   EQU   12                            LINK REGISTER              83000014
SAVREG   EQU   13                            SAVE REGISTER              83500014
ERRETR   EQU   14                            RETURN REGISTER            84000014
BASREG   EQU   15                            BASE REGISTER              84500014
         DCBD  DSORG=BX,DEVD=BS              DCB DESECT MACRO           85000014
         IECTDECB                                                       85500014
         IECTIOBX                                                       86000014
         END                                                            86500014
