         TITLE 'BSC ERP EQUIPMENT CHECK, COMMAND REJECT MODULE'         00400016
IGE0804C CSECT                                                          00800016
*72430013025000,290000-295000                                      000C 01200015
         SPACE 2                                                        01500014
*********************************************************************** 02000014
* STATUS            CHANGE LEVEL  001   NOVEMBER 14, 1967               02500015
*                                                                     * 03000014
* FUNCTION         THIS ROUTINE ATTEMPTS RECOVERY OF EQUIPMENT        * 03500014
*                  CHECK AND CHANNEL DATA CHECK ERRORS DURING         * 04000014
*                  OS/BTAM BINARY SYNCHRONOUS COMMUNICATIONS          * 04500014
*                  OPERATION.                                         * 05000014
*                                                                     * 05500014
* INPUT            REGISTER ONE CONTAINS A POINTER TO THE IO RB       * 06000014
*                  ASSOCIATED TO THE LINE IN ERROR                    * 06500014
*                                                                     * 07000014
* OUTPUT           ATTEMPTED OPERATION IS POSTED WITH OR              * 07500014
*                  WITHOUT ERROR                                      * 08000014
*                                                                     * 08500014
* ENTRY            THE FIRST EXECUTABLE INSTRUCTION OF THE MODULE     * 09000014
*                                                                     * 09500014
* EXITS            IOS VIA EREXCP, SUPERVISOR VIA RETURN, ERROR       * 10000014
*                  POST ROUTINE VIA BRANCH ENTRY TO XCTL              * 10500014
*                                                                     * 11000014
* ATTRIBUTES       THIS ROUTINE IS ENABLE, TRANSIENT, REENTRANT       * 11500014
*                  AND OPERATES WITH A SUPERVISOR PROTECT KEY IN      * 12000014
*                  THE NUCLEUS ERP TRANSIENT AREA.                    * 12500014
*********************************************************************** 13000014
         SPACE 2                                                        13500014
         USING IECTDECB,DECBRG                                          14000014
         USING IECTIOB,IOBRG                                            14500014
         USING IHADCB,DCBREG                                            15000014
         USING *,BASREG                                                 15500014
         L     IOBRG,TSTIOB(TSTREG)    ADDRESS OF IOB                   16000014
         LH    UCBREG,TSTUCB(TSTREG)   ADDRESS OF UCB                   16500014
         L     COMREG,CVTPTR           ADDRESS OF CVT                   17000014
         L     DCBREG,IOBDCBPT         ADDRESS OF DCB                   17500014
         L     DECBRG,IOBECBPT                                          18000014
         L     CCWREG,IOBCSW           ADDRESS OF NEXT CCW              18500014
         SH    CCWREG,ERRCON08         ADJUST TO FAILING CCW            19000014
         L     ERRETR,VECTXL(COMREG)   LINK ROUTINE                     19500014
         MVC   IOBWORK(1),TPOPCODE(CCWREG) INITIALIZE WORK AREA         20000014
         NI    IOBWORK,MASKALL-HIBIT   CLEAR UNUSED BITS                20500014
         TM    IOBSENS0,CSWCDREJ       THIS CMD REJECT                  21000014
         BO    BSCEC03                 YES GET NEXT LOAD                21500014
         TM    IOBCSW+5,CHNDATCK       CHANNEL DATA CHECK               22000014
         BO    BSCDC00                 YES CONTINUE FLOW                22500014
         TM    IOBWORK,TPOPDTXT        ERROR DURING TEXT                23000014
         BNO   BSCEC00E                 NO ALL SET FOR RETRY       000C 23500015
         TM    DCBBFTEK,DYNBUF         THIS DYNAMIC BUFFERING           24000014
         BO    BSCEC02                 YES SET PERM ERROR               24500014
         TM    IOBWORK,TPOPDTXT        ERROR ON WRITE DLE-ETX    A26917 24600019
         BO    BSCEC00D                YES, RETRY CCW            A26917 24700019
BSCEC00F CLI   IOBWORK+4,NONAME        CHECK FOR RD OR SND ENQ          25000014
         BE    BSCEC01                 READ ENQ                         25500014
         LA    ERREG3,CCWWRITE         SET TO GENERATE CHAN PROG        26000014
