         TITLE 'IGE0304A - BTAM ERP INTERVENTION REQUIRED MODULE'       00800013
IGE0304A CSECT                                                          01200013
*126101200600,02341170,02781390                                    000A 01600013
         SPACE 2                                                        02000013
*********************************************************************** 02400013
* STATUS -          CHANGE LEVEL 001    APRIL 25, 1967                  02800013
*                                                                     * 03200013
* FUNCTION-        IF REQUIRED, RETRIES CHANNEL PROGRAM THAT FAILED   * 03600013
*                  BECAUSE OF AN INTERVENTION REQUIRED CONDITION.     * 04000013
*                  DETERMINES IF LINE ERROR RECORDING IS REQUIRED AND * 04400013
*                  LINKS EITHER TO LERB ROUITNE OR POST ROUTINE.      * 04800013
*                                                                     * 05200013
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 05600013
*                  TO THE ASSOCIATED IO RB.                           * 06000013
*                                                                     * 06400013
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 06800013
*                  ERROR.  SETS INDICATOR FOR DISABLE REQUIRED IN     * 07200013
*                  DECERRST.                                          * 07600013
*                                                                     * 08000013
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 08400013
*                                                                     * 08800013
* EXITS-           EXITS THROUGH LINKAGE OT MODULES IGE0504A AND      * 09200013
*                  IGE0204B.                                          * 09600013
*                                                                     * 10000013
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 10400013
*********************************************************************** 10800013
         SPACE 2                                                        11200013
*        INTERVENTION REQUIRED ERP MODULE                               11600013
         USING *,BASREG                                                 12000013
         L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  12400013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  12800013
         L     COMREG,LOC016            ADDRESS OF CVT                  13200013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 13600013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  14000013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  14400013
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           14800013
         CLI   IOBECT+1(IOBRG),MASK3    SPECIAL ENTRY FOR DISABLE       15200013
         BE    ERRTRY03                 YES CHECK FOR DISABLE           15600013
         CLI   IOBECT+1(IOBRG),X'01'    SPECIAL RETURN FOR WR EOTA35750 15700020
         BE    ERRTRY04                 YES, BRANCH              A35750 15800020
         MVC   IOBWRK(1,IOBRG),5(CCWREG) TP OP CODE TO WORK AREA        16000013
         NI    IOBWRK(IOBRG),MASKALL-CCWMASK1 MASKOUT UNUSED BITS       16400013
         CLI   0(CCWREG),CCWAPOLL       THIS AUTOPOLL              000A 16800013
         BE    ERRIRI02                 YES SET UP POLL ADDRESS    000A 17200013
         CLI   0(CCWREG),CCWRDCMD       READ COMMAND                    17600013
         BE    ERRIRR00                 YES CHECK WHEN                  18000013
         CLI   0(CCWREG),CCWINHCD       INHIBIT COMMAND                 18400013
         BE    ERRIRR00                 TREAT SAME AS READ              18800013
         CLI   0(CCWREG),CCWDIAL        DIAL COMMAND                    19200013
         BE    ERRIRI00                 YES RETRY AT START              19600013
         CLI   0(CCWREG),CCWPREP        PREPARE COMMAND                 20000013
         BE    ERRIRI03                 YES, CHECK ADAPTER TYPE  A35750 20400020
         CLI   0(CCWREG),CCWWRT         WRITE COMMAND                   20800013
         BE    ERRIRWT1                 YES SET UP TO FINI              21200013
         CLI   0(CCWREG),CCWBRK         BREAK COMMAND                   21600013
         BE    ERRIRWT1                 YES SET UP TO FINI              22000013
         OI    DECERRST(DECBRG),CSWSNO  SHOULD NOT OCCUR           0217 22400017
         B     ERRTRY01                 SET UP TO POST                  22800013
ERRIRWT1 MVI   IOBECT(IOBRG),ERTRYCT    SET RETRY COUNT TO MAXIMUM      23200013
         B     ERRTOD03                 CHECK FOR LINE ERROR RECORDING  23600013
