         TITLE 'IGE0404B - BTAM ERP RD/SKP WRT/BRK CHECK LOAD TWO'      00500013
IGE0404B CSECT                                                          01000013
*126401400700                                                      000A 01500013
         SPACE 2                                                        02000013
*********************************************************************** 02500013
* STATUS -          CHANGE LEVEL 001    APRIL 25, 1967                  03000013
*                                                                     * 03500013
* FUNCTION-        THIS MODULE DETERMINES IF A READ COMMAND WAS ISSUED* 04000013
*                  A CHANNEL PROGRAM IS CONSTRUCTED AND EXECUTED IF   * 04500013
*                  REQUIRED.  ERRORS ARE RECORDED AND LINKAGE IS      * 05000013
*                  PROVIDED TO THE READ/SKIP-WRITE/BREAK ROUTINE,     * 05500013
*                  INTERVENTION REQUIRED ROUTINE, AND ERROR POST      * 06000013
*                  ROUTINE.                                           * 06500013
*                                                                     * 07000013
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 07500013
*                  TO THE ASSOCIATED IO RB.                           * 08000013
*                                                                     * 08500013
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 09000013
*                  ERROR.  SETS INDICATOR FOR ERROR IN ERP EXCP.      * 09500013
*                                                                     * 10000013
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 10500013
*                                                                     * 11000013
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0404B,         * 11500013
*                  IGE0304A, AND IGE0504A.                            * 12000013
*                                                                     * 12500013
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 13000013
*********************************************************************** 13500013
         SPACE 2                                                        14000013
         USING *,BASREG                                                 14500013
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  15000013
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  15500013
         L     COMREG,LOC016            ADDRESS OF CVT                  16000013
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  16500013
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 17000013
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  17500013
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           18000013
ERRCHK11 CLI   0(CCWREG),CCWRDCMD       WAS A READ ISSUED               18500013
         BNE   ERRCHK10                 NO POST COMPLETE WITH ERROR     19000013
         TM    DCBERROP(DCBREG),DCBRDTRY READ RETRIES REQUIRED          19500013
         BZ    ERRCHK10                 NO POST COMPLETE WITH ERROR     20000013
         CLI   IOBCSW+4(IOBRG),CSWCDE   CHANNEL END DEVICE END ONLY     20500013
         BNE   ERRCHK13                 NO CHECK FURTHER                21000013
         CLI   IOBCSW+5(IOBRG),NONAME   ANY OTHER ERROR                 21500013
         BNE   ERRCHK10                 YES POST COMPLETE WITH ERROR    22000013
ERRCHK14 MVC   IOBWRK+1(1,IOBRG),DECTYPE+1(DECBRG)               A32445 22500020
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS          23000013
         TM    IOBWRK+1(IOBRG),READ     IS OPERATION READ          9362 23100017
         BZ    ERRCHK10                 NO, POST WITH ERROR        9362 23200017
         CLI   IOBWRK+1(IOBRG),DECRDRPT OPERATION TYPE READ REPEAT      23500013
         BNE   ERRCHK12                 NO CONSTRUCT CHAN PROGRAM       24000013
         TM    4(CCWREG),X'10'         IS THIS READ SKIP         A30752 24080020
         BNO   ERRCHK23                NO, START CHAN PROGRAM    A30752 24160020
         TM    IOBSNS(IOBRG),X'08'     IS THERE DATA CHAINING    A30752 24240020
         BO    ERRCHK10                YES,POST WITH ERROR       A30752 24320020
ERRCHK23 EQU   *                                                 A30752 24400020
         LA    ERREG2,IOBCPA(IOBRG)     START OF CHAN PROGRAM           24500013
         B     ERRCHK04                 EXECUTE CHAN PROGRAM            25000013
