         TITLE 'IGE0304C BSC INTERVENTION REQUIRED ERP ROUTINE'         00500016
         SPACE 2                                                        01000016
IGE0304C CSECT                                                          01500016
*C380000-385000                                                  A43763 01700021
         SPACE 2                                                        02000016
*********************************************************************** 02500016
*  STATUS      CHANGE LEVEL 000 JULY 10, 1967                         * 03000016
*                                                                     * 03500016
*  FUNCTION    THIS ROUTINE RECOVERS FROM INTERVENTION REQUIRED       * 04000016
*              ERROR CONDITIONS THAT OCCUR DURING BSC OPERATION.      * 04500016
*              THE CCW THAT IS IN ERROR IS DETECTED. THE PROPER       * 05000016
*              ERROR RECOVERY PROCEDURE FOR THE TYPE OF OPERATION     * 05500016
*              BEING EXECUTED IS THEN INITIATED.                      * 06000016
*                                                                     * 06500016
*  INPUT       INPUT TO THE PROGRAM IS THROUGH REGISTER ONE, A        * 07000016
*              POINTER TO THE ASSOCIATED RB.                          * 07500016
*                                                                     * 08000016
*  OUTPUT      SETS INDICATOR IN DECERRST FIELD OF DECB FOR SHOULD-   * 08500016
*              NOT-OCCUR ERRORS OR INDICATES PERMANENT ERROR. UPDATES * 09000016
*              LINE ERROR COUNTS IF REQUIRED.                         * 09500016
*                                                                     * 10000016
*  ENTRY       ENTRY IS THE FIRST EXECUTABLE INSTRUCTION.             * 10500016
*                                                                     * 11000016
*  EXITS       EXITS ARE VIA SVC 3(RETURN) OR LERB IN CASE LINE       * 11500016
*              ERROR COUNTS ARE REQUIRED OR TO ERRPOST IN CASE        * 12000016
*              OF PERMANENT ERROR WITH NO LERB REQUIRED.              * 12500016
*                                                                     * 13000016
*  ATTRIBUTES  THIS MODULE IS TRANSIENT, ENABLED, REENTRANT, AND      * 13500016
*              OPERATES IN THE NUCLEUS ERROR TRANSIENT AREA WITH      * 14000016
*              A SUPERVISOR PROTECT KEY.                              * 14500016
*                                                                     * 15000016
*********************************************************************** 15500016
         SPACE 2                                                        16000016
TSTREG   EQU   1                                                        16500016
CCWREG   EQU   4                                                        17000016
DECBRG   EQU   5                                                        17500016
DCBREG   EQU   6                                                        18000016
UCBREG   EQU   7                                                        18500016
COMREG   EQU   8                                                        19000016
IOBREG   EQU   10                                                       19500016
ERREG1   EQU   11                                                       20000016
ERREG2   EQU   12                                                       20500016
SAVREG   EQU   13                                                       21000016
ERRETR   EQU   14                                                       21500016
BASREG   EQU   15                                                       22000016
         SPACE 2                                                        22500016
         USING *,BASREG                                                 23000016
         USING IECTIOB,IOBREG           IOB DSECT BASE REGISTER         23500016
         USING IECTDECB,DECBRG          DECB DSECT BASE REGISTER        24000016
         USING IHADCB,DCBREG            DCB DSECT BASE REGISTER         24500016
         L     IOBREG,TSTIOB(TSTREG)    ADDRESS OF IOB FROM RB          25000016
         L     COMREG,CVTPTR            ADDRESS OF CVT                  25500016
         L     DCBREG,IOBDCBPT          ADDRESS OF DCB                  26000016
         L     DECBRG,IOBECBPT          ADDRESS OF DECB                 26500016
         L     CCWREG,IOBCSW            ADDRESS OF CCW IN CHAN. PROG.   27000016
         SH    CCWREG,CCWSIZE           BACK UP TO FAILING CCW          27500016
         MVC   IOBWORK(1),TPOPCODE(CCWREG) TP CODE TO IOB WORK AREA     28000016
         NI    IOBWORK,MASKALL-UNUSBIT  TURN OFF UNUSED HI-ORDER BITS   28500016
         L     ERRETR,CVTXTLER(COMREG) LOAD XCTL ENTRY FROM CVT         29000016
         LH    UCBREG,TSTUCB(TSTREG)                                    29300018
         TM    17(UCBREG),X'90'        IS THIS DIAL LINE                29600018
         BNZ   BSCIR05                 YES, DISABLE AND POST            29900018
         CLI   0(CCWREG),CCWPREP        ERROR OCCUR ON A PREPARE CMD.   30500016
         BE    BSCIR06                                                  31000016
         CLI   0(CCWREG),CCWPOLL        ERROR OCCUR ON A POLL COMMAND   31500016
         BE    BSCIR07                  UPDATE CHAN PROG. RESTART POLL  32000016
         CLI   IOBWORK,DURINTXT        ERROR OCCUR DURING TEXT          32500016
         BE    BSCIR001                YES CHECK BUFFERING TECH         33000016
         CLI   IOBWORK,NONAME          ERP CCW                          33500016
         BE    BSCIR01                  YES, RESTART CHANNEL PROG  000F 34000018
         B     BSCIR06                 RESTART FAILING CCW              34500016
