         TITLE 'IGE0904A - BTAM ERP CONTROL LOAD TWO MODULE'            00600018
IGE0904A CSECT                                                          01200018
*127100920460,01640820,01660830,01800900                           000A 01800018
         SPACE 2                                                        02400018
*********************************************************************** 03000018
* STATUS -          CHANGE LEVEL 001    APRIL 25, 1967                  03600018
*                                                                     * 04200018
* FUNCTION-        THIS MODULE IS ENTERED FOR EQUIPMENT CHECK ERRORS. * 04800018
*                  DETERMINES IF A SPECIAL ENTRY IS REQUIRED FOR      * 05400018
*                  EXECUTING DISABLE.  IF REQUIRED THE FAILING CHANNEL* 06000018
*                  PROGRAM IS RETRIED.  LINKAGE IS PROVIDED TO THE    * 06600018
*                  ERROR POST ROUTINE.                                * 07200018
*                                                                     * 07800018
* INPUT-           INPUT TO THE MODULE IS THROUGH REGISTER 1 POINTER  * 08400018
*                  TO THE ASSOCIATED IO RB.                           * 09000018
*                                                                     * 09600018
* OUTPUT-          SETS INDICATOR IN DECERRST FOR SHOULD NOT OCCUR    * 10200018
*                  ERROR.                                             * 10800018
*                                                                     * 11400018
* ENTRY-           ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION.      * 12000018
*                                                                     * 12600018
* EXITS-           EXITS THROUGH LINKAGE TO MODULE IGE0504A.          * 13200018
*                                                                     * 13800018
* ATTRIBUTES-      MODULE IS TRANSIENT, ENABLED, AND REENTRANT        * 14400018
*********************************************************************** 15000018
         SPACE 2                                                        15600018
         USING *,BASREG                                                 16200018
ERRSTART L     IOBRG,TSTIOB-1(TSTREG)   ADDRESS OF IOB                  16800018
         LH    UCBREG,TSTUCB(TSTREG)    ADDRESS OF UCB                  17400018
         L     COMREG,LOC016            ADDRESS OF CVT                  18000018
         L     DECBRG,IOBDECB(IOBRG)    ADDRESS OF DECB                 18600018
         L     CCWREG,IOBCSW(IOBRG)     ADDRESS OF CCW                  19200018
         SH    CCWREG,ERRCN1            ADJUST TO FAILING CCW           19800018
         CLI   IOBECT+1(IOBRG),MASK15   SPECIAL ENTRY                   20400018
         BE    ERRTOVR5                 YES                             21000018
         L     ERREG2,STATAB(COMREG)    STASTISTICS TABLE POINTER       21600018
         SR    ERREG1,ERREG1            CLEAR REGISTER                  22200018
         IC    ERREG1,UCBSTI(UCBREG)    INDEX TO TABLE ENTRY            22800018
         LR    ERREG4,ERREG2            SAVE STAT TABLE START ADDR 000H 22900018
ERRLOOP1 CH    UCBREG,0(ERREG4)         DEVICE SUPPORTED THIS SECT 000H 23000018
         BL    ERRLOOP2                 YES, ADJUSTED CORRECTLY    000H 23100018
         LA    ERREG4,2(ERREG4)         POINT TO NXT CTL ENTRY     000H 23200018
         LA    ERREG1,256(ERREG1)       POINT TO NXT STAT TBL SECT 000H 23300018
         B     ERRLOOP1                 LOOP TO CHECK THIS SECTION 000H 23400018
