         TITLE  'IGE0104D BSC OVERRUN ERP TOUTINE'                      00600014
         SPACE 2                                                        01200014
IGE0104D CSECT                                                          01800014
         SPACE 2                                                        02400014
*********************************************************************** 03000014
*                                                                     * 03600014
* STATUS            CHANGE LEVEL 000 JUNE 15, 1967                    * 04200014
*                                                                     * 04800014
* FUNCTION          THIS ROUTINE RECOVERS FROM OVERRUN ERROR          * 05400014
*                   CONDITIONS THAT OCCUR DURING BSC OPERAITON.       * 06000014
*                   THE CCW THAT IS IN ERROR WITHIN THE CHANNEL       * 06600014
*                   PROGRAM IS DETECTED. THE PROPER ERROR             * 07200014
*                   RECOVERY PROCEDURE FOR THE TYPE OF OPERATION      * 07800014
*                   BEING EXECUTED IS THEN INITIATED.                 * 08400014
*                                                                     * 09000014
* INPUT             INPUT TO THE MODULE IS THROUGH REGISTER 1,        * 09600014
*                   A POINTER TO THE ASSOCIATED RB.                   * 10200014
*                                                                     * 10800014
* OUTPUT            SETS INDICATOR IN DECERRST FIELD OF DECB FOR      * 11400014
*                   SHOULD-NOT-OCCUR ERRORS OR INDICATES PERM ERROR.  * 12000014
*                                                                     * 12600014
* ENTRY             ENTRY IS THE FIRST EXECUTABLE INSTRUCTION.        * 13200014
*                                                                     * 13800014
* EXITS             EXITS ARE VIA SVC 15(EREXCP) & SVC 3(RETURN) TO   * 14400014
*                   RETRY AND RETURN TO IOS, TO ERROR POST I N CASE   * 15000014
*                   OF A PERMANENT ERROR.                             * 15600014
*                                                                     * 16200014
* ATTRIBUTES        THIS MODULE IS TRANSIENT, ENABLED, REENTRANT,     * 16800014
*                   AND OPERATES IN THE NUCLEUS ERROR TRANSIENT       * 17400014
*                   AREA WITH A SUPERVISOR PROTECT KEY.               * 18000014
*                                                                     * 18600014
*                                                                     * 19200014
*********************************************************************** 19800014
         SPACE 2                                                        20400014
         USING   *,BASREG                                               21000014
         USING  IECTIOB,IOBREG         IOB DESECT BASE REGISTER         21600014
         USING  IECTDECB,DECBRG        DECB DESECT BASE REGISTER        22200014
         USING IHADCB,DCBREG            DCB DSECT BASE REGISTER         22800014
         L     IOBREG,TSTIOB(TSTREG)    ADDRESS OF IOB                  23400014
         L     COMREG,CVTPTR            ADDRESS OF CVT                  24000014
         L     DCBREG,IOBDCBPT          ADDRESS OF DCB                  24600014
         L     DECBRG,IOBECBPT         DECB ADDRESS FROM IOB            25200014
         L     CCWREG,IOBCSW            ADDRESS OF FAILING CCW          25800014
         SH    CCWREG,CCWSIZ08         BACK UP TO FAILING CCW           26400014
         XC    IOBERCCW(8),IOBERCCW    ZERO OUT NEEDED ERP CCW AREA     27000014
         MVC   IOBWORK(1),TPOPCODE(CCWREG)  TP CODE TP IOB WORK AREA    27600014
         NI    IOBWORK,MASKALL-UNUSBIT TURN OFF UNUSED HIGH ORDER BITS  28200014
         CLI   0(CCWREG),CCWREAD        DID ERROR OCCUR ON A READ       28800014
         BNE   BSCOR03                  NO, GO SET SHOULD NOT OCCUR     29400014
         CLI   IOBWORK,TPOPRENQ         IS THIS READ ENQUIRY            30000014
         BE    BSCOR06                  YES, GO TO RESTART CHAN.PROG.   30600014
         CLI   IOBWORK,TPRDRENQ         IS THIS READ RESP TO ENQ        31200014
         BE    BSCOR04                  YES, RESTART W/ PREVIOUS CCW    31800014
         CLI   IOBWORK,TPOPRREN         IS THIS READ RESP TO TEXT       32400014
         BE    BSCOR05                  YES, RESTART W/ READ ENQ CCW    33000014
         CLI   IOBWORK,TPOPRTXT         IS THIS READ TEXT               33600014
         BNE   BSCOR03                  NO, GO SET SHOULD NOT OCCUR     34200014
         TM    DCBBFTEK,BSCDYBUF        WAS DYNAMIC BUFFERING EMPLOYED  34800014
         BO    BSCOR02                  YES, INDICATE PERMANENT ERROR   35400014