*                                                                       23640019
ERRIRWT0 CLI   IOBWRK(IOBRG),CCWRRPL    READ RESPONCE TO POLLING        23680019
         BNE   ERRIRI01                 NO, CHECK FOR READ INDEX        23720019
         CLI   DECBTYPE(DECBRG),TYPEWTTV  IS THE READ RESP IN WRITE TTV 23760019
         BNE   ERRIRI00                 NO, SET UP START OF CHAN PROG   23800019
         LA    ERREG2,IOBCPA+16(IOBRG)  SET UP START OF READ            23840019
         ST    ERREG2,IOBSTART(IOBRG)                                   23880019
         B     ERRTOD03                 CHECK FOR LINE ERROR RECORDING  23920019
ERRIRI01 CLI   IOBWRK(IOBRG),CCWRDIX    THIS READ RESP TO INDEX    000A 24000013
         BNE   ERRIRI00                 NO SETUP START OF CHAN PROG000A 24400013
ERRIRI02 EQU   *                                                   000A 24800013
         L     ERREG1,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FROM    000A 25200013
*    PREVIOUS POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).    000A 25600013
         MVC   IOBCPA+9(3,IOBRG),DECENTRY+1(DECBRG)    MOVE IN     000A 26000013
*    ADDRESS OF LAST ENTRY POLLED (TO BE USED AS RESTART ADDRESS). 000A 26400013
         L     ERREG4,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FOR     000A 26800013
*    NEXT POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).        000A 27200013
         SR    ERREG1,ERREG4            SUBTRACT NEW POLL ADDRESS  000A 27600013
*                                  FROM PREVIOUS POLL ADDRESS.     000A 28000013
         AH    ERREG1,IOBCPA+14(IOBRG)  IF THE NEW POLL ADDRESS    000A 28400013
*    WERE LESS THAN THE PREVIOUS POLL ADDRESS, THE EFFECT IS TO    000A 28800013
*    ADD THE ABSOLUTE DIFFERENCE TO THE PREVIOUS COUNT;  IF IT WERE000A 29200013
*    GREATER, THE EFFECT IS TO SUBTRACT THE ABSOLUTE DIFFERENCE    000A 29600013
*    FROM THE PREVIOUS COUNT.                                      000A 30000013
         STH   ERREG1,IOBCPA+14(IOBRG)  STORE ADJUSTED COUNT IN    000A 30400013
*                                  POLL COMMAND.                   000A 30800013
ERRIRI00 LA    ERREG2,IOBCPA(IOBRG)     RESOLVE START OF CHAN PROGRAM   31200013
         ST    ERREG2,IOBSTART(IOBRG)   STORE CPA POINTER               31600013
         B     ERRTOD03                 CHECK FOR LINE ERROR RECORDING  32000013
ERRIRI03 EQU   *                                                 A35750 32010020
         MVC   IOBWRK+1(1,IOBRG),UCBTYP+3(UCBREG)   MOVE ADAPTER A35750 32020020
         NI    IOBWRK+1(IOBRG),MASK3    CLEAR USED BITS          A35750 32030020
         CLI   IOBWRK+1(IOBRG),X'10'    IBM TYPE 1 ADAPTER       A35750 32040020
         BNE   ERRIRI00                 NO, BRANCH               A35750 32050020
         TM    UCBTYP(UCBREG),X'04'     TEST                     A35750 32060020
         BZ    ERRIRI00                     FOR                  A35750 32070020
         TM    UCBTYP(UCBREG),X'03'            2741              A35750 32080020
         BNM   ERRIRI00                 NOT 2741                 A35750 32090020
         TM    UCBTYP+1(UCBREG),X'90'   SWITCHED LINE            A35750 32100020
         BNZ   ERRIRI00                 YES, BRANCH              A35750 32110020
         MVC   IOBSAV1+8(8,IOBRG),0(CCWREG) SAVE CCW             A35750 32120020
         MVC   IOBSAV1(1,IOBRG),IOBSNS(IOBRG)  SAVE SENSE STATUS A35750 32130020
         MVC   IOBSAV1+1(7,IOBRG),IOBCSW+1(IOBRG) SAVE CSW       A35750 32140020
         MVI   IOBWRK+2(IOBRG),X'1F'    MOVE IN EOT              A35750 32150020
         LA    ERREG1,IOBWRK+2(IOBRG)   GET ADDRESS OF EOT       A35750 32160020
         ST    ERREG1,IOBDCCW(IOBRG)    STORE IN CCW             A35750 32170020
         LA    ERREG1,CCWWRT            GET COMMAND              A35750 32180020
         STC   ERREG1,IOBDCCW(IOBRG)    STORE COMMAND            A35750 32190020
         ST    ERREG1,IOBDCCW+4(IOBRG)  STORE COUNT              A35750 32200020
         LA    ERREG1,IOBDCCW(IOBRG)    LOAD CCW ADDRESS         A35750 32210020
         ST    ERREG1,IOBSTART(IOBRG)   STORE CCW ADDRESS        A35750 32220020
         MVI   IOBECT+1(IOBRG),X'01'    MOVE IN SPECIAL RETURN   A35750 32230020
         B     ERRTOD03                 UPDATE RETRY COUNT       A35750 32240020
