         TITLE 'BSC ERP LOST DATA ROUTINE'                              00400016
IGE0604C CSECT                                                          00800016
*72790001020000,208000,212000                                      000C 01200016
         SPACE 2                                                        01600016
*********************************************************************** 02000016
* STATUS            CHANGE LEVEL  001   NOVEMBER 14, 1967               02400016
*                                                                     * 02800016
* FUNCTION         THIS MODULE IS ENTERED FOR LOST DATA ERRORS.       * 03200016
*                  THE ROUTINE DETERMINES WHEN THE LOST DATA          * 03600016
*                  ERROR OCCURRED WITHIN THE CHANNEL PROGRAM          * 04000016
*                  AND THEN ATTEMPTS THE APPROPRIATE RECOVERY         * 04400016
*                  ACTION TO RECOVER FROM THE ERROR                   * 04800016
*                                                                     * 05200016
* INPUT            REGISTER ONE CONTAINS A POINTER TO THE             * 05600016
*                  ASSOCIATED RB FOR THIS IO OPERATION                * 06000016
*                                                                     * 06400016
* OUTPUT           POSTS THE OPERATION COMPLETE WITH OR WITHOUT       * 06800016
*                  ERRORS DEPENDING ON RECOVERY STATUS                * 07200016
*                                                                     * 07600016
* ENTRY            ENTRY IS THE FIRST EXECUTABLE INSTRUCTION          * 08000016
*                  OF THE MODULE                                      * 08400016
*                                                                     * 08800016
* EXITS            SUPERVISOR POST VIA RETURN, IOS VIA ERREXCP,       * 09200016
*                  ERROR POST VIA IGE0504C, LERB VIA IGE0204B         * 09600016
*                                                                     * 10000016
* ATTRIBUTES       THE MODULE IS TRANSIENT, REENTRANT, ENABLED        * 10400016
*                  AND OPERATES IN THE ERROR TRANSIENT AREA OF        * 10800016
*                  THE NUCLEUS WITH A SUPERVISOR PROTECTION KEY       * 11200016
*********************************************************************** 11600016
         SPACE 2                                                        12000016
         USING IECTDECB,DECBRG                                          12400016
         USING IECTIOB,IOBRG                                            12800016
         USING IHADCB,DCBREG                                            13200016
         USING *,BASREG                                                 13600016
         L     IOBRG,TSTIOB(TSTREG)    ADDRESS OF IOB                   14000016
         LH    UCBREG,TSTUCB(TSTREG)   ADDRESS OF UCB                   14400016
         L     DCBREG,IOBDCBPT         ADDRESS OF DCB                   14800016
         L     DECBRG,IOBECBPT         ADDRESS OF DECB                  15200016
         L     COMREG,CVTPTR           ADDRESS OF CVT                   15600016
         L     CCWREG,IOBCSW           ADDRESS OF NEXT CCW              16000016
         SH    CCWREG,ERRCON08         ADDRESS OF FAILING CCW           16400016
         MVC   IOBWORK(1),TPOPCODE(CCWREG) INITIALIZE WORK AREA         16800016
         NI    IOBWORK,MASKALL-HIBIT   CLEAR UNUSED BITS                17200016
         CLI   0(CCWREG),CCWDIAL       ERROR ON A DIAL                  17600016
         BNE   BSCLD01                 NO CHECK FURTHER                 18000016
         LA    ERREG3,CCWDISAB         INDICATE DISABLE REQUIRED        18400016
         LA    ERRLNK,CHAINCDE        COMMAND CHAIN, SLI FLAGS          18800016
         LA    ERREG4,CCWTIC          2ND COMMAND                       19200016
BSCLD00A SR    ERREG2,ERREG2           NO DATA ADR REQUIRED             19600016
BSCLD00  EQU   *                                                   000F 20000018
         ST    ERREG2,IOBERCCW         SET UP CHAN PROG                 20400016
         STC   ERREG3,IOBERCCW         PUT IN COMMAND                   20800016
         ST    ERREG3,IOBERCCW+4        COUNT FIELD FIRST COMMAND  000F 21200018
         STC   ERRLNK,IOBERCCW+4        SET CCW FLAGS              000C 21600016
         ST    CCWREG,IOBERCCW+8       PUT IN TIC ADDRESS               22000016
         STC   ERREG4,IOBERCCW+8      SET SECOND COMMAND                22400016
         ST    ERREG3,IOBERCCW+12       COUNT FIELD 2ND COMMAND  A66467 22800021
         LA    CCWREG,IOBERCCW         NEW CHAN PROG START              23200016
         CLI   IOBWORK+1,NONAME         INTERNAL ROUTINE SPECIFIED 000F 23280018
         BE    BSCLD00C                                            000F 23360016
         MVI   IOBERRCT+1,RTRNSPCD      SET SPEC RTN INDICATOR     000F 23440018
