         TITLE 'IGE0504A - BTAM ERP ERROR POST MODULE'                  00020000
IGE0504A CSECT                                                          00040000
*12650073,0337                                                          00060000
         SPACE 2                                                        00080000
*********************************************************************** 00100000
* STATUS -          CHANGE LEVEL 000    JANUARY 16, 1967                00120000
*                                                                     * 00140000
* FUNCTION-        PERFORMS ERROR MESSAGE WRITING AND MESSAGE         * 00160000
*                  CONSTRUCTION FOR ALL BTAM ERP ROUTINES.  CHECKS    * 00180000
*                  RESULTS OF DIAGNOSTIC WRITE/READ FOR 2701 ADAPTER  * 00200000
*                  UNIT.  INDICATES ERROR STATUS FOUND IN DECERRST    * 00220000
*                  FIELD OF DECB.  POSTS COMPLETE WITH ERROR.  THIS   * 00240000
*                  MODULE IS ENTERED ONLY FOR PERMANENT ERRORS.       * 00260000
*                                                                     * 00280000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 00300000
*                  TO THE ASSOCIATED IO RB.                           * 00320000
*                                                                     * 00340000
* OUTPUT-          SETS THE FOLLOWING INDICATORS IN DECERRST.         * 00360000
*                  1.  ENABLE FAILED.                                 * 00380000
*                  2.  DIAGNOSTIC WRITE/READ FAILED.                  * 00400000
*C016615-016625                                                  A43789 00410021
*                  3.  DISABLE FAILED.                                * 00420000
*                                                                     * 00440000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 00460000
*                                                                     * 00480000
* EXITS-           EXITS THROUGH RETURN SVC.                          * 00500000
*                                                                     * 00520000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 00540000
*********************************************************************** 00560000
         SPACE 2                                                        00580000
         USING *,15                                                     00600000
         L     IOBRG,TSTIOB-1(TSTREG)   ADDR OF IOB                     00620000
         LH    UCBREG,TSTUCB(TSTREG)    ADDR OF UCB                     00640000
         L     CCWREG,IOBCSW(IOBRG)     ADDR OF CCW+8                   00660000
         SH    CCWREG,ERRCN1            ADJUST TO REAL CCW              00680000
         L     COMREG,LOC016            ADDR OF CVT                     00700000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 00720000
         XC    IOBRST-1(4,IOBRG),IOBRST-1(IOBRG) CLR XTENDED MSG AREA   00740000
         MVI   IOBSNS+1(IOBRG),X'00'                               9854 00760000
         MVI   UCBSNS+1(UCBREG),X'FF'                              9854 00780000
         SR    ERREG1,ERREG1            INITIALIZE WORK                 00800000
         LA    ERRLNK,1                                                 00820000
         IC    ERREG1,IOBECT+1(IOBRG)   PICK UP ENTRY INDEX             00840000
         SRL   ERREG1,4                 ADJUST INDEX VALUE              00860000
         B     ERRPST1(ERREG1)          BRANCH VIA BRANCH TQBLE         00880000
ERRPST1  B     ERRPST                   NORMAL POST                     00900000
         B     ERRPST                  TERM ID BYPASS              3891 00920018
         B     ERRPST6                  DISABLE RESTORE                 00940000
         NI    5(CCWREG),MASK2          SETUP TO DETERMINE FAILING CCW  00960000
         IC    ERREG1,5(CCWREG)         INDEX VALUE                     00980000
         B     ERRPST2(ERREG1)          ENTRY TO ERROR ROUTINE          01000000
ERRPST2  B     ERRPST3                  DISABLE FAILED                  01020000
         B     ERRPST4                  DIAG WRITE FAILED               01040000
         B     ERRPST5                  DIAG READ FAILED                01060000
         CLI   IOBCSW+4(IOBRG),CSWCDE   CHAN AND DEV END ONLY           01080000
         BNE   ERRPST21                 NO INDICATE ERROR               01100000
         TM    IOBCSW+5(IOBRG),MASKALL  CHECK SECOND STATUS BYTE        01120000
         BZ    ERRPST22                 NO ERROR DETECTED               01140000
