         TITLE 'IGE0304D OSBTAM BSC COMMAND REJECT ERP ROUTINE'         00700015
IGE0304D CSECT                                                          01400015
*72440007042000,378000-385000,497000-504000,518000-525000,700000,  000C 01600015
*72440007707000,714000,735000                                      000C 01800015
         SPACE 2                                                        02100015
*********************************************************************** 02800015
*                                                                     * 03500015
* STATUS            CHANGE LEVEL  001   NOVEMBER 14, 1967               04200015
*                                                                     * 04900015
* FUNCTION          THIS ROUTINE RECOVERS FROM COMMAND REJECT         * 05600015
*                   CONDITIONS THAT OCCUR DURING BINARY SYNCHRONOUS   * 06300015
*                   OPERATION.  THE CCW THAT IS IN ERROR WITHIN       * 07000015
*                   THE CHANNEL PROGRAM IS DETECTED.  THE PROPER      * 07700015
*                   ERROR RECOVERY PROCEDURE FOR THE TYPE OF          * 08400015
*                   OPERATION BEING EXECUTED IS THEN INITIATED.       * 09100015
*                                                                     * 09800015
* INPUT             INPUT TO THE MODULE IS THROUGH REGISTER 1,        * 10500015
*                   WHICH CONTAINS A POINTER TO THE ASSOCIATED        * 11200015
*                   REQUEST BLOCK.                                    * 11900015
*                                                                     * 12600015
* OUTPUT            SETS INDICATOR IN DECERRST FIELD OF DECB          * 13300015
*                   FOR SHOULD-NOT-OCCUR ERRORS OR INDICATES          * 14000015
*                   PERMANENT ERROR.                                  * 14700015
*                                                                     * 15400015
* ENTRY             ENTRY IS THE FIRST EXECUTABLE INSTRUCTION.        * 16100015
*                                                                     * 16800015
*                                                                     * 17500015
* EXITS             EXITS ARE VIA SVC 15(EREXCP) AND VIA              * 18200015
*                   SVC 3(RETURN) TO RETRY AND RETURN TO IOS;         * 18900015
*                   TO ERROR POST IN CASE OF A PERMANENT ERROR.       * 19600015
*                                                                     * 20300015
* ATTRIBUTES        THIS MODULE IS TRANSIENT, ENABLED, REENTRANT,     * 21000015
*                   AND OPERATES IN THE NUCLEUS ERROR TRANSIENT       * 21700015
*                   AREA WITH A SUPERVISOR PROTECT KEY.               * 22400015
*                                                                     * 23100015
*********************************************************************** 23800015
         SPACE 2                                                        24500015
         USING IECTIOB,IOBRG                 START OF IOB FOR IOB DSECT 25200015
         USING IECTDECB,DECBRG               START OF DECB FOR DECB     25900015
         USING IHADCB,DCBREG                 START OF DCB FOR DCB DSECT 26600015
         USING *,BASREG                                                 27300015
         SPACE 2                                                        28000015
         L     IOBRG,TSTIOB(TSTREG)          ADDRESSABILITY FOR IOB     28700015
         L     COMREG,CVTPTR                 ADDRESS OF CVT TABLE       29400015
         L     DECBRG,IOBECBPT               ADDRESSABILITY FOR DECB    30100015
         L     DCBREG,IOBDCBPT               ADDRESSABILITY FOR DCB     30800015
         L     CCWREG,IOBCSW                 ADDRESS OF CCW             31500015
         SH    CCWREG,ERRCON1                ADJUST TO FAILING CCW      32200015
         SR    ERREG1,ERREG1                 CLEAR LINKAGE REG          32900015
         CLI   IOBERRCT+1,NORMRET            SPECIAL RETURN             33600015
         BNE   BSCCR02                       YES, CHK FOR GOOD WRT DLE  34300015
         CLI   0(CCWREG),CCWRDCMD                 READ COMMAND          35000015
         BNE   BSCCR03                            NO,  INDICATE SNO ERR 35700015
         CLI   DECTPCOD,RDRESPOP                  READ RESP AFTER TEXT  36400015
         BNE   BSCCR03                            NO,  INDICATE SNO ERR 37100015
         MVC   IOBWORK+2(1),DCBBSDLE    PICK UP DLE CHAR           000C 38000015
         MVC   IOBWORK+3(1),DCBBSENQ    PICK UP ENQ CHAR           000C 38300015
         LA    ERREG2,IOBWORK+2         ADDRESS OF AREA            000C 38500015
         LA    ERREG3,CCWWRTCD          FIRST COMMAND CODE         000C 38700015
         LA    ERREG4,NOOP              SECOND COMMAND             000C 38900015
         LA    ERREG1,2                 COUNT                      000C 39100015
         ST    ERREG2,IOBERCCW          SET UP AREA IN CCW         000C 39300015
         STC   ERREG3,IOBERCCW          PUT IN COMMAND             000C 39500015
         STH   ERREG1,IOBERCCW+6        PUT IN COUNT               000C 39700015
         MVI   IOBERCCW+4,CHAINCDE      SET CHAINING               000C 39900015
         STH   CCWREG,IOBERCCW+8        RESTART ADDRESS            000C 40100015
         STC   ERREG4,IOBERCCW+8        SECOND COMMAND             000C 40300015
         ST    ERREG1,IOBERCCW+12       COUNT IN SECOND CCW        000C 40500015
