         TITLE 'IGE0504B - BTAM ERR OVERRUN MODULE'                     00500000
IGE0504B CSECT                                                          01000000
*126601280640,02261130,02341170,02441220                           000A 01500000
         SPACE 2                                                        02000000
*********************************************************************** 02500000
* STATUS -          CHANGE LEVEL 001    APRIL 25, 1967                  03000000
*                                                                     * 03500000
* FUNCTION-        THIS MODULE IS ENTERED IF AN OVERRUN ERROR HAS     * 04000000
*                  OCCURRED.  A READ REPEAT CHANNEL PROGRAM IS        * 04500000
*                  GENERATED AND EXECUTED IF REQUIRED.  ERRORS ARE    * 05000000
*                  RECORDED AND LINKAGE IS PROVIDED FOR THE ERROR     * 05500000
*                  POST AND EQUIPMENT CHECK ROUTINES.                 * 06000000
*                                                                     * 06500000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 07000000
*                  TO THE ASSOCIATED IO RB.                           * 07500000
*                                                                     * 08000000
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 08500000
*                  ERROR.                                             * 09000000
*                                                                     * 09500000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 10000000
*                                                                     * 10500000
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0504A AND      * 11000000
*                  IGE0904A.                                          * 11500000
*                                                                     * 12000000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 12500000
*********************************************************************** 13000000
         SPACE 2                                                        13500000
*              OVERRUN ERROR RECOVERY ROUTINE                           14000000
         USING *,BASREG                                                 14500000
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  15000000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  15500000
         L     COMREG,LOC016            ADDRESS OF CVT                  16000000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 16500000
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  17000000
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  17500000
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           18000000
         MVC   IOBWRK(1,IOBRG),DECTYPE+1(DECBRG)    PICK UP DEV TYPE    18500000
         NI    IOBWRK(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS            19000000
         MVC   IOBWRK+1(1,IOBRG),TPCODE(CCWREG) PICK UP TP OP CODE      19500000
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS          20000000
         MVC   IOBWRK+2(1,IOBRG),UCBTYP+3(UCBREG) PICK UP ADAPTER  000A 20500000
         NI    IOBWRK+2(IOBRG),MASK15   MASK UNUSED BITS           000A 21000000
         TM    IOBSNS(IOBRG),IOBSNOVR   THIS OVERRUN                    21500000
         BZ    ERRBOSNO                 NO INDICATE SHOULD NOT OCCUR    22000000
         CLI   0(CCWREG),CCWAPOLL       THIS A POLL COMMAND        000A 22500000
         BNE   ERROVR00                 NO CHECK FURTHER           000A 23000000
         CLI   IOBWRK+2(IOBRG),CTRL2702                            000A 23500000
         BNE   ERRBOSNO                 NO SET SHOULD NOT OCCUR    000A 24000000
ERROVR06 LA    ERREG2,IOBCPA(IOBRG)     START OF CHAN PROG         000A 24500000
         ST    ERREG2,IOBSTART(IOBRG)   STORE POINTER              000A 25000000
         L     ERREG1,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FROM    000A 25500000
*    PREVIOUS POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).    000A 26000000
         MVC   IOBCPA+9(3,IOBRG),DECENTRY+1(DECBRG)    MOVE IN     000A 26500000
*    ADDRESS OF LAST ENTRY POLLED (TO BE USED AS RESTART ADDRESS). 000A 27000000
         L     ERREG4,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FOR     000A 27500000
*    NEXT POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).        000A 28000000
         SR    ERREG1,ERREG4            SUBTRACT NEW POLL ADDRESS  000A 28500000
*                                  FROM PREVIOUS POLL ADDRESS.     000A 29000000
         AH    ERREG1,IOBCPA+14(IOBRG)  IF THE NEW POLL ADDRESS    000A 29500000
*    WERE LESS THAN THE PREVIOUS POLL ADDRESS, THE EFFECT IS TO    000A 30000000
*    ADD THE ABSOLUTE DIFFERENCE TO THE PREVIOUS COUNT;  IF IT WERE000A 30500000
*    GREATER, THE EFFECT IS TO SUBTRACT THE ABSOLUTE DIFFERENCE    000A 31000000
*    FROM THE PREVIOUS COUNT.                                      000A 31500000
         STH   ERREG1,IOBCPA+14(IOBRG)  STORE ADJUSTED COUNT IN    000A 32000000
*                                  POLL COMMAND.                   000A 32500000
         B     ERROVR01                 CHECK FOR RETRIES          000A 33000000