ERRPST21 OI    DECERRST(DECBRG),ERRENB  INDICATE ENABLE FAILED          01160000
ERRPST22 EQU   *                                                        01180000
         MVC   IOBSNS(1,IOBRG),IOBERINF(IOBRG)    RESTORE SENSE BYTE    01200000
         MVC   IOBCSW+1(7,IOBRG),IOBERINF+1(IOBRG)     RESTORE 7 LOW    01220000
*                                  ORDER BYTES OF CHANNEL STATUS WORD   01240000
         L     CCWREG,IOBCSW(IOBRG)     RESTORE CCW POINTER             01260000
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           01280000
         MVC   0(8,CCWREG),IOBERINF+8(IOBRG) RESTORE FAILING CCW        01300000
ERRPST   TM    UCBTYP+1(UCBREG),SWLINE  IS THIS A SWITCHED LINE         01320000
         BNZ   ERRPST03                 YES NO TERM ID'S REQUIRED       01340000
         TM    DECTYPE+1(DECBRG),READ   IS THIS READ OPERATION   A25665 01345018
         BO    RDTYPE                   YES, BRANCH              A25665 01350018
         L     ERREG4,DECADRPT(DECBRG)  ADDRESS OF CHARS         A25665 01355018
         B     ERRDATA                                           A25665 01360018
RDTYPE   TM    UCBTYP+1(UCBREG),APOLL   IS OPERATION AUTOPOLL    A25665 01365018
         BO    POLTYPE                  YES, BRANCH              A25665 01370018
         L     ERREG4,DECPOLPT(DECBRG)  ADDRESS OF POLL CHAR     A25665 01375018
         B     ERRDATA                                           A25665 01380018
POLTYPE  L     ERREG4,DECENTRY(DECBRG)  ADDRESS OF POLL CHAR     A25665 01385018
ERRDATA  MVC   IOBWRK1(4,IOBRG),UCBTYP(UCBREG)  MOVE DEVICE DATA A25665 01390018
         NI    IOBWRK1+3(IOBRG),MASK3   CLEAR UNWANTED BITS             01400000
         NI    IOBWRK1(IOBRG),MASK2     CLEAR UNWANTED BITS        9853 01410017
         CLI   IOBWRK1+3(IOBRG),ADAPT5  CHECK FOR TWX ADAPTER           01420017
         BL    ERRPST11                 NO, NOT TWX OR ABOVE       9853 01430017
ERRPST05 CLI   IOBWRK1+3(IOBRG),ADAPT8 THIS A 2260                 3124 01440018
         BNE   ERRPST03                 NO, NO ID NEEDED           9853 01450017
         CLI   IOBCPA+13(IOBRG),X'03'   IS THIS WR ADDR/POLL CCW   9853 01460017
         BNE   ERRPST02                 NO, USE DECENTRY ADDR      9853 01470017
         L     ERREG4,IOBCPA+8(IOBRG)   PICK UP ADDRESS FROM CCW   9853 01480017
         B     ERRPST02                 MOVE ID TO MESSAGE         9853 01490017
ERRPST11 CLI   IOBECT+1(IOBRG),X'40'   SUPPRESS ID IN MESSAGE      3891 01497018
         BE    ERRPST03                YES, NO ID IN MESSAGE       3891 01504018
         CLI   IOBWRK1(IOBRG),X'09'    IS THIS 2740B               00MC 01506020
         BE    A2740                   YES, TREAT AS 2740          00MC 01508020
         CLI   IOBWRK1(IOBRG),MODTYP40  THIS A 2740                3891 01511018
         BNE   ERRPST04                 NO CONTINUE CHECKING            01520000
