         TITLE 'IGE0204B - BTAM LINE ERROR RECORDING MODULE'            00500019
IGE0204B CSECT                                                          01000019
*00011260021200-021400,022600                                      000B 01500019
         SPACE 2                                                        02000019
*********************************************************************** 02500019
* STATUS -          CHANGE LEVEL 000   JANUARY 21, 1967                 03000019
*                                                                     * 03500019
* FUNCTION-        THIS MODULE UPDATES THE FOLLOWING COUNTS IN THE    * 04000019
*                  LINE ERROR RECORDING BLOCK POINTED TO BY THE DCB:  * 04500019
*                  1.  TRANSMISSION COUNT                             * 05000019
*                  2.  LINE ERROR COUNT                               * 05500019
*                  3.  TOTAL TRANSMISSIONS COUNT                      * 06000019
*                  4.  DATA CHECK TOTAL COUNT                         * 06500019
*                  5.  INTERVENTION REQUIRED TOTAL COUNT              * 07000019
*                  6.  TIME OUT TOTAL COUNT                           * 07500019
*                  WRITES A MESSAGE TO THE OPERATOR CONSOLE AND       * 08000019
*                  PROVIDES LINKAGE TO THE ERROR POST AND DIAGNOSTIC  * 08500019
*                  WRITE/READ ROUTINES.                               * 09000019
*                                                                     * 09500019
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 10000019
*                  TO THE ASSOCIATED IO RB.                           * 10500019
*                                                                     * 11000019
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 11500019
*                                                                     * 12000019
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0104B AND      * 12500019
*                  IGE0504A.                                          * 13000019
*                                                                     * 13500019
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 14000019
*********************************************************************** 14500019
         SPACE 2                                                        15000019
         USING *,15                                                     15500019
         L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  16000019
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  16500019
         N     UCBREG,UCBZIP            CLEAR LOW BIT              000C 17000019
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  17500019
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  18000019
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           18500019
         L     COMREG,LOC016            ADDRESS OF CVT                  19000019
         L     ERRETR,VECTXL(COMREG)    XCTL ROUTINE ADDRESS       000B 19500019
         LH    SAVREG,ERLOD5            ERROR POST ADDRESS         000B 20000019
         L     ERREG1,DCBLERB(DCBREG)   ADDRESS OF TABLE                20500019
         LTR   ERREG1,ERREG1            CHECK FOR LERB ADDRESS          21000019
         BZ    ERRDIAG                                                  21500019
         SR    ERREG2,ERREG2            CLEAR REGISTER                  22000019
         IC    ERREG2,IOBUCBX(IOBRG)    INDEX FACTOR TO TABLE ENTRY     22500019
         MH    ERREG2,ERRCN20           RESOLVE TABLE INDEX             23000019
         AR    ERREG2,ERREG1            RESOLVE FINAL ADDRESS           23500019
         SR    ERRLNK,ERRLNK            CLEAR IC REGISTER               24000019
         IC    ERRLNK,LERBTRCT(ERREG2)  TOTAL TRANS COUNT               24500019
         AH    ERRLNK,ERRCN01           UPDATE COUNT                    25000019
         STC   ERRLNK,LERBTRCT(ERREG2)  STORE NEW COUNT                 25500019
         SR    ERREG1,ERREG1            REPLACES 3 INSTRUCTIONS         26000019
         IC    ERREG1,IOBECT-1(IOBRG)   PICK UP TABLE OFFSET            26500019
         AH    ERREG1,ERRCN10           ADD STANDARD OFFSET             27000019
         AR    ERREG1,ERREG2            RESOLVE FINAL ADDRESS           27500019
         IC    ERRLNK,0(ERREG1)         PICK UP ERROR LINE COUNT        28000019
         AH    ERRLNK,ERRCN01           UPDATE COUNT                    28500019
         STC   ERRLNK,0(ERREG1)         STORE NEW COUNT                 29000019
         EX    ERRLNK,ERRCTCMP          COUNT EQUAL MAX ALLOWED         29500019
         BE    ERRLRB01                 BYPASS NO WTO                   30000019
         CLC   LERBTRCT(1,ERREG2),LERBTRT(ERREG2) TRANS COUNT REACHED   30500019
         BNE   ERRDIAG                  NO CHECK IF DIAG WR/RD REQUIRED 31000019
         OI    IOBECT-1(IOBRG),NOPRINT  INDICATE NO WTO                 31500019