BSCIR001 EQU   *                                                        35000016
         CLI   0(CCWREG),CCWREAD        ERROR OCCUR ON A READ COMMAND   35500016
         BNE   BSCIR08                                                  36000016
         TM    DCBBFTEK,BSCDYBUF        IS DYNAMIC BUFFERING EMPLOYED   36500016
         BZ    BSCIR09                                                  37000016
BSCIR00  MVI   IOBERRCT,ERRMAX          SET RETRY COUNT TO MAXIMUM      37500016
BSCIR01  TM    DCBERROP,LERBREQ         IS LERB REQUIRED         A43763 38000021
         BNO   BSCIR02                  NO, SKIP INTV REQ        A43763 38500021
         MVI   IOBINCAM+1,IRIND        TURN ON INTV REQ FLAG            39000016
BSCIR02  CLI   IOBERRCT,ERRMAX          IS RETRY COUNT AT MAXIMUM       39500016
         BE    BSCIR04                  YES, GO INDICATE PERMANENT ERR. 40000016
         IC    ERREG1,IOBERRCT          NO, UPDATE                      40500016
         LA    ERREG1,1(ERREG1)                 RETRY                   41000016
         STC   ERREG1,IOBERRCT                     COUNT                41500016
         CLI   IOBINCAM+1,IRIND                                         42000018
         BE    BSCIR03                                                  42500018
         SVC   EREXCP                   START CHANNEL PROGRAM           43000016
         SVC   RETURN                   NO, RETURN TO IOS               45500016
         SPACE 2                                                        46000016
BSCIR03 LA    SAVREG,LERBADDR          GET LERB ROUTINE ADDR            46500016
         BR    ERRETR                   BRANCH INTO XCTL ROUTINE        47000016
         SPACE 2                                                        47500016
BSCIR04  NI    IOBFLAG1,MASKALL-IOBERR  TURN ON PERM. ERROR INDICATOR   48000016
         CLI   IOBINCAM+1,IRIND         IS LERB REQUIRED                48500016
         BE    BSCIR03                  GO, BRANCH TO LERB              49000016
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            49500016
         BR    ERRETR                                                   50000016
         SPACE 2                                                        50500016
BSCIR05  CLI   0(CCWREG),CCWDIAL        THIS DIAL CCW             M3112 50700018
         BNE   BSCIR00                  NO, POST WITH ERROR       M3112 50900018
         MVI   IOBERCCW,DISABLE         COMMAND CODE DISABLE      M3112 51100018
         MVI   IOBERCCW+7,DISABCNT      MOVE COUNT INTO DISABLE CCW     51500016
         MVI   IOBERCCW+4,SLICCFLG      SLI & CC FLAGS INTO CCW         52000016
         ST    CCWREG,IOBERCCW+8        MOVE FAILING CMD ADDR INTO TIC  52500016
         MVI   IOBERCCW+8,TICCOMMD      MOVE TIC COMMAND CODE INTO CCW  53000016