BSCLD00C EQU   *                                                   000F 23520018
BSCLD03  ST    CCWREG,IOBSTART         STORE IN POINTER LOCATION        23600016
         B     BSCLD06                 CHECK FOR LERB                   24000016
BSCLD01  CLI   0(CCWREG),CCWREAD       ERROR ON A READ COMMAND          24400016
         BE    BSCLD02                 YES CHECK FURTHER                24800016
         CLI   0(CCWREG),CCWPREP        ERROR ON PREPARE COMMAND        24900016
         BE    BSCLD06                  YES CHECK FOR LERB              25000016
         OI    DECERRST,DECSNO         SET SHOULD NOT OCCUR             25200016
BSCLD05C EQU   *                                                        25600016
         MVI   IOBERRCT,ERRMAXCT        SET COUNT TO MAXIMUM            25800016
         MVI   IOBERRCT+1,RTRNCDE5     SET SPECIAL RETURN INDICATOR     26000016
BSCLD01A LA    ERREG4,CCWNOP           SET COMMAND FOR NO OPERATION     26400016
BSCLD01B LA    ERREG3,CCWREAD         SET COMMAND FOR READ              26800016
         LA    ERRLNK,CHAINCD1        COMMAND CHAIN, SLI, SKIP FLAGS    27200016
         B     BSCLD00A                GO COMPLETE CHAN PROGRAM         27600016
BSCLD02  CLI   IOBWORK,TPOPRENQ        ERROR ON READ ENQ                28000016
         BNE   BSCLD02E                 NO, CHECK FURTHER        A33954 28100020
         CLI   DECTYPE+1,WRRESET        WRITE RESET CHAN PROGRAM A33954 28200020
         BNE   BSCLD03                  NO, CONTINUE             A33954 28300020
         MVI   IOBERRCT,ERRMAXCT        YES, SET NO RETRIES      A33954 28400020
         B     BSCLD07                  POST ERROR CONDITION     A33954 28500020
BSCLD02E CLI   IOBWORK,TPOPRIDR         READ ID RESPONSE         A33954 28600020
         BE    BSCLD02C                 YES, GENERATE CHAN PROG    000F 29000018
         CLI   IOBWORK,TPOPRIDE         THIS READ ENQ WITH ID      000F 29200018
         BNE   BSCLD02B                 NO, CHECK FURTHER          000F 29400018
         B     BSCLD03                  RETRY FAILING CCW          000F 29600018
BSCLD02C MVI   IOBWORK+1,RTRNCDE3       INDICATE INTERNAL ROUTINE  000F 29800018
         B     BSCLD02A                 CONTINUE CH.PROG. GENERATN 000F 30000018
BSCLD02B EQU   *                                                        30800016
         CLI   IOBWORK,TPOPRREN        ERROR ON READ RESP ENQ           31200016
         BNE   BSCLD04                 NO CHECK FURTHER                 31600016
BSCLD02D SH    CCWREG,ERRCON08         SET CCW TO WRITE ENQ COMMAND     32100019
         LA    ERREG4,CCWTIC           SET 2ND COMMAND FOR TIC          32400016
         B     BSCLD01B                GO COMPLETE CHAN PROGRAM         32800016
BSCLD02A LA    ERREG4,CCWNOP           SECOND COMMAND                   33200016
         LA    ERRLNK,CHAINCDE         CHAINING FLAGS CC,SLI            33600016
         LA    ERREG2,IOBWORK+2         CONSTANTS FOR CHAN              34000016
         LA    ERREG3,CCWREAD            PROG GENERATION ROUTINE        34400016
         B     BSCLD00                 GENERATE CHANNEL PROGRAM         34800016
BSCLD04  CLI   IOBWORK,TPOPDTXT                                         35200016
         BNE   BSCLD04A                                                 35600016
         MVC   IOBWORK+2(1),DECTYPE+1   OPERATION TYPE CODE        000F 35900018
         NI    IOBWORK+2,MASK1          ZERO OUT UNUSED HALF       000F 36200018
         TM    DCBBFTEK,DYNBUF          DYNAMIC BUFFERING USED     000F 36500018
         BO    BSCLD05C                 YES, POST WITH ERROR       000F 36800018
         CLI   IOBWORK+2,DECCONV        CONVERSATIONAL WRITE       000F 37100018
         BL    BSCLD05A                 NO CHECK FOR POLL          000F 37400018
         SH    CCWREG,ERRCON08          BACK UP TO RD RESP TO TXT  000F 37700018
