IGE0210E CSECT                                                          00050021
* /* START OF SPECIFICATIONS ****                                       00100021
*                                                                       00150021
*01*  MODULE-NAME = IGE0210E                                            00200021
*                                                                       00250021
*01*  COPYRIGHT = NOT APPLICABLE                                        00300021
*                                                                       00310021
*01*  STATUS = LEVEL 01 A68718                                          00350021
*                                                                       00360021
*01*  CHANGE-ACTIVITY = A68718                                          00400021
*                                                                       00410021
*01*  DESCRIPTIVE-NAME = ERP FOR OPEN ,INT REQ SPECIAL, AND CHANNEL     00450021
*     ERRORS.                                                           00452021
*                                                                       00460021
*01*  FUNCTION = HANDLE ERROR RECOVERY FOR OPEN'S ERASE WRITE (OR       00500021
*     LOPEN) ,DO SPECIAL PROCESSING FOR INTERVENTION REQUIRED, AND      00510021
*     HANDLE CHANNEL CONTROL CHECK AND INTERFACE CONTROL CHECK ERRORS.  00512021
*                                                                       00520021
*01*  NOTES = SOME OF THE CHANNEL COMMANDS FOR THE 3270 DEVICES RESULT  00550021
*     IN SEPARATE I/O INTERUPTS FOR CE AND DE. WHEN THIS OCCURS, THE    00560021
*     GRAPHICS TRAP CODE ROUTINE IN IOS WILL CAUSE THE CE TO BE         00570021
*     IGNORED. THAT IS,                                                 00570421
*     THE CE APPENDAGE IS NOT ENTERED AND THE UCBPST BIT, IN THE UCB    00572021
*     FOR THE DEVICE, IS NOT TURNED OFF.                                00574021
*     WHEN THE SUBSEQUENT DE IS RECEIVED, THE RQE OF THE I/O            00580021
*     OPERATION IS STILL VALID. THE UCBPST BIT IS RESET AND THE CE      00590021
*     APPENDAGE ENTERED AT THIS TIME. THIS PROVIDES DE POSTING OF THOSE 00592021
*     OPERATIONS THAT RESULT IN SEPERATE PRESENTATION OF CE/DE AND      00594021
*     ALLOWS ERROR RECOVERY TO BE ATTEMPTED, BY ANALYSIS OF THE CHANNEL 00596021
*     PROGRAM, IF DE/UC IS RECEIVED.                                    00598021
*                                                                       00598421
*02*    DEPENDENCIES = NONE                                             00600021
*                                                                       00610021
*02*    PERFORMANCE = NOT APPLICABLE                                    00650021
*                                                                       00660021
*02*    RESTRICTIONS = NONE                                             00700021
*                                                                       00710021
*02*    REGISTER-CONVENTIONS = REGISTER 1 = RQE ADDRESS, REGISTER 2 =   00750021
*       IOB ADDRESS, REGISTER 3 = DCB ADDRESS, REGISTER 4 = UCB         00760021
*       ADDRESS, REGISTER 5 = CVT ADDRESS, REGISTER 6 = CCW ADDRESS,    00770021
*       REGISTER 7 = STAT TABLE ADDRESS, REGISTER 8 = WORK AND TO HOLD  00780021
*       THE COMMAND CODE, REGISTER 9 IS USED FOR INSERT CHARACTER       00790021
*       OPERATIONS, REGISTER 10 IS USED AS A LINK REG, REGISTER 11 IS   00792021
*       USED AS AN INDEX REG, REGISTER 12 = WORK AND IS USED AS A LINK  00794021
*       REGISTER, REGISTER 13 = XCTL NAME, REGISTER 14 = BRANCH ENTRY   00796021
*       ADDRESS TO XCTL, REGISTER 15 = ERP BASE REG, REGISTER 0 = WORK. 00798021
*                                                                       00798421
*02*    PATCH-LABEL = ERPPATCH                                          00800021
*                                                                       00810021
*01*  MODULE-TYPE = MODULE                                              00850021
*                                                                       00852021
*02*    PROCESSOR = ASSEMBLER                                           00860021
*                                                                       00870021
*02*    MODULE-SIZE = 1028 BYTES                                        00880021
*                                                                       00882021
*02*    ATTRIBUTES = REENTERABLE                                        00890021
*                                                                       00892021
*01*  ENTRY = IGE0210E                                                  00894021
*                                                                       00894421
*02*    PURPOSE = RECOVER FROM I/O ERRORS DURING LOCAL 3270 OPEN IF     00896021
*       POSSIBLE ,PERFORM ERROR RECOVERY UNIQUE TO INTERVENTION         00896421
*       REQUIRED SITUATIONS, AND HANDLE CHANNEL ERRORS (ICC AND CCC).   00896821
*                                                                       00897221
*02*    LINKAGE = XCTL                                                  00898021
*                                                                       00898421
*02*    INPUT = THE ADDRESS OF THE RQE IN REGISTER ONE.                 00898821
*                                                                       00898921
*02*    OUTPUT = 1. SUCCESSFUL RETRY - IOBFLAG1 BIT 2=0, BIT5=0 WITH    00899221
*       STATISTICS TABLE UPDATE IF REQUIRED.                            00899321
*                                                                       00899421
*                       - IOBERRCT+1 BITS 5, 6, AND 7 = 000.            00899521
*                         THE ERROR HAS BEEN PROCESSED BY THE           00899621
*                         ERP AND RECOVERY HAS BEEN SUCCESSFUL.         00899721
*                                                                       00901721
*                2. PERMANENT ERROR - IOBFLAG1 BIT 2=0, BIT 5=1 WITH    00902421
*       OBR LOGOUT IF REQUIRED.                                         00904421
*                                                                       00904521
*                       - IOBERRCT+1 BITS 5, 6, AND 7 = 010.            00904821
*                         THE ERROR WAS NOT CORRECTABLE BY THE          00905221
*                         ERP AND RECONSTRUCTION OF THE DEVICE          00905321
*                         BUFFER IS REQUIRED BY THE REQUESTOR.          00908321
*                                                                       00910321
*                       - IOBERRCT+1 BITS 5, 6, AND 7 = 011.            00910721
*                         THE ERROR WAS PROCESSED BY THE ERP            00911121
*                         AND IT WAS DETERMINED THAT THE ERROR          00911521
*                         IS PERMANENT.                                 00912221
*                                                                       00912621
*                       - IOBERRCT+1 BITS 5, 6, AND 7 = 110.            00913021
*                         THE ERROR WAS PROCESSED BY THE ERP            00913421
*                         AND IT WAS DETERMINED THAT THE ERROR          00913521
*                         IS USER CORRECTABLE BY THE CHANNEL            00913621
*                         PROGRAM OR DATA STREAM BUILDER.               00913721
*                                                                       00914421
*                3. CHANNEL ERROR - IOBWORK CONTAINS THE FOLLOWING      00914521
*        INFORMATION FROM THE ERROR RECOVERY PROCEDURE INTERFACE        00914621
*        BLOCK BUILT BY THE CHANNEL CHECK HANDLER.                      00914721
*                                                                       00916421
*                       - IOBWORK + 0 - PROGRAM FLAGS                   00918421
*                       - IOBWORK + 1 - SOURCE OF ERROR FLAGS           00918521
*                       - IOBWORK + 2 - VALIDITY INDICATORS             00918621
*                       - IOBWORK + 3 - TERMINATION CODE                00918721
*                       - IOBWORK + 4 - SEQUENCE CODE                   00918821
*                                                                       00919221
*02*    EXIT-NORMAL = RETURN                                            00920221
*                 IOS VIA SVC 15                                        00921921
*                 SUPERVISOR VIA SVC 3                                  00923621
*                 STATISTICS UPDATE ROUTINE (IGE0025D) VIA              00925321
*                    BRANCH ENTRY TO XCTL.                              00927021
*                 IOS-WTO ROUTINE (IGE0025C) VIA BRANCH ENTRY TO XCTL.  00928721
*                                                                       00930421
*                                                                       00932121
*                                                                       00933821
*02*    EXIT-ERROR = NONE                                               00935521
*                                                                       00937221
*01*  EXTERNAL-REFERENCES = NONE                                        00938921
*                                                                       00940621
*01*  TABLES = IOB                                                      00942321
*                                                                       00944021
*01*  MACROS = DSECTS                                                   00945721
*                                                                       00947421
**** END OF SPECIFICATIONS ***/                                         00950021
*/*IGE0210E: CHART*/                                                    00950821
*/* E IGE0210E*/                                                        00952521
*/* P INITIALIZE REGISTERS*/                                            00954221
*/* D (NO,,YES,CHKCHAN) CHANNEL ERROR*/                          A68718 00954621
*/* D (NO,,YES,PERMEXIT) OPEN TP-OP CODE IN CCW ? */                    00955921
*/*CHKIR: D (NO,,YES,PERMEXIT) SIO CC=3*/                               00957621
*/* D (NO,,YES,UNREC1) DEVICE AN OP CONSOLE*/                           00959321
*/* D (NO,,YES,SNOEXIT) DIAG RD OR WRT IN CHAN PGM*/                    00961021
*/* S FINDSTAT:LOCATE STAT TABLE ENTRY*/                                00962721
*/* P UPDATE SENSE DATA IN STAT TABLE*/                                 00964421
*/* M TURN ON OPENFAIL FLAG IN UCB GCB */                               00966121
*/* M (,PERMNOBR) INDICATE PERMANENT ERROR BUT DO NO OBR*/              00967821
*/*CHKCHAN: P LOCATE TABLE OF ERPIBS*/                                  00969221
*/*TABLOOP: D (NO,,YES,UNREC1) END OF TABLE*/                           00969321
*/* D (YES,,NO,CHKUCB) ERPIB UNUSED (ZERO)*/                            00969421
*/*INCRPTR: P (,TABLOOP) INCREMENT ERPIB POINTER*/                      00970021
*/*CHKUCB: D (YES,,NO,INCRPTR) CORRECT UCB ADDRESS*/                    00970421
*/* P SAVE ERPIB INFO IS IOBWORK*/                                      00970821
*/* P CLEAR ERPIB*/                                                     00970921
*/* D (YES,,NO,UNREC1) CAN RETRY BE DONE*/                              00971021
*/* D (YES,,NO,UNREC1) INTER @, SEQ CODE & CHAN @ VALID*/               00971121
*/* D (NO,,YES,UNREC1) HALT I/O OR TEST I/O*/                           00971721
*/* D (YES,,NO,TSTRESET) START I/O*/                                    00972121
*/* D (YES,,NO,UNREC1) DEVICE ADDRESS VALID*/                           00972521
*/*TSTRESET: D (NO,,YES,SNOEXIT) SYSTEM RESET*/                         00972921
*/* D (NO,,YES,SNOEXIT) SEQUENCE CODE 0*/                               00973021
*/* D (NO,,YES,SNOEXIT) SEQUENCE CODE 6*/                               00973121
*/* D (NO,,YES,SNOEXIT) SEQUENCE CODE 7*/                               00973221
*/* D (NO,,YES,UNREC1) SIO COND CODE 3*/                                00973721
*/* D (YES,,NO,CKCMDVAL) SIO COND CODE 1*/*                             00974121
*/* P (,SEQ5CHK) GET ADDR OF FAILING CCW FROM IOBSTART*/                00974521
*/*CKCMDVAL: D (YES,,NO,UNREC1) COMMAND ADDRESS VALID*/                 00974921
*/* S GETCMD: GET ADDRESS OF FAILING COMMAND*/                          00975021
*/*SEQ5CHK: D (NO,,YES,SEQ5PROC) SEQUENCE CODE 5*/                      00975121
*/* D (NO,,YES,SEQ4PROC) SEQUENCE CODE 4*/                              00975321
*/* D (NO,,YES,SEQ3PROC) SEQUENCE CODE 3*/                              00975721
*/* D (NO,,YES,SNOEXIT) COMMAND A TIC*/                                 00975821
*/* D (NO,,YES, SEQ2PROC) SEQUENCE CODE 2*/                             00975921
*/*SEQ1PROC: D (NO,,YES,CONDRTRY) TERMINATION CODE 2*/                  00976021
*/*SEQ1TRM1: D (YES,SNOEXIT,NO,RETRY) TERMINATION CODE 1*/              00976421
*/*SEQ2PROC: D (YES,RETRY,NO,SEQ1TRM1) TERMINATION CODE 2*/             00976821
*/*SEQ3PROC: D (NO,,YES,SNOEXIT) SELECT*/                               00977321
*/* D (NO,,YES,SNOEXIT) ERASE ALL UNPROTECTED*/                         00977421
*/* D (NO,RETRY,YES,SNOEXIT) NO-OP*/                                    00977521
*/*SEQ4PROC: D (NO,,YES,CONDRTRY) TERMINATION CODE 2*/                  00977621
*/*RETRY: D (YES,,NO,RTYERR) WRITE COMMAND*/                            00977721
*/* D (YES,,NO,UNREC1) 2ND BYTE OF WRITE DATA AN SBA*/                  00977821
*/*RTYERR: P (,RTYCNT) SET IOBSTART TO FAILING COMMAND*/                00978021
*/*CONDRTRY: D (NO,,YES,UNREC1) IS FAILING COMMAND 1ST CCW*/            00978421
*/* D (NO,RETRY,YES,UNREC1) IS FAILING COMMAND CHAINED*/                00978521
*/*SEQ5PROC: D (NO,RETRY,YES,SEQ3PROC) CSW STORED AFTER SIO*/ SM0401K   00978621
*/* E GETCMD*/                                                          00981221
*/* P GET CCW ADDR FROM CSW*/                                           00983221
*/* D (NO,,YES,CHKDE) IS ADDRESS ZERO*/                                 00985221
*/* P (,CHNLOOP) BACK UP TO FAILING CCW*/                               00985321
*/*CHKDE: D (NO,,YES,SNOEXIT) IS CHANNEL END ON*/                       00985421
*/* D (YES,,NO,SNOEXIT) IS DEVICE END ON*/                              00985521
*/*CHNLOOP: D (NO,,YES,FOUNDCMD) IS THIS THE FAILING CCW*/              00986021
*/* D (NO,,YES,TICRTN) IS THIS CCW A TIC*/                              00986421
*/* D (YES,,NO,TSTCMDCH) IS THIS CCW DATA CHAINED*/                     00986821
*/* P (,CHNLOOP) UP FAILING CCW ADDRESS*/                               00987221
*/*TSTCMDCH: D (YES,,NO,SEEIFDE) IS THIS CCW CMD CHAINED*/              00987321
*/* P (,CHNLOOP) UP RESTART CCW ADDRESS*/                               00987521
*/*SEEIFDE: D (YES,FOUNDCMD,NO,SNOEXIT) IS CSW ADDRESS ZERO*/           00987921
*/*TICRTN: D (NO,,YES,TICTOADR) IS PREVIOUS CCW DATA CHAINED*/          00988021
*/* P SET RESTART CCW ADDR TO ADDR TIC'ED TO*/                          00988121
*/*TICTOADR: P (,CHNLOOP) SET FAILING CCW ADDR TO ADDR TIC'ED TO*/      00988221
*/*FOUNDCMD: D (YES,,NO,CMDOUT) IS RESTART CCW A TIC*/                  00988321
*/* D (NO,,YES,CMDOUT) IS PREVIOUS CCW DATA CHAINED*/                   00989521
*/* P SET RESTART CCW ADDR TO ADDR TIC'ED TO*/                          00989921
*/*CMDOUT: R RETURN TO CALLER*/                                         00990321
*/*STATEXIT: M RESET RETRY COUNT AND RETRY FLAGS*/                      00990821
*/* D (YES,,NO,RETEXIT) LOGOUT OR STAT UPDATE REQD*/                    00992021
*/* R XCTL TO STAT UPDATE (IGE0025D)*/                                  00993221
*/*PERMEXIT: D (NO,,YES,UNREC1) DEVICE AN OP CONSOLE*/                  00994421
*/* M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                             00995621
*/*PERMNOBR: M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0 */         00996821
*/* M RESET RETRY COUNT AND RETRY FLAGS*/                               00998021
*/* M INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT7=1*/                      00999221
*/* M SET MSG FLG TO PERM ERR IOBFLAG3 BIT5=1*/                         01000421
*/*WTOEXIT: R XCTL TO IOS-WTO (IGE0025C)*/                              01001621
*/*UNREC1: M TURN ON LOGOUT FLAG IOBFLAG3 BIT7=1*/                      01002821
*/*SNOEXIT: M TURN OFF USER CORRECT ERP FLAG IOBCNT2 BIT5=0*/           01004021
*/*SETPER: M (,STATEXIT) INDICATE PERM ERROR IOBFLAG1 BIT2=0 BIT5=1*/   01005221
*/*RTYCNT: D (NO,,YES,PERMEXIT) RETRY COUNT = THREE*/                   01006421
*/* P UPDATE COUNT*/                                                    01007621
*/*RETEXIT: L SVC15 ERROR EXCP */                                       01008821
*/* R RETURN TO CALLER*/                                                01010021
*/*IGE0210E: END*/                                                      01011221
         EJECT                                                          01030021
         USING IECTIOB,IOBREG           BASE FOR IOB DSECT              01040021
         USING IHADCB,DCBREG            BASE FOR DCB DSECT              01050021
         USING *,BASREG                 BASE FOR ERP MODULE             01100021
         L     IOBREG,TSTIOB(TSTREG)    ADDRESSABILITY FOR IOB          01150021
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  01200021
         L     DCBREG,IOBDCBPT          ADDRESSABILITY FOR DCB          01250021
         L     CVTREG,CVTADR            ADDRESS OF CVT                  01300021
         L     RETREG,XCTLADR(CVTREG)   BRANCH ENTRY ADDR TO XCTL       01350021
         TM    IOBCNT2,CHANERR      CHANNEL ERROR                A68718 01352021
         BO    CHKCHAN              YES,HANDLE                   A68718 01354021
         L     CCWREG,IOBCSW        PICK UP CCW ADDRESS                 01360021
         LA    CCWREG,0(CCWREG)     CLEAR HIGH BYTE                     01370021
         SH    CCWREG,CONEIGHT      POINT TO FAILING CCW                01380021
         BNP   SNOEXIT              NOT A VALID ADDRESS                 01390021
         CLI   5(CCWREG),X'24'      OPEN TP-OP ?                        01392021
         BE    PERMEXIT             ALL OPEN ERRORS PERMANENT           01394021