ERROVR00 EQU   *                                                   000A 33500000
         CLI   0(CCWREG),CCWRDCMD       THIS A READ COMMAND             34000000
         BNE   ERROVR04                 NO CHECK FOR INHIBIT COMMAND    34500000
         CLI   IOBWRK+1(IOBRG),CCWRDIX  READ RESP TO INDEX         000A 35000000
         BE    ERROVR06                 YES SET UP TO REPOLL       000A 35500000
         CLI   IOBWRK+1(IOBRG),CCWRRTXT THIS READ RESPONSE TO TEXT      36000000
         BE    ERROVR02                 YES REPEAT COMMAND              36500000
         TM    DCBBFTEK(DCBREG),X'08'  IS DYN BUFFERING SPECIFIEDA29561 36600000
         BO    ERRBOC11                YES, NO RETRIES           A29561 36700000
ERROVR05 TM    DCBERROP(DCBREG),DCBRDTRY READ RETRIES REQUIRED          37000000
         BZ    ERRBOC11                 NO POST WITH ERROR              37500000
         CLI   IOBWRK(IOBRG),DECRDRPT   CHAN PROG READ REPEAT           38000000
         BNE   ERROVR03                 NO CREATE READ REPEAT CHAN PROG 38500000
ERROVR01 CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED                  39000000
         BNL   ERRCHK1                  NO CHECK FOR DISABLE            39500000
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             40000000
         LA    ERREG1,1(ERREG1)         BUMP COUNT BY ONE               40500000
         STC   ERREG1,IOBECT(IOBRG)     STORE NEW COUNT                 41000000
         L     ERREG2,STATAB(COMREG)    SDR TABLE POINTER               41500000
         SR    ERREG1,ERREG1                                            42000000
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY            42500000
         LR    ERREG4,ERREG2            SAVE STAT TABLE START ADDR 000H 42600000
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED THIS SECT 000H 42700000
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 42800000
         LA    ERREG4,2(ERREG4)         POINT TO NXT CTL ENTRY     000H 42900000
         LA    ERREG1,256(ERREG1)       POINT TO NXT STAT TBL SECT 000H 43000000
         B     ERRLOOP1                 LOOP TO CHECK THIS SECTION 000H 43100000
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR ENTRY LENGTH    000H 43200000
         AR    ERREG2,ERREG1            RESOLVE FINAL ADDRESS           43500000
         OC    8(1,ERREG2),IOBSNS(IOBRG) RECORD TEMPORARY ERRORS        44000000
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                44500000
         SVC   EXCPER                   EXECUTE CHAN PROGRAM            45000000
         SVC   RETURN                   EXIT                            45500000
ERROVR02 ST    CCWREG,IOBSTART(IOBRG)   CPA POINTER TO FAILING CCW 000A 46000000
         B     ERROVR01                 CHECK FOR RETRIES               46500000
ERROVR03 NI    DECTYPE+1(DECBRG),HIBIT  CLEAR OUT OPERATION TYPE        47000000
         OI    DECTYPE+1(DECBRG),DECRDRPT INDICATE READ REPEAT          47500000
         OI    IOBINCAM(IOBRG),X'08' SET ERP FOR R/W       A29561A33976 47700000
         LR    ERREG2,BASREG            SAVE BASE                       48000000
         LR    ERREG4,TSTREG            SAVE RB POINTER                 48500000
         LA    SAVREG,SAVEAREA-12       REGISTER SAVE AREA              49000000
         LR    TSTREG,DECBRG            INITIALIZE PARAMETER REG        49500000
         READ  (1),T,MF=E               GENERATE READ REPEAT CHAN PROG  50000000
         LR    BASREG,ERREG2            RESTORE BASE                    50500000
         LR    TSTREG,ERREG4            RESTORE RB POINTER              51000000
         NI    IOBINCAM(IOBRG),X'F7' TURN OFF ERP FLAG     A29561A33976 51200000
         B     ERROVR01                 SET UP TO EXECUTE CHAN PROGRAM  51500000
ERROVR04 CLI   0(CCWREG),CCWINHCD       THIS AN INHIBIT COMMAND         52000000
         BE    ERROVR05                 YES CHECK FOR READ REPEAT REQ   52500000
ERRBOSNO OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 53000000
ERRBOC11 OI    IOBFL3(IOBRG),IOBLOG     INDICATE OBR RECORDING          53500000
ERRBOC00 LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         54000000
         NI    IOBFL1(IOBRG),MASKALL-IOBERR INDICATE ERROR POST  A29561 54500000