ERRLRB01 EQU   *                                                        32000019
         L     ERREG1,0(ERREG2)         YES UPDATE ACCUMULATIVE COUNTER 32500019
         IC    ERRLNK,10(ERREG2)        TOTAL TRANSMISSIONS COUNT       33000019
         AR    ERREG1,ERRLNK            UPDATED ACCUM TRANS COUNT       33500019
         ST    ERREG1,0(ERREG2)         STORE NEW COUNT                 34000019
         CVD   ERRLNK,ERRDBLWD          GENERATE MESSAGE FORMAT         34500019
         UNPK  ERRMSG02+7(3),ERRDBLWD+6(2) CREATE PRINTABLE CHARS       35000019
         OI    ERRMSG02+9,MASK16        REMOVE SIGN                     35500019
         LH    ERREG1,4(ERREG2)         DATA CHECK TOTAL ERROR COUNT    36000019
         IC    ERRLNK,11(ERREG2)        DATA CHECK NEW COUNT            36500019
         AR    ERREG1,ERRLNK            NEW TOTAL COUNT                 37000019
         STH   ERREG1,4(ERREG2)         STORE UPDATED TOTAL COUNT       37500019
         CVD   ERRLNK,ERRDBLWD          DECIMAL COUNT FOR WTO MESSAGE   38000019
         UNPK  ERRMSG03+4(3),ERRDBLWD+6(2) PRINTABLE FORMAT INTO MSG    38500019
         OI    ERRMSG03+6,MASK16        MESSAGE FORMAT COMPLETE         39000019
         LH    ERREG1,6(ERREG2)         INTERVENTION REQUIRED TOTAL CT  39500019
         IC    ERRLNK,12(ERREG2)        NEW COUNT                       40000019
         AR    ERREG1,ERRLNK            NEW TOTAL COUNT                 40500019
         STH   ERREG1,6(ERREG2)         STORE NEW TOTAL                 41000019
         CVD   ERRLNK,ERRDBLWD          NEW COUNT TO DECIMAL            41500019
         UNPK  ERRMSG04+4(3),ERRDBLWD+6(2) FORMAT FOR OUTPUT MESSAGE    42000019
         OI    ERRMSG04+6,MASK16        REMOVE SIGN                     42500019
         LH    ERREG1,8(ERREG2)         TIME OUT TOTAL COUNT            43000019
         IC    ERRLNK,13(ERREG2)        TIME OUT NEW COUNT              43500019
         AR    ERREG1,ERRLNK            NEW TOTAL COUNT                 44000019
         STH   ERREG1,8(ERREG2)         STORE NEW TOTAL                 44500019
         TM    IOBECT-1(IOBRG),NOPRINT  WTO REQUIRED                    45000019
         BO    ERRLRB02                 NO CONTINUE PROCESSING          45500019
         CVD   ERRLNK,ERRDBLWD          DECIMAL COUNT FOR WTO           46000019
         UNPK  ERRMSG05+4(3),ERRDBLWD+6(2) FORMAT PRINTABLE CHARS       46500019
         OI    ERRMSG05+6,MASK16        REMOVE SIGN                     47000019
         MVC   ERRMSG01(3),UCBNAME(UCBREG) LINE ADDR TO MESSAGE    000H 47500019
         LR    ERREG1,BASREG            SAVE BASE                       48000019
         LR    ERREG4,TSTREG            SAVE RB POINTER                 48500019
         LA    TSTREG,MSGAREA           POINTER TO MESSAGE              49000019
         WTO   MF=(E,(1))               WRITE MESSAGE                   49500019
         LR    BASREG,ERREG1            RESTORE BASE                    50000019
         LR    TSTREG,ERREG4            RESTORE RB POINTER              50500019
ERRLRB02 EQU   *                                                        51000019
         XC    10(4,ERREG2),10(ERREG2)  CLEAR NEW COUNT FIELDS          51500019
ERRDIAG  MVI   IOBECT-1(IOBRG),NONAME   CLEAR LERB INDICATORS           52000019
         TM    IOBECT+1(IOBRG),RTRNCDE  DIAG WRITE READ REQ             52500019
         BO    ERE5C1                   YES GO TO DIAG ROUTINE          53000019
         TM    IOBFL1(IOBRG),IOBEXE     DETERMINE EXIT                  53500019
         BM    ERRLRB03                                                 54000019
         OI    IOBFL1(IOBRG),IOBEX      SET ON IOB EXCEPTION FLAG       54200019
         SVC   EXCPER                                                   54500019
         SVC   RETURN                                                   55000019