BSCOR00  LA    ERREG1,DCBBSNAK          ADDRESS OF NAK SPECIAL CHAR.    36000014
         ST    ERREG1,IOBERCCW          STORE ADDRESS IN ERP CCW AREA   36600014
         MVI   IOBERCCW+5,TPOPWNAK      TP CODE FOR WRITE NAK IN CCW    37200014
BSCOR00A MVI   IOBERCCW,OPCODWRT        COMMAND CODE INTO ERP CCW       37800014
         MVI   IOBERCCW+4,FLAG                                          38400014
         MVI   IOBERCCW+7,COUNTONE      COUNT OF 1 FOR WRITE NAK CCW    39000014
         ST    CCWREG,IOBERCCW+8        READ TEXT CCW ADDRESS IN TIC    39600014
         MVI   IOBERCCW+8,BSCTICCC      TIC COMMAND CODE INTO ERP CCW   40200014
         LA    ERREG1,IOBERCCW          GET ADDRESS OF ERP CHANNEL PROG 40800014
         ST    ERREG1,IOBSTART          STORE ADDRESS IN IOB FIELD      41400014
BSCOR01  CLI   IOBERRCT,ERRMAX          RETRY COUNT AT MAXIMUM          42000014
         BE    BSCOR02                  INDICATE PERMANENT ERROR        42600014
         IC    ERREG1,IOBERRCT          UPDATE RETRY COUNT              43200014
         LA    ERREG1,1(ERREG1)           TO NEW COUNT                  43800014
         STC   ERREG1,IOBERRCT          STORE IN COUNT FIELD            44400014
         SVC   EREXCP                   GO RESTART CHANNEL PROGRAM      45000014
         SVC   RETURN                   EXIT BACK TO IOS                45600014
         SPACE 2                                                        46200014
BSCOR02  NI    IOBFLAG1,MASKALL-IOBERR  INDICATE PERMANENT ERROR        46800014
         LH    SAVREG,ERLOD25           GET ERROR ROUTINE ADDRESS       47400014
         L     ERRETR,CVTXTLER(COMREG)  LOAD XCTL ENTRY FROM CVT        48000014
         BR    ERRETR                   BRANCH INTO XCTL ROUTINE        48600014
         SPACE 2                                                        49200014
BSCOR03  OI    DECERRST,DECBSNO         SET SHOULD-NOT-OCCUR FLAG       49800014
         B     BSCOR02                  INDICATE PERMANENT ERROR & EXIT 50400014
         SPACE 2                                                        51000014
BSCOR04  SH    CCWREG,CCWSIZ08          BACK UP TO PREVIOUS CCW         51600014
BSCOR06  ST    CCWREG,IOBSTART          STORE CPA ADDRESS IN DCB FIELD  52200014
         B     BSCOR01                                                  52800014
         SPACE 2                                                        53400014
BSCOR05  EQU   *                                                        54000014
         LA    ERREG1,DCBBSENQ          GET ADDRESS OF ENQ CHARACTER    54600014
         ST    ERREG1,IOBERCCW          STORE ENQ ADDRESS IN CCW        55200014
         MVI   IOBERCCW+5,TPOPWENQ      MOVE IN WRITE TQ TP CODE        55800014
         B     BSCOR00A                 GO FINISH CCW AND EXCP          56400014
         SPACE 2                                                        57000014