BSCIR05A LA    CCWREG,IOBERCCW                                          53500016
         SPACE 2                                                        54000016
BSCIR06  ST    CCWREG,IOBSTART          SET CPA ADDR. TO PREPARE        54500016
         B     BSCIR01                                                  55000016
         SPACE 2                                                        55500016
BSCIR07  LA    ERREG2,IOBCPA            UPDATE IOBSTART TO POINT TO     56000016
         ST    ERREG2,IOBSTART            START OF USER CHANNEL PROGRAM 56500016
         L     ERREG1,IOBCPA+8          ADDR OF USER POLLING ENTRY      57000016
         MVC   IOBCPA+9(3),DECENTRY+1   MOVE FAILING ENTRY ADDR TO CCW  57500016
         L     ERREG2,IOBCPA+8          ADDR OF FAILING POLL CCW        58000016
         SR    ERREG1,ERREG2            COUNT BETWEEN USERS AND FAILED  58500016
         AH    ERREG1,IOBCPA+14         ADD TOTAL COUNT FROM USER ENTRY 59000016
         STH   ERREG1,IOBCPA+14        STORE NEW COUNT IN POOL CCW      59500016
         B     BSCIR01                                                  60000016
         SPACE                                                          60500016
BSCIR08  CLC   DECCOUNT(2),6(CCWREG)    RESIDUAL COUNT = ORIGINAL COUNT 61000016
         BNE   BSCIR00                  NO, SET RETRY COUNT TO MAXIMUM  61500016
         B     BSCIR01                  YES, CHECK FOR LERB REQUIRED    62000016
BSCIR09  CLI   IOBCPA,CCWPOLL           OPERATION READ TI W/ MULTIPOINT 62500016
         BNE   BSCIR09A                                                 63000016
         LR    ERREG1,CCWREG            POINT TO CURRENT CCW            63300017
         SH    ERREG1,ERRCON08          BACK UP ONE                     63600017
         L     ERREG1,0(ERREG1)         GET AREA ADDRESS                63900017
         AH    ERREG1,ERRCON01          BUMP BY ONE (INDEX BYTE)        64200017
         C     ERREG1,0(CCWREG)         HAS COUNT BEEN ADJUSTED         64500017
         BE    BSCIR09A                 YES, CONTINUE                   64800017
         ST    ERREG1,0(CCWREG)         NO, RESTORE READ                65100017
         LH    ERREG1,6(CCWREG)         PICK UP COUNT                   65400017
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     65700017
         STH   ERREG1,6(CCWREG)         STORE                           66000017
BSCIR09A LA    ERREG1,IOBWORK+2        ENQ-READ-IN ADDR FOR ERP         67000016
         ST    ERREG1,IOBERCCW          ENQ ADDRESS INTO ERP CCW        67500016
         MVI   IOBERCCW,CCWREAD         READ COMMAND CODE INTO ERP CCW  68000016
         MVI   IOBERCCW+4,SLICCFLG     SLI AND CC FLAGS SET IN CCW      68500016
         MVI   IOBERCCW+7,CCWCOUNT      COUNT FOR READ ENQ IN CCW       69000016
         ST    CCWREG,IOBERCCW+8            AND STORE IN NOP COMMAND    69500016
         MVI   IOBERCCW+8,NOPCC        MOVE NOP COMMAND CODE INTO CCW   70000016
         LA    ERREG1,1                                          A66466 70050021
         ST    ERREG1,IOBERINF+4                                 A66466 70100021
         MVI   IOBWORK+1,RTRNCDE1      SPEC RETURN CODE                 70500016
         MVI   IOBERRCT+1,RTRNSPCD     LINK OFFSET                      71000016
         B     BSCIR05A                                                 71500016
         SPACE 2                                                        72000016