*                                                                       01396021
*              PROCESS THE INTERVENTION REQUIRED                        01398021
*                                                                       01398421
CHKIR    EQU   *                                                        01400021
         TM    IOBSIOCC,IOBCC3          SIO CC=3                        01450021
         BO    PERMEXIT                 IF YES-EXIT WITH PER ERROR      01500021
***                                                                     01550021
         CLI   DEVTYP(UCBREG),DEV3158   IS DEVICE A 3158         S21122 01600021
         BE    TESTCONS                 YES, GO TO TEST FOR      S21122 01650021
*                                       ONLINE ACTIVE CONSOLE    S21122 01700021
***                                                                     01750021
         CLI   DEVTYP(UCBREG),DEV3277        IS DEVICE A 3277     M2523 01800021
         BNE   DIAGIR                        NO,BYPASS CONSOLE    M2523 01850021
*                                               TEST FOR          M2523 01900021
*                                                    PRINTERS     M2523 01950021
***                                                                     02000021
TESTCONS EQU   *                                                 S21122 02050021
         TM    SRTESTAT(UCBREG),OPCNSL  DEVICE AN ONLINE ACTIVE CONSOLE 02100021
         BO    UNREC1                   IF YES-EXIT WITHOUT RETRY       02150021
DIAGIR   BAL   LNKREGB,CHKDIAG               CHECK FOR DIAG CMD   M2523 02200021
         B     BRTAB1(IXREG)            DIAG CHECK RETURN BRANCH TABLE  02250021