BSCLD05  MVI   IOBWORK+1,RTRNCDE2       INDICATE INTERNAL ROUTINE  000F 38000018
         B     BSCLD02A                 COMPLETE CHANNEL PROG           38300018
BSCLD04A EQU   *                                                        39200016
         CLI   IOBWORK,TPOPRRTX        THIS READ RESP TO TEXT           39600016
         BNE   BSCLD100                                                 40000016
         MVI   IOBWORK+1,RTRNCDE3      SPEC RETURN 3O45                 40400016
         B     BSCLD01A                GENERATE CHAN PROGRAM            41200016
BSCLD100 CLI   IOBWORK,TPOPRRAD  READ RESP TO ADDRESSING         A49677 41600021
         BE    BSCLD08            YES, SET UP RETRY              A49677 41630021
         OI    DECERRST,DECSNO    SET SHOULD NOT OCCUR           A49677 41660021
         CLI   5(CCWREG),NONAME         ERP CCW                         41700016
         BNE   BSCLD05C                 NO SET PER ERROR                41800016
         L     CCWREG,IOBERCCW+8        YES PICK UP RESTART ADDRESS     41900016
         LA    ERREG4,CCWTIC           SET COMMAND FOR TIC         2738 41950018
         B     BSCLD01B                GO FINISH CHANNEL PROGRAM   2738 42000018
BSCLD05A CLI   IOBCPA,CCWAPOLL          THIS AN AUTOPOLL DEVICE    000F 42050018
         BNE   BSCLD05                  NO, SET UP CHAN PROG       000F 42100018
         LR    ERREG1,CCWREG            POINT TO CURRENT CCW            42160017
         SH    ERREG1,ERRCON08          BACK UP ONE                     42220017
         L     ERREG1,0(ERREG1)         GET AREA ADDRESS                42280017
         AH    ERREG1,ERRCON01          BUMP BY ONE (INDEX BYTE)        42340017
         C     ERREG1,0(CCWREG)         HAS COUNT BEEN ADJUSTED         42400017
         BE    BSCLD05                  YES, CONTINUE                   42460017
         ST    ERREG1,0(CCWREG)         NO, RESTORE READ                42520017
         LH    ERREG1,6(CCWREG)         PICK UP COUNT                   42580017
         LA    ERREG1,1(ERREG1)         BUMP BY ONE                     42640017
         STH   ERREG1,6(CCWREG)         STORE                           42700017
         LA    ERREG2,DCBBSNAK       GET ADDR. OF A NAK          A66416 42750021
         LA    ERREG3,CCWWRITE       PUT WRITE C.C. IN ERREG3    A66416 42760021
         LA    ERRLNK,CHAINCDE       PUT FLAGS BYTE IN ERRLNK    A66416 42770021
         LA    ERREG4,CCWTIC         PUT TIC C.C. IN ERREG4      A66416 42780021
         MVI   IOBWORK+1,RTRNCDE2    SET SPECIAL RETURN OF 82    A66416 42790021
         B     BSCLD00                  GENERATE CHAN PROG       A66416 42800021
BSCLD08  LA    CCWREG,IOBCPA      START OF CHAN PROG             A49677 43800021
         B     BSCLD03            GO STORE IN IOBSTART           A49677 44800021
BSCLD06  EQU   *                                                        45800018
BSCLD06A CLI   IOBERRCT,ERRMAXCT       ANY RETRIES LEFT                 50400016
         BNL   BSCLD07                 NO SET PERM ERROR                50800016
         IC    ERREG1,IOBERRCT         PICK UP LAST COUNT               51200016
         LA    ERREG1,1(ERREG1)        BUMP OLD COUNT                   51600016
         STC   ERREG1,IOBERRCT         STORE NEW COUNT                  52000016
         SVC   EREXCP                  EXECUTE CHAN PROG                53200016
         SVC   RETURN                  NO FINI                          55200016
BSCLD07  NI    IOBFLAG1,MASKALL-IOBERR SET PERM ERROR INDICATOR         55600016
         LA    SAVREG,ERLOD25                                           56800016