ERRLRB03  TM    UCBTYPE+3(UCBREG),UCBBSC THIS A BI-SYNC DEVICE          55500019
         BCR   14,ERRETR                NO, GO TO ERROR POST ROUTINE    55700019
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            56000019
         BR    ERRETR                  EXIT                             56500019
ERE5C1   LA    SAVREG,ERLOD11           ADDRESS OF DIAG WRT/RD ROUTINE  58500019
         BR    ERRETR                   EXIT                       000B 59000019
ERRCTCMP CLI   4(ERREG1),0                                              59500019
MSGAREA  WTO   'IEC801I     THRESHOLD TRANS=    DC=    IR=    TO=    ',X60000019
               MF=L,ROUTCDE=(8,10),DESC=(4)                        000H 60500019
ERRMSG01 EQU   MSGAREA+12                                          000H 61000019
ERRMSG02 EQU   MSGAREA+25                                          000H 61500019
ERRMSG03 EQU   MSGAREA+35                                          000H 62000019
ERRMSG04 EQU   MSGAREA+42                                          000H 62500019
ERRMSG05 EQU   MSGAREA+49                                          000H 63000019
ERRDBLWD DS    0D                                                       63500019
         DC    CL8'0'                                                   64000019
UCBZIP   DC    X'FFFFFFFE'                                         000C 64500019
ERRCN01  DC    AL2(1)                                                   65000019
ERRCN1   DC    AL2(8)                        DECIMAL 8                  65500019
DCBLERB  EQU   52                                                       66000019
ERLOD5   DC    AL2(5041)                                                66500019
ERLOD11  EQU   1042                                                     67000019
ERRCN10  DC    AL2(10)                                                  67500019
ERRCN20  DC    AL2(20)                                                  68000019
EXCPER   EQU   15                           EXCP ERROR ROUTINE          68500019
UCBBSC   EQU   X'90'                                               000B 69000019
UCBTYPE  EQU   16                                                  000B 69500019
IOBCSW   EQU   8                            CSW STORAGE                 70000019
IOBDCBAD EQU   20                                                       70500019
IOBECT   EQU   30                      ERROR COUNTS                     71000019
IOBERR   EQU   X'20'                        IOB ERROR FLAG              71500019
IOBEX    EQU   X'04'                        EXCEPT FLAG                 72000019
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                72500019
IOBFL1   EQU 0                              FLAGS 1                     73000019
ERLOD25  EQU   2043                                                     73500019
IOBUCBX  EQU   32                                                       74000019
LERBTRCT EQU   10                                                       74500019
LERBTRT  EQU   14                                                       75000019
LOC016   EQU   16                           COMMUNICATIONS TABLE        75500019
MASK16   EQU   X'F0'                                                    76000019
NONAME   EQU   0                                                        76500019
NOPRINT  EQU   X'10'                                                    77000019
RETURN   EQU   3                       RETURN SVC                       77500019
RTRNCDE  EQU   X'C0'                                                    78000019
TSTIOB   EQU   5                            IOB POINTER                 78500019
TSTUCB   EQU   2                            UCB POINTER                 79000019
UCBNAME  EQU   13                                                       79500019
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      80000019
*        REGISTER DEFINITION                                            80500019
ERREG3   EQU   0                             WORK REG                   81000019
TSTREG   EQU   1                             TWELVE STAR REG            81500019
ERREG2   EQU   2                             WORK REG                   82000019
CRBREG   EQU   3                             3U9955T 92 957             82500019
CCWREG   EQU   4                             CCW ADMRESS REG            83000019
DECBRG   EQU   5                        DECB REGISTER                   83500019
DCBREG   EQU   6                        DCB REGISTER                    84000019
UCBREG   EQU   7                             UCB ADDRESS  REG           84500019
COMREG   EQU   8                             COMMUNICATION TABLE REG    85000019
ERREG1   EQU   9                                                        85500019
IOBRG    EQU   10                            IOB ADDRESS REG            86000019
ERREG4   EQU   11                            WORK REG                   86500019
ERRLNK   EQU   12                            LINK REG                   87000019
SAVREG   EQU   13                                                       87500019
ERRETR   EQU   14                            RETURN REG                 88000019
BASREG   EQU   15                            BASE REG                   88500019
         END                                                            89000019