BRTAB1   B     SNOEXIT                  DIAG CMD-SNO ERR EXIT NG        02300021
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   02350021
         OI    8(STABREG),STATIR        INDICATE IR IN STAT TBL  A59117 02400021
         OI    GRAF(UCBREG),OPENFAIL SET FAILED FLAG IN GCB             02450021
         B     PERMNOBR             SET PERMANENT BUT NO OBR            02500021
*                                                                A68718 02550021
*                   PROCESS CHANNEL (ICC AND CCC) ERRORS         A68718 02560021
*                                                                A68718 02570021
CHKCHAN  EQU   *                                                 A68718 02580021
         L     WKREG1,CVTDCB(CVTREG) GET @ OF SYS1.LOGREC DCB    A68718 02590021
         L     WKREG1,0(WKREG1)    GET @ OF LOGREC PARM TAB      A68718 02592021
         L     WKREG1,0(WKREG1)    GET @ OF ERPIB                A68718 02594021
TABLOOP  EQU   *                                                 A68718 02596021
         CLI   0(WKREG1),ALLONE    END OF TABLE                  A68718 02598021
         BE    UNREC1              YES, UNREC                    A68718 02598421
         CLC   0(FOUR,WKREG1),ZEROWORD  ERPIB UNUSED             A68718 02598821
         BNE   CHKUCB              NO, BRANCH                    A68718 02599621
INCRPTR  EQU   *                                                 A68718 02599721
         LA    WKREG1,DBLWORD(WKREG1) INCR ERPIB PTR             A68718 02609721
         B     TABLOOP             LOOP                          A68718 02616621
CHKUCB   EQU   *                                                 A68718 02626621
         CLC   TWO(TWO,WKREG1),TWO(TSTREG) CORRECT UCB ADDR      A68718 02628621
         BNE   INCRPTR             NO, TRY NEXT ERPIB            A68718 02630621
         MVC   IOBWORK(FOUR),FOUR(WKREG1) SAVE  INFO             A68718 02632621
         XC    0(DBLWORD,WKREG1),0(DBLWORD)  CLEAR ERPIB         A68718 02633021
         MVC   ERPIBSEQ(1),ERPIBTRM  MOVE SEQ CODE TO IOB        A68718 02633121
         NI    ERPIBTRM,TERMBITS  AND OFF UNUSED BITS            A68718 02633221
         NI    ERPIBSEQ,SEQBITS  AND OFF UNUSED BITS             A68718 02638821
         TM    ERPIBFLG,RTYB       CAN RETRY BE DONE             A68718 02640821
         BO    UNREC1              NO, UNREC                     A68718 02642821
         TM    ERPIBVAL,INTV+SEQV+CAV INTERFACE @,SEQ CODE       A68718 02643221