ERRTRY04 EQU   *                                                 A35750 32250020
         NI    IOBECT+1(IOBRG),X'FE'    CLEAR SPECIAL RETURN     A35750 32260020
         CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED           A35750 32270020
         BNL   ERRTRY05                 NO, BRANCH               A35750 32280020
         LA    ERREG2,IOBCPA(IOBRG)                              A35750 32290020
         ST    ERREG2,IOBSTART(IOBRG)                            A35750 32300020
         B     ERRTRY06                 RESTART FAILING CCW      A35750 32310020
ERRTRY05 EQU   *                                                 A35750 32320020
         MVC   IOBSNS(1,IOBRG),IOBSAV1(IOBRG)  RESTORE SENSE     A35750 32330020
         MVC   IOBCSW+1(7,IOBRG),IOBSAV1+1(IOBRG) RESTORE CSW    A35750 32340020
         B     ERRPERM1                 POST WITH ERROR          A35750 32350020
ERRIRR00 TM    IOBWRK(IOBRG),CCWPTXFR   PRIOR TO TEXT TRANSFER          32400013
         BZ    ERRIRWT0                 YES, CHECK FOR RESPONCE TO POLL 32800019
         CLI   IOBWRK(IOBRG),CCWRRTXT   READ RESPONSE TO TEXT           33200013
         BNE   ERRTSTX                  NO TEST FOR READ TEXT    A63105 33600021
         TM    DCBERROP(DCBREG),DCBRDTRY TEXT READ RETRIES REQUIRED     34000013
         BZ    ERRTOT06                 NO CHECK FOR LINE ERROR UPDATE  34400013
         MVC   IOBWRK+1(1,IOBRG),DECTYPE+1(DECBRG) OP TYPE TO WORK AREA 34800013
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT CLEAR UNUSED BIT           35200013
         CLI   IOBWRK+1(IOBRG),CCWWRTCT OPERATION A WRITE CONTINUE      35600013
         BNE   ERRTOD03                 CHECK FOR LINE ERROR UPDATE     36000013
ERRTOT06 TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQUIRED   36400013
         BZ    ERRTOT04                 NO POST COMPLETE WITH ERROR     36800013
         MVI   IOBECT-1(IOBRG),LERBIR   INDICATE LERB RECORDING         37200013
         NI    IOBFL1(IOBRG),MASKALL-IOBEXE INDICATE POST NO WTO        37600013
         LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         38000013
         B     ERRLINK1                                                 38400013
ERRTSTX  EQU   *                                                 A63105 38450021
         CLI   IOBWRK(IOBRG),CCWRDTXT   READ TEXT?               A63105 38500021
         BNE   ERRTOT06                 NO, BRANCH               A63105 38550021
         TM    DCBERROP(DCBREG),DCBLERB LERB REQ'D?              A63105 38600021
         BZ    ERRPERM1                 NO, POST COMPLETE        A63105 38650021
         MVI   IOBECT-1(IOBRG),LERBIR   INDICATE INT REQ LERB    A63105 38700021
         B     ERRPERM1                 EXIT                     A63105 38750021
