         TITLE 'IGE0604A - BTAM ERR BUS OUT MODULE'                     00500018
IGE0604A CSECT                                                          01000018
*126701880940,02301150,02421210,02521260,02641320                  000A 01500018
         SPACE 2                                                        02000018
*********************************************************************** 02500018
* STATUS -          CHANGE LEVEL 001    APRIL 25, 1967                  03000018
*                                                                     * 03500018
* FUNCTION-        THIS MODULE IS ENTERED ON THE OCCURRENCE OF A BUS  * 04000018
*                  OUT ERROR.  CHECKS FOR AN OVERRUN ERROR AND        * 04500018
*                  BRANCHES TO THE OVERRUN ROUTINE IF NECESSARY.  THE * 05000018
*                  CHANNEL PROGRAM IS RETRIED IF REQUIRED.  LINKS TO  * 05500018
*                  ERROR POST AND EQUIPMENT CHECK ROUTINES.           * 06000018
*                                                                     * 06500018
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 07000018
*                  TO THE ASSOCIATED IO RB.                           * 07500018
*                                                                     * 08000018
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 08500018
*                  ERROR.                                             * 09000018
*                                                                     * 09500018
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 10000018
*                                                                     * 10500018
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0504B,         * 11000018
*                  IGE0504A, AND IGE0904A.                            * 11500018
*                                                                     * 12000018
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 12500018
*********************************************************************** 13000018
         SPACE 2                                                        13500018
*              BUS OUT CHECK ERROR RECOVERY ROUTINE                     14000018
         USING *,BASREG                                                 14500018
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  15000018
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  15500018
         L     COMREG,LOC016            ADDRESS OF CVT                  16000018
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 16500018
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  17000018
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  17500018
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           18000018
         MVC   IOBWRK(1,IOBRG),DECTYPE+1(DECBRG)    PICK UP DEV TYPE    18500018
         NI    IOBWRK(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS            19000018
         MVC   IOBWRK+1(1,IOBRG),TPCODE(CCWREG) PICK UP TP OP CODE      19500018
         NI    IOBWRK+1(IOBRG),MASKALL-HIBIT CLEAR UNUSED BITS          20000018
         TM    IOBSNS(IOBRG),IOBSNBOC   THIS BUSSOUT ERROR              20500018
         BZ    ERROVR00                 NO CHECK FOR OVERRUN            21000018
         CLI   0(CCWREG),CCWAPOLL       THIS A POLL COMMAND        000A 21500018
         BE    ERRBOC03                 YES SET UP REPOLL FUNCTION 000A 22000018
         CLI   0(CCWREG),CCWWRT         THIS A WRITE COMMAND            22500018
         BNE   ERRBOC02                 NO CHECK FURTHER                23000018
         TM    IOBWRK+1(IOBRG),PTXTXFER IS COMMAND PRIOR TO TEXT XFERS  23500018
         BZ    ERROVR01                 YES RETRY CHAN PROGRAM          24000018
         TM    IOBWRK+1(IOBRG),ATXTXFER IS COMMAND AFTER TEXT XFER      24500018
         BZ    ERRBOC01                 NO CHECK FURTHER                25000018
         ST    CCWREG,IOBSTART(IOBRG)   CPA START TO FAILING CCW        25500018
         B     ERROVR01                 EXECUTE FAILING CCW             26000018
ERRBOC01 TM    DCBERROP(DCBREG),DCBWRTRY WRITE RETRIES REQUESTED        26500018
         BZ    ERRBOC00                 NO POST WITH ERROR              27000018
         TM    TPCODE(CCWREG),CCWLAST   THIS LAST CCW                   27500018
         BO    ERROVR01                 YES RE-EXECUTE CHAN PROG        28000018
         MVC   IOBWRK+3(1,IOBRG),TPCODE+8(CCWREG) PICK UP NEXT OP CODE  28500018
         NI    IOBWRK+3(IOBRG),MASKALL-HIBIT CLEAR UNWANTED BITS        29000018
         CLI   IOBWRK+3(IOBRG),CCWRRTXT READ RESPONSE TO TEXT           29500018
         BNE   ERROVR01                 NO RE-EXECUTE CHAN PROGRAM      30000018
          ST    CCWREG,IOBSTART(IOBRG)   RETRY FAILING WRITE COMMAND    30500018
         B     ERROVR01                 EXECUTE CHAN PROGRAM            31000018
ERRBOC02 EQU   *                                                        31500018
         CLI   0(CCWREG),CCWDIAL        THIS A DIAL COMMAND             32000018
         BE    ERROVR01                 YES RETRY CHANNEL PROGRAM       32500018
ERRBOSNO OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 33000018
ERRBOC00 LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         33500018
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOG OUT                34000018
ERRLINK1 L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         34500018
         BR    ERRETR                   LINK                            35000018
ERRCHK1  EQU   *                                                        35500018
         TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                36000018
         BZ    ERRBOC00                 NO POST ERROR                   36500018
         MVI   IOBECT+1(IOBRG),MASK15   SPECIAL ENTRY TO DISABLE ROUTIN 37000018
         LH    SAVREG,ERLOD9            ADDRESS OF DISABLE ROUTINE      37500018
         B     ERRLINK1                 EXIT ROUTINE                    38000018
ERRBOC03 LA    ERREG2,IOBCPA(IOBRG)     START OF CHAN PROG         000A 38500018
         ST    ERREG2,IOBSTART(IOBRG)   STORE POINTER              000A 39000018
         L     ERREG1,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FROM    000A 39500018
*    PREVIOUS POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).    000A 40000018
         MVC   IOBCPA+9(3,IOBRG),DECENTRY+1(DECBRG)    MOVE IN     000A 40500018