ERRLOOP2 MH    ERREG1,ERRCN2            ADJUST FOR ENTRY LENGTH    000H 23500018
         AR    ERREG2,ERREG1            ACTUAL TABLE ENTRY              24000018
         OC    8(1,ERREG2),IOBSNS(IOBRG) PUT SENSE DATA INTO TABLE      24600018
         CLI   IOBECT(IOBRG),ERTRYCT    RETRY COUNT 2                   25200018
         BE    ERRTOVR                  YES POST COMPLETE               25800018
         IC    ERREG1,IOBECT(IOBRG)     PICK UP RETRY COUNT             26400018
         LA    ERREG1,1(ERREG1)         UPDATE COUNT                    27000018
         STC   ERREG1,IOBECT(IOBRG)     STORE IN COUNT FIELD            27600018
         ST    CCWREG,IOBSTART(IOBRG)   START PTR TO FAILING CCW   000A 28200018
         SVC   EXCPER                                                   28800018
         SVC   RETURN                                                   29400018
ERRTOVR  TM    IOBCSW+4(IOBRG),CSWASCB  SHOULD NOT OCCUR ERROR          30000018
         BNZ   ERRTOVR1                 YES SNO MSG REQ                 30600018
         TM    IOBCSW+4(IOBRG),CSWUCK   UNIT CHECK                      31200018
         BZ    ERRTOVR1                 NO INDICATE SNO ERROR           31800018
         TM    IOBSNS(IOBRG),CSWCRBO    CMD REJ OR BUSS OUT             32400018
         BNZ   ERRTOVR2                 YES-BYPASS SNO MESSAGE          33000018
ERRTOVR1 OI    DECERRST(DECBRG),CSWSNO  INDICATE SNO ERROR              33600018
ERRTOVR2 TM    IOBCC(IOBRG),IOBCC1      SIO COND CODE 1                 34200018
         BZ    ERRTOVR3                 NO CONTINUE                     34800018
         LA    ERREG1,ERRCN08           BUMP CONSTANT                   35400018
         MVC   IOBCSW+1(3,IOBRG),IOBSTART+1(IOBRG) WHEW!                36000018
ERRTOVR4 L     ERREG2,IOBCSW(IOBRG)     FIRST WORD OF CSW               36600018
         AR    ERREG2,ERREG1            ADJUST TO FAILING CCW           37200018
         ST    ERREG2,IOBCSW(IOBRG)     STORE IN CSW                    37800018
         NI    IOBCC(IOBRG),MASKALL-IOBCC1 TURN OF SIO COND CODE        38400018
ERRTOVR3 MVI   IOBECT+1(IOBRG),TERMPASS INDICATE TERM ID BYPASS         39000018
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOG OUT                39600018
         LH    SAVREG,ERLOD5            ADDRESS OF  POST ROUTINE        40200018
         L     ERRETR,VECTXL(COMREG)    ADDR OF LINK ROUTINE            40800018
         BR    ERRETR                                                   41400018
ERRTOVR5 TM    UCBTYP+1(UCBREG),SWLINE  DISABLE REQUIRED                42000018
         BZ    ERRTOVR3                 NO, WTO                         42600018
         MVC   IOBSAV1+8(8,IOBRG),0(CCWREG) SAVE FAILING CCW            43200018
         MVC   IOBSAV1(1,IOBRG),IOBSNS(IOBRG) SAVE SENSE DATA           43800018
         MVC   IOBSAV1+1(7,IOBRG),IOBCSW+1(IOBRG) SAVE CSW DATA         44400018
         MVI   IOBECT+1(IOBRG),DISABIND INDICATE DISABLE EXECUTED       45000018
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOG OUT                45600018
         MVC   IOBDCCW(8,IOBRG),DISABCMD GENERATE CCW                   46200018
         LA    ERREG1,IOBDCCW(IOBRG)    CHANNEL PROGRAM START           46800018
         ST    ERREG1,IOBSTART(IOBRG)   CPA IN POINTER                  47400018
         SVC   EXCPER                   EXECUTE CHANNEL PROGRAM         48000018
         SVC   RETURN                   EXIT                            48600018
