         TITLE 'IGE0110E - 3270 ERROR RECOVERY PROCEDURES'              00100000
IGE0110E CSECT                                                          00200000
*                                                                       00300000
* C374000,A374300-374600,C375000,A375300-375600,A566500          A55306 00330021
* C537000                                                        A59081 00340021
* C194000,235000,A591600-591960                                  A59117 00350021
* D327000-328000,A327500-327900                                  A60093 00352021
*                                                                       00360021
*********************************************************************** 00400000
*              3270  ERROR RECOVERY PROCEDURES   SECOND LOAD          * 00500000
*********************************************************************** 00600000
*                                                                     * 00700000
* STATUS:                                                             * 00800000
*    CHANGE LEVEL 000         JUNE 15,1971                            * 00900000
*                                                                     * 01000000
* FUNCTION:                                                           * 01100000
*    THIS MODULE IS THE SECOND LOAD OF THE ERP FOR LOCALLY ATTACHED   * 01200000
*    DEVICES OF THE 3270 DISPLAY SYSTEM. THE MODULE IS GIVEN CONTROL  * 01300000
*    BY THE FIRST ERP LOAD (IGE0010E) WHEN THAT MODULE DETECTS A      * 01400000
*    CHANNEL ERROR OR DEVICE END ERROR. THE FOLLOWING FUNCTIONS ARE   * 01500000
*    PERFORMED BY THIS MODULE:                                        * 01600000
*      1. DETERMINES IF AN ERROR IS RETRYABLE BY THE ERP AND RETRIES  * 01700000
*         THOSE THAT ARE.                                             * 01800000
*      2. MAINTAINS THE STATISTICS TABLE FOR THE DEVICE.              * 01900000
*      3. REQUESTS OBR LOGOUT WHEN REQUIRED.                          * 02000000
*      4. REQUESTS INT REQ OR PERM ERROR MESSAGES WHEN REQUIRED.      * 02100000
*      5. HANDLES CHANNEL DATA CHECK ERRORS                           * 02150021
*      6. IF CCH IS IN THE SYSTEM, TRANSFERS CONTROL TO THE OPEN/     * 02160021
*         IR/CHANNEL ERROR LOAD OF THE 3270 ERP IF A CCC OR ICC ERROR * 02170021
*         OCCURRED.                                                   * 02190021
*                                                                     * 02200000
* ENTRY:                                                              * 02300000
*         TO THE FIRST EXECUTABLE INSTRUCTION                         * 02400000
*                                                                     * 02500000
* INPUT:                                                              * 02600000
*    THE ADDRESS OF THE RQE IN REGISTER ONE.                          * 02700000
*                                                                     * 02800000
* OUTPUT:                                                             * 02900000
*    1. PERMENENT ERROR  - IOBFLAG1 BIT 2=0,BIT 5=1 WITH OBR LOGOUT   * 03000000
*                        IF REQUIRED.                                 * 03100000
*                                                                     * 03200000
*                        - IOBERRCT+1 BIT 5,6 AND 7 = 011.THE ERROR   * 03300000
*                        WAS PROCESSED BY THE ERP AND IT WAS          * 03400000
*                        DETERMINED THAT THE ERROR IS PERMENENT.      * 03500000
*                                                                     * 03600000
*    2. RETRY BY THE ERP - IOBFLAG1 BIT 2=1,BIT 5=1.                  * 03700000
*                                                                     * 03800000
* EXTERNAL REFERENCES:                                                * 03900000
*         NONE                                                        * 04000000
*                                                                     * 04100000
* EXITS,NORMAL:                                                       * 04200000
*         IOS VIA SVC 15.                                             * 04300000
*         SUPERVISOR VIA SVC 3.                                       * 04400000
*         STATISTICS UPDATE RTN (IGE0025D) VIA BRANCH ENTRY TO XCTL.  * 04500000
*         IOS-WTO ROUTINE (IGE0025C) VIA BRANCH ENTRY TO XCTL.        * 04600000
*         3270 ERP OPEN/IR/CHAN ERROR LOAD (IGE0210E) VIA BRANCH      * 04650021
*         ENTRY TO XCTL.                                              * 04660021
*                                                                     * 04700000
* EXITS,ERROR:                                                        * 04800000
*         NONE                                                        * 04900000
*                                                                     * 05000000
* TABLES/WORKAREAS:                                                   * 05100000
*    IOB OF THE I/O REQUEST IN PROCESS.                               * 05200000
*                                                                     * 05300000
* ATTRIBUTES:                                                         * 05400000
*    TRANSIENT,ENABLED,REENTRANT AND IS EXECUTED IN THE IOS TRANSIENT * 05500000
*    AREA WITH A SUPERVISOR PROTECT KEY.                              * 05600000
*                                                                     * 05700000
* CHARACTER CODE DEPENDENCY:                                          * 05800000
*    NONE                                                             * 05900000
*                                                                     * 06000000
* NOTES:                                                              * 06100000
*    SOME OF THE CHANNEL COMMANDS FOR THE 3270 DEVICES RESULT IN      * 06200000
*    SEPARATE I/O INTERRUPTS FOR CE AND DE. WHEN THIS OCCURS,THE      * 06300000
*    GRAPHICS TRAP CODE ROUTINE IN IOS WILL CAUSE THE CE TO BE        * 06400000
*    IGNORED. THAT IS,THE CE APPENDAGE IS NOT ENTERED AND THE UCBPST  * 06500000
*    BIT,IN THE UCB FOR THE DEVICE,IS NOT TURNED OFF. WHEN THE        * 06600000
*    SUBSEQUENT DE IS RECEIVED,THE RQE OF THE I/O OPERATION IS STILL  * 06700000
*    VALID.THE UCBPST BIT IS RESET AND THE CE APPENDAGE ENTERED AT    * 06800000
*    THIS TIME. THIS PROVIDES DE POSTING OF THOSE OPERATIONS THAT     * 06900000
*    RESULT IN SEPARATE PRESENTATION OF CE/DE AND ALLOWS ERROR        * 07000000
*    RECOVERY TO BE ATTEMPTED,BY ANALYSIS OF THE CHANNEL PROGRAM,IF   * 07100000
*    DE,UC IS RECEIVED.                                               * 07200000
*                                                                     * 07300000
*********************************************************************** 07400000
         EJECT                                                          07500000
