         TITLE '  IGE0704B - 3270 ERROR POST '                          00400021
IGE0704B CSECT                                                          00800021
         EJECT                                                          00865021
*********************************************************************** 01200021
*                   3270 ERROR POST                                   * 01600021
*********************************************************************** 02000021
*                                                                     * 02400021
* STATUS:                                                             * 02800021
*    CHANGE LEVEL 001         APRIL 4, 1972                           * 03200021
*                                                                     * 03600021
* FUNCTION:                                                           * 04000021
*    THIS MODULE IS AN ADDITIONAL LOAD OF THE BSC ERP AND IS XCTL'D   * 04400021
*    TO BY BSC ERP CONTROL (IGE0004C). IT FORMATS THE T-TYPE RECORD   * 04800021
*    USING INFORMATION IN THE ERROR STATUS MESSAGE (SOH%R MESSAGE)    * 05200021
*    FOR THE DEVICES OF THE REMOTE 3270 DISPLAY SYSTEM.               * 05600021
*                                                                     * 06000021
* ENTRY:                                                              * 06400021
*         TO THE FIRST EXECUTABLE INSTRUCTION.                        * 06800021
*                                                                     * 07200021
* INPUT:                                                              * 07600021
*    THE ADDRESS OF THE RQE IN REGISTER ONE.                          * 08000021
*    THE ADDRESS OF THE SOH%R MESSAGE IN IOBERINF.                    * 08400021
*    SOH%R MESSAGE FORMAT (BSC3):                                     * 08800021
*       +++++++++++++++++++++++++++++++++++++++++++++++++             * 09200021
*       +       +       +       +       +       +       +             * 09600021
*    +0 +  SOH  +   %   +   R   +  STX  +   CU  +   DS  +             * 10000021
*       +       +       +       +       +       +       +             * 10400021
*       +++++++++++++++++++++++++++++++++++++++++++++++++             * 10800021
*       +       +       +       +                                     * 11200021
*    +6 + STAT1 + STAT2 +  ETX  +                                     * 11600021
*       +       +       +       +                                     * 12000021
*       +++++++++++++++++++++++++                                     * 12400021
*    SOH%R MESSAGE FORMAT (BSC2):                                     * 12450021
*       +++++++++++++++++++++++++++++++++++++++++++                   * 12500021
*       +     +     +     +8    +     +     +     +                   * 12550021
*    +0 + SOH +  %  +  R  + STX + SS1 + SS2 + ETX +                   * 12600021
*       +     +     +     +     +     +     +     +                   * 12650021
*       +++++++++++++++++++++++++++++++++++++++++++                   * 12700021
* OUTPUT:                                                             * 12800021
*    IOBERCCW = ADDRESS OF T-RECORD.                                  * 13200021
*    IOBFLAG1, BIT 2 (ERP IN CONTROL) = 0.                            * 13600021
*    IOBFLAG1,BIT 5 (IOB EXCEPTION) = 0.                              * 14000021
*    IOBFLAG3, BIT 7 (NO LOG BIT) = 0.                                * 14400021
*    IOBCSW, BYTE 4, BIT 7 (UNIT EXCEPTION) = 0.                      * 14800021
*    IOBINCAM, BYTE 0, BIT 5 (SOH%R MSG PROCESSED) = 1.               * 15200021
*    BSC3: IOBERINF+4: T-TYPE RECORD WITH THE FOLLOWING FORMAT:       * 15600021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 16000021
*       +        +        +        +        +        +        +       * 16400021
*    +0 +     BUFFER      +   NOT  +    XCTL INFO    + RECORD +       * 16800021
*       +      SIZE       +  USED  +        +        +   ID   +       * 17200021
*       +        +        +        +        +        +        +       * 17600021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 18000021
*       +        +        +        +        +        +        +       * 18400021
*    +6 +  CHANNEL/UNIT   +   CU   +   DS   +  STAT1 +  STAT2 +       * 18800021
*       +    ADDRESS      +        +        +        +        +       * 19200021
*       +        +        +        +        +        +        +       * 19600021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 20000021
*                                                                     * 20400021
*    BUFFER SIZE (2 BYTES) = X'000C'                                  * 20800021
*    NOT USED (1 BYTE) = X'00'.                                       * 21200021
*    XCTL INFO (2 BYTES) = X'0000' (IE. TP RECORDER SHOULD TRANSFER   * 21600021
*    CONTROL TO IOS).                                                 * 22000021
*    RECORD ID (1 BYTE) = X'03'.                                      * 22400021
*    CHANNEL/UNIT ADDRESS (2 BYTES) = CUA OF THE LINE.                * 22800021
*    CU,DS,STAT1,STAT2 (4 BYTES) = INFO FROM THE SOH%R MESSAGE        * 23200021
*    TRANSLATED TO EBCDIC IF THEY ARE IN ASCII.                       * 23600021
*                                                                     * 24000021
*    BSC2: IOBERINF+0: MDR (T-TYPE) RECORD WITH THE FOLLOWING FORMAT: * 24010021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 24020021
*       +        +        +        +        +        +        +       * 24030021
*    +0 +     BUFFER      + SUB-ID +    XCTL INFO    + RECORD +       * 24040021
*       +      SIZE       +  INFO  +        +        +   ID   +       * 24050021
*       +        +        +        +        +        +        +       * 24060021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 24070021
*       +        +        +        +        +        +        +       * 24080021
*    +6 +  CHANNEL/UNIT   +     T E R M I N A L     I D       +       * 24090021
*       +    ADDRESS      +        +        +        +        +       * 24100021
*       +        +        +        +        +        +        +       * 24110021
*       +++++++++++++++++++++++++++++++++++++++++++++++++++++++       * 24120021
*       +        +        +                                           * 24130021
*       +  STAT1 +  STAT2 +                                           * 24140021
*    +C +        +        +                                           * 24150021
*       +        +        +                                           * 24160021
*       +++++++++++++++++++                                           * 24170021
*                                                                     * 24180021
*    BUFFER SIZE (2 BYTES) = X'000E'.                                 * 24190021
*    SUB-ID INFO (1 BYTE)  = X'83' (IE, THERE IS A 4-BYTE TERMINAL ID)* 24200021
*    XCTL INFO (2 BYTES) = X'0000' (SEE BSC3 EXPLANATION).            * 24210021
*    RECORD ID (1 BYTE) = X'0B'.                                      * 24220021
*    CHANNEL/UNIT ADDR (2 BYTES) = CUA OF THE LINE.                   * 24230021
*    TERMINAL ID (4 BYTES) = UNIQUE ID OF THE TERMINAL - SAVED IN IOB.* 24240021
*    STAT1,STAT2 (2 BYTES) = SENSE/STATUS FROM SOH%R MSG.             * 24250021
*                                                                     * 24260021
*    THE TERMINAL ID AND SENSE/STATUS BYTES WILL BE TRANSLATED TO     * 24270021
*    EBCDIC IF THEY ARE IN ASCII.                                     * 24280021
*                                                                     * 24290021
* EXTERNAL REFERENCES:                                                * 24400021
*         NONE                                                        * 24800021
*                                                                     * 25200021
* EXITS, NORMAL:                                                      * 25600021
*         TP RECORDER (IGE0625F) VIA BRANCH ENTRY TO XCTL.            * 26000021
*                                                                     * 26400021
* EXITS, ERROR:                                                       * 26800021
*         NONE                                                        * 27200021
*                                                                     * 27600021
* TABLES/WORK AREAS:                                                  * 28000021
*    ASCTAB IS A 64 BYTE TRANSLATE TABLE USED TO TRANSLATE THE CU,    * 28400021
*    DS, STAT1, AND STAT2 BYTES IN THE T-RECORD TO EBCDIC IF THEY     * 28800021
*    WERE IN ASCII. (FOR BSC2, THE TERMINAL ID, RATHER THAN CU,DS, IS * 29200021
*    TRANSLATED.                                                      * 29400021
*                                                                     * 29600021
* ATTRIBUTES:                                                         * 30000021
*    TRANSIENT, ENABLED, AND REENTRANT.                               * 30400021
*                                                                     * 30800021
* CHARACTER CODE DEPENDENCY:                                          * 31200021
*    TRANSLATE TABLE AND CODE TO PROCESS ASCII DATA ARE CHARACTER     * 31600021
*    CODE DEPENDENT.                                                  * 32000021
*                                                                     * 32400021
* NOTES:                                                              * 32420021
*    NONE                                                             * 32440021
*                                                                     * 32460021
*********************************************************************** 32800021
         EJECT                                                          32820021
*/*IGE0704B: CHART*/                                                    32840021
*/* E IGE0704B*/                                                        32860021
*/* D (NO,,YES,BSC2RTN) IS IT A BSC2 DEVICE*/                           32870021
*/* P PUT RECORD ADDRESS IN IOB+40*/                                    32880021
*/* M TURN OFF 'NO' LOG BIT */                                          32900021
*/* P SET UP TPR INTERFACE INFO IN RECORD*/                             32920021
*/* P MOVE LINE ADDR FROM UCB INTO RECORD*/                             32940021
*/* P MOVE CU & DS ADDRS AND STATUS BYTES INTO RECORD*/                 32960021
*/* D (YES,,NO,NOTRANS) ASCII TRANSMISSION CODE*/                       32980021
*/* P TRANSLATE STATUS BYTES AND ADDRESS TO EBCDIC*/                    33000021
*/*NOTRANS: M TURN OFF ERP IN CONTROL INDICATORS*/                      33020021
*/* M TURN ON 'SOH%R MSG PROCESSED' BIT*/                               33040021
*/* R XCTL TO TP RECORDER*/                                             33050021
*/*                                                                     33051021
*/*BSC2RTN: P PUT RECORD ADDRESS IN IOB+40*/                            33052021
*/* M TURN OFF LOG AND PERMANENT ERROR BITS*/                           33053021
*/* P SET UP MDR INTERFACE INFO IN RECORD*/                             33054021
*/* P MOVE LINE ADDRESS INTO RECORD*/                                   33055021
*/* P MOVE TERMINAL ID INTO RECORD*/                                    33056021
*/* P MOVE SENSE/STATUS BYTES INTO RECORD*/                             33057021
*/* D (YES,,NO,NOTRANS) IS IT ASCII*/                                   33058021
*/* P (,NOTRANS) TRANSLATE TERM ID AND S/S TO EBCDIC*/                  33059021
*/*IGE0704B: END*/                                                      33060021
         EJECT                                                          33080021
         SPACE 2                                                        33200021
*        ESTABLISH ADDRESSABILITY                                       33600021
         SPACE                                                          34000021
         USING *,BASEREG                                                34400021
         USING IECTIOB,IOBREG                                           34800021
         USING IHADCB,DCBREG                                            35200021
         SPACE 2                                                        35600021
*        ADDRESS CONTROL BLOCKS AND XCTL ROUTINE                        36000021
         SPACE                                                          36400021
         L     IOBREG,TSTIOB(TSTREG)    GET ADDR OF IOB                 36800021
         LH    UCBREG,TSTUCB(TSTREG)    GET ADDR OF UCB                 37200021
         L     DCBREG,IOBDCBPT          GET ADDR OF DCB                 37600021
         L     CVTREG,CVTPTR       GET ADDR OF CVT                      38000021
         L     BRREG,XCTL(CVTREG)       XCTL ROUTINE ADDR               38400021
         SPACE 2                                                        38800021
*        SET UP TPR INTERFACE                                           39200021
         SPACE                                                          39600021
         TM    UCBTYP+1(UCBREG),BSC2  IS IT DIAL                 S99245 39700021
         BO    BSC2RTN             YES, HANDLE                   S99245 39800021
         LA    RECDPTR,IOBERINF+TRECD   POINT TO T-RECORD               40000021
         ST    RECDPTR,IOBERCCW         SAVE ADDR OF T-RECD             40400021
*                                        FOR EREP                       40800021
         NI    IOBFLAG3,LOGPMERR        TURN OFF LOG BIT AND            41000021
*                                       PERMANENT ERROR BIT             41200021
*                                       CLEAR T-RECORD                  41600021
         XC    0(RCDLNGTH,RECDPTR),0(RECDPTR)                           42000021
         MVI   BUFSIZE(RECDPTR),SIZE    MOVE BUFFER SIZE                42400021
*                                        INTO T-RECORD                  42800021
         MVI   RECDID(RECDPTR),ID       MOVE IN RECORD ID               43200021
         SPACE 2                                                        43600021
*        MOVE LINE ADDR FROM UCB INTO T-RECORD                          44000021
         SPACE                                                          44400021
         MVC   CUA(LINEADDR,RECDPTR),UCBCUA(UCBREG)                     44800021
         SPACE 2                                                        45200021
*        MOVE CU & DS ADDRS, AND STATUS BYTES INTO RECORD               45600021
         SPACE                                                          46000021
         L     RMSGPTR,IOBERINF         GET ADDR OF SOH%R               46400021
*                                        MESSAGE                        46800021
*                                       MOVE INFO INTO RECD             47200021
         MVC   CU(TOSTAT2,RECDPTR),RMSGCU(RMSGPTR)                      47600021
         SPACE 2                                                        48000021
*        TRANSLATE ADDRESS AND STATUS BYTES TO                          48400021
*         EBCIC IF THEY ARE ASCII                                       48800021
         SPACE                                                          49200021
         TM    DCBXCODE,ASCII           IS IT ASCII                     49600021
         BNO   NOTRANS                  NO, DON'T TRANSLATE             50000021
         LA    RECDPTR,CU(RECDPTR)      GET BEGIN ADDR OF               50400021
*                                        4 BYTES TO TRANS               50800021
         TR    0(ADRLNGTH,RECDPTR),ASCTAB TRANSLATE TO EBCDIC           51200021
         SPACE 2                                                        51600021
*        TURN OFF ERP IN CONTROL INDICATORS                             52000021
         SPACE                                                          52400021
*                                       TURN OFF --                     52800021
NOTRANS  EQU   *                                                        53200021
         NI    IOBCSW+4,UE                   EXCEPTION BIT              53600021
         NI    IOBCSW+5,IL        INCORRECT LENGTH BIT           A66408 53650021
         NI    IOBFLAG1,EXCEPERP         IOB EXCEPTION AND              54000021
*                                         ERP IN CTL BITS               54400021
         SPACE 2                                                        54800021
*        TURN ON 'SOH%R MSG PROCESSED' BIT                              55200021
         SPACE                                                          55600021
         OI    IOBINCAM,RMSGPROC        TURN ON BIT 5                   56000021
         SPACE 2                                                        56400021
*        TRANSFER CONTROL TO TP RECORDER                                56800021
         SPACE                                                          57200021
         L     XCTLREG,TPRADDR         ADDR OF TP RECORDER              57600021
         BR    BRREG                   EXIT VIA XCTL ROUTINE            58000021
         SPACE 2                                                 S99245 58010021
*        3275 DIAL SECTION - SET UP MDR INTERFACE                S99245 58020021
         SPACE                                                          58030021
BSC2RTN  EQU   *                                                 S99245 58040021
         L     RMSGPTR,IOBERINF    GET ADDR OF S/S MSG           S99245 58050021
         LA    RECDPTR,IOBERINF    POINT TO MDR RECORD           S99245 58060021
         ST    RECDPTR,IOBERCCW    SAVE ADDR OF MDR FOR EREP     S99245 58070021
         NI    IOBFLAG3,LOGPMERR   TURN OFF LOG BIT AND          S99245 58080021
*                                   PERMANENT ERROR BIT          S99245 58090021
         XC    0(MDRLNGTH,RECDPTR),0(RECDPTR)  CLEAR MDR AREA    S99245 58100021
         MVI   BUFRSZ(RECDPTR),BUFSZ MOVE IN BUFFER SIZE         S99245 58110021
         MVI   RCDID(RECDPTR),DIALID  MOVE IN RECORD ID          S99245 58120021
         MVI   SUBID(RECDPTR),SUBIDINF  MOVE IN SUB-ID           S99245 58130021
         SPACE 2                                                 S99245 58140021
*        PUT DEVICE-DEPENDENT INFO IN RECORD                     S99245 58150021
         SPACE                                                          58160021
         MVC   CHANUNIT(LINEADDR,RECDPTR),UCBCUA(UCBREG)         S99245 58170021
*                                  MOVE LINE ADDR INTO MDR       S99245 58180021
         MVC   TERMID(IDLENGTH,RECDPTR),IOBCPA+CPAEND            S99245 58190021
*                                  MOVE IN TERMINAL ID           S99245 58200021
         MVC   SS1(STATLNG,RECDPTR),STATUS(RMSGPTR)              S99245 58210021
*                                  MOVE IN SENSE & STATUS        S99245 58220021
         TM    DCBXCODE,ASCII      IS IT ASCII ?                 S99245 58230021
         BNO   NOTRANS             NO, DON'T TRANSLATE           S99245 58240021
         LA    RECDPTR,TERMID(RECDPTR)  GET BEGIN ADDR OF        S99245 58250021
*                                       BYTES TO TRANSLATE       S99245 58260021
         TR    0(TRANSLNG,RECDPTR),ASCTAB  TRANSLATE TERM ID     S99245 58270021
*                                          AND STATUS TO EBCDIC  S99245 58280021
         B     NOTRANS             SET UP TO XCTL                S99245 58290021
         SPACE 2                                                        58400021
*        REGISTER EQUATES                                               58800021
         SPACE                                                          59200021
TSTREG   EQU   1                        TWELVE STAR REG                 59600021
RECDPTR  EQU   2                        T-RECORD ADDR                   60000021
CVTREG   EQU   3                        CVT ADDR                        60400021
UCBREG   EQU   4                        UCB ADDR                        60800021
IOBREG   EQU   5                        IOB ADDR                        61200021
DCBREG   EQU   6                        DCB ADDR                        61600021
RMSGPTR  EQU   7                        SOH%R MSG ADDR                  62000021
WORKREG1 EQU   8                        WORK REG                        62400021
LOOPREG  EQU   10                       LOOP COUNTER REG                62800021
BASEREG  EQU   15                  BASE REG                             63200021
XCTLREG  EQU   13                                                       63600021
BRREG    EQU   14                       RETURN REG                      64000021
         SPACE 2                                                        64400021
*        CONSTANT AND DISPLACEMENT EQUATES                              64800021
         SPACE                                                          65200021
TSTIOB   EQU   4                        RQE DISP OF IOB ADDR            65600021
TSTUCB   EQU   2                        RQE DISP OF UCB ADDR            66000021
XCTL     EQU   44                       CVT DISP OF XCTL                66400021
*                                        ROUTINE ADDR                   66800021
TRECD    EQU   4                        IOBERINF DISP OF                67200021
*                                        T-RECORD                       67600021
CVTPTR   EQU   16                  POINTER TO CVT                       68000021
SIZE     EQU   X'0C'                    SIZE OF RECORD                  68400021
ID       EQU   X'03'                    RECORD ID                       68800021
*                                       T-RECORD DISP OF--              69200021
BUFSIZE  EQU   1                          BUFFER SIZE + 1               69600021
RECDID   EQU   5                          RECORD ID                     70000021
CUA      EQU   6                          CHANNEL/UNIT ADDR             70400021
CU       EQU   8                          CONTROL UNIT ADDR             70800021
DS       EQU   9                          DEVICE ADDR                   71200021
STAT1    EQU   10                         STATUS BYTE 1                 71600021
STAT2    EQU   11                         STATUS BYTE 2                 72000021
RCDLNGTH EQU   12                       LENGTH OF T-RECORD              72400021
UCBCUA   EQU   4                        UCB DISP OF CUA                 72800021
TOSTAT2  EQU   4                        LENGTH OF ADDR AND              73200021
*                                        STATUS BYTES                   73600021
RMSGCU   EQU   4                        CU DISP IN SOH%R MSG            74000021
LINEADDR EQU   2                        DISP OF LINE ADDR IN            74100021
*                                        T-RECORD                       74200021
ADRLNGTH EQU   4                        LENGTH OF ADDR IN RECORD        74300021
UCBTYP   EQU   16                  DISP OF TYPE IN UCB           S99245 74306021
MDRLNGTH EQU   14                  LENGTH OF DIAL MDR RECORD     S99245 74312021
*                                  MDR RECORD DISP OF --         S99245 74318021
BUFRSZ   EQU   1                       BUFFER SIZE               S99245 74324021
SUBID    EQU   2                       SUB-ID INFO               S99245 74330021
RCDID    EQU   5                       RECORD ID                 S99245 74336021
CHANUNIT EQU   6                       CUA                       S99245 74342021
TERMID   EQU   8                       TERMINAL ID               S99245 74348021
SS1      EQU   12                      S/S1                      S99245 74354021
SS2      EQU   13                      S/S2                      S99245 74360021
IDLENGTH EQU   4                   LENGTH OF TERMINAL ID         S99245 74366021
CPAEND   EQU   64                  DISP PAST IOBCPA OF TERM ID   S99245 74372021
STATUS   EQU   4                   DISP OF STATUS IN S/S MSG     S99245 74378021
STATLNG  EQU   2                   NO. OF STATUS BYTES           S99245 74384021
TRANSLNG EQU   6                   NO. OF BYTES TO TRANSLATE     S99245 74390021
         SPACE 2                                                        74400021
*        MISCELLANEOUS EQUATES                                          74800021
         SPACE                                                          75200021
LOGPMERR EQU   X'FA'                    LOG BIT AND PERM ERR BIT        75600021
ASCII    EQU   X'14'                    ASCII SETTING                   76000021
UE       EQU   X'FE'                    UNIT EXCEPTION BIT              76400021
IL       EQU   X'BF'              INCORRECT LENGTH BIT           A66408 76450021
EXCEPERP EQU   X'DB'                    IOB EXCEPTION AND               76800021
*                                        ERP IN CONTROL BITS            77200021
RMSGPROC EQU   X'04'                    SOH%R MSG PROCESSED             77600021
BSC2     EQU   X'90'               BSC2 FEATURE IN UCB           S99245 77700021
DIALID   EQU   X'0B'                ID FOR DIAL IN MDR           S99245 77800021
SUBIDINF EQU   X'83'               SUB-ID INFO FOR DIAL - TELLS  S99245 77900021
*                                   EREP THERE IS A 4-BYTE TERM ID      78000021
*                                      ABOVE LINE CHANGED BY S99245     78100021
BUFSZ    EQU   X'0E'               BUFFER LENGTH OF MDR          S99245 78200021
         SPACE 2                                                        78400021
*        64 BYTE TRANSLATION TABLE - FROM ASCII TO EBCDIC               78800021
*         INCLUDES VALUES FROM X'20' TO X'5F' (ASCII)                   79200021
         SPACE                                                          79600021
         ORG   *-X'20'                  SAVE 20 BYTES WITH ORG          80000021
ASCTAB   DS    0F                                                       80400021
         ORG   *+X'20'                  ORG TO START OF TABLE           80800021
*                EBCDIC EQUIVALENTS     ASCII                           81200021
         DC    X'404F7F7B5B6C507D4D5D'  X'20' TO X'29'                  81600021
         DC    X'5C4E6B604B61F0F1F2F3'  X'2A' TO X'33'                  82000021
         DC    X'F4F5F6F7F8F97A5E4C7E'  X'34' TO X'3D'                  82400021
         DC    X'6E6F7CC1C2C3C4C5C6C7'  X'3E' TO X'47'                  82800021
         DC    X'C8C9D1D2D3D4D5D6D7D8'  X'48' TO X'51'                  83200021
         DC    X'D9E2E3E4E5E6E7E8E94A'  X'52' TO X'5B'                  83600021
         DC    X'6A5A5F6D'              X'5C' TO X'5F'                  84000021
*        STORAGE                                                        84010021
         SPACE                                                          84020021
TPRADDR  DC    F'6256'                  TP RECORDER IDENT               84030021
         SPACE 2                                                        84040021
         SPACE 2                                                        84400021
*        DSECTS                                                         84800021
         SPACE                                                          85200021
         IECTIOBX                                                       85600021
         DCBD  DSORG=BX,DEVD=BS                                         86000021
         END                                                            86400021
