         TITLE 'IGE0404A - BTAM ERP LOST DATA MODULE'                   00020000
IGE0404A CSECT                                                          00040000
         SPACE 2                                                        00060000
*********************************************************************** 00080000
* STATUS -          CHANGE LEVEL 000   JANUARY 21, 1967                 00100000
*                                                                     * 00120000
* FUNCTION-        IF REQUIRED, RETRIES CHANNEL PROGRAM THAT FAILED   * 00140000
*                  BECAUSE OF A LOST DATA CONDITION. LINKS TO DISABLE * 00160000
*                  ROUTINE OR POST ROUTINE.                           * 00180000
*                                                                     * 00200000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 00220000
*                  TO THE ASSOCIATED IO RB.                           * 00240000
*                                                                     * 00260000
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 00280000
*                  ERROR.                                             * 00300000
*                                                                     * 00320000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 00340000
*                                                                     * 00360000
* EXITS-           EXITS THROUGH LINKAGE OT MODULE IGE0304A AND       * 00380000
*                  IGE0504A.                                          * 00400000
*                                                                     * 00420000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 00440000
*********************************************************************** 00460000
         SPACE 2                                                        00480000
*              LOST DATA ERROR RECOVERY ROUTINE                         00500000
         USING *,BASREG                                                 00520000
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  00540000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  00560000
         L     COMREG,LOC016            ADDRESS OF CVT                  00580000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 00600000
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  00620000
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           00640000
         MVC   IOBWRK(1,IOBRG),TPCODE(CCWREG) PUT TP OP CODE IN WORK    00660000
         NI    IOBWRK(IOBRG),MASKALL-CCWMASK1 MASK OUT UNUSED BITS      00680000
         CLI   0(CCWREG),CCWDIAL        THIS A DIAL COMMAND             00700000
         BNE   ERRLDC02                 NO CHECK FOR READ               00720000
ERRLDC00 CLI   IOBECT(IOBRG),ERTRYCT    RETRY AGAIN                     00740000
         BNL   ERRLDC04                 NO CHECK FOR SWITCHED LINE      00760000
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             00780000
         LA    ERREG1,1(ERREG1)        INCREMENT RETRY COUNT     A41127 00800021
ERRLDC01 STC   ERREG1,IOBECT(IOBRG)     RETRY CHANNEL PROG              00820000
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                00840000
         SVC   EXCPER                                                   00860000
         SVC   RETURN                   RETURN                          00880000
ERRLDC02 CLI   0(CCWREG),CCWRDCMD       THIS A READ COMMAND             00900000
         BE    ERRLDC03                 YES CHECK IF READ TWX           00920000
         CLI   0(CCWREG),CCWINHCD       THIS AN INHIBIT COMMAND         00940000
         BNE   ERRLDC05                 NO INDICATE SHOULD NOT OCCUR    00960000
ERRLDC03 CLI   IOBWRK(IOBRG),CCWTWXID   THIS A READ TWX ID RESPONSE     00980000
         BE    ERRLDC00                 YES CHECK FOR RETRY REQUIRED    01000000
         CLI   IOBWRK(IOBRG),CCWRRADR   THIS A READ RESPONSE TO ADDRESS 01020000
         BE    ERRLDC06                 YES SET UP TO RETRY CHAN PROG   01040000
         MVC   IOBERINF(1,IOBRG),IOBSNS(IOBRG) SAVE PRIOR SENSE DATA    01060000
         MVC   IOBERINF+1(7,IOBRG),IOBCSW+1(IOBRG) SAVE PRIOR CSW DATA  01080000
         MVC   IOBERINF+8(8,IOBRG),0(CCWREG) SAVE FAILING CCW           01100000
         LA    ERREG1,IOBDCCW(IOBRG)    ADDRESS OF DUMMY CCW            01120000
         ST    ERREG1,IOBSTART(IOBRG)   POINTER TO CHAN PROGRAM         01140000
         CLI   IOBWRK(IOBRG),CCWRDTXT   THIS A READ TEXT                01160000
         BE    ERRLDC10                 YES CHECK RESIDUAL COUNT        01180000
         CLI   IOBWRK(IOBRG),CCWRRTXT   THIS A READ RESPONSE TO TEXT    01200000
         BE    ERRLDC11                 YES SET UP READ SKIP OPERATION  01220000
         CLI   IOBWRK(IOBRG),CCWRDSKP   THIS A READ SKIP                01240000
         BNE   ERRLDC05                 INDICATE SHOULD NOT OCCURA32452 01270020
