         TITLE 'IGE0704A - RD/SKP WRT/BK CHECK MODULE'                  00020000
IGE0704A CSECT                                                          00040000
*126901260630                                                      9855 00060000
         SPACE 2                                                        00080000
*********************************************************************** 00100000
* STATUS -          CHANGE LEVEL 000    JANUARY 31, 1967                00120000
*                                                                     * 00140000
* FUNCTION-        THIS MODULE DETERMINES IF A WRITE/BREAK WAS ISSUED * 00160000
*                  IF A LOST DATA ERROR HAS OCCURRED A BRANCH TO THE  * 00180000
*                  LOST DATA ROUTINE IS TAKEN.  IF NECESSARY THE      * 00200000
*                  CHANNEL PROGRAM IS RETRIED.  LINKAGE IS PROVIDED   * 00220000
*                  TO THE DISABLE ROUTINE IF REQUIRED.                * 00240000
*                                                                     * 00260000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 00280000
*                  TO THE ASSOCIATED IO RB.                           * 00300000
*                                                                     * 00320000
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 00340000
*                  ERROR.  SETS INDICATOR FOR ERROR IN ERP EXCP.      * 00360000
*                                                                     * 00380000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 00400000
*                                                                     $ 00420000
* EXITS-           EXITS THROUGH LINKAGE TO MODULES IGE0304B,         * 00440000
*                  IGE0504A, AND IGE0904A.                            * 00460000
*                                                                     * 00480000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 00500000
*********************************************************************** 00520000
         SPACE 2                                                        00540000
         USING *,BASREG                                                 00560000
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  00580000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  00600000
         L     COMREG,LOC016            ADDRESS OF CVT                  00620000
         L     DCBREG,IOBDCBAD(IOBRG)   ADDRESS OF DCB                  00640000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 00660000
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  00680000
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           00700000
         CLI   0(CCWREG),CCWWRTBK       WAS A WRITE BREAK ISSUED        00720000
         BNE   ERRCHK03                 NO DETERMINE ENTRY POINT        00740000
         TM    IOBCSW+4(IOBRG),MASKALL-CSWCDE IS THIS NORMAL COMPLETION 00760000
         BNZ   ERRCHK01                 NO DETERMINE FAILURE TYPE       00780000
         CLI   IOBCSW+5(IOBRG),NONAME   EXAMINE SECOND STATUS BYTE      00800000
         BE    ERRCHK03                 NO ERROR CONTINUE NORMAL OPER.  00820000
ERRCHK01 CLI   IOBCSW+4(IOBRG),CSWCDEUC ERROR UNIT CHECK WITH CHAN END  00840000
         BNE   ERRCHK19                 NO INDICATE ERP AND SNO ERROR   00860000
         TM    IOBSNS(IOBRG),IOBSNDC    DATA CHECK ERROR                00880000
         BO    ERRCHK02                 YES CHECK XFER COUNT IN CCW     00900000
         TM    IOBSNS(IOBRG),IOBSNBOC   BUSSOUT ERROR                   00920000
         BO    ERRCHK03                 NORMAL ERROR CONTINUE PROCESSNG 00940000
         B     ERRCHK19                 INDICATE ERP AND SNO ERROR      00960000
ERRCHK02 CLI   7(CCWREG),MASK15         FIRST WRITE BREAK               00980000
         BNE   ERRCHK19                 NO INDICATE ERP AND SNO ERROR   01000000
         LH    ERREG1,6(CCWREG)         PICK UP WRITE COUNT             01020000
         SLL   ERREG1,1                 DOUBLE WRITE COUNT              01040000
         STH   ERREG1,6(CCWREG)         STORE NEW COUNT                 01060000
         SVC   EXCPER                   RE-EXECUTE CHAN PROGRAM         01080000
         SVC   RETURN                   EXIT                            01100000
ERRCHK03 CLI   IOBECT+1(IOBRG),ERRLDIND LOST DATA FAILURE               01120000
         BE    ERRCHK11                 YES GO TO LOST DATA ERROR ENTRY 01140000
         L     ERREG2,IOBERINF(IOBRG)   POINTER TO ORIGINAL FAILING CCW 01160000
         SH    ERREG2,ERRCN8            ADJUST TO REAL FAILING CCW      01180000
         MVC   IOBWRK(1,IOBRG),TPCODE(ERREG2) PICK UP TP OP CODE        01200000
         NI    IOBWRK(IOBRG),MASKALL-HIBIT CLEAR UNWANTED BITS          01220000
         TM    IOBWRK(IOBRG),CCWAFTXT   ERROR AFTER TEXT TRANSFER       01240000
         BZ    ERRCHK06                 NO CHECK FOR DYNAMIC BUFFERING  01260000