ERRTOD03 TM    DCBERROP(DCBREG),DCBLERB LINE ERROR RECORDING REQUIRED   38800013
         BZ    ERRCTT01                 NO CONTINUE FLOW                39200013
         MVI   IOBECT-1(IOBRG),LERBIR   INDICATE INT REQ LERB           39600013
ERRCTT01 CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED                  40000013
         BL    ERRTRY02                 YES SET UP FOR RETRY            40400013
         CLI   0(CCWREG),CCWDISAB       DISABLE EXECUTED                40800013
         BE    ERRPERM1                 YES POST COMPLETE WITH ERROR    41200013
ERRTRY01 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                41600013
         BZ    ERRPERM1                 NO POST COMPLETE                42000013
ERRTRY03 EQU   *                                                        42400013
         MVC   IOBSAV1+8(8,IOBRG),0(CCWREG)                             42800013
         MVC   IOBSAV1(1,IOBRG),IOBSNS(IOBRG) SAVE SENSE DATA           43200013
         MVC   IOBSAV1+1(7,IOBRG),IOBCSW+1(IOBRG) SAVE CSW DATA         43600013
         MVI   IOBECT+1(IOBRG),DISABIND INDICATE DISABLE REQUIRED       44000013
         LA    ERREG1,IOBDCCW(IOBRG)    CHANNEL PROG ADDRESS            44400013
         ST    ERREG1,IOBSTART(IOBRG)   CHAN PROG POINTER               44800013
         OI    DECERRST(DECBRG),DISABLOK INDICATE DISABLE EXECUTED      45200013
         MVC   IOBDCCW(8,IOBRG),DISABCMD GENERATE DISABLE CCW           45600013
ERRTRY02 IC    ERREG1,IOBECT(IOBRG)     ERROR RETRY COUNT               46000013
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     46400013
         STC   ERREG1,IOBECT(IOBRG)     RESTORE IN COUNT FIELD          46800013
         CLI   IOBECT-1(IOBRG),LERBIR  LINE ERR RECORDING REQ'D  A66468 47200021
         BE    ERLERBTO                YES, EXIT TO LERB RTN     A66468 47600021
ERRTRY06 EQU   *                                                 A35750 47800020
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                48000013
         SVC   EXCPER                   EXECUTE CHAN PROG               48400013
         SVC   RETURN                   NO FINI                         50400013
ERRPERM1 EQU   *                                                 A35750 50600020
         NI    IOBFL1(IOBRG),MASKALL-IOBERR                      A35750 50800020
         CLI   IOBECT-1(IOBRG),LERBIR   LINE ERROR REC REQUIRED  A66468 51000021
         BE    ERLERBTO                 YES, EXIT                A66468 51200021
         LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         51600013
ERRLINK1 L     ERRETR,VECTXL(COMREG)    LINK ROUTINE                    52000013
         BR    ERRETR                   LINK                            52400013
ERLERBTO LA    SAVREG,ERLOD12           ADDRESS OF LERB ROUTINE         53200013
         B     ERRLINK1                                                 53600013
ERRTOT04 NI    IOBFL1(IOBRG),MASKALL-IOBERR INDICATE PERM ERROR         54000013
         SVC   EXCPER                   THATS FINI                      54400013
         SVC   RETURN                   RELEASE TRANSIENT AREA          54800013