ERRLDC10 CLC   IOBCSW+6(2,IOBRG),ERRHLF00 RESIDUAL COUNT = 0            01300000
         BNE   ERRLDC05                 NO INDICATE SHOULD NOT OCCUR    01320000
         MVC   IOBWRK+1(1,IOBRG),UCBTYP+3(UCBREG) ADAPTER TYPE TO WORK  01340000
         NI    IOBWRK+1(IOBRG),MASK3    CLEAR UNWANTED BITS             01360000
         CLI   IOBWRK+1(IOBRG),UCBTTYP1 THIS A TELETYPE ADAPTER 1       01380000
         BE    ERRLDC12                 YES WRITE BREAK REQUIRED        01400000
         CLI   IOBWRK(IOBRG),CCWRDSKP   THIS A READ SKIP         A32452 01420020
         BE    ERRLDC04                 YES, CHK FOR SWITCH LINE A32452 01440020
         CLI   IOBWRK+1(IOBRG),ADAPT8   THIS A 2260              A38545 01446020
         BE    ERRLDC14                 YES, ISSUE READ CLEAR    A38545 01452020
ERRLDC11 SR    ERREG1,ERREG1            CLEAR REGISTER                  01460000
         ST    ERREG1,IOBDCCW(IOBRG)    CLEAR DUMMY CCW                 01480000
         MVI   IOBDCCW(IOBRG),CCWRDCMD  PUT READ COMMAND IN CCW         01500000
         MVI   IOBDCCW+4(IOBRG),RDSKPIND PUT SKIP INDICATOR IN CCW      01520000
         LA    CRBREG,1                                                 01540000
         SR    ERREG1,CRBREG                                            01560000
         STH   ERREG1,IOBDCCW+6(IOBRG)  PUT READ COUNT IN CCW           01580000
         MVI   IOBDCCW+5(IOBRG),X'30'  SET TPOP CODE             A27610 01590019
         B     ERRLDC13                 EXIT VIA ERROR EXCP ROUTINE     01600000
ERRLDC14 EQU   *                                                 A38545 01605020
         MVC   IOBDCCW(8,IOBRG),RDCL2848 SET UP RD CLEAR         A38545 01610020
         B     ERRLDC13                 COMPLETE CHAN PROGRAM    A38545 01615020
ERRLDC12 ST    IOBRG,IOBDCCW(IOBRG)     GENERATE LEGAL DATA ADDRESS     01620000
         MVI   IOBDCCW(IOBRG),WRTBKCMD  PUT WRITE BREAK COMMAND IN CCW  01640000
         LA    ERREG1,MASK15            BREAK COUNT                     01660000
         ST    ERREG1,IOBDCCW+4(IOBRG)  PUT IN CCW AND CLEAR REST       01680000
         MVI   IOBDCCW+4(IOBRG),SILLYBIT SET SUPPRESS LENGTH INDICATOR  01700000
ERRLDC13 MVI   IOBECT+1(IOBRG),ERRLDIND INDICATE LOST DATA RETURN       01720000
         MVI   IOBSNS(IOBRG),NONAME     CLEAR PREVIOUS SENSE DATA       01740000
         SR    ERREG1,ERREG1            CLEAR REGISTER           A24926 01741018
         L     ERREG2,STATAB(COMREG)    SDR TABLE POINTER        A24926 01742018
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY     A24926 01743018
         LR    ERREG4,ERREG2            SAVE START ADDRESS       A24926 01744018
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED         A24926 01745018
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY  A24926 01746018
         LA    ERREG4,2(ERREG4)         INCREMENT TO NEXT ENTRY  A24926 01747018
         LA    ERREG1,256(ERREG1)       INCREMENT TO NEXT SECT   A24926 01748018
         B     ERRLOOP1                 LOOP TO CHECK IT         A24926 01749018
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR LENGTH        A24926 01750018
         AR    ERREG2,ERREG1            FINAL ADDRESS            A24926 01751018
         OC    8(1,ERREG2),IOBERINF(IOBRG) OR IN SENSE INFO      A24926 01752018
         SVC   EXCPER                                                   01760000
         SVC   RETURN                                                   01780000
ERRLDC04 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                01800000
         BZ    ERRLDC09                 NO GO TO ERROR POST             01820000
         MVI   IOBECT+1(IOBRG),MASK3    INDICATE SPECIAL ENTRY          01840000
         LA    SAVREG,ERLOD3            DISABLE CHECK ROUTINE ADDRESS   01860000
ERRLINK1 L     ERRETR,VECTXL(COMREG)    LINK ROUTINE                    01880000
         BR    ERRETR                   LINK                            01900000
ERRLDC05 OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 01920000
         B     ERRLDC04                 CHECK FOR DISABLE REQUIRED      01940000