DISABCMD DC    X'2F00000020300001'                                      49200018
*   THE FOLLOWING CONSTANTS MUST BE ALIGNED ON A HALFWORD BOUNDARY 000A 49800018
ERRCN1   DC    H'8'                     DECIMAL 8                  000A 50400018
ERRCN2   DC    H'10'                                               000A 51000018
ERLOD5   DC    H'5041'                                             000A 51600018
CSWASCB  EQU   X'F0'                                                    52200018
CSWCRBO  EQU   X'A0'                                                    52800018
CSWSNO   EQU   X'40'                                                    53400018
CSWUCK   EQU   X'02'                        UNIT CHECK                  54000018
DECERRST EQU   29                                                       54600018
DISABIND EQU   X'80'                                                    55200018
ERRCN08  EQU   8                                                        55800018
ERTRYCT  EQU   X'02'                                                    56400018
EXCPER   EQU   15                           EXCP ERROR ROUTINE          57000018
IOBCC    EQU   16                           CONDITION CODE              57600018
IOBCC1   EQU   X'10'                        CONDITION CODE OF SIO       58200018
IOBCC3   EQU   X'30'                                                    58800018
IOBCPA   EQU   64                                                       59400018
IOBCSW   EQU   8                            CSW STORAGE                 60000018
IOBDCCW  EQU   40                                                       60600018
IOBDECB  EQU   4                                                        61200018
IOBECT   EQU   30                      ERROR COUNTS                     61800018
IOBERR   EQU   X'20'                        IOB ERROR FLAG              62400018
IOBEX    EQU   X'04'                        EXCEPT FLAG                 63000018
IOBEXE   EQU   IOBEX+IOBERR                 EX+ERR FLAGS                63600018
IOBFL1   EQU 0                              FLAGS 1                     64200018
IOBFL3   EQU   8                            FLAGS3                      64800018
IOBLOG   EQU   X'01'                        LOGOUT FLAG                 65400018
IOBSAV1  EQU   48                                                       66000018
IOBSNS   EQU   2                            SENSE DATA                  66600018
IOBSRS   EQU   X'01'                        START/RESTART FLAG          67200018
IOBSTART EQU   16                                                       67800018
LOC016   EQU   16                           COMMUNICATIONS TABLE        68400018
MASKALL  EQU   255                                                      69000018
MASK15   EQU   X'0F'                                                    69600018
RETURN   EQU   3                       RETURN SVC                       70200018
STATAB   EQU  112                          INDEX TO STATISTICS TABLE    70800018
SWLINE   EQU   X'90'                                                    71400018
TERMPASS EQU   X'40'                                                    72000018
TSTIOB   EQU   5                            IOB POINTER                 72600018
TSTUCB   EQU   2                            UCB POINTER                 73200018
UCBSTI   EQU   9                            STATISTICS POINTER          73800018
UCBTYP   EQU   16                      DEVICE TYPE CODE                 74400018
VECTXL   EQU   44                           VECTOR TO XCTL ROUT955      75000018
*        REGISTER DEFINITION                                            75600018
ERREG3   EQU   0                             WORK REG                   76200018
TSTREG   EQU   1                             TWELVE STAR REG            76800018
ERREG2   EQU   2                             WORK REG                   77400018
CRBREG   EQU   3                             CURRENT RB REG             78000018
CCWREG   EQU   4                             CCW ADDRESS REG            78600018
DECBRG   EQU   5                        DECB REGISTER                   79200018
DCBREG   EQU   6                        DCB REGISTER                    79800018
UCBREG   EQU   7                             UCB ADDRESS  REG           80400018
COMREG   EQU   8                             COMMUNICATION TABLE REG    81000018
ERREG1   EQU   9                                                        81600018
IOBRG    EQU   10                            IOB ADDRESS REG            82200018
ERREG4   EQU   11                            WORK REG                   82800018
ERRLNK   EQU   12                            LINK REG                   83400018
SAVREG   EQU   13                                                       84000018
ERRETR   EQU   14                            RETURN REG                 84600018
BASREG   EQU   15                            BASE REG                   85200018
         END                                                            85800018