A2740    EQU   *                                                   00MC 01530020
         TM    IOBWRK1+1(IOBRG),STACTRL DOES 2740 HAVE STATION CONTROL  01540000
         BZ    ERRPST03                 NO TERM ID NOT REQUIRED         01560000
ERRPST01 BCTR  ERRLNK,0                 REDUCE REG FOR MOVE             01580000
ERRPST02 EX    ERRLNK,ERRMOVE           MOVE TERM ID INTO MSG           01600000
ERRPST03 OI    IOBFL2(IOBRG),IOBRHA     INDICATE EXTENDED MSG TO WTO    01620000
         MVC   IOBRST-1(1,IOBRG),5(CCWREG) PUT TP OP CODE IN MSG        01640000
         LR    ERREG2,CCWREG            SAVE CCW POINTER         A30746 01640120
         L     DCBREG,IOBDCB(IOBRG)     PICK UP POINTER TO DCB   A30746 01640220
         LA    ERREG2,0(ERREG2)         CLEAR 1ST BYTE OF REG    A30746 01640320
         CR    CCWREG,ERREG2            IS THIS FIRST CCW        A30746 01640420
         BNE   ERRPST06                 NO, BRANCH               A30746 01640520
         TM    IOBRST-1(IOBRG),X'21'    IS THIS WRITE RESET      A30746 01640620
         BO    ERRPST07                 YES, BRANCH              A30746 01640720
ERRPST06 EQU   *                                                        01640820
         LA    CCWREG,IOBCPA(IOBRG)    POINT TO FIRST CCW          2724 01641018
         TM    DCBBFTEK(DCBREG),X'08'  DYNAMIC BUFFERING           2724 01643018
         BNO   ERRWTO                  NO, NORMAL POST             2724 01644018
         TM    IOBERINF+13(IOBRG),X'30' ERROR PRIOR TO TEXT      A24925 01644218
         BNZ   ERRWTO                   NO, DON'T POST BUFFER    A24925 01644418
         TM    IOBRST-1(IOBRG),X'11'    IS TP OP CODE RD/WR TEXT A24928 01644618
         BO    ERRWTO                   YES, DON'T POST BUFFER   A24928 01644818
ERRPST07 SR    ERREG2,ERREG2            CLEAR REGISTER           A30746 01645420
         LA    IOBRG,0(IOBRG)          CLEAR HI-ORDER BYTE         2724 01646018
         IC    ERREG2,DCBIOBSZ(DCBREG) PICK UP IOB SIZE            2724 01647018
         AR    ERREG2,IOBRG            CALCULATE IOB END           2724 01648018
ERRPST9B CR    ERREG2,CCWREG           ARE WE IN IOB               2724 01649018
         BNH   ERRWTO                  NO, NORMAL POST             2724 01650018
         TM    5(CCWREG),X'11'         IS THIS READ OR WRITE DATA  2724 01651018
         BO    ERRPST9A                YES, POST THE BUFFER        2724 01652018
         LA    CCWREG,8(CCWREG)        POINT TO NEXT CCW           2724 01653018
         B     ERRPST9B                CHECK IT                    2724 01654018
ERRPST9A L     ERREG4,0(CCWREG)        PICK UP DATA ADDRESS        2724 01655018
         N     ERREG4,MASKDB           AND TO FULL WORD BOUNDARY   3140 01656018
         SH    ERREG4,ERRCN4           BACK UP TO LINK FIELD       2724 01657018
         LTR   ERREG4,ERREG4           TEST FOR ZERO ADDRESS     A29582 01657319
         BNP   ERRWTO                  BRANCH IF YES             A29582 01657619
         TM    0(ERREG4),X'40'         IS BUFFER POSTED            2724 01658018
         BO    ERRWTO                  YES, DON'T POST AGAIN       2724 01659018
         LR    ERREG2,IOBRG            SAVE IOB POINTER            2724 01660018
         LR    ERREG3,BASREG           SAVE BASE ADDRESS           2724 01661018
         TM    DECSDECB(DECBRG),X'80' IS DECB WAITING           SA68725 01663021
         BO    ERRWTO              YES, DO NO POST              SA68725 01663421
         L     IOBRG,0(ERREG4)     GET NEXT BFR ADDR            SA68725 01663821
         LA    IOBRG,0(IOBRG)      CLEAR HI BYTE                SA68725 01664221
