         TITLE 'IGE0204A - BTAM ERP TIME OUT MODULE'                    00400013
IGE0204A CSECT                                                          00800013
*71660068028000,524000                                             000C 01400015
         SPACE 2                                                        02000013
*********************************************************************** 02400013
* STATUS            CHANGE LEVEL  002   NOVEMBER 17, 1967               02800015
*                                                                     * 03200013
* FUNTION-         IF REQUIRED, RETRIES CHANNEL PROGRAM THAT FAILED   * 03600013
*                  BECAUSE OF A TIME OUT CONDITION.  DETERMINES IF    * 04000013
*                  LINE ERROR RECORDING IS REQUIRED AND LINKS EITHER  * 04400013
*                  TO DISABLE ROUTINE, LERB ROUTINE, OR POST ROUTINE. * 04800013
*                                                                     * 05200013
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 05600013
*                  TO THE ASSOCIATED IO RB.                           * 06000013
*                                                                     * 06400013
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 06800013
*                  ERROR.                                             * 07200013
*                                                                     * 07600013
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 08000013
*                                                                     * 08400013
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0304A,         * 08800013
*                  IGE0504A, AND IGE0204B.                            * 09200013
*                                                                     * 09600013
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 10000013
*********************************************************************** 10400013
         SPACE 2                                                        10800013
*          TIME OUT MODULE                                              11200013
         USING *,BASREG                                                 11600013
         L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  12000013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  12400013
         L     COMREG,LOC016            ADDRESS OF CVT                  12800013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 13200013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  13600013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  14000013
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           14400013
         MVC   IOBWRK(1,IOBRG),5(CCWREG) TP OP CODE TO WORK AREA        14800013
         NI    IOBWRK(IOBRG),MASKALL-CCWMASK1  MASK OUT UNUSED BITS     15200013
         LA    ERREG1,IOBCPA(IOBRG)     ADDRESS OF CHAN PROG       000A 15600013
         ST    ERREG1,IOBSTART(IOBRG)   STORE IN PTR LOC           000A 16000013
         CLI   0(CCWREG),CCWAPOLL       THIS POLL COMMAND          000A 16400013
         BE    ERRTOT02                 UPDATE POLL COMMAND        000A 16800013
         CLI   0(CCWREG),CCWINCMD       INHIBIT COMMAND                 16900019
         BE    READ                                                     17000019
         CLI   0(CCWREG),CCWRDCMD       READ COMMAND                    17200013
         BNE   ERRTOD00                 NO CHECK FOR DISABLE OR PREPARE 17600013
READ     EQU   *                                                        17800019
         TM    IOBWRK(IOBRG),CCWPTXFR   PRIOR TO TEXT TRANSFER          18000013
         BZ    ERRTOD06                YES, CHECK ADAPTER        A28615 18080019
         TM    DCBBFTEK(DCBREG),X'08'  DYNAMIC BUFFER SPECIFIED  A28615 18160019
         BZ    ERRTOT03                NO, CHECK FOR RD RESP TXT A28615 18240019
         NI    IOBFL1(IOBRG),MASKALL-IOBERR TURN OFF ERP CONTROL A28615 18320019
         B     ERRPERM1                POST PERMANENT ERROR      A28615 18400019
ERRTOD06 TM    UCBTYP+3(UCBREG),T83B3A IS THIS 83B3 ADAPTER      A28615 18480019
         BNZ   ERRTOT08                 NO CONTINUE PROCESSING     0038 18600017
         TM    UCBTYP(UCBREG),T83B3D    IS THIS 83B3               0038 18700017
         BNO   ERRTOT08                 NO CONTINUE PROCESSING-    0038 18800017
         CLI   IOBWRK(IOBRG),CCWRDRSP   READ RESP TO ADDRESSING    0038 18900017
         BE    ERRTOT09                 YES SET UP RETRY           0038 19000017
ERRTOT08 CLI   IOBWRK(IOBRG),CCWTWXID   THIS TWX ID RESPONSE       0038 19100017
         BE    ERRTOD03                 YES CHK FOR LERB           000A 19200013