ERRLINK1 L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         55000000
         BR    ERRETR                   LINK                            55500000
ERRCHK1  OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOG OUT REQUIRED       56000000
         TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                56500000
         BZ    ERRBOC00                 NO POST ERROR                   57000000
         MVI   IOBECT+1(IOBRG),MASK15   SPECIAL ENTRY TO DISABLE ROUTIN 57500000
         LH    SAVREG,ERLOD9            ADDRESS OF DISABLE ROUTINE      58000000
         B     ERRLINK1                 EXIT ROUTINE                    58500000
SAVEAREA DC    16F'0'                                                   59000000
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 59500000
ERRCN8   DC    H'8'                     DECIMAL 8                  000A 60000000
ERLOD5   DC    H'5041'                                             000A 60500000
ERLOD9   DC    H'9041'                                             000A 61000000
IOBSTART EQU   16                                                       61500000
RETURN   EQU   3                                                        62000000
EXCPER   EQU   15                                                       62500000
ERRCN2   DC    H'10'                                                    63000000
UCBSTI   EQU   9                                                        63500000
STATAB   EQU   112                                                      64000000
CCWAPOLL EQU   X'09'                                               000A 64500000
CCWRDIX  EQU   X'0A'                                               000A 65000000
CTRL2702 EQU   X'01'                                               000A 65500000
NONAME   EQU   X'00'                                                    66000000
ERTRYCT  EQU   X'02'                                                    66500000
DECRDRPT EQU   X'07'                                                    67000000
DCBRDTRY EQU   X'02'                                                    67500000
DCBERROP EQU   33                                                       68000000
CCWRRTXT EQU   X'20'                                                    68500000
IOBWRK   EQU   33                                                       69000000
HIBIT    EQU   X'C0'                                                    69500000
MASKALL  EQU   X'FF'                                                    70000000
DECTYPE  EQU   4                                                        70500000
TPCODE   EQU   5                                                        71000000
IOBDCBAD EQU   20                                                       71500000
TSTIOB   EQU   4                                                        72000000
DCBBFTEK EQU   X'20'                                             A29561 72100000
IOBFL1   EQU   0                                                 A29561 72200000
IOBERR   EQU   X'20'                                             A29561 72300000
IOBINCAM EQU   X'1C'                                             A29561 72400000
TSTUCB   EQU   2                                                        72500000
LOC016   EQU   16                                                       73000000
IOBCSW   EQU   8                                                        73500000
MASK15   EQU   X'0F'                                                    74000000
IOBDECB  EQU   4                                                        74500000
DECERRST EQU   29                                                       75000000
VECTXL   EQU   44                                                       75500000
UCBTYP   EQU   16                                                       76000000
SWLINE   EQU   X'90'                                                    76500000
IOBECT   EQU   30                                                       77000000
IOBCPA   EQU   64                                                       77500000
IOBSNOVR EQU   X'04'                                                    78000000
DECENTRY EQU   20                                                  000A 78500000
CCWRDCMD EQU   X'02'                                                    79000000
CSWSNO   EQU   X'40'                                                    79500000
IOBSNS   EQU   2                            SENSE DATA                  80000000
CCWINHCD EQU   X'0A'                                                    80500000
IOBFL3   EQU   8                                                        81000000
IOBLOG   EQU   X'01'                                                    81500000
*        REGISTER DEFINITION                                            82000000
ERREG3   EQU   0                             W69K REG                   82500000
TSTREG   EQU   1                             TWELVE STAR REG            83000000
ERREG2   EQU   2                             WORK REG                   83500000
CRBREG   EQU   3                             CURRENT RB REG             84000000
CCWREG   EQU   4                             CCW ADDRESS REG            84500000
DECBRG   EQU   5                        DECB REGISTER                   85000000
DCBREG   EQU   6                        DCB REGISTER                    85500000
UCBREG   EQU   7                             UCB ADDRESS  REG           86000000
COMREG   EQU   8                             COMMUNICATION TABLE REG    86500000
ERREG1   EQU   9                                                        87000000
IOBRG    EQU   10                            IOB ADDRESS REG            87500000
ERREG4   EQU   11                            WORK R57                   88000000
ERRLNK   EQU   12                            LINK REG                   88500000
SAVREG   EQU   13                                                       89000000
ERRETR   EQU   14                            RETURN REG                 89500000
BASREG   EQU   15                            BASE REG                   90000000
         END                                                            90500000