CCWSIZE  DC    H'08'                    SIZE IN BYTES OF CCW            72500016
DEC10    DC    H'10'                    NO. BYTES PER ENTRY IN STATAB   73000016
ERRCON01 DC    H'1'                                                000F 73200016
ERRCON08 DC    H'8'                                                     73300017
TSTIOB   EQU   4                        IOB ADDR OFFSET IN RB           73500016
CVTPTR   EQU   16                       COMM, VECTOR TABLE ADDRESS      74000016
TSTUCB   EQU   2                        OFFSET TO UCB ADDR IN RB        74500016
STATAB   EQU   112                      STATISTICS TABLE PTR IN CVT     75000016
NONAME   EQU   X'00'                                                    75500016
UCBSTI   EQU   9                        LINE ENTRY INDEX IN STATAB      76000016
MASKALL  EQU   X'FF'                                                    76500016
UNUSBIT  EQU   X'C0'                    HI-ORDER BITS OF TP CODE        77000016
CCWDIAL  EQU   X'29'                    COMMAND CODE FOR DIAL           77500016
CCWPREP  EQU   X'06'                    COMMAND CODE FOR PREPARE        78000016
CCWPOLL  EQU   X'09'                    COMMAND CODE FOR POLL           78500016
DURINTXT EQU   X'11'                   CCW DURING TEXT TRANSFER  A26894 79000019
CCWREAD  EQU   X'02'                    COMMAND CODE FOR READ           79500016
BSCDYBUF EQU   X'08'                    DYNAMIC BUFFERING FLAG          80000016
ERRMAX   EQU   7                        MAXIMUM RETRY COUNT IN ERP      80500016
LERBREQ  EQU   X'08'                    FLAG IN DCB INDICATING LERB     81000016
IRIND    EQU   2                                                        81500016
EREXCP   EQU   15                       SVC 15 TO START CHAN.PROGRAM    82000016
RETURN   EQU   3                        SVC 3 TO RETURN TO IOS          82500016
LERBADDR EQU   2042                    LERB ROUTINE ADDR FOR XCTL       83000016
CVTXTLER EQU   44                       XCTL RTN ADDR                   83500016
ERLOD25  EQU   2043                                                     84000016
TPOPCODE EQU   5                        OFFSET TO TP CODE IN CCW        84500016
DISABLE  EQU   X'2F'                    COMMAND CODE FOR DISABLE        85000016
DISABCNT EQU   X'01'                    COUNT FOR DISABLE CCW           85500016
DISABTP  EQU   X'01'                    TP CODE FOR DISABLE             86000016
TICCOMMD EQU   X'08'                    COMMAND CODE FOR TIC            86500016
TPOPENQ  EQU   X'02'                    TP CODE FOR READ ENQ            87000016
NOPCC    EQU   X'03'                                                    87500016
COUNT   EQU   X'01'                                                     88000016
SLICCFLG EQU   X'60'                    SLI & CC FLAGS                  88500016
CCWCOUNT EQU   X'02'                   COUNT FOR READ ENQ CCW IN ERP    89000016
SLIFLAG  EQU   X'20'                    SLI FLAG ALONE                  89500016
CCWWRIT  EQU   X'01'                    COMMAND CODE FOR WRITE CCW      90000016
IOBERR   EQU   X'20'                    PERMANENT ERROR FLAG            90500016
NORMRET  EQU   X'00'                    NORMAL RETURN FLAGS             91000016
RTRNCDE1 EQU   X'81'                                                    91500016
RTRNSPCD EQU   X'14'                                                    92000016
         SPACE 2                                                        92500016
         IECTDECB                                                       93000016
         SPACE 2                                                        93500016
         IECTIOBX                                                       94000016
         SPACE 2                                                        94500016
         DCBD  DSORG=BX,DEVD=BS                                         95000016
         END                                                            95500016