ERRTOT00 CLI   IOBCPA(IOBRG),CCWDISAB   FIRST COMMAND DISABLE           19600013
         BNE   ERRTOT01                 NO CHECK FOR POLL RESP     000A 20000013
ERRTOT09 LA    ERREG1,IOBCMD3(IOBRG)    INITIALIZE CPA TO 3RD COMMND    20400017
         ST    ERREG1,IOBSTART(IOBRG)   STORE CPA START IN POINTER      20800013
ERRTOT01 CLI   IOBWRK(IOBRG),CCWPOLL    READ RESPONSE TO POLLING        21200013
         BNE   ERRTOD04                 NO, CHECK FOR AUTOPOLL     000A 21600013
*                                  READ INDEX.                     000A 22000013
         CLC   IOBCSW+6(2,IOBRG),6(CCWREG) RESIDUAL CT EQU ORIG COUNT   22400013
         BE    ERRTOD03                 YES CHECK FOR LERB              22800013
         B     ERRCTT01                 NO CHECK FOR RETRY              23200013
ERRTOD04 CLI   5(CCWREG),CCWRDIX       READ RESP TO INDEX        A28615 23600019
         BNE   ERRTOD03                 NO CHECK FOR LERB          000A 24000013
ERRTOT02 EQU   *                                                   000A 24400013
         L     ERREG1,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FROM    000A 24800013
*    PREVIOUS POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).    000A 25200013
         MVC   IOBCPA+9(3,IOBRG),DECENTRY+1(DECBRG)    MOVE IN     000A 25600013
*    ADDRESS OF LAST ENTRY POLLED (TO BE USED AS RESTART ADDRESS). 000A 26000013
         L     ERREG4,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FOR     000A 26400013
*    NEXT POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).        000A 26800013
         SR    ERREG1,ERREG4            SUBTRACT NEW POLL ADDRESS  000A 27200013
*                                  FROM PREVIOUS POLL ADDRESS.     000A 27600013
         AH    ERREG1,IOBCPA+14(IOBRG)  IF THE NEW POLL ADDRESS    000A 28000013
*    WERE LESS THAN THE PREVIOUS POLL ADDRESS, THE EFFECT IS TO    000A 28400013
*    ADD THE ABSOLUTE DIFFERENCE TO THE PREVIOUS COUNT;  IF IT WERE000A 28800013
*    GREATER, THE EFFECT IS TO SUBTRACT THE ABSOLUTE DIFFERENCE    000A 29200013
*    FROM THE PREVIOUS COUNT.                                      000A 29600013
         STH   ERREG1,IOBCPA+14(IOBRG)  STORE ADJUSTED COUNT IN    000A 30000013
*                                  POLL COMMAND.                   000A 30400013
         CLI   0(CCWREG),CCWAPOLL       POLL COMMAND               000A 30800013
         BE    ERRTOD03                 YES CHK FOR LERB           000A 31200013
         B     ERRCTT01                 NO CHK FOR MORE RETRIES    000A 31600013
