         TITLE  'IGE0704C BSC BUS OUT ERP ROUTINE'                      00600014
IGE0704C CSECT                                                          01200014
*72420009036000,348000,360000,690000                               000C 01500015
         SPACE 2                                                        01800014
*********************************************************************** 02400014
*                                                                     * 03000014
* STATUS            CHANGE LEVEL 001    NOVEMBER 13, 1967             * 03600015
*                                                                     * 04200014
* FUNCTION          THIS ROUTINE RECOVERS FROM A BUS OUT ERROR        * 04800014
*                   WHICH MAY OCCUR DURING BSC OPERATION. THE         * 05400014
*                   TYPE OF CCW ON WHICH THE ERROR OCCURRED           * 06000014
*                   IS DETERMINED AND THE PROPER ERROR RECOVERY       * 06600014
*                   PROCEDURE IS INITIATED.                           * 07200014
*                                                                     * 07800014
* INPUT             INPUT TO THE ROUTINE IS THROUGH REGISTER 1,       * 08400014
*                   THE ADDRESS OF AN ASSOCIATED RB.                  * 09000014
*                                                                     * 09600014
* OUTPUT            SETS INDICATOR IN DERRST FIELD OF DECB FOR        * 10200014
*                   SHOULD NOT OCCUR ERROR OR INIDCATES PERMANENT     * 10800014
*                   ERROR IN IOBFLG1.                                 * 11400014
*                                                                     * 12000014
* ENTRY             ENTRY IS THE FIRST EXECUTABLE INSTRUCTION         * 12600014
*                                                                     * 13200014
* EXITS             EXITS ARE VIA SVC 15(EREXCP) & SVC 3(RETURN) TO   * 13800014
*                   RETRY AND RETURN TO IOS, TO ERROR POST IN CASE    * 14400014
*                   OF A PERMANENT ERROR                              * 15000014
*                                                                       15600014
* ATTRIBUTES        THIS MODULE IS TRANSIENT, ENABLED, REENTRANT,     * 16200014
*                   AND OPERATES IN THE ERP TRANSIENT AREA OF THE     * 16800014
*                   NUCLEUS WITH A SUPERVISOR PROTECT KEY             * 17400014
*                                                                     * 18000014
*********************************************************************** 18600014
         SPACE 2                                                        19200014