*/*IGE0110E: CHART*/                                                    07600000
*/* E IGE0110E*/                                                        07700000
*/* P INITIALIZE REGISTERS*/                                            07800000
*/* D (NO,,YES,ANALCHAN) CHANNEL ERROR*/                                07900000
*/* D (NO,SNOEXIT,YES,ANALDERR) DEVICE END ERROR*/                      08000000
*/*ANALDERR: D (NO,,YES,PERMEXIT) DIAG RD OR WRT IN CHAN PGM*/          08100000
*/* D (NO,,YES,CHKIR) IR*/                                              08200000
*/* D (NO,,YES,CHKEC) IR,EC,US*/                                        08300000
*/* D (NO,,YES,CHKEC) EC,US*/                                           08400000
*/* D (NO,,YES,ANALCMD) DC*/                                            08500000
*/* D (NO,,YES,ANALCMD) CC*/                                            08600000
*/* D (NO,SNOEXIT,YES,ANALCMD) DC,US*/                                  08700000
*/*CHKIR: D (NO,,YES,DEIRRTY) LAST CHAN PGM CMD WRT*/                   08800000
*/* D (NO,SNOEXIT,YES,DEIRRTY) LAST CHAN PGM CMD ER/WRT*/               08900000
*/*DEIRRTY: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                        09000000
*/* P UPDATE SENSE DATA IN STAT TABLE*/                                 09100000
*/* M SET CCW BYTE COUNT TO ONE*/                                       09200000
*/* M SET IOBSTART ADDR TO RETRY WCC*/                                  09300000
*/* M TURN ON IR RETRY FLAG IOBCNT2 BIT3=1*/                            09400000
*/* M (,WTOEXIT) SET MSG FLG TO INT REQ IOBFLAG3 BIT5=0*/               09500000
*/*CHKEC: D (NO,,YES,PERMEXIT) LAST CHAN PGM CMD WRT*/                  09600000
*/* D (NO,SNOEXIT,YES,PERMEXIT) LAST CHAN PGM CMD ER/WRT*/              09700000
*/*ANALCMD: D (NO,,YES,UNREC1) LAST CHAN PGM CMD WRT*/                  09800000
*/* D (NO,,YES,RECRTY) LAST CHAN PGM CMD ER/WRT*/                       09900000
*/* D (NO,,YES,CHKRTY) LAST CHAN PGM CMD SELECT*/                       10000000
*/* D (NO,SNOEXIT,YES,CHKRTY) LAST CHAN PGM CMD EUP*/                   10100000
*/*CHKRTY: D (NO,,YES,UNREC1) DC,US*/                                   10200000
*/*RECRTY: S FINDSTAT: LOCATE STAT TABLE ENTRY*/                        10300000
*/* P (,STORCCW) UPDATE SENSE DATA IN STAT TABLE*/                      10400000
*/*ANALCHAN: D (NO,,YES,PERMEXIT) DIAG RD OR WRT IN CHAN PGM*/          10500000
*/* D (NO,,YES,CDCERR) CHAN DATA CHK*/                                  10600000
*/* D (YES,,NO,SNOEXIT) CCC OR ICC*/                                    10650021
*/* D (YES,,NO,PERMEXIT) CCH IN SYSTEM*/                                10700021
*/* R XCTL TO IGE0210E*/                                                10750021
*/*CDCERR: P GET FAILING CCW ADDR*/                                     10800000
*/* D (YES,,NO,SNOEXIT) ADDR VALID*/                                    10900000
*/* D (NO,,YES,UNREC1) TIC*/                                            11000000
*/* D (NO,,YES,UNREC1) WRT*/                                            11100000
*/* D (NO,,YES,CHKCHAIN) ER/WRT*/                                       11200000
*/* D (NO,,YES,CHKWRCMD) RD MOD*/                                       11300000
*/* D (NO,,YES,CHKWRCMD) RD BFR*/                                       11400000
*/*RTYCCW: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                         11500000
*/* P (,STORCCW) SET CDC ERROR IN STAT TABLE*/                          11600000
*/*CHKCHAIN: D (NO,RTYCCW,YES,RTYCHPGM) DATA CHAIN IN CHAN PGM*/        11700000
*/*CHKWRCMD: D (NO,,YES,UNREC1) WRT CMD IN CHAN PGM*/                   11800000
*/*RTYCHPGM: S FINDSTAT:LOCATE STAT TABLE ENTRY*/                       11900000
*/* P (,RTYCNT) SET CDC ERROR IN STAT TABLE*/                           12000000
*/*UNREC1: M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                      12100000
*/*SNOEXIT: M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0*/           12200000
*/*SETPER: M (,STATEXIT) INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT5=1*/   12300000
*/*STATEXIT: M RESET RETRY COUNT AND RETRY FLAGS*/                      12400000
*/* D (YES,,NO,RETEXIT) LOGOUT OR STAT UPDATE REQD*/                    12500000
*/* R XCTL TO STAT UPDATE (IGE0025D)*/                                  12600000
*/*STORCCW: M SET IOBSTART ADDR TO RETRY FAILING CCW*/                  12700000
*/*RTYCNT: D (NO,,YES,PERMEXIT) MAX RETRY COUNT*/                       12800000
*/* P INCR COUNT BY ONE*/                                               12900000
*/*RETEXIT: L SVC15 ERROR EXCP*/                                        13000000
*/* R RETURN SVC3*/                                                     13100000
*/*PERMEXIT: D (NO,,YES,UNREC1) DEVICE AN OP CONSOLE*/                  13200000
*/* M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0*/                   13300000
*/* M RESET RETRY COUNT AND RETRY FLAGS*/                               13400000
*/* M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                             13500000
*/* M INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT7=1*/                      13600000
*/* M SET MSG FLG TO PERM ERR IOBFLAG3 BIT5=1*/                         13700000
*/*WTOEXIT: R XCTL TO IOS-WTO (IGE0025C)*/                              13800000
*/* E FINDSTAT*/                                                        13900000
*/* P PICK UP STAT TABLE ADDR FROM CVT*/                                14000000
*/* P PICK UP STAT TABLE INDEX FROM UCB*/                               14100000
*/*STATLOOP: D (NO,,YES,SECTFND) CORRECT TABLE SECTION*/                14200000
*/* P INCR STAT ADDR TO NEXT CTRL ENTRY*/                               14300000
*/* P (,STATLOOP) INCR INDEX TO NEXT SECTION*/                          14400000
*/*SECTFND: P RESOLVE ENTRY ADDR*/                                      14500000
*/* R RETURN TO CALLER*/                                                14600000
*/*IGE0110E: END*/                                                      14700000
         EJECT                                                          14800000
         USING IECTIOB,IOBREG           BASE FOR IOB DSECT              14900000
         USING IHADCB,DCBREG            BASE FOR DCB DSECT              15000000
         USING *,BASREG                 BASE FOR ERP MODULE             15100000
         L     IOBREG,TSTIOB(TSTREG)    ADDRESSABILITY FOR IOB          15200000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  15300000
         L     DCBREG,IOBDCBPT          ADDRESSABILITY FOR DCB          15400000
         L     CVTREG,CVTADR            ADDRESS OF CVT                  15500000
         L     RETREG,XCTLADR(CVTREG)   BRANCH ENTRY ADDR TO XCTL       15600000