ERRTOD00 CLI   0(CCWREG),CCWDISAB       DISABLE COMMAND                 32000013
         BE    ERRTOD02                 YES  SET CPA TO STAR  CHAN PROG 32400013
         CLI   0(CCWREG),CCWENABL       ENABLE COMMAND             1286 32500017
         BE    ERRFIX01                 YES, CHECK FOR RESTART     1286 32600017
         CLI   0(CCWREG),CCWPREP        PREPARE COMMAND                 32800013
         BE    ERRTOD02                 YES  SET CPA TO START CHAN PROG 33200013
         CLI   0(CCWREG),CCWDIAL        DIAL COMMAND                    33600013
         BE    ERRCTT01                 YES CHECK FOR LERB         000A 34000013
         CLI   0(CCWREG),CCWWRITE       WRITE COMMAND              7752 34450017
         BNE   ERRTOSNO                 NO, SHOULD NOT OCCUR       7752 34500017
         MVC   IOBWRK(1,IOBRG),UCBTYP+3(UCBREG) MOVE DEVTP TO WORK 7752 34550017
         NI    IOBWRK(IOBRG),MASK3      AND OFF UNUSED BITS        7752 34600017
         CLI   IOBWRK(IOBRG),IBMTYP3    IBM TYPE 3 ADAPTER         7752 34650017
         BNE   ERRTOSNO                 NO  SET SHOULD NOT OCCUR   7752 34700017
         MVC   IOBERINF+8(1,IOBRG),IOBSNS(IOBRG) SAVE SENSE BYTE A35742 34750020
         MVC   IOBERINF+9(7,IOBRG),IOBCSW+1(IOBRG) SAVE 7 BYTE CSW35742 34800020
         MVC   IOBERCCW(16,IOBRG),IOBCPA(IOBRG)                  A30752 34870020
         MVC   IOBCPA(16,IOBRG),RSET2848 SET UP RESET CHAN PROG    7752 34900017
         MVI   IOBECT+1(IOBRG),RTRN2848 INDICATE 2848 RESET        7752 34950017
         B     ERRTRY02                 EXECUTE RESET CHAN PROG    7752 35000017
ERRFIX01 SH    CCWREG,ERRCN1            BACK UP ONE CCW            1286 35010017
         CLI   0(CCWREG),CCWDISAB       DISABLE COMMAND            1286 35020017
         BE    ERRTOD02                 YES,RESTART CHAN PROG      1286 35030017
ERRTOSNO OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR  7752 35050017
         B     ERRTRY01                 EXIT TO WRITE MESSAGE           35120017
ERRTOD02 ST    CCWREG,IOBSTART(IOBRG)   ADDR OF FAILING CCW IN POINTER  35200013
ERRTOD03 TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQUIRED   35600013
         BNO   ERRCTT01                 NO CONTINUE FLOW                36000013
         MVI   IOBECT-1(IOBRG),LERBTO   IND TIME OUT LERB REQUIRED      36400013
ERRCTT01 CLI   DECTYPE+1(DECBRG),TYPETTV  IS OP TYPE A WRITE TTV?       36500019
         BNE   ERRTOD05                 NO, CHECK FOR RETRY             36600019
         LA    ERREG1,IOBCMD3(IOBRG)    YES, POINT TO START OF POLLING  36700019
         ST    ERREG1,IOBSTART(IOBRG)   STORE FOR RESTART               36800019
ERRTOD05 CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED                  36900019
         BL    ERRTRY02                 YES SET UP FOR RETRY            37200013
         CLI   0(CCWREG),CCWDISAB       DISABLE EXECUTED                37600013
         BE    ERRPERM1                 YES POST COMPLETE WITH ERROR    38000013
ERRTRY01 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                38400013
         BZ    ERRPERM1                 NO POST COMPLETE                38800013
         MVI   IOBECT+1(IOBRG),MASK3                                    39200013
         LA    SAVREG,ERLOD3            ADDRESS OF DISABLE ROUTINE      39600013
         B     ERRLINK1                 EXIT ROUTINE                    40000013
ERRTRY02 IC    ERREG1,IOBECT(IOBRG)     ERROR RETRY COUNT               40400013
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     40800013
         STC   ERREG1,IOBECT(IOBRG)     RESTORE IN COUNT FIELD          41200013
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                42400013
         CLI   IOBECT-1(IOBRG),LERBTO  LINE ERROR RECORDING REQ  A66468 42500021
         BE    ERLERBTO                YES, EXIT TO LERB RTN     A66468 42600021
         SVC   EXCPER                                                   42800013
         SVC   RETURN                   NO FINI                         44800013
ERRTOT04 EQU   *                                                 A25661 45000018
ERRPERM1 CLI   IOBECT-1(IOBRG),LERBTO   LINE ERROR RECORDING REQ A66468 45200021
         BE    ERLERBT1                 YES EXIT                 A66468 45600021
         LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         46000013