TSTREG   EQU   1                                                        19800014
CCWREG   EQU   4                                                        20400014
DECBRG   EQU   5                                                        21000014
DCBREG   EQU   6                                                        21600014
UCBREG   EQU   7                                                        22200014
COMREG   EQU   8                                                        22800014
IOBREG   EQU   10                                                       23400014
ERREG1   EQU   11                                                       24000014
ERREG2   EQU   12                                                       24600014
SAVREG   EQU   13                                                       25200014
ERRETR   EQU   14                                                       25800014
BASREG   EQU   15                                                       26400014
         SPACE 2                                                        27000014
         USING *,BASREG                                                 27600014
         USING   IECTIOB,IOBREG        BASE REGISTER FOR IOB DSECT      28200014
         USING IECTDECB,DECBRG          BASE REGISTER FOR DECB DSECT    28800014
         USING IHADCB,DCBREG            BASE REGISTER FOR DCB DSECT     29400014
         L     IOBREG,TSTIOB(TSTREG)   ADDRESS OF IOB FROM REQUEST BLK  30000014
         L     COMREG,CVTPTR                                            30600014
         L     DECBRG,IOBECBPT          ADDRESS OF DECB FROM IOB        31200014
         L     DCBREG,IOBDCBPT          ADDRESS OF DCB FROM IOB         31800014
         L     CCWREG,IOBCSW            DETERMINE ADDRESS OF FAILING    32400014
         SH    CCWREG,ERR08                  CCW                        33000014
         XC    IOBERCCW(16),IOBERCCW    CLEAR ERP CCW AREA              33300015
         L     ERRETR,CVTXTLER(COMREG)  GET XCTL RTN DDDR FROM CVT      33600014
         TM    IOBSENS0,BUSOUT         IS THIS A BUSOUT CHECK           34200014
         BO    BSCBO00B                 YES BRANCH INTO ROUTINE    000C 34800015
         CLI   0(CCWREG),CCWREAD        DID ERROR OCCUR ON A READ       34920016
         BNE   BSCOR03                  NO, GO SET SHOULD NOT OCCUR     34980016
         CLI   IOBWORK,TPOPRENQ         IS THIS READ ENQUIRY            35040016
         BE    BSCOR06                  YES, GO TO RESTART CHAN.PROG.   35100016
         CLI   IOBWORK,TPRDRENQ         IS THIS READ RESP TO ENQ        35160016
         BE    BSCOR04                  YES, RESTART W/ PREVIOUS CCW    35220016
         CLI   IOBWORK,TPOPRREN         IS THIS READ RESP TO TEXT       35280016
         BE    BSCOR05                  YES, RESTART W/ READ ENQ CCW    35340016
         CLI   IOBWORK,TPOPRTXT         IS THIS READ TEXT               35400016
         BNE   BSCOR03                  NO, GO SET SHOULD NOT OCCUR     35460016
         CLI   5(DECBRG),DECCONV  CONVERSATIONAL WRITE ?         A49678 35480021
         BNL   BSCCCC                                            A49678 35500021
         TM    4(DECBRG),AUTPOLL   USING AUTOPOLL?              SA70035 35510021
         BZ    TSTDB               NO,RETURN-GO CK DYN BFR      SA70035 35512021
         CLI   5(DECBRG),DECTYP1   READ INITIAL                 SA70035 35514021
         BNE   TSTDB               NO RETURN-CK DYN BFR         SA70035 35516021
         L     ERREG1,0(CCWREG)    GET DATA ADDR OF RD TXT      SA70035 35518021
         BCTR  ERREG1,0            SUBTRACT 1                   SA70035 35518421
         ST    ERREG1,0(CCWREG)                                 SA70035 35518821
         LH    ERREG1,6(CCWREG)    GET CCW BYTE COUNT           SA70035 35519221
         LA    ERREG1,1(ERREG1)    ADD 1 TO BYTE COUNT          SA70035 35519621
         STH   ERREG1,6(CCWREG)    RESTORE COUNT TO CCW         SA70035 35519721
TSTDB    TM    DCBBFTEK,BSCDYBUF  WAS DYNAMIC BUFFERING EMPLOYED A49678 35520021
         BO    BSCOR02                  YES, INDICATE PERMANENT ERROR   35580016
BSCOR00  LA    ERREG1,DCBBSNAK          ADDRESS OF NAK SPECIAL CHAR.    35640016
         ST    ERREG1,IOBERCCW          STORE ADDRESS IN ERP CCW AREA   35700016
BSCOR00A MVI   IOBERCCW,OPCODWRT        COMMAND CODE INTO ERP CCW       35820016
         MVI   IOBERCCW+4,FLAG                                          35880016
         MVI   IOBERCCW+7,COUNTONE      COUNT OF 1 FOR WRITE NAK CCW    35940016
         ST    CCWREG,IOBERCCW+8        READ TEXT CCW ADDRESS IN TIC    36000016
         MVI   IOBERCCW+8,BSCTICCC      TIC COMMAND CODE INTO ERP CCW   36060016
         LA    ERREG1,IOBERCCW          GET ADDRESS OF ERP CHANNEL PROG 36120016
         ST    ERREG1,IOBSTART          STORE ADDRESS IN IOB FIELD      36180016
BSCOR01  CLI   IOBERRCT,ERRMAX          RETRY COUNT AT MAXIMUM          36240016
         BE    BSCOR02                  INDICATE PERMANENT ERROR        36300016
         IC    ERREG1,IOBERRCT          UPDATE RETRY COUNT              36360016
         LA    ERREG1,1(ERREG1)           TO NEW COUNT                  36420016
         STC   ERREG1,IOBERRCT          STORE IN COUNT FIELD            36480016
         SVC   EREXCP                   GO RESTART CHANNEL PROGRAM      36540016
         SVC   RETURN                   EXIT BACK TO IOS                36600016
         SPACE 2                                                        36660016