*                                                                     * 41300015
*                   A WRITE DLE-ENQ CCW IS SET IN IOBERCCW            * 42000015
*                   FAILING CCW ADDRESS IS SAVED FOR RESTART          * 42700015
*                                                                     * 43400015
         MVI   IOBERRCT+1,SPECRET                 SPECIAL RETURN SET    44100015
         CLI   IOBERRCT,ERRMAXCT                  RETRIES EXHAUSTED     44800015
         BE    BSCCR03                            YES,  SET PERM ERROR  45500015
         IC    ERREG1,IOBERRCT                    UPDATE RETRY COUNT    46200015
         LA    ERREG1,1(ERREG1)                    TO NEW VALUE         46900015
         STC   ERREG1,IOBERRCT                    STORE IN COUNT FIELD  47600015
         LA    WORKREG,IOBERCCW                   ADDRESS OF DUMMY CCW  48300015
         ST    WORKREG,IOBSTART                   TO CHAN PROG POINTER  49000015
         SVC   EREXCP                             EXECUTE CHANNEL PROG  51100015
         SVC   RETURN                             EXIT VIA POST         53200015
         SPACE 2                                                        53900015
BSCCR03  NI    IOBFLAG1,MASKALL-IOBERR            INDICATE PERM ERROR   54600015
         MVI   IOBERRCT,ERRMAXCT       INDICATE NO RETRIES         000C 54900015
         LH    SAVREG,ERLOD5C                     ADDR OF ERROR POST    55300015
         L     ERRETR,VECTXL(COMREG)              ADDR OF XCTL ROUTINE  56000015
         BR    ERRETR                             EXIT VIA XCTL         56700015
         SPACE 2                                                        57400015
BSCCR02  TM    IOBCSW+4,MASKALL-CSWCDE            ANY COND BUT CE-DE    58100015
         BM    BSCCR03                            YES, PERMANENT ERROR  58800015
         TM    IOBCSW+4,CSWCDE                    CHAN END AND DEV END  59500015
         BNO   BSCCR03                            NO,  PERMANENT ERROR  60200015
         CLI   IOBCSW+5,NONAME                    ANY STATUS IN BYTE 2  60900015
         BNE   BSCCR03                            YES, PERMANENT ERROR  61600015
         MVC   IOBSTART+1(3),IOBERCCW+9      WRT DLE-ENQ WAS GOOD       62300015
         MVI   IOBERRCT+1,NORMRET                 NORMAL RETURN. RETRY  63000015
*                                                  THE FAILING CCW      63700015
         SVC   EREXCP                             EXECUTE CHANNEL PROG  65800015
         SVC   RETURN                             EXIT VIA POST         68600015
         SPACE 2                                                        69300015
ERLOD5C  DC    H'5043'                            BSC ERROR POST I.D.   72100015
ERRCON1  DC    AL2(8)                             DECIMAL EIGHT         72800015
CCWRDCMD EQU   X'02'                              READ COMMAND CODE     74200015
CCWWRTCD EQU   X'01'                              WRITE COMMAND CODE    74900015
CSWCDE   EQU   X'0C'                              CHAN-DEVICE END       75600015
CVTPTR   EQU   16                                 CVT TABLE LOCATION    76300015
EREXCP   EQU   15                                 EXCP SVC CALL         77000015
ERRMAXCT EQU   X'07'                              MAX RETRY COUNT       77700015
IOBERR   EQU   X'20'                              IOB ERROR FLAG        78400015
NOOP     EQU   X'03'                                               000C 78700015
IOBEX    EQU   X'04'                              EXCEPTION FLAG        79100015
IOBEXE   EQU   IOBERR+IOBEX                       ERR & EXCEPTION FLAGS 79800015
MASKALL  EQU   X'FF'                              ALL FLAGS ON MASK     80500015
NONAME   EQU   X'00'                              NO FLAGS ON           81200015
NORMRET  EQU   X'00'                              NORMAL RETURN         81900015
RETURN   EQU   3                                  EXIT SVC CALL         82600015
RDRESPOP EQU   X'25'                              BSC RD RESP AFTER TXT 83300015
SPECRET  EQU   X'04'                              SPECIAL RETURN CMDREJ 84000015
CHAINCDE EQU   X'60'                                               000C 84200015
CCWCOUNT EQU   X'02'                                               000C 84400015
TSTIOB   EQU   4                                  TWELVE STAR OFFSET    84700015
VECTXL   EQU   44                                 XCTL ADDR OFFSET      85400015
         SPACE 2                                                        86100015
TSTREG   EQU   1                                  TWELVE STAR REG       86800015
ERREG1   EQU   2                                  WORK REG              87500015
ERREG2   EQU   3                                  WORK REG              88200015
CCWREG   EQU   4                                  CCW ADDRESS REG       88900015
DECBRG   EQU   5                                  DECB ADDRESS REG      89600015
DCBREG   EQU   6                                  DCB ADDRESS REG       90300015
ERREG3   EQU   7                                                   000C 90600015
COMREG   EQU   8                                  CVT ADDRESS REG       91000015
WORKREG  EQU   9                                  WORK REG              91700015
IOBRG    EQU   10                                 IOB ADDRESS REG       92400015
ERREG4   EQU   11                                                  000C 92700015
SAVREG   EQU   13                                 SAVE ADDRESS REG      93100015
ERRETR   EQU   14                                 RETURN REG            93800015
BASREG   EQU   15                                 BASE ADDRESS REG      94500015
         IECTDECB                                                  000C 94600015
         IECTIOBX                                                  000C 94700015
         DCBD  DSORG=BX,DEVD=BS                                    000C 94800015
         END                                                            95200015