ERRCHK04 ST    ERREG2,IOBSTART(IOBRG)   SET CPA TO FAILING CCW     9855 01280000
ERRCHK05 CLI   IOBECT(IOBRG),ERTRYCT    MORE RETRIES NECESSARY          01300000
         BNL   ERRCHK07                 NO CHECK FOR DISABLE REQUIRED   01320000
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             01340000
         LA    ERREG1,1(ERREG1)         BUMP COUNT BY ONE               01360000
         STC   ERREG1,IOBECT(IOBRG)     STORE NEW COUNT                 01380000
         MVI   IOBECT+1(IOBRG),NONAME   INDICATE NORMAL RETURN          01400000
         SVC   EXCPER                   EXECUTE CHAN PROG.              01420000
         SVC   RETURN                   EXIT                            01440000
ERRCHK06 TM    DCBBFTEK(DCBREG),DCBDYNBF DYNAMIC BUFFERING SPECIFIED    01460000
         BO    ERRCHK10                 YES POST COMPLETE WITH ERROR    01480000
         LA    ERREG2,IOBCPA(IOBRG)     SET CPA TO START OF CHAN PROG.  01500000
         B     ERRCHK04                 RETRY CHAN PROGRAM              01520000
ERRCHK07 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                01540000
         BZ    ERRCHK10                 NO POST WITH ERROR              01560000
         LA    SAVREG,ERLOD3            ADDRESS OF DISABLE ROUTINE      01580000
ERRCHK08 L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         01600000
         BR    ERRETR                   EXIT                            01620000
ERRCHK19 OI    DECERRST(DECBRG),DECERPER INDICATE ERROR IN ERP EXCP     01640000
ERRCHK09 OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR       01660000
ERRCHK10 MVC   IOBSNS(1,IOBRG),IOBERINF(IOBRG) RESTORE SENSE DATA       01680000
         MVC   IOBCSW+1(7,IOBRG),IOBERINF+1(IOBRG)  RESTORE CSW DATA    01700000
         L     ERREG2,IOBCSW(IOBRG)     PICK UP CCW POINTER             01720000
         SH    ERREG2,ERRCN8            ADJUST TO FAILING CCW           01740000
         MVC   0(8,ERREG2),IOBERINF+8(IOBRG) RESTORE FAILING CCW        01760000
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE OBR REQUIRED           01780000
         LH    SAVREG,ERLOD5            ADDRESS OF ERROR POST           01800000
         B     ERRCHK08                 LINK TO POST ROUTINE            01820000
ERRCHK11 LA    SAVREG,ERLOD14           ADDRESS OF LOST DATA CHECK RTNE 01840000
         B     ERRCHK08           LINK VIA LINK ROUTINE                 01860000
ERRCHK15 LA    CCWREG,IOBCPA+24(IOBRG) POINT TO FOURTH CCW         1262 01860819
         TM    5(CCWREG),X'11'         READ OR WIRTE TEXT          1262 01861619
         BNO   ERRCHK10                NO, DON'T POST BUFFER       1262 01862419
         L     ERREG4,0(CCWREG)        POINT TO BUFFER             1262 01863219
         N     ERREG4,MASK             AND TO FULLWORD BOUNDARY  A27608 01864019
         SH    ERREG4,ERRCN4          POINT TO BUFFER LINK FIELD   1262 01864819
         TM    0(ERREG4),X'80'         IS WAIT BIT ON              1262 01865619
         BNO   ERRCHK10                NO, DON'T POST BUFFER       1262 01866419
         LR    ERREG2,IOBRG            SAVE IBO ADDRESS            1262 01867219
         LR    ERREG3,BASREG           SAVE BASE ADDRESS           1262 01868019
         L     IOBRG,0(ERREG4)         GET BUFFER CHAIN ADDRESS  A27607 01868419
         LA    IOBRG,0(IOBRG)          CLEAR HIGH ORDER BYTE     A27607 01868819
         O     IOBRG,POSTCODE          OR IN COMPLETION CODE     A27607 01869219
         L     ERRLNK,DCBDEBAD(DCBREG) PICK UP DEB ADDRESS         1262 01869619
         L     ERRLNK,0(ERRLNK)        PICK UP TCB ADDRESS         1262 01870419
         L     BASREG,POST(COMREG)     ADDRESS OF POST ROUTINE     1262 01871219
         BALR  ERRETR,BASREG           LINK TO POST ROUTINE        1262 01872019
         LR    IOBRG,ERREG2            RESTORE IOB ADDRESS         1262 01872819
         LR    BASREG,ERREG3           RESTORE BASE ADDRESS        1262 01873619
         B     ERRCHK10                CONTINUE PROCESSING         1262 01874419
          SPACE   2                                                     01875219
         DS    0F                                                  1262 01876019