BSCOR02  NI    IOBFLAG1,MASKALL-IOBERR  INDICATE PERMANENT ERROR        36720016
         LA    SAVREG,ERLOD25           GET ERROR ROUTINE ADDRESS       36780016
         L     ERRETR,CVTXTLER(COMREG)  LOAD XCTL ENTRY FROM CVT        36840016
         BR    ERRETR                   BRANCH INTO XCTL ROUTINE        36900016
         SPACE 2                                                        36960016
BSCOR03  OI    DECERRST,DECBSNO         SET SHOULD-NOT-OCCUR FLAG       37020016
         B     BSCOR02                  INDICATE PERMANENT ERROR & EXIT 37080016
         SPACE 2                                                        37140016
BSCOR04  SH    CCWREG,CCWSIZ08          BACK UP TO PREVIOUS CCW         37200016
BSCOR06  ST    CCWREG,IOBSTART          STORE CPA ADDRESS IN DCB FIELD  37260016
         B     BSCOR01                                                  37320016
BSCCCC   SH    CCWREG,ERR08  BACK UP TO RD RESP TO TEXT          A49678 37340021
         B     TSTDB                                             A49678 37360021
         SPACE 2                                                        37380016
BSCOR05  EQU   *                                                        37440016
         LA    ERREG1,DCBBSENQ          GET ADDRESS OF ENQ CHARACTER    37500016
         ST    ERREG1,IOBERCCW          STORE ENQ ADDRESS IN CCW        37560016
         MVI   IOBERCCW+5,TPOPWENQ      MOVE IN WRITE TQ TP CODE        37620016
         B     BSCOR00A                 GO FINISH CCW AND EXCP          37680016
BSCBO00B EQU   *                                                        37800014
         CLI   0(CCWREG),CCWREAD        WAS CCW FOR A READ OPERATION    39600014
         BE    BSCBO02                  CHK. CT. AND RETRY IF POSSIBLE  40200014
         CLI   0(CCWREG),CCWDIAL        CCW FOR A DIAL COMMAND          40800014
         BE    BSCBO03                  DISABLE LINE AND DIAL AGAIN     41400014
         CLI   0(CCWREG),CCWPOLL        CCW FOR A POLL COMMAND          42000014
         BE    BSCBO04                  RE-EXECUTE CHANNEL PROGRAM      42600014
         CLI   0(CCWREG),CCWRITE        CCW FOR A WRITE COMMAND         43200014
         BNE   BSCBO00                  NO, RETRY FAILING COMMAND       43800014
         TM    TPOPCODE(CCWREG),PRIORTXT  CCW PRIOR TO TEXT TRANSFER    44400014
         BZ    BSCBO05                  YES, CHECK FOR WRITE EOT CCW    45000014
         TM    TPOPCODE(CCWREG),DURINTXT  CCW DURING TEXT TRANSFER      45600014
         BO    BSCBO02                  YES, RETRY FAILING CCW IF CAN   46200014
         TM    TPOPCODE(CCWREG),LASTCOMD  CCW LAST ONE IN CHAN.PROGRAM  46800014
         BZ    BSCBO06                  NO, RESTART W/ NEXT CCW         47400014
BSCBO00  ST    CCWREG,IOBSTART          ADDR. OF FAILING CCW IN IOBSTAR 48000014
BSCBO00A CLI   IOBERRCT,ERRMAX          RETRY COUNT AT MAXIMUM          48600014
         BE    BSCBO01                  YES, GO INDICATE A PERM. ERROR  49200014
         IC    ERREG1,IOBERRCT          NO, UPDATE RETRY COUNT BY ONE   49800014
         LA    ERREG1,1(ERREG1)             AND ISSUE EXCP TO RESTART   50400014
         STC   ERREG1,IOBERRCT              WITH THE FAILING CCW        51000014
         SVC   EREXCP                                                   51600014
         SVC   RETURN                   RETURN TO IOS                   52200014
         SPACE 2                                                        52800014