*                                  AND CHAN @ VALID              A68718 02643621
         BNO   UNREC1              NO, UNREC                     A68718 02644021
         TM    ERPIBFLG,HIOB+TIOB  HALT IO OR TEST IO            A68718 02644121
         BM    UNREC1              YES, UNREC                    A68718 02644221
         TM    ERPIBFLG,SIOB       START I/O                     A68718 02644321
         BO    TSTRESET            NO, BRANCH                    A68718 02658221
         TM    ERPIBVAL,DAV        DEVICE @ VALID                A68718 02668221
         BNO   UNREC1              NO, BRANCH                    A68718 02670221
TSTRESET EQU   *                                                 A68718 02670621
         CLI   ERPIBTRM,TERM3      SYSTEM RESET                  A68718 02671021
         BE    SNOEXIT             YES, SNO                      A68718 02671421
         CLI   ERPIBSEQ,SEQ0       SEQ CODE 0                    A68718 02671821
         BE    SNOEXIT             YES, SNO                      A68718 02671921
         CLI   ERPIBSEQ,SEQ6       SEQ CODE 6                    A68718 02672021
         BE    SNOEXIT             YES, SNO                      A68718 02672121
         CLI   ERPIBSEQ,SEQ7       SEQ CODE 7                    A68718 02676721
         BE    SNOEXIT             YES, SNO                      A68718 02678721
         TM    IOBSIOCC,IOBCC3     SIO COND CODE 3               A68718 02680721
         BO    UNREC1              YES, UNREC                    A68718 02681121
         TM    IOBSIOCC,IOBCC1     SIO COND CODE 1               A68718 02681221
         BNO   CKCMDVAL            NO,BRANCH                     A68718 02681321
         L     CCWREG,IOBSTART     GET @ FAILLING CCW            A68718 02681421
         LA    CCWREG,0(CCWREG)    CLEAR HIGH BYTE               A68718 02686021
         B     SEQ5CHK             BRANCH                        A68718 02688021
CKCMDVAL EQU   *                                                 A68718 02690021
         TM    ERPIBVAL,CMDAV      CMD ADDR VALID                A68718 02690421
         BNO   UNREC1              NO, UNREC                     A68718 02690521
         BAL   LNKREG,GETCMD       GET ADDR OF FAILING CMD       A68718 02690621
SEQ5CHK  EQU   *                                                 A68718 02690721
         CLI   ERPIBSEQ,SEQ5       SEQ CODE 5                    A68718 02702521
         BE    SEQ5PROC            YES, HANDLE                   A68718 02712521
         CLI   ERPIBSEQ,SEQ4       SEQ CODE 4                    A68718 02714521
         BE    SEQ4PROC            YES,HANDLE                    A68718 02718421
         CLI   ERPIBSEQ,SEQ3       SEQ CODE 3                    A68718 02720421
         BE    SEQ3PROC            YES, HANDLE                   A68718 02722421
         CLI   0(CCWREG),CCWTIC    CMD A TIC                     A68718 02726321
         BE    SNOEXIT             YES, SNO                      A68718 02728321
         CLI   ERPIBSEQ,SEQ2       SEQ CODE 2                    A68718 02730321
         BE    SEQ2PROC            YES, HANDLE                   A68718 02734221
SEQ1PROC EQU   *                                                 A68718 02736221
         CLI   ERPIBTRM,TERM2      SELECTIVE RESET               A68718 02738221
         BE    CONDRTRY            YES, MAY BE RETRIED           A68718 02748521
SEQ1TRM1 EQU   *                                                 A68718 02752021
         CLI   ERPIBTRM,TERM1      NORMAL TERMINATION            A68718 02758721
         BE    SNOEXIT             YES, SNO                      A68718 02760821
         B     RETRY               NO, RETRY                     A68718 02762821
SEQ2PROC EQU   *                                                 A68718 02764821
         CLI   ERPIBTRM,TERM2      SELECTIVE RESET               A68718 02765221
         BE    RETRY               YES,RETRY                     A68718 02765621
         B     SEQ1TRM1            NO, BRANCH                    A68718 02769021
SEQ3PROC EQU   *                                                 A68718 02771021
         CLI   0(CCWREG),CCWSEL    SELECT CMD                    A68718 02771421
         BE    SNOEXIT             YES, SNO                      A68718 02771821
         CLI   0(CCWREG),CCWEUP    ERASE ALL UNPROTECTED         A68718 02772221
         BE    SNOEXIT             YES, SNO                      A68718 02772321
         CLI   0(CCWREG),CCWNOP    NO-OP                         A68718 02772421
         BE    SNOEXIT             YES, SNO                      A68718 02772521
         B     RETRY               NO, RETRY                     A68718 02775921
SEQ4PROC EQU   *                                                 A68718 02777921
         CLI   ERPIBTRM,TERM2      SELECTIVE RESET               A68718 02778321
         BE    CONDRTRY            YES, MAY BE RETRIED           A68718 02778721
RETRY    EQU   *                                                 A68718 02779121
         CLI   0(CCWREG),CCWWRT    WRITE COMMAND                 A68718 02779221
         BNE   RTYERR              NO, BRANCH                    A68718 02779321
         L     ICREG,0(CCWREG)     GET WRT OUT DATA              A68718 02779421
         CLI   SBABYTE(ICREG),SBA  2ND BYTE AN SBA               A68718 02782821
         BNE   UNREC1              NO, UNREC                     A68718 02784821
RTYERR   EQU   *                                                 A68718 02785221
         ST    CCWREG,IOBSTART     POINT TO FAILING CMD          A68718 02785621
         B     RTYCNT              GO RETRY                      A68718 02786021
CONDRTRY EQU   *                                                 A68718 02786121
         L     ICREG,IOBSTART      GET ADDR OF 1ST CCW           A68718 02786221
         LA    ICREG,0(ICREG)      CLEAR HIGH BYTE               A68718 02786321
         CR    ICREG,CCWREG        IS FAILING CMD 1ST IN STRING  A68718 02787421
         BE    UNREC1              YES, UNREC                    A68718 02789421
         B     RETRY               NO, RETRY                     A68718 02798221
SEQ5PROC EQU   *                                                 A68718 02802021
         TM    ERPIBFLG,SIOB       CSW STORED AFTER SIO          A68718 02804021
         BO    SEQ3PROC            YES, HANDLE AS SEQ 3          A68718 02806021
         B     RETRY               NO,RETRY                    SM0401K  02806421
**************************************************************** A68718 02834621
*          GETCMD SUBROUTINE                                   * A68718 02836021
*       THIS SUBROUTINE STORES THE ADDRESS OF THE FAILING      * A68718 02837421
*       COMMAND IN CCWREG, IF THE FAILING CCW HAS DATA CHAINING* A68718 02838821
*       ON, THIS ROUTINE BACKS UP THE ADDR TO THE 1ST CCW IN   * A68718 02840221
*       STRING WITH DATA CHAINING. IF THE FAILING CCW IS A TIC * A68718 02841621
*       THE ADDRESS OF THE CCW TIC'ED TO IS USED.              * A68718 02843021
*       NOTE: IF THE CSW ADDRESS IS ZERO AND DEVICE END        * A68718 02844421
*       OCCURRED WITHOUT CHANNEL END, THE FAILING CCW IS THE   * A68718 02845821
*       LAST CCW IN THE CHAIN.                                 * A68718 02847221
**************************************************************** A68718 02848621
GETCMD   EQU   *                                                 A68718 02850021
         L     ICREG,IOBCSW        GET CCW @ FROM CSW            A68718 02851221
         LA    ICREG,0(ICREG)      CLEAR HIGH BYTE               A68718 02861221
         LTR   ICREG,ICREG         IS ADDR ZERO                  A68718 02863221
         BZ    CHKDE               YES,SEE IF DE WITHOUT CE      A68718 02863621
         SH    ICREG,CONEIGHT      NO, BACK UP TO FAILING CCW    A68718 02863721
         BNP   SNOEXIT             IF BAD, GET OUT               A68718 02863821
         B     GETSTART            GO GET CPA ADDRESS            A68718 02863921