*    ADDRESS OF LAST ENTRY POLLED (TO BE USED AS RESTART ADDRESS). 000A 41000018
         L     ERREG4,IOBCPA+8(IOBRG)   LOAD ENTRY ADDRESS FOR     000A 41500018
*    NEXT POLL (WITH POLL COMMAND CODE IN HIGH ORDER BYTE).        000A 42000018
         SR    ERREG1,ERREG4            SUBTRACT NEW POLL ADDRESS  000A 42500018
*                                  FROM PREVIOUS POLL ADDRESS.     000A 43000018
         AH    ERREG1,IOBCPA+14(IOBRG)  IF THE NEW POLL ADDRESS    000A 43500018
*    WERE LESS THAN THE PREVIOUS POLL ADDRESS, THE EFFECT IS TO    000A 44000018
*    ADD THE ABSOLUTE DIFFERENCE TO THE PREVIOUS COUNT;  IF IT WERE000A 44500018
*    GREATER, THE EFFECT IS TO SUBTRACT THE ABSOLUTE DIFFERENCE    000A 45000018
*    FROM THE PREVIOUS COUNT.                                      000A 45500018
         STH   ERREG1,IOBCPA+14(IOBRG)  STORE ADJUSTED COUNT IN    000A 46000018
*                                  POLL COMMAND.                   000A 46500018
ERROVR01 CLI   IOBECT(IOBRG),ERTRYCT    RETRY REQUIRED                  47000018
         BNL   ERRCHK1                  NO CHECK FOR DISABLE            47500018
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             48000018
         LA    ERREG1,1(ERREG1)         BUMP COUNT BY ONE               48500018
         STC   ERREG1,IOBECT(IOBRG)     STORE NEW COUNT                 49000018
         L     ERREG2,STATAB(COMREG)    SDR TABLE POINTER               49500018
         SR    ERREG1,ERREG1                                            50000018
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY            50500018
         LR    ERREG4,ERREG2            SAVE STAT TABLE START ADDR 000H 50600018
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED THIS SECT 000H 50700018
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 50800018
         LA    ERREG4,2(ERREG4)         POINT TO NXT CTL ENTRY     000H 50900018
         LA    ERREG1,256(ERREG1)       POINT TO NXT STAT TBL SECT 000H 51000018
         B     ERRLOOP1                 LOOP TO CHECK THIS SECTION 000H 51100018
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR ENTRY LENGTH    000H 51200018
         AR    ERREG2,ERREG1            RESOLVE FINAL ADDRESS           51500018
         OC    8(1,ERREG2),IOBSNS(IOBRG) RECORD TEMPORARY ERRORS        52000018
         MVI   IOBSNS(IOBRG),NONAME     CLEAR SENSE BYTE                52500018
         SVC   EXCPER                   EXECUTE CHAN PROGRAM            53000018
         SVC   RETURN                   EXIT                            53500018