BSCBO02  CLC   COUNT(2,CCWREG),IOBCSW+6 RESIDUAL COUNT = ORIGINAL  000F 53400018
         BE    BSCBO00                  YES, RETRY FAILING COMMAND      54000014
BSCBO01  NI    IOBFLAG1,MASKALL-IOBERR  SET PERMANENT ERROR FLAGS       54600014
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            55200016
         BR    ERRETR                   BRANCH TO XCTL ROUTINE          55800014
BSCBOSNO OI    DECERRST,DECBSNO        SET PERMANENT ERROR FLAG         56400014
         B     BSCBO01                 GO TO ERRPOST VIA XCTL ROUTINE   57000014
         SPACE 2                                                        57600014
         SPACE 2                                                        58200014
BSCBO03  XC    IOBERCCW(12),IOBERCCW    CLEAR OUT NEEDED CCW AREA       58800014
         MVI   IOBERCCW,DISABLE         MOVE DISABLE COMMAND CODE       59400014
         MVI   IOBERCCW+5,TPDISAB       DSABLE TP CODE IN CCW           60000014
         MVI   IOBERCCW+7,DISABCNT      COUTN IN CCW                    60600014
         MVI   IOBERCCW+4,FLAGS         CC & SLI FLAGS INTO CCW         61200014
         ST    CCWREG,IOBERCCW+8        USER CCW ADDR IN TIC COMMAND    61800014
         MVI   IOBERCCW+8,TICCOMMD      TIC COMMAND CODE IN CCW         62400014
BSCBO04  LA    ERREG2,IOBCPA           UPDATE IOBSTART TO POINT TO      64200014
         ST    ERREG2,IOBSTART            START OF USER CHANNEL PROG.   64800014
         L     ERREG1,IOBCPA+8         ADDR. OF USER POLLING ENTRY      65400014
         MVC   IOBCPA+9(3),DECENTRY+1  MOVE FAILING ENTRY ADDR TO CCW   66000014
         L     ERREG2,IOBCPA+8         ADDR. OF FAILING POLL CCW        66600014
         SR    ERREG1,ERREG2           COUNT BETWEEN USER AND FAILED    67200014
         AH    ERREG1,IOBCPA+14        ADD TOTAL COUNT FROM USER ENTRY  67800014
         STH   ERREG1,IOBCPA+14        STORE NEW COUNT IN POLL CCW      68400014
         B     BSCBO00A                 GO EXECUTE                 000C 69000015
         SPACE 2                                                        69600014
BSCBO05  CLI   IOBWORK,WRITEOT         WRITE EOT CCW                    70200014
         BE    BSCBO00                                                  70800014
BSCBO06  LA    CCWREG,NEXTCCW(CCWREG)  ADDRESS OF NEXT CCW       A26893 71400019
         ST    CCWREG,IOBSTART                                          72000014
         B     BSCBO00A                                                 72600014
         SPACE 2                                                        73200014