ERRLINK1 L     ERRETR,VECTXL(COMREG)    LINK ROUTINE                    46400013
         BR    ERRETR                   LINK                            46800013
ERLERBT1 NI    IOBFL1(IOBRG),MASKALL-IOBERR INDICATE POST AFTER LERB    47200013
ERLERBTO LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         47600013
         B     ERRLINK1                 LINK ROUTINE                    48000013
ERRTOT03 TM    IOBWRK(IOBRG),CCWTXTDT   ERROR DURING TRANSFER           48400013
         BZ    ERRTOT07                 NO CHK FOR RD RESPONSE TO TXT   48800013
         CLI   IOBWRK(IOBRG),CCWRDTXT  CHECK FOR READ TEXT       A28632 49000019
         BNE   ERRPERM1                NO, CHECK FOR LERB        A28632 49200019
         TM    UCBTYP+3(UCBREG),IBMTYP3 IS DEVICE 2260/2265 ?    A66473 49250021
         BO    ERRPERM1                                          A66473 49300021
         NI    IOBFL1(IOBRG),MASKALL-IOBERR YES, INDICATE POST   A28632 49400019
         SVC   EXCPER                                            A28632 49600019
         SVC   RETURN                                            A28632 49800019
ERRTOT07 CLI   IOBWRK(IOBRG),CCWRRTXT   READ RESPONSE TO TEXT           50400013
         BE    ERRTOT05                 YES CONTINUE FLOW               50800013
         B     ERRTOT04                 NO  INDICATE PER ERROR          51200013
ERRTOT05 TM    DCBERROP(DCBREG),CCWRTRT WRITE RETRY REQUIRED            51600013
         BZ    ERRTOT06                 NO CONTINUE FLOW                52000013
         MVC   IOBWRK+1(1,IOBRG),DECTYPE+1(DECBRG) TYPE CDE TO WRK 000C 52400015
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS          52800013
         CLI   IOBWRK+1(IOBRG),CCWWRTCT PREVIOUS CMD WRITE CONTINUE     53200013
         BNE   ERRTOT00                NO RESUME FLOW                   53600013
ERRTOT06 TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQ        54000013
         BNO   ERRTOT04                 NO POST COMPLETE WITH ERROR     54400013
         MVI   IOBECT-1(IOBRG),LERBTO   INDICATE LERB RECORDING         54800013
         NI    IOBFL1(IOBRG),MASKALL-IOBEXE INDICATE POST NO WTO        55200013
         LA    SAVREG,ERLOD12           LINE ERROR RECORDING ROUTINE    55600013
         B     ERRLINK1                 EXIT VIA LINK ROUTINE           56000013
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 56400013
ERRCN1   DC    H'8'                     DECIMAL 8                  000A 56800013
ERLOD5   DC    H'5041'                                             000A 57200013
RSET2848 DC    X'42000001700003C0'                                 7752 57250017
         DC    X'41000001200003E8'                                 7752 57300017