ERRLDC06 CLI   IOBCPA(IOBRG),CCWDISAB   FIRST CCW DISABLE COMMAND       01960000
         BE    ERRLDC08                 YES SET CPA TO THIRD COMMAND    01980000
         LA    ERREG1,IOBCPA(IOBRG)     SET CPA TO START OF CHAN PROG   02000000
ERRLDC07 ST    ERREG1,IOBSTART(IOBRG)   STORE CPA POINTER               02020000
         B     ERRLDC00                 CHECK FOR RETRY REQUIRED        02040000
ERRLDC08 LA    ERREG1,IOBCMD3(IOBRG)    ADDRESS OF THIRD COMMAND        02060000
         B     ERRLDC07                 CHECK FOR RETRY REQUIRED        02080000
ERRLDC09 LH    SAVREG,ERLOD5            ADDRESS OF ERROR POST ROUTINE   02100000
         B     ERRLINK1                                                 02120000
ADAPT8   EQU   X'80'                                             A38545 02121020
RDCL2848 DC    X'42000001303003C0'      READ CLEAR               A38545 02122020
STATAB   EQU   112                                                      02125018
UCBSTI   EQU   9                                                        02130018
ERRCN2   DC    H'10'                                                    02135018
IOBERINF EQU   48                                                       02140000
IOBDCCW  EQU   40                                                       02160000
CCWRDTXT EQU   X'11'                                                    02180000
CCWRRTXT EQU   X'20'                                                    02200000
CCWRDSKP EQU   X'12'                                                    02220000
ERRHLF00 DC    H'00'                                                    02240000
UCBTTYP1 EQU   X'40'                                                    02260000
UCBTTYP2 EQU   X'50'                                                    02280000
WRTBKCMD EQU   X'0D'                                                    02300000
ERRLDIND EQU   X'08'                                                    02320000
MASK15   EQU   X'0F'                                                    02340000
UCBTYP   EQU   16                                                       02360000
SWLINE   EQU   X'90'                                                    02380000
CCWDIAL  EQU   X'29'                                                    02400000
CCWDISAB EQU   X'2F'                                                    02420000
CCWMASK1 EQU   X'C0'                                                    02440000
CCWRDCMD EQU   X'02'                                                    02460000
CCWRRADR EQU   X'06'                                                    02480000
CCWINHCD EQU   X'0A'                                                    02500000
TSTIOB   EQU   4                                                        02520000
TSTUCB   EQU   2                                                        02540000
LOC016   EQU   16                                                       02560000
IOBCSW   EQU   8                                                        02580000
IOBSNS   EQU   2                                                        02600000
EXCPER   EQU   15                                                       02620000
ERRCN8   DC    AL2(8)                                                   02640000
IOBWRK   EQU   33                                                       02660000
TPCODE   EQU   5                                                        02680000
MASKALL  EQU   X'FF'                                                    02700000
IOBECT   EQU   30                                                       02720000
RDSKPIND EQU   X'30'                                                    02740000
SILLYBIT EQU   X'20'                                                    02760000
ERTRYCT  EQU   X'02'                                                    02780000
RETURN   EQU   3                                                        02800000
MASK3    EQU   X'F0'                                                    02820000
ERLOD3   EQU   3041                                                     02840000
VECTXL   EQU   44                                                       02860000
NONAME   EQU   X'00'                                                    02880000
IOBDECB  EQU   4                                                        02900000
DECERRST EQU   29                                                       02920000
IOBCPA   EQU   64                                                       02940000
IOBSTART EQU   16                                                       02960000
IOBCMD3  EQU   IOBCPA+16                                                02980000
CCWTWXID EQU   X'07'                                                    03000000
ERLOD5   DC    AL2(5041)                                                03020000
CSWSNO   EQU   X'40'                                                    03040000
*        REGISTER DEFINITION                                            03060000
ERREG3   EQU   0                             W69K REG                   03080000
TSTREG   EQU   1                             TWELVE STAR REG            03100000
ERREG2   EQU   2                             WORK REG                   03120000
CRBREG   EQU   3                             CURRENT RB REG             03140000
CCWREG   EQU   4                             CCW ADDRESS REG            03160000
DECBRG   EQU   5                        DECB REGISTER                   03180000
DCBREG   EQU   6                        DCB REGISTER                    03200000
UCBREG   EQU   7                             UCB ADDRESS  REG           03220000
COMREG   EQU   8                             COMMUNICATION TABLE REG    03240000
ERREG1   EQU   9                                                        03260000
IOBRG    EQU   10                            IOB ADDRESS REG            03280000
ERREG4   EQU   11                            WORK R57                   03300000
ERRLNK   EQU   12                            LINK REG                   03320000
SAVREG   EQU   13                                                       03340000
ERRETR   EQU   14                            RETURN REG                 03360000
BASREG   EQU   15                            BASE REG                   03380000
         END                                                            03400000