*                                                                       15700000
         TM    IOBCNT2,CHANERR          CHANNEL ERROR         NG        15800000
         BO    ANALCHAN                 YES-CHECK ERROR       NG        15900000
         TM    IOBCNT2,DEERR            DEVICE END ERROR      NG        16000000
         BO    ANALDERR                 YES-CHECK ERROR       NG        16100000
         B     SNOEXIT                  NO-SNO EXIT           NG        16200000
*********************************************************************** 16300000
*        DEVICE END - UNIT CHECK                                      * 16400000
*********************************************************************** 16500000
ANALDERR EQU   *                                              NG        16600000
         BAL   LNKREGB,CHKDIAG          CHECK FOR DIAG CMD    NG        16700000
         B     BRTAB1(IXREG)            DIAG CMD RTN BR TBL   NG        16800000
BRTAB1   B     PERMEXIT                 DIAG CMD-PER ERR EXIT NG        16900000
         LA    IXREG,4            SET NO SELECT RETRY            A65119 16950021
         L     CCWREG,IOBCSW      GET FAILING CCW ADDRESS        A65119 16960021
         LA    CCWREG,0(CCWREG)   CLEAR ERROR FLAGS              A65119 16970021
         SH    CCWREG,CONEIGHT    BACK UP ONE CCW                A65119 16980021
         BNP   ANDERCNT           IF NOT VALID ADDRESS,          A65119 16990021
*                                 GO CHECK LAST CCW              A65119 16992021
         L     WKREG1,IOBSTART    GET ADDRESS OF FIRST CCW       A65119 16994021
         LA    WKREG1,0(WKREG1)   CLEAR SIO CC                   A65119 16996021
         CR    CCWREG,WKREG1      FAILING IS FIRST ?             A65119 16998021
         BNE   ANDERCNT           NO, CHECK LAST                 A65119 16998421
         CLI   CCWCMD(CCWREG),CCWSEL FAIL ON A SELECT ?          A65119 16998821
         BNE   ANDERCNT           NO, CHECK LAST                 A65119 16999621
         LA    IXREG,0            SET RETRY SELECT               A65119 16999721
ANDERCNT EQU   *                  RETRY SELECT ARGUMENT SET      A65119 16999821
         CLI   IOBSENS0,SENIR           INT REQ               NG        17000000
         BE    CHKIR(IXREG)             YES-CHECK CHAN PGM    NG A65119 17100021
         CLI   IOBSENS0,SNIRECUS        IR,EQUIP CHK,UNIT SP  NG        17200000
         BE    CHKEC(IXREG)             YES-CHECK CHAN PGM    NG A65119 17300021
         CLI   IOBSENS0,SENECUS         EQUIP CHK,UNIT SP     NG        17400000
         BE    CHKEC(IXREG)             YES-CHECK CHAN PGM    NG A65119 17500021
         CLI   IOBSENS0,SENDC           DATA CHECK            NG        17600000
         BE    ANALCMD(IXREG)           YES-CHECK CHAN PGM    NG A65119 17700021
         CLI   IOBSENS0,SENCC           CONTROL CHECK         NG        17800000
         BE    ANALCMD(IXREG)           YES-CHECK CHAN PGM    NG A65119 17900021
         CLI   IOBSENS0,SENDCUS         DATA CHK,UNIT SPECIFY NG        18000000
         BE    ANALCMD(IXREG)           YES-CHECK CHAN PGM    NG A65119 18100021
         B     SNOEXIT                  EXIT WITH SNO ERROR   NG        18200000
*                                                                       18300000
CHKIR    EQU   *                                              NG        18400000
         B     DEIRSEL1           RETRY IR ON SELECT             A65119 18450021
         BAL   LNKREG,CMDSRCH           FIND LAST COMMAND     NG        18500000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        18600000
         BE    DEIRRTY                  YES-RETRY WCC ONLY    NG        18700000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        18800000
         BE    WRTERASE                 YES-RETRY ALL DATA       A63478 18900021
         B     SNOEXIT                  NO-SNO EXIT           NG        19000000
DEIRSEL1 EQU   *                  UPDATE STAT FOR IR ON SELECT   A65119 19050021
         BAL   LNKREG,FINDSTAT    FIND STAT TBL ENTRY            A65119 19060021
         OI    8(STABREG),STATIR  SET IR IN STAT TABLE           A65119 19070021
         B     DEIRSEL2           RESTART AT SELECT              A65119 19080021
*                                                                       19100000
DEIRRTY  EQU   *                                              NG        19200000
         LH    WKREG1,CONONE            PICK UP RETRY BYTE CNT.  A63478 19250021
         STH   WKREG1,CCWCNT(CCWREG)    SET CNT. TO RETRY WCC    A63478 19260021
WRTERASE EQU   *                                                 A63478 19270021
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        19300000
         OI    8(STABREG),STATIR        SET IR IN STAT TBL       A59117 19400021
DEIRSEL2 EQU   *                  RESTART POINT IS ESTABLISHED   A65119 19650021
         ST    CCWREG,IOBSTART          RETRY LAST/ONLY CMD   NG        19700000
         OI    IOBCNT2,IRERTY           INDICATE IR RETRY     NG        19800000
         NI    IOBFLAG3,ALLONE-IOBMSG   INT REQ MSG INDICATOR NG        19900000
         B     WTOEXIT                  EXIT TO WTO AND RETRY NG        20000000