DISABCMD DC    X'2F00000020300001'                                      55200013
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 55600013
ERRCN1   DC    H'8'                     DECIMAL 8                  000A 56000013
ERLOD5   DC    H'5041'                                             000A 56400013
CCWAPOLL EQU   X'09'                                               000A 56800013
CCWBRK   EQU   X'0D'                                                    57200013
CCWDIAL  EQU   X'29'                                                    57600013
CCWDISAB EQU   X'2F'                                                    58000013
CCWINHCD EQU   X'0A'                                                    58400013
CCWMASK1 EQU   X'C0'                                                    58800013
CCWPREP  EQU   X'06'                                                    59200013
CCWPTXFR EQU   X'30'                                                    59600013
CCWRDCMD EQU   X'02'                                                    60000013
CCWRDIX  EQU   X'0A'                                               000A 60400013
CCWRRPL  EQU   X'05'                                                    60600019
CCWRRTXT EQU   X'20'                                                    60800013
CCWRDTXT EQU   X'11'                    READ TEXT TP OP CODE     A63105 60850021
CCWRTRT  EQU   X'04'                                                    61200013
CCWWRT   EQU   X'01'                                                    61600013
CCWWRTCT EQU   X'04'                                                    62000013
CSWSNO   EQU   X'40'                                                    62400013
DCBERROP EQU   33                                                       62800013
DCBLERB  EQU   X'08'                                                    63200013
DCBRDTRY EQU   X'02'                                                    63600013
DECBDCB  EQU   8                                                        64000013
DECBTYPE EQU   X'04'                                                    64200019
DECENTRY EQU   20                                                  000A 64400013
DECERRST EQU   29                                                       64800013
DECTYPE  EQU   4                                                        65200013
DISABIND EQU   X'80'                                                    65600013
DISABLOK EQU   X'08'                                                    66000013
ERLOD12  EQU   2042                                                     66400013
ERTRYCT  EQU   X'02'                                                    66800013
EXCPER   EQU   15                           EXCP ERROR ROUTINE          67200013
HIBIT    EQU   X'C0'                                                    67600013
IOBCPA   EQU   64                                                       68000013
IOBCSW   EQU   8                            CSW STORAGE                 68400013
IOBDCCW  EQU   40                                                       68800013
IOBDCBAD EQU   20                                                       69200013
IOBDECB  EQU   4                                                        69600013
IOBECT   EQU   30                      ERROR COUNTS                     70000013
IOBERR   EQU   X'20'                        IOB ERROR FLAG              70400013
IOBEX    EQU   X'04'                        EXCEPT FLAG                 70800013
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                71200013
IOBFL1   EQU 0                              FLAGS 1                     71600013
IOBSAV1  EQU   48                                                       72000013
IOBSNS   EQU   2                                                        72400013
IOBSTART EQU   16                                                       72800013
IOBWRK   EQU   33                                                       73200013
LERBIR   EQU   X'02'                                                    73600013
LOC016   EQU   16                           COMMUNICATIONS TABLE        74000013
MASKALL  EQU   255                                                      74400013
MASK3    EQU   X'F0'                                                    74800013
NONAME   EQU   X'00'                                                    75200013
RETURN   EQU   3                       RETURN SVC                       75600013
SWLINE   EQU   X'90'                                                    76000013
TSTIOB   EQU   5                            IOB POINTER                 76400013
TSTUCB   EQU   2                            UCB POINTER                 76800013
TYPEWTTV EQU   X'0F'                                                    77000019
UCBTYP   EQU   16                      DEVICE TYPE CODE                 77200013
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      77600013
*        REGISTER DEFINITION                                            78000013
ERREG3   EQU   0                             WORK REG                   78400013
TSTREG   EQU   1                             TWELVE STAR REG            78800013
ERREG2   EQU   2                             WORK REG                   79200013
CRBREG   EQU   3                             CURRENT RB REG             79600013
CCWREG   EQU   4                             CCW ADDRESS REG            80000013
DECBRG   EQU   5                        DECB REGISTER                   80400013
DCBREG   EQU   6                        DCB REGISTER                    80800013
UCBREG   EQU   7                             UCB ADDRESS  REG           81200013
COMREG   EQU   8                             COMMUNICATION TABLE REG    81600013
ERREG1   EQU   9                                                        82000013
IOBRG    EQU   10                            IOB ADDRESS REG            82400013
ERREG4   EQU   11                            WORK REG                   82800013
ERRLNK   EQU   12                            LINK REG                   83200013
SAVREG   EQU   13                                                       83600013
ERRETR   EQU   14                            RETURN REG                 84000013
BASREG   EQU   15                            BASE REG                   84400013
         END                                                            84800013