ERR08    DC    H'08'                    NO BYTES IN ONE CCW             73800014
AUTPOLL  EQU   X'80'               DECTYPE BIT FOR AUTOPOLL     SA70035 73850021
DECTYP1  EQU   X'01'               DECTYPE+1                    SA70035 73900021
TPOPCODE EQU   5                        LOCATION OF TP CODE IN CCW      74400014
MASKALL  EQU   X'FF'                                                    75000014
UNUSBIT  EQU   X'C0'                    HIGH ORDER BITS OF TP CODE      75600014
DECCONV  EQU   X'0D'   CONVERSATIONAL WRITE                      A49678 75900021
CCWREAD  EQU   X'02'                    COMMAND CODE FOR READ CCW       76200014
CCWDIAL  EQU   X'29'                    COMMAND CODE FOR DIAL           76800014
CCWPOLL  EQU   X'09'                    COMMAND CODE FOR POLL           77400014
CCWRITE  EQU   X'01'                    COMMAND CODE FOR WRITE          78000014
PRIORTXT EQU   X'F0'                    MASK TO SEE IF CCW PRIOR TO TXT 78600014
DURINTXT EQU   X'10'                    CCW DURING TEXT TRANSFER        79200014
LASTCOMD EQU   X'80'                    LAST CCW IN CHANNEL PROGRAM     79800014
NORMRET  EQU   X'00'                    NORMAL RETURN FLAGS SET BY ERP  80400014
ERRMAX   EQU   7                        MAXIMUM NO RETRIES ALLOWED      81000014
IOBERR   EQU   X'20'                    PERMANENT ERROR FLAG            81600014
STATAB   EQU   112                      STATISTCS TAB POINTER IN CVT    82200014
DEC10    EQU   10                       NO. BYTES PER ENTRY IN STATAB   82800014
COUNT    EQU   6                                                        83400018
DISABLE  EQU   X'27'                    COMMAND CODE FOR DISABLE CCW    84000014
TPDISAB  EQU   X'01'                    TP CODE FOR DISABLE CCW         84600014
DISABCNT EQU   X'01'                    COUNT FOR DISABLE CCW           85200014
FLAGS    EQU   X'60'                    FLAGS FOR DISABLE CCW           85800014
TICCOMMD EQU   X'08'                    COMMAND CODE FOR TIC COMMAND    86400014
WRITEOT  EQU   X'02'                    TP CODE FOR WRITE EOT           87000014
NEXTCCW  EQU   X'08'                                                    87600014
CVTXTLER EQU   44                                                       88200014
ERLOD25  EQU   2043                                                     88800016
EREXCP   EQU   15                                                       89400014
RETURN   EQU   3                                                        90000014
TSTIOB   EQU   4                                                        90600014
UCBSTI   EQU   9                                                        91200014
CVTPTR   EQU   16                                                       91800014
BUSOUT   EQU   X'20'                   BUS OUT BIT IN SENSE BYTE        92400014
OVERRUN  EQU   X'04'                   OVERRUN BIT IN SENSE BYTE        93000014
DECBSNO  EQU   X'40'                   SHOULD NOT OCCUR FLAG IN DECB    93600014
LODOVRRN   EQU   1044                                                   94200014
TPOPRENQ EQU   X'0B'                    TP CODE FOR READ ENQ            94240016
TPRDRENQ EQU   X'0C'                    TP CODE FOR READ-RESPONSE-ENQ   94280016
TPOPRREN EQU   X'25'                    TP OP CODE FOR RD RESP TO TEXT  94320016
TPOPRTXT EQU   X'11'                    TP CODE FOR READ TEXT           94360016
BSCDYBUF EQU   X'08'                    DYNAMIC BUFFERING FLAG          94400016
NONAME   EQU   X'00'                    NULL FLAG BYTE TO TURN OFF FLGS 94440016
TPOPWNAK EQU   X'08'                                                    94480016
COUNTONE EQU   X'01'                    COUNT FOR WRITE NAK & ENQ CCWS  94520016
OPCODWRT EQU   X'01'                    OP-CODE FOR A WRITE COMMAND     94560016
BSCTICCC EQU   X'08'                    OP-CODE FOR TIC COMMAND         94600016
CCWSIZ08 DC    H'08'                    BYTE-SIZE OF CCW                94640016
TPOPWENQ EQU   X'03'                                                    94680016
FLAG     EQU   X'60'                                                    94720016
         SPACE 2                                                        94800014
         IECTDECB                                                       95400014
         SPACE 2                                                        96000014
         IECTIOBX                                                       96600014
         SPACE 2                                                        97200014
         DCBD  DSORG=BX,DEVD=BS                                         97800014
         SPACE 2                                                        98400014
         END                                                            99000014