CHKDE    EQU   *                                                 A68718 02865621
         TM    IOBCSW+4,CSWCHE     IS CHAN END ON                A68718 02868821
         BO    SNOEXIT             YES, ADDR SHOULD NOT BE ZERO  A68718 02869221
         TM    IOBCSW+4,CSWDVE     IS DVC END ON                 A68718 02869621
         BNO   SNOEXIT             NO, SHOULDN'T OCCUR           A68718 02870021
GETSTART EQU   *                                                 A68718 02870121
         L     CCWREG,IOBSTART     GET START OF CHAN PGM         A68718 02870421
         LA    CCWREG,0(CCWREG)    CLEAR HIGH BYTE               A68718 02871821
         LR    WKREG1,CCWREG                                     A68718 02873521
CHNLOOP  EQU   *                                                 A68718 02875221
         CR    WKREG1,ICREG        IS THIS THE FAILING CCW       A68718 02876921
         BE    FOUNDCMD            YES, BRANCH                   A68718 02878621
         CLI   0(WKREG1),CCWTIC    IS THIS CCW A TIC             A68718 02880321
         BE    TICRTN              YES, HANDLE                   A68718 02882021
         TM    CCWFLGS(WKREG1),DATCHAIN  IS THIS CCW DATA CHN'ED A68718 02883721
         BNO   TSTCMDCH            NO, CONTINUE CHECKING         A68718 02885421
         AH    WKREG1,CONEIGHT     UP FAILING CCW ADDR           A68718 02887121
         B     CHNLOOP             CHECK NEXT CCW                A68718 02888821
TSTCMDCH EQU   *                                                 A68718 02890521
         TM    CCWFLGS(WKREG1),CMDCHAIN  IS THIS CCW CMD CHN'D   A68718 02892221
         BNO   SEEIFDE             NO, END OF CHAN PGM           A68718 02893921
         AH    WKREG1,CONEIGHT     UPDATE FAILING CCW ADDR AND   A68718 02895621
         LR    CCWREG,WKREG1         RESTART ADDR                A68718 02897321
         B     CHNLOOP             CHECK NEXT CCW                A68718 02899021
SEEIFDE  EQU   *                                                 A68718 02900421
         LTR   ICREG,ICREG         IS CSW ADDRESS ZERO           A68718 02900521
         BNZ   SNOEXIT             NO,SHOULD HAVE FOUND FAIL CCW A68718 02900621
         B     FOUNDCMD            YES, FAILING CCW FOUND        A68718 02905721
TICRTN   EQU   *                                                 A68718 02907021
         SH    WKREG1,CONEIGHT     BACK UP TO PREVIOUS CCW       A68718 02910121
         TM    CCWFLGS(WKREG1),DATCHAIN IS IT DATA CHAINED       A68718 02913221
         BO    TICTOADR            YES,BRANCH                    A68718 02916321
         L     CCWREG,0(CCWREG)    SET RESTART @ TO @ TIC'ED TO  A68718 02919421
         LA    CCWREG,0(CCWREG)    CLEAR HIGH BYTE               A68718 02922521
TICTOADR EQU   *                                                 A68718 02925621
         AH    WKREG1,CONEIGHT     GET FAILING TIC ADDR          A68718 02928721
         L     WKREG1,0(WKREG1)    SET FAILING CCW @ TO CCW      A68718 02931821
*                                    TIC'ED TO                   A68718 02934921
         LA    WKREG1,0(WKREG1)    CLEAR HIGH BYTE               A68718 02938021
         B     CHNLOOP             CONTINUE LOOP                 A68718 02941121
FOUNDCMD EQU   *                                                 A68718 02944221
         CLI   0(WKREG1),CCWTIC    IS RESTART CCW A TIC          A68718 02947321
         BNE   CMDOUT              NO, RETURN                    A68718 02950421
         SH    WKREG1,CONEIGHT     BACK UP TO PREV CCW           A68718 02953521
         TM    CCWFLGS(WKREG1),DATCHAIN  DATA CHAINED            A68718 02956621
         BO    CMDOUT              YES, RETURN                   A68718 02959721
         L     CCWREG,8(WKREG1)    SET RESTART @ TO @ TIC'ED TO  A68718 02962821
         LA    CCWREG,0(CCWREG)    CLEAR HIGH BYTE               A68718 02965921
CMDOUT   EQU   *                                                 A68718 02969021
         BR    LNKREG              RETURN TO CALLER              A68718 02972121
*********************************************************************** 02975221
*              CHKDIAG SUBROUTINE                                     * 02978321
*        THIS  SUBROUTINE PLACES A DIAGNOSTIC WRITE / DIAGNOSTIC READ * 02981421
*        COMMAND CODE IN CMDREG AND LINKS TO THE CHKCMD SUBRTN. THE   * 02984521
*        CHKCMD SUBRTN CHECKS IF EITHER COMMAND IS CONTAINED IN THE   * 02987621
*        CHANNEL PROGRAM.THE RETURN CODE RETURNED BY THE CHKCMD SUBRTN* 02990721
*        IS PASSED BACK TO THE CALLER.                                * 02993821
*********************************************************************** 02996921
CHKDIAG  EQU   *                                                        03000021
         LA    CMDREG,CCWDWR            DIAG WRITE CMD                  03050021
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               03100021
         B     BRTABD(IXREG)            RETURN BRANCH TABLE             03150021
BRTABD   BR    LNKREGB                  DWR FOUND-RETURN      NG        03200021
         BCR   ZERO,ZERO                PAD FOR RET CODE IX   NG        03250021
         LA    CMDREG,CCWDRD            DIAG READ CMD                   03300021
         BAL   LNKREG,CHKCMD            LINK TO CHECK CMD               03350021
         BR    LNKREGB                  RETURN WITH RET CODE  NG        03400021
*********************************************************************** 03450021
*              EXITS                                                  * 03500021
*********************************************************************** 03550021
UNREC2   EQU   *                                                        03600021
         NI    IOBCNT2,ALLONE-PERMERR   INDICATE USER CORRECT NG        03650021
         B     SETPER                                                   03700021
*                                                                       03750021
UNREC1   EQU   *                                                        03800021
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             03850021
SNOEXIT  EQU   *                                                        03900021
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLAGS  NG        03950021
SETPER   EQU   *                                                        04000021
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       04050021
CHKSTAT  EQU   *                                                        04100021
         NI    IOBCNT1,ALLZERO          CLEAR RETRY COUNT     NG        04150021
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RETRY FLAGS     NG        04200021
         TM    IOBFLAG3,IOBLOG          OBR LOGOUT REQUIRED             04250021
         BO    STATEXIT                 IF YES-EXIT TO STAT UPDATE      04300021
         BAL   LNKREG,FINDSTAT          LINK TO FIND STAT TABLE ENTRY   04350021
         NI    8(STABREG),STMSK1        CHECK FOR SINGLE BIT ENTRIES    04400021
         BZ    CHKMULTI                 IF NONE-CHECK MULTI BIT         04450021
         B     STATEXIT                 IF PRESENT-EXIT TO STAT UPDATE  04500021
CHKMULTI EQU   *                                                        04550021
         NI    9(STABREG),STMSK2        CHECK FOR MULTI BIT ENTRIES     04600021
         BZ    RETEXIT                  IF NONE-STAT UPDATE NOT REQD    04650021