BSCEC00  LA    ERREG4,CCWTIC           2ND COMMAND CODE                 26500014
BSCEC00A LA    ERREG2,DCBBSENQ         DATA AREA                        27000014
BSCEC00B LA    ERREG1,1                DATA COUNT                 23125 27500018
BSCEC00C ST    ERREG2,IOBERCCW         CONSTRUCT 1ST CCW DATA ADDR      28000014
         STC   ERREG3,IOBERCCW         PUT IN COMMAND                   28500014
         ST    ERREG1,IOBERCCW+4        STORE COUNT                000C 29000015
         MVI   IOBERCCW+4,CHAINCDE      SET CCW FLAGS              000C 29500015
         ST    CCWREG,IOBERCCW+8       SET TO RETRY CCW ADDRESS         30000014
         STC   ERREG4,IOBERCCW+8       SET TIC OR NOP COMMAND           30500014
         ST    ERREG1,IOBERINF+4                                 A66466 30550021
         LA    CCWREG,IOBERCCW         NEW CCW ADDRESS                  31000014
BSCEC00D ST    CCWREG,IOBSTART         SET CCW POINTER TO CHAN RESTART  31500014
BSCEC00E CLI   IOBERRCT,ERRMAXCT       RETRY COUNT AT MAX               32000014
         BNL   BSCEC02                 YES SET PERM ERROR INDICATOR     32500014
         IC    ERREG1,IOBERRCT         PICK UP OLD COUNT                33000014
         LA    ERREG1,1(ERREG1)        BUMP TO NEW COUNT                33500014
         STC   ERREG1,IOBERRCT         STORE NEW COUNT                  34000014
         SVC   EREXCP                  EXECUTE CHAN PROG                34500014
         SVC   RETURN                  RETURN TO SUPERVISOR             35000014
BSCEC01  CLI   0(CCWREG),CCWREAD       THIS A READ FAILURE              35500014
         BNE   BSCEC01A               NO, SET UP READ ENQ               36000014
         CLI   IOBCPA,CCWAPOLL         POLLING OPERATION                36500014
         BNE   BSCEC01A                NO NORMAL READ                   37000014
         L     ERREG1,IOBCPA+48        READ TEXT CCW                    37500014
         BCTR  ERREG1,0               REDUCE BY ONE                     38000014
         ST    ERREG1,IOBCPA+48        RESTORE NEW AREA AND COMMAND     38500014
         LH    ERREG1,IOBCPA+54        PICK UP COUNT                    39000014
         LA    ERREG1,1(ERREG1)       BUMP BY ONE                       39500014
         STH   ERREG1,IOBCPA+54        PUT NEW COUNT IN CCW             40000014
         LA    CCWREG,IOBCPA+48       ADDRESS OF FAILING COMMAND        40500014
BSCEC01A LA    ERREG2,IOBWORK+2        DATA AREA                        41000014
BSCEC01B LA    ERREG4,CCWNOP           2ND COMMAND                      41500014
         LA    ERREG3,CCWREAD          GENERATE CHAN PROG 1ST COMMAND   42000014
         MVI   IOBWORK+1,RTRNCDE0      SPECIAL ROUTIN IND               42300016
         MVI   IOBERRCT+1,RTRNSPCD     SET FOR SPECIAL RETURN           42600016
         LA    ERREG1,2                DATA COUNT                 23125 42900018
         B     BSCEC00C                                           23125 43200018
BSCDC00  CLI   0(CCWREG),CCWWRITE      ERROR ON A WRITE                 43500014
         BNE   BSCDC01                 NO CHECK FURTHER                 44000014
         CLI   IOBWORK,TPOPDTXT        DURING TEXT                      44500014
         BE    BSCEC02                 YES SET PERM ERROR               45000014
         ST    CCWREG,IOBSTART         SET TO RETRY CHAN PROG           45500014
         B     BSCEC00E                CHECK RETRIES                    46000014
BSCDC01  CLI   IOBWORK,TPOPDTXT        DURING TEXT                      46500014
         BNE   BSCDC02                 NO CHK FURTHER                   47000014
         TM    DCBBFTEK,DYNBUF         DYNAMIC BUFFERING                47500014
         BO    BSCEC02                 SET PERM ERROR                   48000014
         LA    ERREG2,DCBBSNAK         ADDRESS OF NAK CHARS             48500014
         LA    ERREG4,CCWTIC           2ND COMMAND                      49000014
         LA    ERREG3,CCWWRITE         1ST COMMAND                      49500014
         B     BSCEC00B                GENERATE CHAN PROGRAM            50000014
BSCDC02  CLI   IOBWORK,TPOPRENQ        READ ENQ                         50500014
         BE    BSCEC00D                YES RETRY CHAN PROG              51000014
         B     BSCEC00F                CHECK SEND OR RCV ENQ            51500014
BSCEC02  NI    IOBFLAG1,MASKALL-IOBERR INDICATE PERM ERROR              52000014
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            52500016
         BR    ERRETR                  LINK TO ERROR POST               53000014