*                                                                       20100000
CHKEC    EQU   *                                              NG        20200000
         B     RECRTY             RETRY THE SELECT               A65119 20250021
         BAL   LNKREG,CMDSRCH           FIND LAST COMMAND     NG        20300000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        20400000
         BE    PERMEXIT                 YES-PER ERROR EXIT    NG        20500000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        20600000
         BE    PERMEXIT                 YES-PER ERROR EXIT    NG        20700000
         B     SNOEXIT                  NO-SNO EXIT           NG        20800000
*                                                                       20900000
ANALCMD  EQU   *                                              NG        21000000
         B     RECRTY             RETRY SELECT                   A65119 21050021
         BAL   LNKREG,CMDSRCH           FIND LAST COMMAND     NG        21100000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        21200000
         BE    UNREC1                   YES-EXIT WITH ERROR   NG        21300000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        21400000
         BE    RECRTY                   YES-RETRY             NG        21500000
         CLI   CCWCMD(CCWREG),CCWSEL    SELECT                NG        21600000
         BE    CHKRTY                   YES-CHECK FOR RETRY   NG        21700000
         CLI   CCWCMD(CCWREG),CCWEUP    ERASE UNPROTECTED     NG        21800000
         BE    CHKRTY                   YES-CHECK FOR RETRY   NG        21900000
         B     SNOEXIT                  NO-SNO EXIT           NG        22000000
*                                                                       22100000
CHKRTY   EQU   *                                              NG        22200000
         CLI   IOBSENS0,SENDCUS         DATA CHK,UNIT SPECIFY NG        22300000
         BE    UNREC1                   YES-EXIT WITH ERROR   NG        22400000
RECRTY   EQU   *                                              NG        22500000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        22600000
         CLI   IOBSENS0,SENDC           DATA CHK IN SENSE     NG        22700000
         BE    SETDC                    YES-SET DATA CHK ERR  NG        22800000
         CLI   IOBSENS0,SENCC           CTRL CHK IN SENSE     NG        22900000
         BE    SETCC                    YES-SET CTRL CHK ERR  NG        23000000
         OI    9(STABREG),STDCUS        SET DC,US IN STAT TBL NG        23100000
         B     STORCCW                  RETRY CCW ADDR        NG        23200000
*                                                                       23300000
SETDC    EQU   *                                              NG        23400000
         OI    8(STABREG),STATDC        SET DC IN STAT TBL       A59117 23500021
         B     STORCCW                  RETRY CCW ADDR        NG        23600000
*                                                                       23700000
SETCC    EQU   *                                              NG        23800000
         OI    8(STABREG),SENCC         SET CC IN STAT TBL    NG        23900000
         B     STORCCW                  RETRY CCW ADDR        NG        24000000
*********************************************************************** 24100000
*        CHANNEL DATA CHECK                                           * 24200000
*********************************************************************** 24300000
ANALCHAN EQU   *                                              NG        24400000
         BAL   LNKREGB,CHKDIAG          CHECK FOR DIAG CMD    NG        24500000
         B     BRTAB2(IXREG)            DIAG CMD RTN BR TBL   NG        24600000
BRTAB2   B     PERMEXIT                 DIAG CMD-PER ERR EXIT NG        24700000
         TM    IOBCSW+5,CSWCCC      CHAN CONTROL CHECK           A68718 24800021
         BO    TESTCCH              YES, SEE IF CCH PRESENT      A68718 24850021
         TM    IOBCSW+5,CSWICC      INTERFACE CONTROL CHECK      A68718 24950021
         BO    TESTCCH              YES, SEE IF CCH PRESENT      A68718 25000021
         TM    IOBCSW+5,CSWCDC      CHANNEL DATA CHECK           A68718 25050021
         BO    CDCERR               YES, HANDLE                  A68718 25100021
         B     SNOEXIT              NO, SNO EXIT                 A68718 25110021
TESTCCH  EQU   *                                                 A68718 25120021
         TM    OPTFLGS(CVTREG),CCHFLG  CCH IN SYSTEM             A68718 25150021
         BNO   PERMEXIT             NO, PERM ERROR               A68718 25200021
         LA    LDNAMREG,LOAD210E    NAME OF SPECIAL ERP          A68718 25250021
         BR    RETREG               EXIT VIA BR EP               A68718 25260021
*                                                                       25300000
CDCERR   EQU   *                                              NG        25400000
         L     CCWREG,IOBCSW            ADDR OF CCW           NG        25500000
         LA    CCWREG,0(CCWREG)         CLEAR HI BYTE         NG        25600000
         SH    CCWREG,CONEIGHT          FAILING CCW ADDR      NG        25700000
         BNP   SNOEXIT                  EXIT IF ADDR INVALID  NG        25800000
         TM    CCWCMD(CCWREG),CCWTIC    TIC COMMAND           NG        25900000
         BZ    UNREC1                   YES-UNREC EXIT        NG        26000000
         CLI   CCWCMD(CCWREG),CCWWRT    WRITE                 NG        26100000
         BE    UNREC1                   YES-UNREC EXIT        NG        26200000
         CLI   CCWCMD(CCWREG),CCWEWR    ERASE WRITE           NG        26300000
         BE    CHKCHAIN                 YES-CHECK CHAINING    NG        26400000
         CLI   CCWCMD(CCWREG),CCWRDM    READ MODIFIED         NG        26500000
         BE    CHKWRCMD                 YES-CHECK CHAN PGM    NG        26600000
         CLI   CCWCMD(CCWREG),CCWRDB    READ BUFFER           NG        26700000
         BE    CHKWRCMD                 YES-CHECK CHAN PGM    NG        26800000
RTYCCW   EQU   *                                              NG        26900000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        27000000
         OI    9(STABREG),STCDC         SET CDC IN STAT TBL   NG        27100000
         B     STORCCW                  RETRY FAILING CMD     NG        27200000
*                                                                       27300000
CHKCHAIN EQU   *                                              NG        27400000
         TM    IOBFLAG1,IOBDCH          DATA CHAIN IN CH PGM  NG        27500000
         BO    RTYCHPGM                 YES-RETRY CHAN PGM    NG        27600000
         B     RTYCCW                   NO-RETRY FAILING CMD  NG        27700000
