         TITLE 'IGE0804A - BTAM ERP STATUS CHECK MODULE'                00020000
IGE0804A CSECT                                                          00040000
         SPACE 2                                                        00060000
*********************************************************************** 00080000
* STATUS -          CHANGE LEVEL 000    DECEMBER 27, 1966               00100000
*                                                                     * 00120000
* FUNCTION-        CHECKS FOR THE FOLLOWING CINDITIONS AND BRANCHES   * 00140000
*                  TO THE PROPER ROUTINE.                             * 00160000
*                        1. CHAIN CHECK                               * 00180000
*                        2. PROGRAM CHECK                             * 00200000
*                        3. PROTECTION CHECK                          * 00220000
*                        4. UNIT EXCEPTION                            * 00240000
*                                                                     * 00260000
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 00280000
*                  TO THE ASSOCIATED IO RB.                           * 00300000
*                                                                     * 00320000
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 00340000
*                  ERROR.                                             * 00360000
*                                                                     * 00380000
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 00400000
*                                                                     * 00420000
* EXITS-           EXITS THROUGH RESIDENT ERROR INTERPRETER           * 00440000
*                  AND MODULES IGE0504A, IGE0904A, IGE0304B.          * 00460000
*                                                                     * 00480000
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 00500000
*********************************************************************** 00520000
         SPACE 2                                                        00540000
*        STATUS CHECK MODULE                                            00560000
         USING *,BASREG                                                 00580000
         L     IOBRG,TSTIOB(TSTREG)     ADDRESS OF IOB                  00600000
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  00620000
         L     COMREG,LOC016            ADDRESS OF CVT                  00640000
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 00660000
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  00680000
         SH    CCWREG,ERRCN8            ADJUST TO FAILING CCW           00700000
         STM   ERREG3,BASREG,SAVEAREA   SAVE REGISTERS                  00720000
         LA    SAVREG,SAVEAREA          POINT TO SAVEAREA               00740000
         LR    ERREG1,BASREG            SAVE BASE                       00760000
         L     BASREG,VECT68(COMREG)    ADDRESS OF INTERPRETER          00780000
ERRSCR00 BALR  ERRLNK,BASREG            LINK TO INTERPRETER             00800000
         DC    X'1F'                    CHAIN CHECK INDICATOR           00820000
         DC    AL1(ERRSCR01-ERRSCR00-2) INDEX TO CHAIN CHECK ROUTINE    00840000
         DC    X'1A'                    PROGRAM CHECK INDICATOR         00860000
         DC    AL1(ERRSCR02-ERRSCR00-4) INDEX TO PROGRAM CHECK ROUTINE  00880000
         DC    X'1B'                    PROTECTION CHECK INDICATOR      00900000
         DC    AL1(ERRSCR03-ERRSCR00-6) INDEX TO PROTECTION CHECK RTN   00920000
         DC    X'17'                    UNIT EXCEPTION INDICATOR        00940000
         DC    AL1(ERRSCR04-ERRSCR00-8) UNIT EXCEPTION ROUTINE POINTER  00960000
         DC    X'2F'                    SCAN END INDICATOR              00980000
         DC    AL1(ERRSCR05-ERRSCR00-10) SHOULD NOT OCCUR ERRORS        01000000
ERRSCR01 EQU   *                                                        01020000
ERRSCR02 EQU   *                                                        01040000
ERRSCR03 EQU   *                                                        01060000
         B     ERRSCR06                 CHECK FOR SWITCHED LINE         01080000
ERRSCR04 LA    SAVREG,ERLOD13           ADDRESS OF UNIT EXCEPTION RTN   01100000
         B     ERRLINK1                 EXIT ROUTINE                    01120000
ERRSCR05 OI    DECERRST(DECBRG),CSWSNO  INDICATE SHOULD NOT OCCUR ERROR 01140000
ERRSCR06 TM    UCBTYP+1(UCBREG),SWLINE  IS A DISABLE REQUIRED           01160000
         BZ    ERRSCR07                 NO GO TO OBR ROUTINE            01180000
         MVI   IOBECT+1(IOBRG),MASK15   SPECIAL ENTRY INDICATOR         01200000
         LH    SAVREG,ERLOD9            ADDRESS OF DISABLE ROUTINE      01220000
ERRLINK1 L     ERRETR,VECTXL(COMREG)    ADDRESS OF LINK ROUTINE         01240000
         BR    ERRETR                   LINK                            01260000
ERRSCR07 OI    IOBFL3(IOBRG),IOBLOG     INDICATE OUTBOARD RECORDING     01280000
         LH    SAVREG,ERLOD5            ADDRESS OF POST ROUTINE         01300000
         B     ERRLINK1                 EXIT                            01320000
TSTIOB   EQU   4                                                        01340000
TSTUCB   EQU   2                                                        01360000
LOC016   EQU   16                                                       01380000
IOBCSW   EQU   8                                                        01400000
ERRCN8   DC    AL2(8)                                                   01420000
SAVEAREA DC    16F'0'                                                   01440000
VECT68   EQU   68                                                       01460000
ERLOD9   DC    AL2(9041)                                                01480000
IOBDECB  EQU   4                                                        01500000
DECERRST EQU   29                                                       01520000
CSWSNO   EQU   X'40'                                                    01540000
UCBTYP   EQU   16                                                       01560000
SWLINE   EQU   X'90'                                                    01580000
IOBECT   EQU   30                                                       01600000
MASK15   EQU   X'0F'                                                    01620000
ERLOD13  EQU   3042                                                     01640000
VECTXL   EQU   44                                                       01660000
ERLOD5   DC    AL2(5041)                                                01680000
IOBFL3   EQU   8                                                        01700000
IOBLOG   EQU   X'01'                                                    01720000
*        REGISTER DEFINITION                                            01740000
ERREG3   EQU   0                             W69K REG                   01760000
TSTREG   EQU   1                             TWELVE STAR REG            01780000
ERREG2   EQU   2                             WORK REG                   01800000
CRBREG   EQU   3                             CURRENT RB REG             01820000
CCWREG   EQU   4                             CCW ADDRESS REG            01840000
DECBRG   EQU   5                        DECB REGISTER                   01860000
DCBREG   EQU   6                        DCB REGISTER                    01880000
UCBREG   EQU   7                             UCB ADDRESS  REG           01900000
COMREG   EQU   8                             COMMUNICATION TABLE REG    01920000
ERREG1   EQU   9                                                        01940000
IOBRG    EQU   10                            IOB ADDRESS REG            01960000
ERREG4   EQU   11                            WORK R57                   01980000
ERRLNK   EQU   12                            LINK REG                   02000000
SAVREG   EQU   13                                                       02020000
ERRETR   EQU   14                            RETURN REG                 02040000
BASREG   EQU   15                            BASE REG                   02060000
         END                                                            02080000