IBMTYP3  EQU   X'80'                                               7752 57350017
IOBERINF EQU   48                                                  7752 57400017
IOBERCCW EQU   40                                                A30752 57420020
CCWWRITE EQU   X'01'                                               7752 57450017
RTRN2848 EQU   X'80'                                               7752 57500017
T83B3A   EQU   X'B0'                                                    57520017
T83B3D   EQU   X'01'                                                    57540017
CCWRDRSP EQU   X'06'                                                    57560017
CCWAPOLL EQU   X'09'                                                    57600013
CCWDIAL  EQU   X'29'                                                    58000013
CCWDISAB EQU   X'2F'                                                    58400013
CCWENABL EQU   X'27'                                                    58600017
CCWMASK1 EQU   X'C0'                                                    58800013
CCWPOLL  EQU   X'05'                                                    59200013
CCWPREP  EQU   X'06'                                                    59600013
CCWPTXFR EQU   X'30'                                                    60000013
CCWRDCMD EQU   X'02'                                                    60400013
CCWINCMD EQU   X'0A'                                                    60600019
CCWRDIX  EQU   X'0A'                                               000A 60800013
CCWRRTXT EQU   X'20'                                                    61200013
CCWRTRT  EQU   X'04'                                                    61600013
CCWTWXID EQU   X'07'                                                    62000013
CCWTXTDT EQU   X'10'                                                    62400013
CCWWRTCT EQU   X'04'                                                    62800013
CSWSNO   EQU   X'40'                                                    63200013
DCBBFTEK EQU   X'20'                                             A28615 63400019
DCBERROP EQU   33                                                       63600013
DCBLERB  EQU   X'08'                                                    64000013
DECBDCB  EQU   8                                                        64400013
DECENTRY EQU   20                                                  000A 64800013
DECERRST EQU   29                                                       65200013
DECTYPE  EQU   4                                                        65600013
ERLOD3   EQU   3041                                                     66000013
ERLOD12  EQU   2042                                                     66400013
ERTRYCT  EQU   X'02'                                                    66800013
EXCPER   EQU   15                           EXCP ERROR ROUTINE          67200013
HIBIT    EQU   X'C0'                                                    67600013
IOBCPA   EQU   64                                                       68000013
IOBCMD3  EQU   IOBCPA+16                                                68400013
IOBCSW   EQU   8                            CSW STORAGE                 68800013
IOBDCBAD EQU   20                                                       69200013
IOBDECB  EQU   4                                                        69600013
IOBECT   EQU   30                      ERROR COUNTS                     70000013
IOBERR   EQU   X'20'                        IOB ERROR FLAG              70400013
IOBEX    EQU   X'04'                        EXCEPT FLAG                 70800013
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                71200013
IOBFL1   EQU 0                              FLAGS 1                     71600013
IOBSAV1  EQU   48                                                       72000013
IOBSAV2  EQU   64                                                       72400013
IOBSNS   EQU   2                                                        72800013
IOBSTART EQU   16                                                       73200013
IOBWRK   EQU   33                                                       73600013
LERBTO   EQU   X'03'                                                    74000013
LOC016   EQU   16                           COMMUNICATIONS TABLE        74400013
MASKALL  EQU   255                                                      74800013
MASK3    EQU   X'F0'                                                    75200013
NONAME   EQU   X'00'                                                    75600013
RETURN   EQU   3                       RETURN SVC                       76000013
SWLINE   EQU   X'90'                                                    76400013
TSTIOB   EQU   5                            IOB POINTER                 76800013
TSTUCB   EQU   2                            UCB POINTER                 77200013
TYPETTV  EQU   X'0F'                                                    77400019
UCBTYP   EQU   16                      DEVICE TYPE CODE                 77600013
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      78000013
CCWRDTXT EQU   X'11'                                             A28632 78200019
*        REGISTER DEFINITION                                            78400013
ERREG3   EQU   0                             WORK REG                   78800013
TSTREG   EQU   1                             TWELVE STAR REG            79200013
ERREG2   EQU   2                             WORK REG                   79600013
CRBREG   EQU   3                             CURRENT RB REG             80000013
CCWREG   EQU   4                             CCW ADDRESS REG            80400013
DECBRG   EQU   5                        DECB REGISTER                   80800013
DCBREG   EQU   6                        DCB REGISTER                    81200013
UCBREG   EQU   7                             UCB ADDRESS  REG           81600013
COMREG   EQU   8                             COMMUNICATION TABLE REG    82000013
ERREG1   EQU   9                                                        82400013
IOBRG    EQU   10                            IOB ADDRESS REG            82800013
ERREG4   EQU   11                            WORK REG                   83200013
ERRLNK   EQU   12                            LINK REG                   83600013
SAVREG   EQU   13                                                       84000013
ERRETR   EQU   14                            RETURN REG                 84400013
BASREG   EQU   15                            BASE REG                   84800013
         END                                                            85200013