*                                                                       27800000
CHKWRCMD EQU   *                                              NG        27900000
         LA    CMDREG,CCWWRT            WRITE CMD             NG        28000000
         BAL   LNKREG,CHKCMD            LINK TO CHK CHAN PGM  NG        28100000
         B     BRTAB3(IXREG)            RETURN BRANCH TABLE   NG        28200000
BRTAB3   B     UNREC1                   WRT IN CHAN PGM-EXIT  NG        28300000
RTYCHPGM EQU   *                                              NG        28400000
         BAL   LNKREG,FINDSTAT          FIND STAT TBL ENTRY   NG        28500000
         OI    9(STABREG),STCDC         SET CDC IN STAT TBL   NG        28600000
         B     RTYCNT                   RETRY CHAN PGM        NG        28700000
*                                                                       28800000
*********************************************************************** 28900000
*              FINDSTAT SUBROUTINE                                    * 29000000
*        THIS SUBROUTINE SEARCHS THE DEVICE STATISTICS TABLE FOR THE  * 29100000
*        ENTRY ASSIGNED TO THE I/O DEVICE THAT IS CURRENTLY BEING     * 29200000
*        HANDLED BY THE ERP. THE ADDRESS OF THE ENTRY IS RETURNED TO  * 29300000
*        THE CALLER IN STABREG.                                       * 29400000
*********************************************************************** 29500000
FINDSTAT EQU   *                                                        29600000
         L     STABREG,STATADR(CVTREG)  STAT TABLE ADDRESS              29700000
         LR    WKREG1,STABREG           SAVE STAT TABLE START ADDR      29800000
         SR    ICREG,ICREG              CLEAR FOR STAT TABLE INDEX      29900000
         IC    ICREG,UCBSTI(UCBREG)     PICK UP INDEX                   30000000
STATLOOP CH    UCBREG,0(WKREG1)         TEST FOR CORRECT TABLE SECT     30100000
         BL    SECTFND                  IF FOUND-RESOLVE ENTRY ADDR     30200000
         LA    WKREG1,2(WKREG1)         IF NOT-INCR TO NEXT CTRL ENTRY  30300000
         LA    ICREG,256(ICREG)         INCR INDEX TO NEXT SECT         30400000
         B     STATLOOP                 CHECK AGAIN                     30500000
SECTFND  EQU   *                                                        30600000
         MH    ICREG,CONTEN             ADJUST FOR ENTRY LENGTH         30700000
         AR    STABREG,ICREG            RESOLVE ENTRY ADDR              30800000
         BR    LNKREG                   RETURN TO CALLER                30900000
*********************************************************************** 31000000
*              CMDSRCH SUBROUTINE                                     * 31100000
*        THE CMDSRCH SUBROUTINE SEARCHS A CHANNEL PROGRAM,BEGINNING   * 31200000
*        WITH THE ADDRESS IN IOBSTART,TO FIND THE ADDRESS OF THE LAST * 31300000
*        COMMAND IN THE CHANNEL PROGRAM. THAT IS,THE LAST CCW THAT IS * 31400000
*        NOT A TIC AND DOES NOT HAVE THE COMMAND CHAINING FLAG ON.    * 31500000
*        WHEN CONTROL IS RETURNED TO THE CALLER,THE LAST COMMAND      * 31600000
*        ADDRESS IS IN CCWREG.                                        * 31700000
*********************************************************************** 31800000
CMDSRCH  EQU   *                                              NG        31900000
         L     CCWREG,IOBSTART          FIRST CCW ADDR        NG        32000000
         LA    CCWREG,0(CCWREG)         CLEAR HI BYTE         NG        32100000
         LR    WKREG1,CCWREG            ESTABLISH WORK REG    NG        32200000
CHKLOOP  TM    CCWFLGS(WKREG1),CCWCC    CMD CHAINING          NG        32300000
         BO    NEXTCCWA                 YES-CHECK NEXT CCW    NG        32400000
         TM    CCWFLGS(WKREG1),CCWCD    DATA CHAINING         NG        32500000
         BO    NEXTCCWB                 YES-CHECK NEXT CCW    NG        32600000
         TM    CCWCMD(WKREG1),CCWTIC    LOW ORDER BITS ZERO?     A60093 32750021
         BO    NOTICCMD                 NO,RETURN,LAST FOUND     A60093 32760021
         TM    CCWCMD(WKREG1),CCWTIC1   TIC COMMAND CODE?        A60093 32770021
         BO    ADJADR2                  YES,ADJUST ADDRESS.      A60093 32780021
NOTICCMD EQU   *                                                 A60093 32790021
         BR    LNKREG                   NO-LAST FOUND,RETURN  NG        32900000
*                                                                       33000000
NEXTCCWA EQU   *                                              NG        33100000
         LA    WKREG1,8(WKREG1)         NEXT CCW ADDR         NG        33200000
         LR    CCWREG,WKREG1            MAINTAIN LAST CMD ADR NG        33300000
         B     CHKLOOP                  CONTINUE CHAINING CHK NG        33400000
*                                                                       33500000
NEXTCCWB EQU   *                                              NG        33600000
         LA    WKREG1,8(WKREG1)         NEXT CCW ADDR         NG        33700000
         B     CHKLOOP                  CONTINUE CHAINING CHK NG        33800000
ADJADR2  EQU   *                                              NG        33900000
         L     WKREG1,0(WKREG1)         NEXT CCW ADDR         NG        34000000
         LR    CCWREG,WKREG1            MAINTAIN LAST CMD ADR NG        34100000
         B     CHKLOOP                  CONTINUE CHAINING CHK NG        34200000
*********************************************************************** 34300000
*              CHKDIAG SUBROUTINE                                     * 34400000
*        THIS  SUBROUTINE PLACES A DIAGNOSTIC WRITE / DIAGNOSTIC READ * 34500000
*        COMMAND CODE IN CMDREG AND LINKS TO THE CHKCMD SUBRTN. THE   * 34600000
*        CHKCMD SUBRTN CHECKS IF EITHER COMMAND IS CONTAINED IN THE   * 34700000
*        CHANNEL PROGRAM.THE RETURN CODE RETURNED BY THE CHKCMD SUBRTN* 34800000
*        IS PASSED BACK TO THE CALLER.                                * 34900000
*********************************************************************** 35000000
CHKDIAG  EQU   *                                                        35100000
         LA    CMDREG,CCWDWR            DIAG WRITE CMD                  35200000
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               35300000
         B     BRTABD(IXREG)            RETURN BRANCH TABLE             35400000