ERRPST9C O     IOBRG,POSTCODE      OR IN COMPLETION CODE        SA68725 01664821
         L     ERRLNK,DCBDEBAD(DCBREG) GET DEB ADDRESS             2724 01666721
         L     ERRLNK,0(ERRLNK)        GET TCB ADDRESS FROM DEB    2724 01668621
         L     BASREG,POST(COMREG)     GET ADDRESS OF POST RTN     2724 01670521
         BALR  ERRETR,BASREG           LINK TO POST BUFFER         2724 01672421
         LR    IOBRG,ERREG2            RESTORE IOB REGISTER        2724 01674321
         LR    BASREG,ERREG3           RESTORE BASE REGISTER       2724 01676221
ERRWTO   LA    SAVREG,WTORTN           NAME OF WTO ROUTINE         2724 01678121
         L     ERRETR,VECTXL(COMREG)    ADDR OF XCTL ROUTINE            01680000
         BR    ERRETR                   BRANCH                          01700000
ERRPST04 CLI   IOBWRK1+3(IOBRG),ADAPT2  THIS A 1030                     01720000
         BE    ERRPST01                 YES REDUCE MOVE COUNT           01740000
         B     ERRPST02                 NO MOVE COUNT CORRECT           01760000
ERRPST5  MVC   IOBWRK1+3(1,IOBRG),UCBTYP+3(UCBREG) ADAPTER TYPE BYTE    01840000
         NI    IOBWRK1+3(IOBRG),MASK3   CLEAR UNWANTED BITS             01860000
         CLI   IOBWRK1+3(IOBRG),ADAPT4  CHECK FOR TELEGRAPH ADAPTER -   01880000
*                                  TYPE I                               01900000
         BNE   ERRPST52                 NO ALL ERRORS VALID             01920000
         CLI   IOBCSW+4(IOBRG),CSWCDEE  CHECK FOR CHANNEL END - DEVICE  01940000
*                                  END - UNIT EXCEPTION STATUS          01960000
         BNE   ERRPST4                  NO INDICATE FAILURE             01980000
ERRPST51 TM    IOBCSW+5(IOBRG),MASKALL  ANY OTHER ERRORS                02000000
         BNZ   ERRPST4                  INDICATE DIAG W/R FAILED        02020000
         B     ERRPST41                 NORMAL COMPLETION               02040000
ERRPST52 TM    4(CCWREG),CHAINCDE       THIS COMMAND CHAINED            02060000
         BO    ERRPST4                  INDICATE FAILURE                02080000
         TM    IOBCSW+4(IOBRG),CSWCDE   CHAN AND DEV END                02100000
         BC    12,ERRPST4               INDICATE FAILURE                02120000
         TM    IOBCSW+4(IOBRG),MASKALL-CSWCDE ANY ERRORS                02140000
         BZ    ERRPST51                 NO ERRORS CHECK FURTHER         02160000
ERRPST4  OI    DECERRST(DECBRG),ERRDIAG INDICATE DIAG W/R FAILED        02180000
ERRPST41 MVC   IOBSNS+1(1,IOBRG),IOBSNS(IOBRG)    SAVE DIAGNOSTIC       02200000
*                                  WRITE/READ SENSE BYTE IN SECOND BYTE 02220000
         MVI   IOBSNS(IOBRG),X'00'      CLEAR FIRST SENSE BYTE          02240000
         TM    IOBCPA+20(IOBRG),CHAINCDE ENABLE REQUIRED                02260000
         BC   12,ERRPST22              NO GO TO WTO AND POST MSG        02280000
         LA    ERREG1,IOBCPA+24(IOBRG)  ADDRESS OF CCW                  02300000