POSTCODE DC    X'41000000'                                         1262 01876819
MASK     DC    X'00FFFFFC'                                       A27608 01877219
ERRCN4   DC    H'4'                                                1262 01877619
POST     EQU   X'98'                                               1262 01878419
DCBDEBAD EQU   X'2C'                                               1262 01879219
TSTIOB   EQU   4                                                        01880000
TSTUCB   EQU   2                                                        01900000
LOC016   EQU   16                                                       01920000
IOBDCBAD EQU   20                                                       01940000
IOBDECB  EQU   4                                                        01960000
IOBCSW   EQU   8                                                        01980000
ERRCN8   DC    H'8'                                                     02000000
CCWWRTBK EQU   X'0D'                                                    02020000
MASKALL  EQU   X'FF'                                                    02040000
CSWCDE   EQU   X'0C'                                                    02060000
NONAME   EQU   X'00'                                                    02080000
CSWCDEUC EQU   X'0E'                                                    02100000
IOBSNDC  EQU   X'80'                                                    02120000
IOBSNBOC EQU   X'20'                                                    02140000
IOBSNOVR EQU   X'40'                                                    02160000
IOBSNS   EQU   2                                                        02180000
MASK15   EQU   X'0F'                                                    02200000
EXCPER   EQU   15                                                       02220000
RETURN   EQU   3                                                        02240000
IOBECT   EQU   30                                                       02260000
ERRLDIND EQU   X'08'                                                    02280000
IOBERINF EQU   48                                                       02300000
IOBWRK   EQU   33                                                       02320000
DECERRST EQU   29                                                       02340000
ERRCN2   DC    H'10'                                                    02360000
TPCODE   EQU   5                                                        02380000
HIBIT    EQU   X'C0'                                                    02400000
CCWAFTXT EQU   X'20'                                                    02420000
IOBSTART EQU   16                                                       02440000
ERTRYCT  EQU   X'02'                                                    02460000
STATAB   EQU   112                                                      02480000
UCBSTI   EQU   9                                                        02500000
DECTYPE  EQU   4                                                        02520000
DECDYNBF EQU   X'80'                                                    02540000
IOBCPA   EQU   64                                                       02560000
UCBTYP   EQU   16                                                       02580000
DCBBFTEK EQU   32                                                       02600000
DCBDYNBF EQU   X'08'                                                    02620000
DECERPER EQU   X'20'                                                    02640000
CSWSNO   EQU   X'40'                                                    02660000
SWLINE   EQU   X'90'                                                    02680000
ERLOD3   EQU   3041                                                     02700000
VECTXL   EQU   44                                                       02720000
IOBLOG   EQU   X'01'                                                    02740000
IOBFL3   EQU   8                                                        02760000
ERLOD5   DC    H'5041'                                                  02780000
CCWRDCMD EQU   X'02'                                                    02800000
DCBERROP EQU   33                                                       02820000
DCBRDTRY EQU   X'02'                                                    02840000
DECRDRPT EQU   X'07'                                                    02860000
SAVEAREA DC    16F'0'                                                   02880000
CSWLDDCO EQU   X'0E'                                                    02900000
CSWLD    EQU   X'02'                                                    02920000
ERRCN0   DC    H'00'                                                    02940000
ERLOD14  EQU   4042                                                     02960000
*        REGISTER DEFINITION                                            02980000
ERREG3   EQU   0                             W69K REG                   03000000
TSTREG   EQU   1                             TWELVE STAR REG            03020000
ERREG2   EQU   2                             WORK REG                   03040000
CRBREG   EQU   3                             CURRENT RB REG             03060000
CCWREG   EQU   4                             CCW ADDRESS REG            03080000
DECBRG   EQU   5                        DECB REGISTER                   03100000
DCBREG   EQU   6                        DCB REGISTER                    03120000
UCBREG   EQU   7                             UCB ADDRESS  REG           03140000
COMREG   EQU   8                             COMMUNICATION TABLE REG    03160000
ERREG1   EQU   9                                                        03180000
IOBRG    EQU   10                       IOB BASE REGISTER               03200000
ERREG4   EQU   11                            WORK R57                   03220000
ERRLNK   EQU   12                            LINK REG                   03240000
SAVREG   EQU   13                                                       03260000
ERRETR   EQU   14                            RETURN REG                 03280000
BASREG   EQU   15                            BASE REG                   03300000
         END                                                            03320000