BRTABD   BR    LNKREGB                  DWR FOUND-RETURN      NG        35500000
         BCR   ZERO,ZERO                PAD FOR RET CODE IX   NG        35600000
         LA    CMDREG,CCWDRD            DIAG READ CMD                   35700000
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               35800000
         BR    LNKREGB                  RETURN WITH RET CODE  NG        35900000
*                                                                       36000000
*********************************************************************** 36100000
*              CHKCMD SUBROUTINE                                      * 36200000
*        THIS SUBROUTINE COMPARES THE COMMAND CODE OF EACH CCW IN A   * 36300000
*        CHANNEL PROGRAM TO THE COMMAND CODE CONTAINED IN CMDREG.     * 36400000
*        IF THE COMMAND IS FOUND,A RETURN CODE OF ZERO IS PLACED IN   * 36500000
*        IXREG. IF IT IS NOT FOUND,THE RETURN CODE IS FOUR.           * 36600000
*********************************************************************** 36700000
CHKCMD   EQU   *                                                        36800000
         L     CCWREG,IOBSTART          PICK UP FIRST CCW ADDR          36900000
         SR    ICREG,ICREG              CLEAR FOR CMD                   37000000
CMDLOOP  IC    ICREG,CCWCMD(CCWREG)     PICK UP COMMAND                 37100000
         CLR   CMDREG,ICREG             CHECK FOR COMMAND               37200000
         BE    SETCFND                  YES-SET COMMAND FOUND RET CODE  37300000
         TM    CCWCMD(CCWREG),CCWTIC    LOW ORDER BIT 0'S        A55306 37400021
         BNZ   CHKCMD1                  BRANCH IF NOT            A55306 37430021
         TM    CCWCMD(CCWREG),CCWTIC1   TIC COMMAND              A55306 37460021
         BO    ADJADR1                  YES-ADJUST ADDR          A55306 37500021
*                                           TO NEXT CCW          A55306 37530021
CHKCMD1  EQU   *                                                 A55306 37560021
         TM    CCWFLGS(CCWREG),CCWCC+CCWCD CHAINING INDICATED           37600000
         BZ    SETCNFND                 NO-SET CMD NOT FOUND RET CODE   37700000
         LA    CCWREG,8(CCWREG)         YES-INCR TO NEXT CCW            37800000
         B     CMDLOOP                  CONTINUE CHECKING               37900000
*                                                                       38000000
ADJADR1  EQU   *                                                        38100000
         L     CCWREG,0(CCWREG)         PICK UP NEXT CCW ADDR           38200000
         B     CMDLOOP                  CONTINUE TO CHECK COMMAND       38300000
*                                                                       38400000
SETCNFND EQU   *                                                        38500000
         LA    IXREG,FOUR               SET CMD NOT FOUND RC  NG        38600000
         BR    LNKREG                   RETURN TO CALLER                38700000
*                                                                       38800000
SETCFND  EQU   *                                                        38900000
         LA    IXREG,ZERO               SET CMD FOUND RC      NG        39000000
         BR    LNKREG                   RETURN TO CALLER                39100000
*********************************************************************** 39200000
*              EXITS                                                  * 39300000
*********************************************************************** 39400000
UNREC1   EQU   *                                                        39500000
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             39600000
SNOEXIT  EQU   *                                                        39700000
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLGS   NG        39800000
SETPER   EQU   *                                                        39900000
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       40000000
CHKSTAT  EQU   *                                              NG        40100000
         NI    IOBCNT1,ALLZERO          CLEAR RTY CNT FIELD   NG        40200000
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RTY FLG FIELD   NG        40300000
         TM    IOBFLAG3,IOBLOG          OBR LOGOUT REQUIRED             40400000
         BO    STATEXIT                 IF YES-EXIT TO STAT UPDATE      40500000
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   40600000
         NI    8(STABREG),STMSK1        CHECK FOR SINGLE BIT ENTRIES    40700000
         BZ    CHKMULTI                 IF NONE-CHECK MULTI BIT         40800000
         B     STATEXIT                 IF PRESENT-EXIT TO STAT UPDATE  40900000
CHKMULTI EQU   *                                                        41000000
         NI    9(STABREG),STMSK2        CHECK FOR MULTI BIT ENTRIES     41100000
         BZ    RETEXIT                  IF NONE-STAT UPDATE NOT REQD    41200000
STATEXIT EQU   *                                                        41300000
         LA    LDNAMREG,STATUP          ADDRESS OF STAT UPDATE ROUTINE  41400000
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      41500000
*                                                                       41600000
STORCCW  EQU   *                                              NG        41700000
         ST    CCWREG,IOBSTART          RETRY CCW ADDR        NG        41800000
RTYCNT   EQU   *                                              NG        41900000
         CLI   IOBCNT1,THREE            RETRY COUNT AT MAX    NG        42000000
         BNL   PERMEXIT                 MAX CNT-PER ERR EXIT  NG        42100000
         SR    ICREG,ICREG              CLEAR REG             NG        42200000
         IC    ICREG,IOBCNT1            PICK UP COUNT         NG        42300000
         LA    ICREG,ONE(ICREG)         BUMP BY ONE           NG        42400000
         STC   ICREG,IOBCNT1            SAVE COUNT            NG        42500000
RETEXIT  EQU   *                                                        42600000
         SVC   EREXCP                   ERROR EXCP                      42700000
         SVC   RETURN                   RETURN TO SVPR                  42800000
*                                                                       42900000
PERMEXIT EQU   *                                                        43000000
         TM    SRTESTAT(UCBREG),OPCNSL  DEVICE AN ONLINE ACTIVE CONSOLE 43100000
         BO    UNREC1                   IF YES-LOG WITHOUT ERROR MSG    43200000
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLGS   NG        43300000
         NI    IOBCNT1,ALLZERO          CLEAR RTY CNT FIELD   NG        43400000
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RTY FLG FIELD   NG        43500000
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             43600000
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       43700000
         OI    IOBFLAG3,IOBMSG          PERM ERROR MSG REQUIRED         43800000