ERRPST42 ST    ERREG1,IOBSTART(IOBRG)   LOCATION OF POINTER TO CCW      02320000
         SVC   EXCPER                                                   02360000
         SVC   RETURN                                                   02380000
ERRPST3  OI    DECERRST(DECBRG),ERRENB  INDICATE DISABLE FAILED         02400000
         NI    DECERRST(DECBRG),MASKALL-DISABLOK TURN OFF DISABLE SW    02420000
         LA    ERREG1,IOBCPA+8(IOBRG)   ADDR OF DIAG WRITE CCW          02440000
         B     ERRPST42                 EXECUTE DIAG WRITE              02460000
ERRPST6  CLI   IOBCPA(IOBRG),RSET2848   2848 RESET CHANNEL PROG    7752 02470017
         BE    ERRPST7                  YES  BRANCH                7752 02480017
         CLI   IOBCSW+4(IOBRG),CSWCDE   CHAN AND DEVICE END ONLY   7752 02490017
         BE    ERRPST22                 YES CONTINUE FLOW               02500000
         NI    DECERRST(DECBRG),MASKALL-DISABLOK INCICATE DISABLE FAIL  02520000
         OI    DECERRST(DECBRG),ERRENB  MAKE IT POSITIVE                02540000
         B     ERRPST22                 POST OPERATION COMPLETE         02560000
ERRPST7  CLI   0(CCWREG),CCWBREAK       INTERRUPT CAUSED BY BRK CCW7752 02562017
         BNE   ERRPST71                 NO  CAUSED BY READ SKIP    7752 02564017
         MVC   IOBSNS(1,IOBRG),IOBERINF+8(IOBRG) RESTORE SENSE   A35742 02565020
         MVC   IOBCSW+1(7,IOBRG),IOBERINF+9(IOBRG) RESTORE CSW   A35742 02566020
         MVC   IOBCPA(16,IOBRG),IOBERCCW(IOBRG)                  A30752 02568520
         L     ERREG4,DECENTRY(DECBRG) ADDR OF TERM ID/POLL CHARS  3886 02569018
         B     ERRPST02                POST WITH ERROR             3886 02570018
ERRPST71 MVC   IOBSTART+1(3,IOBRG),IOBCSW+1(IOBRG) SET FOR RESTART 7752 02572017
         SVC   EXCPER                                              7752 02574017
         SVC   RETURN                                              7752 02576017
ERRMOVE  MVC   IOBRST+1(0,IOBRG),0(ERREG4) EXECUTED MOVE INSTRUCTION    02580000
         DS    0F                                                       02584018