STATEXIT EQU   *                                                        04700021
         LA    LDNAMREG,STATUP          ADDRESS OF STAT UPDATE ROUTINE  04750021
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      04800021
*                                                                       04850021
RTYCNT   EQU   *                                              NG        04900021
         CLI   IOBCNT1,THREE            RETRY COUNT AT MAX    NG        04950021
         BNL   PERMEXIT                 MAX CNT-PER ERR EXIT  NG        05000021
         SR    ICREG,ICREG              CLEAR REG             NG        05050021
         IC    ICREG,IOBCNT1            PICK UP COUNT         NG        05100021
         LA    ICREG,ONE(ICREG)         BUMP BY ONE           NG        05150021
         STC   ICREG,IOBCNT1            SAVE COUNT            NG        05200021
RETEXIT  EQU   *                                                        05250021
         SVC   EREXCP                   ERROR EXCP                      05300021
         SVC   RETURN                   RETURN TO SVPR                  05350021
*                                                                       05400021
PERMEXIT EQU   *                                                        05450021
         OI    IOBFLAG3,IOBLOG          INDICATE OBR LOGOUT             05460021
PERMNOBR EQU   *                    SET PERMANENT BUT NO OBR            05470021
         TM    SRTESTAT(UCBREG),OPCNSL  DEVICE AN ONLINE ACTIVE CONSOLE 05500021
         BO    UNREC1                   IF YES-LOG WITHOUT ERROR MSG    05550021
         NI    IOBCNT2,ALLONE-USRCRCT   SET PER IN ERP FLAGS  NG        05600021
         NI    IOBCNT1,ALLZERO          CLEAR RETRY COUNT     NG        05650021
         NI    IOBCNT2,ALLONE-RTYFLD    CLEAR RETRY FLAGS     NG        05700021
         NI    IOBFLAG1,ALLONE-IOBERR   INDICATE PER IN IOB FLAGS       05800021
         OI    IOBFLAG3,IOBMSG          PERM ERROR MSG REQUIRED         05850021
WTOEXIT  EQU   *                                                        05900021
         LA    LDNAMREG,IOSWTO          ADDRESS OF IOS WTO ROUTINE      05950021
         BR    RETREG                   EXIT VIA XCTL BRANCH ENTRY      06000021
*********************************************************************** 06010021
*              FINDSTAT SUBROUTINE                                    * 06020021
*        THIS SUBROUTINE SEARCHS THE DEVICE STATISTICS TABLE FOR THE  * 06030021
*        ENTRY ASSIGNED TO THE I/O DEVICE THAT IS CURRENTLY BEING     * 06040021
*        HANDLED BY THE ERP. THE ADDRESS OF THE ENTRY IS RETURNED TO  * 06042021
*        THE CALLER IN STABREG.                                       * 06044021
*********************************************************************** 06046021
FINDSTAT EQU   *                                                        06048021
         L     STABREG,STATADR(CVTREG)  STAT TABLE ADDRESS              06048421
         LR    WKREG1,STABREG           SAVE STAT TABLE START ADDR      06048821
         SR    ICREG,ICREG              CLEAR FOR STAT TABLE INDEX      06049221
         IC    ICREG,UCBSTI(UCBREG)     PICK UP INDEX                   06049621
STATLOOP CH    UCBREG,0(WKREG1)         TEST FOR CORRECT TABLE SECT     06049721
         BL    SECTFND                  IF FOUND-RESOLVE ENTRY ADDR     06049821
         LA    WKREG1,2(WKREG1)         IF NOT-INCR TO NEXT CTRL ENTRY  06049921
         LA    ICREG,256(ICREG)         INCR INDEX TO NEXT SECT         06066621
         B     STATLOOP                 CHECK AGAIN                     06076621
SECTFND  EQU   *                                                        06078621
         MH    ICREG,CONTEN             ADJUST FOR ENTRY LENGTH         06080621
         AR    STABREG,ICREG            RESOLVE ENTRY ADDR              06082621
         BR    LNKREG                   RETURN TO CALLER                06083021
*                                                                       06083121
*********************************************************************** 06083221
*              CHKCMD SUBROUTINE                                      * 06088821
*        THIS SUBROUTINE COMPARES THE COMMAND CODE OF EACH CCW IN A   * 06090821
*        CHANNEL PROGRAM TO THE COMMAND CODE CONTAINED IN CMDREG.     * 06092821
*        IF THE COMMAND IS FOUND,A RETURN CODE OF ZERO IS PLACED IN   * 06093221
*        IXREG. IF IT IS NOT FOUND,THE RETURN CODE IS FOUR.           * 06093621
*********************************************************************** 06094021
CHKCMD   EQU   *                                                        06094121
         L     CCWREG,IOBSTART          PICK UP FIRST CCW ADDR          06094221
         SR    ICREG,ICREG              CLEAR FOR CMD                   06094321
CMDLOOP  IC    ICREG,CCWCMD(CCWREG)     PICK UP COMMAND                 06108221
         CLR   CMDREG,ICREG             CHECK FOR COMMAND               06118221
         BE    SETCFND                  YES-SET COMMAND FOUND RET CODE  06120221
         CLI   CCWCMD(CCWREG),CCWTIC         TIC COMMAND          M2523 06120621
         BE    ADJADR1                       YES-ADJUST ADDRESS   M2523 06121021
*                                                TO NEXT CCW      M2523 06121421
         TM    CCWFLGS(CCWREG),CCWCC+CCWCD CHAINING INDICATED           06121821
         BZ    SETCNFND                 NO-SET CMD NOT FOUND RET CODE   06121921
         LA    CCWREG,8(CCWREG)         YES-INCR TO NEXT CCW            06122021
         B     CMDLOOP                  CONTINUE CHECKING               06122121
*                                                                       06126721
ADJADR1  EQU   *                                                        06128721
         L     CCWREG,0(CCWREG)         PICK UP NEXT CCW ADDR           06130721
         B     CMDLOOP                  CONTINUE TO CHECK COMMAND       06131121
*                                                                       06131221
SETCNFND EQU   *                                                        06131321
         LA    IXREG,FOUR               SET CMD NOT FOUND RC  NG        06131421
         BR    LNKREG                   RETURN TO CALLER                06136021
*                                                                       06138021
SETCFND  EQU   *                                                        06140021
         LA    IXREG,ZERO               SET CMD FOUND RC      NG        06140421
         BR    LNKREG                   RETURN TO CALLER                06140521