ERROVR00 LH    SAVREG,ERLOD15           ADDRESS OF OVERRUN ROUTINE      54000018
         L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         54500018
         BR    ERRETR                   LINK                            55000018
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 55500018
ERLOD5   DC    H'5041'                                             000A 56000018
ERLOD9   DC    H'9041'                                             000A 56500018
ERLOD15  DC    H'5042'                                             000A 57000018
ERRCN2   DC    H'10'                                               000A 57500018
ERRCN8   DC    H'8'                     DECIMAL 8                  000A 58000018
IOBSTART EQU   16                                                       58500018
RETURN   EQU   3                                                        59000018
EXCPER   EQU   15                                                       59500018
UCBSTI   EQU   9                                                        60000018
STATAB   EQU   112                                                      60500018
NONAME   EQU   X'00'                                                    61000018
ERTRYCT  EQU   X'02'                                                    61500018
DCBERROP EQU   33                                                       62000018
CCWRRTXT EQU   X'20'                                                    62500018
IOBWRK   EQU   33                                                       63000018
HIBIT    EQU   X'C0'                                                    63500018
MASKALL  EQU   X'FF'                                                    64000018
DECTYPE  EQU   4                                                        64500018
PTXTXFER EQU   X'F0'                                                    65000018
ATXTXFER EQU   X'20'                                                    65500018
TPCODE   EQU   5                                                        66000018
CCWLAST  EQU   X'80'                                                    66500018
DCBWRTRY EQU   X'40'                                                    67000018
IOBDCBAD EQU   20                                                       67500018
TSTIOB   EQU   4                                                        68000018
TSTUCB   EQU   2                                                        68500018
LOC016   EQU   16                                                       69000018
IOBCSW   EQU   8                                                        69500018
CCWWRT   EQU   X'01'                                                    70000018
MASK15   EQU   X'0F'                                                    70500018
CCWDIAL  EQU   X'29'                                                    71000018
IOBDECB  EQU   4                                                        71500018
CCWAPOLL EQU   X'09'                                               000A 72000018
DECENTRY EQU   20                                                  000A 72500018
IOBCPA   EQU   64                                                       73000018
DECERRST EQU   29                                                       73500018
VECTXL   EQU   44                                                       74000018
UCBTYP   EQU   16                                                       74500018
SWLINE   EQU   X'90'                                                    75000018
IOBECT   EQU   30                                                       75500018
IOBSNBOC EQU   X'20'                                                    76000018
CSWSNO   EQU   X'40'                                                    76500018
IOBSNS   EQU   2                            SENSE DATA                  77000018
IOBFL3   EQU   8                                                        77500018
IOBLOG   EQU   X'01'                                                    78000018
*        REGISTER DEFINITION                                            78500018
ERREG3   EQU   0                             WORK REG                   79000018
TSTREG   EQU   1                             TWELVE STAR REG            79500018
ERREG2   EQU   2                             WORK REG                   80000018
CRBREG   EQU   3                             CURRENT RB REG             80500018
CCWREG   EQU   4                             CCW ADDRESS REG            81000018
DECBRG   EQU   5                        DECB REGISTER                   81500018
DCBREG   EQU   6                        DCB REGISTER                    82000018
UCBREG   EQU   7                             UCB ADDRESS  REG           82500018
COMREG   EQU   8                             COMMUNICATION TABLE REG    83000018
ERREG1   EQU   9                                                        83500018
IOBRG    EQU   10                            IOB ADDRESS REG            84000018
ERREG4   EQU   11                            WORK R57                   84500018
ERRLNK   EQU   12                            LINK REG                   85000018
SAVREG   EQU   13                                                       85500018
ERRETR   EQU   14                            RETURN REG                 86000018
BASREG   EQU   15                            BASE REG                   86500018
         END                                                            87000018