POSTCODE DC    X'41000000'                                         2724 02588018
MASKDB   DC   X'00FFFFFC'                                          3140 02592018
ERRCN4   DC    H'4'                                                2724 02596018
ERRCN1   DC    AL2(8)                                                   02600000
IOBERCCW EQU   X'28'                                             A30752 02603020
CCWBREAK EQU   X'41'                                               7752 02606017
RSET2848 EQU   X'42'                                               7752 02612017
ADAPT2   EQU   X'20'                                                    02620000
POST     EQU   X'98'                                               2724 02623018
IOBDCB   EQU   X'14'                                               2724 02626018
DCBIOBSZ EQU   X'24'                                               2724 02629018
DCBDEBAD EQU   X'2C'                                               2724 02632018
DCBBFTEK EQU   X'20'                                               2724 02635018
ADAPT4   EQU   X'40'                                                    02640000
DECTYPE  EQU   4                                                        02643018
DECADRPT EQU   32                                                       02646018
DECPOLPT EQU   36                                                       02649018
READ     EQU   X'01'                                                    02652018
APOLL    EQU   X'40'                                                    02655018
ADAPT5   EQU   X'50'                                                    02660000
ADAPT8   EQU   X'80'                                                    02680000
CHAINCDE EQU   X'60'                                                    02700000
CHAININD EQU   X'40'                                                    02720000
CSWCDE   EQU   X'0C'                        CHANNEL AND DEVICE END      02740000
CSWCDEE  EQU   X'0D'                                                    02760000
DECENTRY EQU   X'14'                                                    02780000
DECERRST EQU   X'1D'                                                    02800000
DECSDECB EQU   0                                                 A68725 02810021
DISABLOK EQU   X'08'                                                    02820000
ERRDIAG  EQU   X'10'                                                    02840000
ERRENB   EQU   X'20'                                                    02860000
EXCPER   EQU   15                           EXCP ERROR ROUTINE          02880000
IOBCPA   EQU   64                                                       02900000
IOBCSW   EQU   8                            CSW STORAGE                 02920000
IOBDECB  EQU   4                                                        02940000
IOBECT   EQU   30                      ERROR COUNTS                     02960000
IOBERINF EQU   48                                                       02980000
IOBERR   EQU   X'20'                        IOB ERROR FLAG              03000000
IOBEX    EQU   X'04'                        EXCEPT FLAG                 03020000
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                03040000
IOBFL1   EQU 0                              FLAGS 1                     03060000
IOBFL2   EQU 1                              FLAGS2                      03080000
IOBRHA   EQU   X'10'                                                    03100000
IOBRST   EQU   25                                                       03120000
IOBSAV1  EQU   48                                                       03140000
IOBSNS   EQU   2                            SENSE DATA                  03160000
IOBSTART EQU   16                                                       03180000
IOBWRK1  EQU   36                                                       03200000
LOC016   EQU   16                           COMMUNICATIONS TABLE        03220000
MASKALL  EQU   X'FF'                                                    03240000
MASK2    EQU   X'0F'                                                    03260000
MASK3    EQU   X'F0'                                                    03280000
MODTYP40 EQU   X'04'                                                    03300000
RETURN   EQU   3                       RETURN SVC                       03320000
STACTRL  EQU   X'08'                                                    03340000
SWLINE   EQU   X'90'                                                    03360000
TSTIOB   EQU   5                            IOB POINTER                 03380000
TSTUCB   EQU   2                            UCB POINTER                 03400000
UCBTYP   EQU   16                      DEVICE TYPE CODE                 03420000
UCBSNS   EQU   22                                                  9854 03440000
VECTXL   EQU   44                           VECTOR TO XCTL ROUTINE      03460000
WTORTN   EQU   253                     LOAD NAME TO WTO ROUTINE         03480000
*        REGISTER DEFINITION                                            03500000
ERREG3   EQU   0                             WORK REG                   03520000
TSTREG   EQU   1                             TWELVE STAR REG            03540000
ERREG2   EQU   2                             WORK REG                   03560000
CRBREG   EQU   3                             CURRENT RB REG             03580000
CCWREG   EQU   4                             CCW ADDRESS REG            03600000
DECBRG   EQU   5                        DECB REGISTER                   03620000
DCBREG   EQU   6                        DCB REGISTER                    03640000
UCBREG   EQU   7                             UCB ADDRESS  REG           03660000
COMREG   EQU   8                             COMMUNICATION TABLE REG    03680000
ERREG1   EQU   9                                                        03700000
IOBRG    EQU   10                            IOB ADDRESS REG            03720000
ERREG4   EQU   11                            WORK REG                   03740000
ERRLNK   EQU   12                            LINK REG                   03760000
SAVREG   EQU   13                                                       03780000
ERRETR   EQU   14                            RETURN REG                 03800000
BASREG   EQU   15                            BASE REG                   03820000
         END                                                            03840000