BSCEC03  SR    ERREG1,ERREG1            CLEAR LINKAGE REGISTER          53020016
         CLI   IOBERRCT+1,NORMRET            SPECIAL RETURN             53040016
         BNE   BSCCR02                       YES, CHK FOR GOOD WRT DLE  53060016
         CLI   0(CCWREG),CCWRDCMD                 READ COMMAND          53080016
         BNE   BSCCR03                            NO,  INDICATE SNO ERR 53100016
         CLI   DECTPCOD,RDRESPOP                  READ RESP AFTER TEXT  53120016
         BNE   BSCCR03                            NO,  INDICATE SNO ERR 53140016
         MVC   IOBWORK+2(1),DCBBSDLE    PICK UP DLE CHAR           000C 53160016
         MVC   IOBWORK+3(1),DCBBSENQ    PICK UP ENQ CHAR           000C 53180016
         LA    ERREG2,IOBWORK+2         ADDRESS OF AREA            000C 53200016
         LA    ERREG3,CCWWRTCD          FIRST COMMAND CODE         000C 53220016
         LA    ERREG4,NOOP              SECOND COMMAND             000C 53240016
         LA    ERREG1,2                 COUNT                      000C 53260016
         ST    ERREG2,IOBERCCW          SET UP AREA IN CCW         000C 53280016
         STC   ERREG3,IOBERCCW          PUT IN COMMAND             000C 53300016
         STH   ERREG1,IOBERCCW+6        PUT IN COUNT               000C 53320016
         MVI   IOBERCCW+4,CHAINCDE      SET CHAINING               000C 53340016
         ST    CCWREG,IOBERCCW+8        RESTART ADDRESS                 53360017
         STC   ERREG4,IOBERCCW+8        SECOND COMMAND             000C 53380016
         ST    ERREG1,IOBERCCW+12       COUNT IN SECOND CCW        000C 53400016
*                                                                     * 53420016
*                   A WRITE DLE-ENQ CCW IS SET IN IOBERCCW            * 53440016
*                   FAILING CCW ADDRESS IS SAVED FOR RESTART          * 53460016
*                                                                     * 53480016
         MVI   IOBERRCT+1,SPECRET                 SPECIAL RETURN SET    53500016
         CLI   IOBERRCT,ERRMAXCT                  RETRIES EXHAUSTED     53520016
         BE    BSCCR03                            YES,  SET PERM ERROR  53540016
         IC    ERREG1,IOBERRCT                    UPDATE RETRY COUNT    53560016
         LA    ERREG1,1(ERREG1)                    TO NEW VALUE         53580016
         STC   ERREG1,IOBERRCT                    STORE IN COUNT FIELD  53600016
         LA    CCWREG,IOBERCCW         CHAN START                       53620016
         ST    CCWREG,IOBSTART         SET RESTART ADDRESS              53640016
         SVC   EREXCP                             EXECUTE CHANNEL PROG  53660016
         SVC   RETURN                             EXIT VIA POST         53680016
         SPACE 2                                                        53700016
BSCCR03  NI    IOBFLAG1,MASKALL-IOBERR            INDICATE PERM ERROR   53720016
         MVI   IOBERRCT,ERRMAXCT       INDICATE NO RETRIES         000C 53740016
         LA    SAVREG,ERLOD25          ADDRESS OF ERROR POST            53760016
         L     ERRETR,VECTXL(COMREG)              ADDR OF XCTL ROUTINE  53780016
         BR    ERRETR                             EXIT VIA XCTL         53800016
         SPACE 2                                                        53820016
BSCCR02  TM    IOBCSW+4,MASKALL-CSWCDE            ANY COND BUT CE-DE    53840016
         BM    BSCCR03                            YES, PERMANENT ERROR  53860016
         TM    IOBCSW+4,CSWCDE                    CHAN END AND DEV END  53880016
         BNO   BSCCR03                            NO,  PERMANENT ERROR  53900016
         CLI   IOBCSW+5,NONAME                    ANY STATUS IN BYTE 2  53920016
         BNE   BSCCR03                            YES, PERMANENT ERROR  53940016
         MVC   IOBSTART+1(3),IOBERCCW+9      WRT DLE-ENQ WAS GOOD       53960016
         MVI   IOBERRCT+1,NORMRET                 NORMAL RETURN. RETRY  53980016
*                                                  THE FAILING CCW      54000016
         SVC   EREXCP                             EXECUTE CHANNEL PROG  54020016
         SVC   RETURN                             EXIT VIA POST         54040016
         SPACE 2                                                        54060016