BSCLD07A L     ERRETR,VECTXL(COMREG)   LINK ROUTINE                     57200016
         BR    ERRETR                  LINK                             57600016
ERRCON01 DC    H'1'                                                000F 58600016
CCWDIAL EQU    X'29'                                                    58800016
CCWDISAB EQU   47                                                       59200016
CCWRDSKP EQU   0                                                        59600016
CCWNOP   EQU   3                                                        60000016
TPOPDTXT EQU   X'11'                                                    60400016
TPOPRRAD EQU   X'06'              READ RESP TO ADDRESSING        A49677 60500021
TPOPRIDE EQU   X'03'                                                    60600018
TPOPRRTX EQU   X'25'                                                    61200016
READINIT EQU   X'01'                                                    61600016
RDINITEN EQU   X'15'                                                    62000016
CHAINCDE EQU   X'60'                                                    62400016
TPOPRIDR EQU   X'07'                                                    62800016
RTRNSPCD EQU   X'14'                                                    63200016
RTRNCDE5 EQU   X'1A'                                                    63600016
RTRNCDE3 EQU   X'83'                                                    64000016
RTRNCDE2 EQU   X'82'                                               000F 64200018
RTRNCDE0 EQU   X'80'                                                    64400016
MASK1    EQU   X'0F'                                               000F 64600018
CHAINCD1 EQU   X'70'                                                    64800016
IOBSNDEN EQU   X'80'                                                    65600016
TPOPRRPL EQU   X'05'                                                    66000016
CHNDATCK EQU   X'08'                                                    66400016
TSTIOB   EQU   4                                                        67200016
TSTUCB   EQU   2                                                        67600016
CVTPTR   EQU   16                                                       68000016
ERRCON08 DC    H'8'                                                     68400016
TPOPCODE EQU   5                                                        68800016
MASKALL  EQU   X'FF'                                                    69200016
DECCONV  EQU   X'0D'                                                    69600016
CCWREAD  EQU   X'02'                                                    70000016
TPOPPTXT EQU   X'30'                                                    70400016
HIBIT    EQU   X'C0'                                                    70800016
TPOPATXT EQU   X'20'                                                    71200016
DECSNO   EQU   X'40'                                                    71600016
ERRMAXCT EQU   7                                                        72000016
NONAME   EQU   X'00'                                                    72400016
EREXCP   EQU   15                                                       72800016
RETURN   EQU   3                                                        73200016
TPOPRENQ EQU   X'0B'                                                    73600016
TPOPRREN EQU   X'0C'                                                    74000016
DYNBUF   EQU   X'08'                                                    74400016
CCWAPOLL EQU   X'09'                                                    74800016
CCWWRITE EQU   X'01'                                                    75200016
CCWPREP  EQU   X'06'                                                    75400016
CMDCHAIN EQU   X'60'                                                    76000016
NAKCOUNT EQU   2                                                        76400016
CCWTIC   EQU   X'08'                                                    76800016
ENQCOUNT EQU   X'01'                                                    77200016
IOBERR   EQU   X'20'                                                    77600016
ERLOD25  EQU   2043                                                     78000016
VECTXL   EQU   44                                                       78400016
WRRESET  EQU   X'0A'                                             A27601 78800019
ERREG4   EQU   0                                                        79200016
TSTREG   EQU   1                             TWELVE STAR REGISTER       79600016
ERREG2   EQU   2                             WORK REGISTER 2            80000016
ERREG3   EQU   3                             WORK REGISTER 3            80400016
CCWREG   EQU   4                             CCW ADDRESS REGISTER       80800016
DECBRG   EQU   5                             DECB ADDRESS REGISTER      81200016
DCBREG   EQU   6                             DCB  ADDRESS REGISTER      81600016
UCBREG   EQU   7                             UCB  ADDRESS REGISTER      82000016
COMREG   EQU   8                             COMMUNICATION VECTOR REG   82400016
ERREG1   EQU   9                                                        82800016
IOBRG    EQU   10                            IOB ADDRESS REGISTER       83200016
ERRLNK   EQU   12                            LINK REGISTER              83600016
SAVREG   EQU   13                            SAVE REGISTER              84000016
ERRETR   EQU   14                            RETURN REGISTER            84400016
BASREG   EQU   15                            BASE REGISTER              84800016
         DCBD  DSORG=BX,DEVD=BS              DCB DESECT MACRO           85200016
         IECTIOBX                                                       85600016
         IECTDECB                                                       86000016
         END                                                            86400016