WTOEXIT  EQU   *                                                        43900000
         LA    LDNAMREG,IOSWTO          ADDRESS OF IOS WTO ROUTINE      44000000
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      44100000
*                                                                       44200000
*        REGISTER DEFINITIONS                                           44300000
*                                                                       44400000
TEMPREG  EQU   0                        TEMPORARY SAVE REG    NG        44500000
TSTREG   EQU   1                        RQE ADDRESS                     44600000
IOBREG   EQU   2                        IOB ADDRESS                     44700000
DCBREG   EQU   3                        DCB ADDRESS                     44800000
UCBREG   EQU   4                        UCB ADDRESS                     44900000
CVTREG   EQU   5                        CVT ADDRESS                     45000000
CCWREG   EQU   6                        CCW ADDRESS                     45100000
STABREG  EQU   7                        STAT TABLE ADDRESS              45200000
WKREG1   EQU   8                        WORK REG                        45300000
CMDREG   EQU   WKREG1                   COMMAND REG                     45400000
ICREG    EQU   9                        CHAR REG                        45500000
LNKREG   EQU   10                       LINK REG                        45600000
IXREG    EQU   11                       INDEX REG                       45700000
LNKREGB  EQU   12                       SECOND LINK REG       NG        45800000
LDNAMREG EQU   13                       NEXT LOAD MODULE NAME           45900000
RETREG   EQU   14                       BRANCH ENTRY ADDR TO XCTL       46000000
BASREG   EQU   15                       ERP BASE REG                    46100000
*                                                                       46200000
*        IOB DEFINITIONS AND FLAGS                                      46300000
*                                                                       46400000
IOBDCH   EQU   X'80'                    DATA CHAIN FLAG       NG        46500000
IOBERR   EQU   X'20'                    ERP IN CONTROL                  46600000
IOBEXC   EQU   X'04'                    IOB EXCEPTION                   46700000
IOBEXE   EQU   IOBERR+IOBEXC            EXCEPTION AND ERP IN CONTROL    46800000
IOBINT   EQU   X'7E'                    INTERCEPT CODE                  46900000
GOODIO   EQU   X'7F'                    GOOD I/O CODE                   47000000
IOBMSG   EQU   X'04'                    PERMENENT ERROR MESSAGE         47100000
IOBLOG   EQU   X'01'                    OBR LOGOUT                      47200000
IOBCC1   EQU   X'10'                    SIO CC=1                        47300000
IOBCC3   EQU   X'30'                    SIO CC=3                        47400000
CHANERR  EQU   X'80'                    CHANNEL ERROR FLAG    NG        47500000
UEXRTY   EQU   X'20'                    UNIT EXCEPTION RETRY            47600000
IRERTY   EQU   X'10'                    INTERVENTION REQUIRED RETRY     47700000
DEERR    EQU   X'08'                    DEVICE END ERROR      NG        47800000
USRCRCT  EQU   X'04'                    USER CORRECTABLE                47900000
ERPCOMP  EQU   X'02'                    ERP COMPLETE                    48000000
PERMERR  EQU   X'01'                    PERMENENT ERROR                 48100000
ERPFLGS  EQU   USRCRCT+ERPCOMP+PERMERR  ERP FLAGS                       48200000
RTYFLD   EQU   X'F8'                    RETRY FLAGS FIELD     NG        48300000
*                                                                       48400000
*        UCB DEFINITIONS AND FLAGS                                      48500000
*                                                                       48600000
SRTESTAT EQU   3                        STATUS A                        48700000
UCBFL1   EQU   6                        FLAGS 1                         48800000
UCBSTI   EQU   9                        STATISTICS TABLE INDEX          48900000
UCBTYP   EQU   16                       DEVICE TYPE FIELD               49000000
DEVCLS   EQU   UCBTYP+2                 DEVICE CLASS BYTE               49100000
UCBNRY   EQU   X'40'                    DEVICE NOT READY                49200000
UCBITF   EQU   X'10'                    INTERCEPT FLAG                  49300000
OPCNSL   EQU   X'82'                    ONLINE ACTIVE CONSOLE           49400000
GRTYPE   EQU   X'10'                    GRAPHICS CLASS                  49500000
DEV3277  EQU   X'09'                    3277 DEVICE                     49600000
DEV3284  EQU   X'0A'                    3284 DEVICE                     49700000
DEV3286  EQU   X'0B'                    3286 DEVICE                     49800000
DEVTYP   EQU   UCBTYP+3                 DEVICE TYPE BYTE                49900000
*                                                                       50000000
*        DCB  FLAGS                                                     50100000
*                                                                       50200000
DCBPER   EQU   X'C0'                    PERMENENT ERROR                 50300000
DCBCLOS  EQU   X'11'                    CLOSE IN PROGRESS               50400000
*                                                                       50500000
*        RQE  DEFINITIONS                                               50600000
*                                                                       50700000
TSTUCB   EQU   2                        UCB ADDRESS                     50800000
TSTIOB   EQU   4                        IOB ADDRESS                     50900000
*                                                                       51000000
*        CSW  FLAGS                                                     51100000
*                                                                       51200000
CSWCHE   EQU   X'08'                    CHANNEL END                     51300000
CSWDVE   EQU   X'04'                    DEVICE END                      51400000
CSWCDE   EQU   CSWCHE+CSWDVE            CHANNEL END AND DEVICE END      51500000
CSWUCK   EQU   X'02'                    UNIT CHECK                      51600000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  51700000
CSWIL    EQU   X'40'                    INCORRECT LENGTH                51800000
CSWPGC   EQU   X'20'                    PROGRAM CHECK                   51900000
CSWPTC   EQU   X'10'                    PROTECTION CHECK                52000000
CSWCDC   EQU   X'08'                    CHANNEL DATA CHECK              52100000
CSWCCC   EQU   X'04'                    CHANNEL CONTROL CHECK           52200000
CSWICC   EQU   X'02'                    INTERFACE CONTROL CHECK         52300000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  52400000
CATCHAN  EQU   CSWCDC+CSWCCC+CSWICC     CATASTROPHIC CHANNEL ERRORS     52500000
CATERR   EQU   CSWIL+CSWPGC+CSWPTC+CSWCCK STATUS ERRORS                 52600000
*                                                                       52700000
*        SENSE FLAGS                                                    52800000
*                                                                       52900000
SENCR    EQU   X'80'                    COMMAND REJECT                  53000000
SENIR    EQU   X'40'                    INTERVENTION REQUIRED           53100000
SENBOC   EQU   X'20'                    BUS OUT CHECK                   53200000
SENEC    EQU   X'10'                    EQUIPMENT CHECK                 53300000
SENDC    EQU   X'08'                    DATA CHECK                      53400000
SENCC    EQU   X'02'                    CONTROL CHECK                   53500000
SENOC    EQU   X'01'                    OPERATION CHECK                 53600000
SENDCUS  EQU   X'0C'                    DATA CHECK,UNIT SPECIFY  A59081 53700021
SENIRUS  EQU   X'44'                    INT REQ,UNIT SPECIFY            53800000
SNIRECUS EQU   X'54'                    INT REQ,EQUIP CHK,UNIT SPECIFY  53900000
SENECUS  EQU   X'14'                    EQUIP CHECK,UNIT SPECIFY        54000000
*                                                                       54100000
*        STATISTICS TABLE MULTI BIT SENSE FLAGS                         54200000
*                                                                       54300000
STDCUS   EQU   X'10'                    DATA CHECK,UNIT SPECIFY         54400000
STIRUS   EQU   X'08'                    INT REQ,UNIT SPECIFY            54500000
STIRECUS EQU   X'04'                    INT REQ,EQUIP CHK,UNIT SPECIFY  54600000
STECUS   EQU   X'02'                    EQUIP CHECK,UNIT SPECIFY        54700000
STCDC    EQU   X'01'                    CHAN DATA CHECK       NG        54800000
STMSK1   EQU   X'7A'                    SINGLE BIT POS USED MASK        54900000
STMSK2   EQU   X'1F'                    MULTI BIT POS USED MASK         55000000
*                                                                       55100000
*        CCW COMMAND CODES , DEFINITIONS AND FLAGS                      55200000
*                                                                       55300000
CCWWRT   EQU   X'01'                    WRITE                           55400000
CCWEWR   EQU   X'05'                    ERASE WRITE                     55500000
CCWRDM   EQU   X'06'                    READ MODIFIED                   55600000
CCWSNS   EQU   X'04'                    SENSE                 NG        55700000
CCWNOP   EQU   X'03'                    NO-OP                 NG        55800000
CCWRDB   EQU   X'02'                    READ BUFFER                     55900000
CCWDWR   EQU   X'09'                    DIAGNOSTIC WRITE                56000000
CCWDRD   EQU   X'0A'                    DIAGNOSTIC READ                 56100000
CCWSEL   EQU   X'0B'                    SELECT                          56200000
CCWEUP   EQU   X'0F'                    ERASE ALL UNPROTECTED           56300000
CCWCC    EQU   X'40'                    COMMAND CHAINING                56400000
CCWCD    EQU   X'80'                    DATA CHAINING                   56500000
CCWTIC   EQU   X'07'                    TIC MASK                        56600000
CCWTIC1  EQU   X'08'                    TIC MASK                 A55306 56650021
CCWCMD   EQU   0                        COMMAND FIELD                   56700000
CCWFLGS  EQU   4                        FLAGS FIELD                     56800000
CCWCNT   EQU   6                        COUNT FIELD                     56900000
*                                                                       57000000
*        MISC   DEFINITIONS,FLAGS AND CONSTANTS                         57100000
*                                                                       57200000
ZERO     EQU   0                        ZERO                  NG        57300000
ONE      EQU   X'01'                    ONE                   NG        57400000
THREE    EQU   X'03'                    THREE                 NG        57500000
FOUR     EQU   4                        FOUR                  NG        57600000
CVTADR   EQU   16                       LOCATION OF CVT ADDRESS         57700000
XCTLADR  EQU   44                       ADDRESS OF BRANCH EP TO XCTL    57800000
STATADR  EQU   112                      ADDRESS OF STATISTICS TABLE     57900000
OPTFLGS  EQU   182                      ADDRESS OF OPTION FLAGS         58000000
IOSWTO   EQU   253                      IOS WTO ROUTINE ID              58100000
STATUP   EQU   254                      STATISTICS UPDATE ROUTINE ID    58200000
CCHFLG   EQU   X'80'                    CCH IN SYSTEM                   58300000
RETURN   EQU   3                        RETURN SVC                      58400000
EREXCP   EQU   15                       ERROR SVC                       58500000
BADSENS  EQU   X'FE'                    SENSE NOT VALID                 58600000
ALLONE   EQU   X'FF'                    ALL ONES BYTE                   58700000
ALLZERO  EQU   X'00'                    ALL ZEROS BYTE                  58800000
CONONE   DC    H'1'                     CONSTANT ONE          NG        58900000
CONEIGHT DC    H'8'                     CONSTANT EIGHT        NG        59000000
CONTEN   DC    H'10'                    CONSTANT TEN          NG        59100000
LOAD210E EQU   2105                 SPECIAL ERP LOAD             A68718 59110021
*                                                                       59150021
* THE FOLLOWING FLGS ARE USED TO SET THE PROPER BITS FOR EDITING A59117 59160021
* AND PRINTING DC,EC,BOC AND IR ERRORS WHEN SYS1.LOGREC IS       A59117 59170021
* PRINTED.                                                       A59117 59180021
STATEC   EQU   X'10'                    EQUIPMENT CHECK          A65099 59190021
STATDC   EQU   X'08'                    DATA CHECK               A65099 59192021
STATBOC  EQU   X'20'                    BUS OUT CHECK            A65099 59194021
STATIR   EQU   X'40'                    INTERVENTION REQUIRED    A65099 59196021
*                                                                       59200000
PATCHLEN EQU   IGE0110E+1024-*     LENGTH OF PATCH AREA          A68718 59250021
PATCH    DC    (PATCHLEN)X'00'     VARIABLE LENGTH PATCH AREA    A68718 59260021
         IECTIOBX                                                       59300000
IOBCNT1  EQU   IOBERRCT                                       NG        59400000
IOBCNT2  EQU   IOBERRCT+1                                     NG        59500000
         DCBD  DSORG=BX,DEVD=BS                                         59600000
         END                                                            59700000