*                                                                       06140821
*        REGISTER DEFINITIONS                                           06145421
*                                                                       06150021
TEMPREG  EQU   0                        TEMPORARY SAVE REG    NG        06200021
TSTREG   EQU   1                        RQE ADDRESS                     06250021
IOBREG   EQU   2                        IOB ADDRESS                     06300021
DCBREG   EQU   3                        DCB ADDRESS                     06350021
UCBREG   EQU   4                        UCB ADDRESS                     06400021
CVTREG   EQU   5                        CVT ADDRESS                     06450021
CCWREG   EQU   6                        CCW ADDRESS                     06500021
STABREG  EQU   7                        STAT TABLE ADDRESS              06550021
WKREG1   EQU   8                        WORK REG                        06600021
CMDREG   EQU   WKREG1                   COMMAND REG                     06650021
ICREG    EQU   9                        CHAR REG                        06700021
LNKREG   EQU   10                       LINK REG                        06750021
IXREG    EQU   11                       INDEX REG                       06800021
LNKREGB  EQU   12                       SECOND LINK REG       NG        06850021
LDNAMREG EQU   13                       NEXT LOAD MODULE NAME           06900021
RETREG   EQU   14                       BRANCH ENTRY ADDR TO XCTL       06950021
BASREG   EQU   15                       ERP BASE REG                    07000021
*                                                                       07050021
*        IOB DEFINITIONS AND FLAGS                                      07100021
*                                                                       07150021
IOBDCH   EQU   X'80'                    DATA CHAIN FLAG       NG        07200021
IOBERR   EQU   X'20'                    ERP IN CONTROL                  07250021
IOBEXC   EQU   X'04'                    IOB EXCEPTION                   07300021
IOBEXE   EQU   IOBERR+IOBEXC            EXCEPTION AND ERP IN CONTROL    07350021
IOBINT   EQU   X'7E'                    INTERCEPT CODE                  07400021
GOODIO   EQU   X'7F'                    GOOD I/O CODE                   07450021
IOBMSG   EQU   X'04'                    PERMENENT ERROR MESSAGE         07500021
IOBLOG   EQU   X'01'                    OBR LOGOUT                      07550021
IOBCC1   EQU   X'10'                    SIO CC=1                        07600021
IOBCC3   EQU   X'30'                    SIO CC=3                        07650021
CHANERR  EQU   X'80'                    CHANNEL ERROR FLAG    NG        07700021
UEXRTY   EQU   X'20'                    UNIT EXCEPTION RETRY            07750021
IRERTY   EQU   X'10'                    INTERVENTION REQUIRED RETRY     07800021
DEERR    EQU   X'08'                    DEVICE END ERROR      NG        07850021
USRCRCT  EQU   X'04'                    USER CORRECTABLE                07900021
ERPCOMP  EQU   X'02'                    ERP COMPLETE                    07950021
PERMERR  EQU   X'01'                    PERMENENT ERROR                 08000021
ERPFLGS  EQU   USRCRCT+ERPCOMP+PERMERR  ERP FLAGS                       08050021
RTYFLD   EQU   X'F8'                    RETRY FLAGS FIELD     NG        08100021
*                                                                       08150021
*        UCB DEFINITIONS AND FLAGS                                      08200021
*                                                                       08250021
SRTESTAT EQU   3                        STATUS A                        08300021
UCBFL1   EQU   6                        FLAGS 1                         08350021
UCBSTI   EQU   9                        STATISTICS TABLE INDEX          08400021
UCBTYP   EQU   16                       DEVICE TYPE FIELD               08450021
UCBSNS   EQU   22                  UCB SENSE BYTES               A68718 08460021
DEVCLS   EQU   UCBTYP+2                 DEVICE CLASS BYTE               08500021
UCBNRY   EQU   X'40'                    DEVICE NOT READY                08550021
UCBITF   EQU   X'10'                    INTERCEPT FLAG                  08600021
OPCNSL   EQU   X'82'                    ONLINE ACTIVE CONSOLE           08650021
GRTYPE   EQU   X'10'                    GRAPHICS CLASS                  08700021
DEV3277  EQU   X'09'                    3277 DEVICE                     08750021
DEV3284  EQU   X'0A'                    3284 DEVICE                     08800021
DEV3286  EQU   X'0B'                    3286 DEVICE                     08850021
DEV3158  EQU   X'0C'                    3158 DEVICE              S21122 08900021
DEVTYP   EQU   UCBTYP+3                 DEVICE TYPE BYTE                08950021
*                                                                       09000021
*        DCB  FLAGS                                                     09050021
*                                                                       09100021
DCBPER   EQU   X'C0'                    PERMENENT ERROR                 09150021
DCBCLOS  EQU   X'11'                    CLOSE IN PROGRESS               09200021
*                                                                       09250021
*        RQE  DEFINITIONS                                               09300021
*                                                                       09350021
TSTUCB   EQU   2                        UCB ADDRESS                     09400021
TSTIOB   EQU   4                        IOB ADDRESS                     09450021
*                                                                       09500021
*        CSW  FLAGS                                                     09550021
*                                                                       09600021
CSWCHE   EQU   X'08'                    CHANNEL END                     09650021
CSWDVE   EQU   X'04'                    DEVICE END                      09700021
CSWCDE   EQU   CSWCHE+CSWDVE            CHANNEL END AND DEVICE END      09750021
CSWUCK   EQU   X'02'                    UNIT CHECK                      09800021
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  09850021
CSWIL    EQU   X'40'                    INCORRECT LENGTH                09900021
CSWPGC   EQU   X'20'                    PROGRAM CHECK                   09950021
CSWPTC   EQU   X'10'                    PROTECTION CHECK                10000021
CSWCDC   EQU   X'08'                    CHANNEL DATA CHECK              10050021
CSWCCC   EQU   X'04'                    CHANNEL CONTROL CHECK           10100021
CSWICC   EQU   X'02'                    INTERFACE CONTROL CHECK         10150021
CSWCCK   EQU   X'01'                    CHAINING CHECK                  10200021
CATCHAN  EQU   CSWCDC+CSWCCC+CSWICC     CATASTROPHIC CHANNEL ERRORS     10250021
CATERR   EQU   CSWIL+CSWPGC+CSWPTC+CSWCCK STATUS ERRORS                 10300021
*                                                                       10350021
*        SENSE FLAGS                                                    10400021
*                                                                       10450021
SENCR    EQU   X'80'                    COMMAND REJECT                  10500021
SENIR    EQU   X'40'                    INTERVENTION REQUIRED           10550021
SENBOC   EQU   X'20'                    BUS OUT CHECK                   10600021
SENEC    EQU   X'10'                    EQUIPMENT CHECK                 10650021
SENDC    EQU   X'08'                    DATA CHECK                      10700021
SENCC    EQU   X'02'                    CONTROL CHECK                   10750021
SENOC    EQU   X'01'                    OPERATION CHECK                 10800021
SENDCUS  EQU   X'0C'                    DATA CHECK,UNIT SPECIFY  A59081 10850021
SENIRUS  EQU   X'44'                    INT REQ,UNIT SPECIFY            10900021
SNIRECUS EQU   X'54'                    INT REQ,EQUIP CHK,UNIT SPECIFY  10950021
SENECUS  EQU   X'14'                    EQUIP CHECK,UNIT SPECIFY        11000021
*                                                                       11050021
*        STATISTICS TABLE MULTI BIT SENSE FLAGS                         11100021
*                                                                       11150021
STDCUS   EQU   X'10'                    DATA CHECK,UNIT SPECIFY         11200021
STIRUS   EQU   X'08'                    INT REQ,UNIT SPECIFY            11250021
STIRECUS EQU   X'04'                    INT REQ,EQUIP CHK,UNIT SPECIFY  11300021
STECUS   EQU   X'02'                    EQUIP CHECK,UNIT SPECIFY        11350021
STMSK1   EQU   X'7A'                    SINGLE BIT POS USED MASK        11400021
STMSK2   EQU   X'1F'                    MULTI BIT POS USED MASK         11450021
*                                                                       11500021
*        CCW COMMAND CODES , DEFINITIONS AND FLAGS                      11550021
*                                                                       11600021
CCWWRT   EQU   X'01'                    WRITE                           11650021
CCWEWR   EQU   X'05'                    ERASE WRITE                     11700021
CCWRDM   EQU   X'06'                    READ MODIFIED                   11750021
CCWSNS   EQU   X'04'                    SENSE                 NG        11800021
CCWNOP   EQU   X'03'                    NO-OP                 NG        11850021
CCWRDB   EQU   X'02'                    READ BUFFER                     11900021
CCWDWR   EQU   X'09'                    DIAGNOSTIC WRITE                11950021
CCWDRD   EQU   X'0A'                    DIAGNOSTIC READ                 12000021
CCWSEL   EQU   X'0B'                    SELECT                          12050021
CCWEUP   EQU   X'0F'                    ERASE ALL UNPROTECTED           12100021
CCWCC    EQU   X'40'                    COMMAND CHAINING                12150021
CCWCD    EQU   X'80'                    DATA CHAINING                   12200021
CCWTIC   EQU   X'08'                         TIC OP CODE          M2523 12250021
CCWCMD   EQU   0                        COMMAND FIELD                   12300021
CCWFLGS  EQU   4                        FLAGS FIELD                     12350021
CCWCNT   EQU   6                        COUNT FIELD                     12400021
*                                                                       12450021
*        MISC   DEFINITIONS,FLAGS AND CONSTANTS                         12500021
*                                                                       12550021
ZERO     EQU   0                        ZERO                  NG        12600021
ONE      EQU   X'01'                    ONE                   NG        12650021
THREE    EQU   X'03'                    THREE                 NG        12700021
FOUR     EQU   4                        FOUR                  NG        12750021
GCB      EQU   27                   OFFSET TO GRAPHICS CONTROL BYTE     12760021
GRAF     EQU   28                   OFFSET TO GRAPHICS STATUS FLAGS     12762021
OPENFAIL EQU   X'02'                FAIL FLAG                           12770021
CVTADR   EQU   16                       LOCATION OF CVT ADDRESS         12800021
XCTLADR  EQU   44                       ADDRESS OF BRANCH EP TO XCTL    12850021
STATADR  EQU   112                      ADDRESS OF STATISTICS TABLE     12900021
OPTFLGS  EQU   182                      ADDRESS OF OPTION FLAGS         12950021
IOSWTO   EQU   253                      IOS WTO ROUTINE ID              13000021
STATUP   EQU   254                      STATISTICS UPDATE ROUTINE ID    13050021
LOADTWO  EQU   1105                     3270 ERP SECOND LOAD  NG        13100021
LOAD210E EQU   2105                     OPEN INT REQ LOAD     SB A57064 13150021
CCHFLG   EQU   X'80'                    CCH IN SYSTEM                   13200021
RETURN   EQU   3                        RETURN SVC                      13250021
EREXCP   EQU   15                       ERROR SVC                       13300021
BADSENS  EQU   X'FE'                    SENSE NOT VALID                 13350021
ALLONE   EQU   X'FF'                    ALL ONES BYTE                   13400021
ALLZERO  EQU   X'00'                    ALL ZEROS BYTE                  13450021
CONTEN   DC    H'10'                    CONSTANT TEN          NG        13500021
CONEIGHT DC    H'8'                     CONSTANT EIGHT        NG        13550021
ZEROWORD DC    F'0'                FULL WORD OF ZEROS            A68718 13560021
DBLWORD  EQU   8                   LENGTH OF DOUBLE WORD         A68718 13570021
TWO      EQU   2                   TWO                           A68718 13580021
FIVE     EQU   5                   FIVE                          A68718 13590021
TERMBITS EQU   X'C0'               TERMINATION CODE BITS         A68718 13592021
SEQBITS  EQU   X'07'               SEQUENCE CODE BITS            A68718 13594021
CVTDCB   EQU   116                 DISP IN CVT OF LOGREC @       A68718 13594421
SBABYTE  EQU   1                   DISP OF SBA IN DATA STREAM    A68718 13596021
SBA      EQU   X'11'               SET BUFFER ADDRESS CHAR       A68718 13598021
CMDCHAIN EQU   X'40'               COMMAND CHAIN BIT             A68718 13598421
DATCHAIN EQU   X'80'               DATA CHAIN BIT                A68718 13598821
*                                                                       13600021
* THE FOLLOWING FLGS ARE USED TO SET THE PROPER BITS FOR EDITING A59117 13650021
* AND PRINTING DC,EC,BOC AND IR ERRORS WHEN SYS1.LOGREC IS       A59117 13700021
* PRINTED.                                                       A59117 13750021
STATEC   EQU   X'20'               EQUIPMENT CHECK               A59117 13800021
STATDC   EQU   X'10'               DATA CHECK                    A59117 13850021
STATBOC  EQU   X'40'               BUS OUT CHECK                 A59117 13900021
STATIR   EQU   X'08'               INTERVENTION REQUIRED         A59117 13950021
*                                                                A68718 13960021
*        ERPIB IGPRGFLG BITS                                     A68718 13970021
*                                                                A68718 13980021
SIOB     EQU   X'80'               START I/O                     A68718 13990021
INTB     EQU   X'40'               INTERRUPT                     A68718 13992021
TIOB     EQU   X'20'               TEST I/O                      A68718 13994021
HIOB     EQU   X'10'               HALT I/O                      A68718 13996021
RTYB     EQU   X'01'               RETRY BYTE                    A68718 13998021
*                                                                A68718 13998421
*        ERPIB IGVALIDB BITS                                     A68718 13998821
*                                                                A68718 13999221
INTV     EQU   X'80'               INTERFACE ADDR VALID          A68718 13999621
SEQV     EQU   X'10'               SEQUENCE CODE VALID           A68718 13999721
CMDAV    EQU   X'04'               COMMAND ADDR VALID            A68718 13999821
CAV      EQU   X'02'               CHANNEL ADDR VALID            A68718 13999921
DAV      EQU   X'01'               DEVICE ADDR VALID             A68718 14016621
*                                                                A68718 14026621
*        ERPIB TERMINATION AND SEQUENCE CODES                    A68718 14028621
*                                                                A68718 14030621
TERM0    EQU   X'00'               INTERFACE DISCONNECT          A68718 14032621
TERM1    EQU   X'40'               NORMAL TERMINATION            A68718 14033021
TERM2    EQU   X'80'               SELECTIVE RESET               A68718 14033121
TERM3    EQU   X'C0'               SELECTIVE RESET               A68718 14033221
SEQ0     EQU   X'00'               TEST I/O FAILURE              A68718 14033321
SEQ1     EQU   X'01'               CHAN SENT CMD OUT - HASN'T    A68718 14038821
*                                   EXAMINED UNIT STATUS         A68718 14040821
SEQ2     EQU   X'02'               DVC ACCEPTED DMC - NO DATA    A68718 14042821
*                                   TRANSFERED                   A68718 14043221
SEQ3     EQU   X'03'               DATA XFERED OVER INTERFACE    A68718 14043621
SEQ4     EQU   X'04'               CMD NOT ACCEPTED BY CTL UNIT  A68718 14044021
*                                   OR CMD OUT NOT SEND          A68718 14044121
SEQ5     EQU   X'05'               CMD ACCEPTED BIT NO DATA      A68718 14044221
*                                   TRANSFERED                   A68718 14044321
SEQ6     EQU   X'06'               RESERVED                      A68718 14058221
SEQ7     EQU   X'07'               RESERVED                      A68718 14068221
*                                                                       14072221
PATCHLEN EQU   IGE0210E+1024-*     LENGTH OF PATCH AREA          A68718 14082221
PATCH    DC    (PATCHLEN)X'00'     VARIABLE LENGTH PATCH AREA    A68718 14084221
         IECTIOBX                                                       14086121
IOBCNT1  EQU   IOBERRCT                                       NG        14100021
IOBCNT2  EQU   IOBERRCT+1                                     NG        14160021
ERPIBFLG EQU   IOBWORK             FLG BYTE FROM ERPIB           A68718 14170021
ERPIBVAL EQU   IOBWORK+2           VALIDITY BYTE FROM ERPIB      A68718 14180021
ERPIBTRM EQU   IOBWORK+3           TERM CODE FROM ERPIB          A68718 14190021
ERPIBSEQ EQU   IOBWORK+4           SEQUENCE CODE FROM ERPIB      A68718 14192021
         DCBD  DSORG=BX,DEVD=BS                                         14200021
         END                                                            14250021