ERRCHK12 EQU   *                                                        25500013
         L     ERREG4,DECAREA(DECBRG)   SAVE AREA ADDRESS          0387 25520017
         LH    ERREG3,DECLNGTH(DECBRG)  SAVE AREA LENGTH           0387 25540017
         CLI   IOBWRK+1(IOBRG),DECRDINT OPERATION READ INITIAL     0387 25560017
         BNE   ERRCHK20                 NO, DON'T SET DECB         0387 25580017
         TM    UCBTYP+1(UCBREG),AUTOPOLL                         A46824 25600021
         BNO   ERRCHK20                                          A46824 25610021
         CLI   IOBCPA(IOBRG),X'09'                               A46824 25620021
         BNE   ERRCHK20                                          A46824 25630021
         TM    5(CCWREG),X'30'                                   A46824 25640021
         BZ    ERRCHK10                                          A46824 25650021
         L     ERREG3,DECAREA(DECBRG)                            A46824 25660021
         MVC   DECPOLPT(1,DECBRG),0(ERREG3)                             25670021
ERRCHK22 LR    ERREG3,ERREG4            SAVE AREA ADDRESS          0387 25680017
         AH    ERREG3,ERRCN1            ADD ONE TO ADDRESS         0387 25700017
         ST    ERREG3,DECAREA(DECBRG)   UPDATE DECB                0387 25720017
         LH    ERREG3,DECLNGTH(DECBRG)  PICK UP AREA LENGTH        0387 25740017
         BCTR  ERREG3,0                 REDUCE BY ONE              0387 25760017
         STH   ERREG3,DECLNGTH(DECBRG)  UPDATE DECB                0387 25780017
         AH    ERREG3,ERRCN1            RESTORE LENGTH             0387 25800017
ERRCHK20 EQU   *                                                   0387 25820017
         LR    ERREG2,BASREG            SAVE BASE                       26000013
         LR    ERREG1,TSTREG            SAVE RB POINTER                 26500013
         LA    SAVREG,SAVEAREA-12       ADDRESS OF REGISTER SAVE AREA   27000013
         LR    TSTREG,DECBRG            DECB ADDRESS IN PARAMETER REG   27500013
         NI    DECTYPE+1(DECBRG),HIBIT  CLEAR OP TYPE CODE              28000013
         OI    DECTYPE+1(DECBRG),DECRDRPT INDICATE READ REPEAT          28500013
         OI    28(IOBRG),X'08'          SET ERP FLAG FOR RD/WR   A23900 28700018
         READ  (1),T,MF=E               CONSTRUCT CHAN PROGRAM          29000013
         LR    BASREG,ERREG2            RESTORE BASE                    29500013
         LR    TSTREG,ERREG1            RESTORE RB POINTER              30000013
         NI    28(IOBRG),MASKALL-X'08'  ERP RD/WR FLAG OFF       A23900 30050018
         ST    ERREG4,DECAREA(DECBRG)   RESET DECB                 0387 30100017
         STH   ERREG3,DECLNGTH(DECBRG)  RESET DECB                 0387 30200017
         B     ERRCHK05                 UPDATE RETRY COUNT              30500013
ERRCHK13 CLI   IOBCSW+4(IOBRG),CSWCDEUC CHAN AND DEV END WITH UNIT CHK. 31000013
         BNE   ERRCHK10                 NO POST COMPLETE WITH ERROR     31500013
         TM    IOBSNS(IOBRG),MASKALL-CSWLDDCO EXPECTED ERROR            32000013
         BNZ   ERRCHK10                 NO POST COMPLETE WITH ERROR     32500013
         TM    IOBSNS(IOBRG),CSWLD      LOST DATA ERROR                 33000013
         BZ    ERRCHK14                 NO CHECK FOR RETRIES            33500013
         CLC   6(2,CCWREG),ERRCN0       RESIDUAL COUNT 0                34000013
         BE    ERRCHK10                 YES POST WITH ERROR             34500013
         B     ERRCHK14                 NO CHECK FOR RETRIES            35000013