ERLOD33  EQU   3044                                                     54500014
CSWCDREJ EQU   X'80'                                                    55000014
CCWDIAL EQU    X'29'                                                    55500014
CCWDISAB EQU   47                                                       56000014
RTRNCDE0 EQU   X'80'                                                    56500014
CCWRDSKP EQU   0                                                        57000014
CCWNOP   EQU   3                                                        57500014
TPOPDTXT EQU   X'11'                                                    58000014
LERBLDID EQU   X'00'                                                    58500014
TPOPRRTX EQU   X'25'                                                    59000014
READINIT EQU   X'01'                                                    59500014
RDINITEN EQU   X'15'                                                    60000014
CHAINCDE EQU   X'60'                                                    60500014
LERBTOID EQU   X'02'                                                    61000014
IOBSNDEN EQU   X'80'                                                    61500014
TPOPRRPL EQU   X'05'                                                    62000014
CHNDATCK EQU   X'08'                                                    62500014
LERBDCID EQU   X'01'                                                    63000014
TSTIOB   EQU   4                                                        63500014
TSTUCB   EQU   2                                                        64000014
CVTPTR   EQU   16                                                       64500014
ERRCON08 DC    H'8'                                                     65000014
TPOPCODE EQU   5                                                        65500014
MASKALL  EQU   X'FF'                                                    66000014
CCWREAD  EQU   X'02'                                                    66500014
TPOPPTXT EQU   X'30'                                                    67000014
HIBIT    EQU   X'C0'                                                    67500014
TPOPATXT EQU   X'20'                                                    68000014
DECSNO   EQU   X'40'                                                    68500014
ERRMAXCT EQU   7                                                        69000014
NONAME   EQU   X'00'                                                    69500014
EREXCP   EQU   15                                                       70000014
RETURN   EQU   3                                                        70500014
TPOPRENQ EQU   X'0B'                                                    71000014
TPOPRREN EQU   X'0C'                                                    71500014
DYNBUF   EQU   X'08'                                                    72000014
CCWAPOLL EQU   X'09'                                                    72500014
CCWWRITE EQU   X'01'                                                    73000014
CMDCHAIN EQU   X'60'                                                    73500014
NAKCOUNT EQU   2                                                        74000014
CCWTIC   EQU   X'08'                                                    74500014
ENQCOUNT EQU   X'01'                                                    75000014
IOBERR   EQU   X'20'                                                    75500014
VECTXL   EQU   44                                                       76500014
ERLOD12  EQU   1042                                                     77000014
ERREG4   EQU   0                                                        77500014
TSTREG   EQU   1                             TWELVE STAR REGISTER       78000014
ERREG2   EQU   2                             WORK REGISTER 2            78500014
ERREG3   EQU   3                             WORK REGISTER 3            79000014
CCWREG   EQU   4                             CCW ADDRESS REGISTER       79500014
DECBRG   EQU   5                             DECB ADDRESS REGISTER      80000014
DCBREG   EQU   6                             DCB  ADDRESS REGISTER      80500014
UCBREG   EQU   7                             UCB  ADDRESS REGISTER      81000014
COMREG   EQU   8                             COMMUNICATION VECTOR REG   81500014
ERREG1   EQU   9                                                        82000014
IOBRG    EQU   10                            IOB ADDRESS REGISTER       82500014
ERRLNK   EQU   12                            LINK REGISTER              83000014
SAVREG   EQU   13                            SAVE REGISTER              83500014
ERRETR   EQU   14                            RETURN REGISTER            84000014
BASREG   EQU   15                            BASE REGISTER              84500014
ERLOD25  EQU   2043                                                     84530016
ERRCON1  DC    AL2(8)                             DECIMAL EIGHT         84560016
RTRNSPCD EQU   X'14'                                                    84590016
CCWRDCMD EQU   X'02'                              READ COMMAND CODE     84620016
CCWWRTCD EQU   X'01'                              WRITE COMMAND CODE    84650016
CSWCDE   EQU   X'0C'                              CHAN-DEVICE END       84680016
NOOP     EQU   X'03'                                               000C 84710016
IOBEX    EQU   X'04'                              EXCEPTION FLAG        84740016
IOBEXE   EQU   IOBERR+IOBEX                       ERR & EXCEPTION FLAGS 84770016
NORMRET  EQU   X'00'                              NORMAL RETURN         84800016
RDRESPOP EQU   X'25'                              BSC RD RESP AFTER TXT 84830016
SPECRET  EQU   X'04'                              SPECIAL RETURN CMDREJ 84860016
CCWCOUNT EQU   X'02'                                               000C 84890016
         DCBD  DSORG=BX,DEVD=BS              DCB DESECT MACRO           85000014
         IECTDECB                                                       85500014
         IECTIOBX                                                       86000014
         END                                                            86500014