TSTREG   EQU   1                                                        57600014
CCWREG   EQU   4                                                        58200014
DECBRG   EQU   5                                                        58800014
DCBREG   EQU   6                                                        59400014
UCBREG   EQU   7                                                        60000014
COMREG   EQU   8                                                        60600014
IOBREG   EQU   10                                                       61200014
ERREG1   EQU   11                                                       61800014
ERREG2   EQU   12                                                       62400014
SAVREG   EQU   13                                                       63000014
ERRETR   EQU   14                                                       63600014
BASREG   EQU  15                                                        64200014
         SPACE 2                                                        64800014
TPOPRENQ EQU   X'0B'                    TP CODE FOR READ ENQ            65400014
TPRDRENQ EQU   X'0C'                    TP CODE FOR READ-RESPONSE-ENQ   66000014
TPOPRREN EQU   X'25'                    TP OP CODE FOR RD RESP TO TEXT  66600014
TPOPRTXT EQU   X'11'                    TP CODE FOR READ TEXT           67200014
BSCDYBUF EQU   X'08'                    DYNAMIC BUFFERING FLAG          67800014
STATAB   EQU   112                      STATISTICS TABLE OFFSET IN CVT  68400014
UCBSTI   EQU   9                        INDEX TO ENTRY FOR UCB          69000014
MASKALL  EQU   X'FF'                                                    69600014
EREXCP   EQU   15                       SVC TO START CHANNEL PROGRAM    70200014
RETURN   EQU   3                        SVC TO GO BACK TO IOS           70800014
DECBSNO  EQU   X'40'                    SHOULD NOT OCCUR FLAG IN DECB   71400014
CVTPTR   EQU   16                       COMMUNICATIONS VECTOR TABLE     72000014
CVTXTLER EQU   44                       ENTRY TO XCTL ROUTINE IN CVT    72600014
ERLOD25  DC    H'5043'                  ERROR POST ROUTINE ADDRESS      73200014
IOBERR   EQU   X'20'                   PERMANENT ERROR FLAG             73800014
NONAME   EQU   X'00'                    NULL FLAG BYTE TO TURN OFF FLGS 74400014
TPOPWNAK EQU   X'02'                    TP CODE FOR WRITE NAK           75000014
COUNTONE EQU   X'01'                    COUNT FOR WRITE NAK & ENQ CCWS  75600014
OPCODWRT EQU   X'01'                    OP-CODE FOR A WRITE COMMAND     76200014
BSCTICCC EQU   X'08'                    OP-CODE FOR TIC COMMAND         76800014
ERRMAX   EQU   X'07'                    MAXIMUM ERROR RETRY COUNT       77400014
CCWREAD  EQU   X'02'                    OP-CODE FOR READ COMMAND        78000014
CCWSIZ08 DC    H'08'                    BYTE-SIZE OF CCW                78600014
TPOPCODE EQU   5                        POSITION OF TP-CODE IN CCW      79200014
UNUSBIT  EQU   X'C0'                    HIGH ORDER 2 BITS OF TP CODE    79800014
TSTIOB   EQU   4                        IOB ADDRESS IN REQUEST BLOCK    80400014
TPOPWENQ EQU   OPCODWRT                                                 81000014
FLAG     EQU   X'60'                                                    81600014
TSTUCB   EQU   2                       UCB ADDRESS IN REQUEST BLOCK     82200014
DEC10    EQU   10                       LENGTH OF ENTRY IN STATAB.      82800014
         SPACE 2                                                        83400014
         IECTDECB                                                       84000014
         SPACE 2                                                        84600014
         DCBD  DSORG=BX,DEVD=BS                                         85200014
         SPACE 2                                                        85800014
         IECTIOBX                                                       86400014
         SPACE 2                                                        87000014
         END                                                            87600014