ERRCHK04 ST    ERREG2,IOBSTART(IOBRG)   SET CPA TO FAILING CCW     000A 35500013
ERRCHK05 CLI   IOBECT(IOBRG),ERTRYCT    MORE RETRIES NECESSARY          36000013
         BNL   ERRCHK07               NO CHECK FOR DISABLE REQUIRED     36500013
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             37000013
         LA    ERREG1,1(ERREG1)         BUMP COUNT BY ONE               37500013
         STC   ERREG1,IOBECT(IOBRG)     STORE NEW COUNT                 38000013
         MVI   IOBECT+1(IOBRG),NONAME   INDICATE NORMAL RETURN          38500013
         SR    ERREG1,ERREG1            CLEAR REGISTER                  39000013
         L     ERREG2,STATAB(COMREG)    SDR TABLE POINTER               39500013
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY            40000013
         LR    ERREG4,ERREG2            SAVE STAT TABLE START ADDR 000H 40100017
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED THIS SECT 000H 40200017
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 40300017
         LA    ERREG4,2(ERREG4)         POINT TO NXT CTL ENTRY     000H 40400017
         LA    ERREG1,256(ERREG1)       POINT TO NXT STAT TBL SECT 000H 40500017
         B     ERRLOOP1                 LOOP TO CHECK THIS SECTION 000H 40600017
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR ENTRY LENGTH    000H 40700017
         AR    ERREG2,ERREG1            RESOLVE FINAL ADDRESS           41000013
         OC    8(1,ERREG2),IOBERINF(IOBRG) RECORD TEMPORARY ERRORS      41500013
         SVC   EXCPER                   EXECUTE CHAN PROG.              42000013
         SVC   RETURN                   EXIT                            42500013
ERRCHK06 TM    DCBBFTEK(DCBREG),DCBDYNBF DYNAMIC BUFFERING SPECIFIED    43000013
         BO    ERRCHK10                 YES POST COMPLETE WITH ERROR    43500013
         LA    ERREG2,IOBCPA(IOBRG)     SET CPA TO START OF CHAN PROG.  44000013
         B     ERRCHK04                 RETRY CHAN PROGRAM              44500013
ERRCHK07 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                45000013
         BZ    ERRCHK10                 NO POST WITH ERROR              45500013
         LA    SAVREG,ERLOD3            ADDRESS OF DISABLE ROUTINE      46000013
ERRCHK08 L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         46500013
         BR    ERRETR                   EXIT                            47000013
ERRCHK19 OI    DECERRST(DECBRG),DECERPER INDICATE ERROR IN ERP EXCP     47500013
ERRCHK09 OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR       48000013
ERRCHK10 MVI   IOBCSW+4(IOBRG),CSWCDE   SET UP SPECIAL ENTRY TO POST    48500013
         MVI   IOBECT+1(IOBRG),RTRNCDE  FAKE OUT POST ROUTINE           49000013
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE OBR REQUIRED           49500013
         LH    SAVREG,ERLOD5            ADDRESS OF ERROR POST           50000013
         B     ERRCHK08                 LINK TO POST ROUTINE            50500013
AUTOPOLL EQU   X'40'                                                    50560021
DECPOLPT EQU   36                                                       50620021
READ     EQU   X'01'                                               9362 50700017
TSTIOB   EQU   4                                                        51000013
TSTUCB   EQU   2                                                        51500013
LOC016   EQU   16                                                       52000013
IOBDCBAD EQU   20                                                       52500013
IOBDECB  EQU   4                                                        53000013
IOBCSW   EQU   8                                                        53500013
ERRCN8   DC    H'8'                                                     54000013
CCWWRTBK EQU   X'0D'                                                    54500013
MASKALL  EQU   X'FF'                                                    55000013
CSWCDE   EQU   X'0C'                                                    55500013
NONAME   EQU   X'00'                                                    56000013
CSWCDEUC EQU   X'0E'                                                    56500013
IOBSNDC  EQU   X'80'                                                    57000013
IOBSNOVR EQU   X'40'                                                    57500013
IOBSNS   EQU   2                                                        58000013
MASK15   EQU   X'0F'                                                    58500013
EXCPER   EQU   15                                                       59000013
RETURN   EQU   3                                                        59500013
IOBECT   EQU   30                                                       60000013
ERRLDIND EQU   X'08'                                                    60500013
DCBBFTEK EQU   32                                                       61000013
DCBDYNBF EQU   X'08'                                                    61500013
DECERPER EQU   X'20'                                                    62000013
CSWSNO   EQU   X'40'                                                    62500013
IOBERINF EQU   48                                                       63000013
DECERRST EQU   29                                                       63500013
ERRCN0   DC    F'0'                                                     63600017
ERRCN1   DC    H'1'                                                     63700017
DECAREA  EQU   12                                                       63800017
DECLNGTH EQU   6                                                        63900017
DECENTRY EQU   32                                                       64000017
DECRDINT EQU   X'01'                                                    64100017
NOT1050D EQU   X'0E'                                                    64200017
NOT1050A EQU   X'E0'                                                    64300017
ERRCN2   DC    H'10'                                                    64500013
IOBWRK   EQU   33                                                       65000013
TPCODE   EQU   5                                                        65500013
HIBIT    EQU   X'C0'                                                    66000013
CCWAFTXT EQU   X'20'                                                    66500013
IOBSTART EQU   16                                                       67000013
RTRNCDE  EQU   X'80'                                                    67500013
ERTRYCT  EQU   X'02'                                                    68000013
STATAB   EQU   112                                                      68500013
UCBSTI   EQU   9                                                        69000013
DECTYPE  EQU   4                                                        69500013
DECDYNBF EQU   X'80'                                                    70000013
IOBCPA   EQU   64                                                       70500013
UCBTYP   EQU   16                                                       71000013
SWLINE   EQU   X'90'                                                    71500013
ERLOD3   EQU   3041                                                     72000013
VECTXL   EQU   44                                                       72500013
IOBLOG   EQU   X'01'                                                    73000013
IOBFL3   EQU   8                                                        73500013
ERLOD5   DC    H'5041'                                                  74000013
CCWRDCMD EQU   X'02'                                                    74500013
DCBERROP EQU   33                                                       75000013
DCBRDTRY EQU   X'02'                                                    75500013
DECRDRPT EQU   X'07'                                                    76000013
SAVEAREA DC    16F'0'                                                   76500013
CSWLDDCO EQU   X'0E'                                                    77000013
CSWLD    EQU   X'02'                                                    77500013
ERLOD14  EQU   4042                                                     78000013
*        REGISTER DEFINITION                                            78500013
ERREG3   EQU   0                             W69K REG                   79000013
TSTREG   EQU   1                             TWELVE STAR REG            79500013
ERREG2   EQU   2                             WORK REG                   80000013
CRBREG   EQU   3                             CURRENT RB REG             80500013
CCWREG   EQU   4                             CCW ADDRESS REG            81000013
DECBRG   EQU   5                        DECB REGISTER                   81500013
DCBREG   EQU   6                        DCB REGISTER                    82000013
UCBREG   EQU   7                             UCB ADDRESS  REG           82500013
COMREG   EQU   8                             COMMUNICATION TABLE REG    83000013
ERREG1   EQU   9                                                        83500013
IOBRG    EQU   10                       IOB BASE REGISTER               84000013
ERREG4   EQU   11                            WORK R57                   84500013
ERRLNK   EQU   12                            LINK REG                   85000013
SAVREG   EQU   13                                                       85500013
ERRETR   EQU   14                            RETURN REG                 86000013
BASREG   EQU   15                            BASE REG                   86500013
         END                                                            87000013
