 TITLE 'IGG0193S  BTAM LINE GROUP OPEN EXECUTOR - LOAD 4'               00200017
IGG0193S CSECT                                                          00400017
* STATUS -          CHANGE LEVEL 006    23JUNE 1969                000M 00700019
*                                                                     * 01000017
*FUNCTION/OPERATION- THIS ROUTINE IS BROUGHT INTO CORE AND GIVEN      * 01200017
*  CONTROL WHEN OPEN EXECUTOR LOAD3 FOR TELECOMMUNICATIONS ISSUES     * 01400017
*  'XCTL' TO IGG0193S.                                                * 01600017
*  THIS ROUTINE LOADS THE REQUIRED OPEN TELECOMMUNICATION MODULES,AND * 01800017
*  STORES THE ID OF THE MODULES AND A COUNT OF MODULES LOADED, INTO   * 02000017
*  THE DEB AND SETS UP TERMINAL TEST MASK IF REQUIRED.                * 02200017
*                                                                     * 02400017
*                                                                     * 02600017
*                                                                     * 02800017
*ENTRY POINT- ENTRY WILL BE TO THE FIRST BYTE OF THE MODULE BY AN     * 03000017
*  'XCTL' TO IGG0193S THE FOURTH BTAM LOAD.                             03200017
*INPUT-  THE REGISTERS 6,7,8 ARE THE INPUT AS FOLLOWS,                * 03400017
*       6 -   BEGINNING OF THE WHERE-TO-GO TABLE                      * 03600017
*       7 -   ADDRESS OF THE CURRENT ENTRY IN THE                     * 03800017
*       8 -   ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE   * 04000017
*         REGESTERS 9-15 ARE BROUGHT FORWARD IN THE WORK AREA PROVIDED* 04200017
*        BY THE WTG ENTRY.                                            * 04400017
*                                                                     * 04600017
*                                                                     * 04800017
*OUTPUT-THE REGISTERS 7,8 WILL BE POSITIONED TO THE NEXT UNFINISHED   * 05000017
*  ENTRY, AND THE REQUIRED BTAM MODULES WILL BE LOADED INTO CORE.     * 05200017
*EXTERNAL ROUTINES-                                                   * 05400017
*                                                                     * 05600017
*EXIT-NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO   * 05800017
*  ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO THAT       * 06000017
*  ROUTINE.                                                           * 06200017
*EXIT-ERRORS-                                                         * 06400017
*                                                                     * 06600017
*TABLES/WORK AREAS- 1.DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH * 06800017
*  DCB SPECIFIED IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO    * 07000017
*  TABLE CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE * 07200017
*  DCB WHICH CORRESPONDS TO THIS ENTRY. THE CHNIDTBL CONTAINS THE     * 07400017
*  IDS NEEDED FOR WHERE-TO-GO TABLE AND LOAD OF REQUIRED OPEN MODULES.* 07600017
*         REGESTERS 9-15 ARE BROUGHT FORWARD IN THE WORK AREA PROVIDED* 07800017
*        BY THE WTG ENTRY.                                            * 08000017
*ATTRIBUTES-THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS         * 08200017
*       ENABLED, PRIVILEGED, AND REENTRANT.                           * 08400017
*                                                                     * 08600017
*NOTES-  THIS ROUTINE COMPLETES THE OPEN PROCESSING FOR               * 08800017
*  TELECOMMUNICATION SO THE WHERE-TO-GO TABLE ENTRY WILL BE SET TO 0  * 09000017
RE       EQU   0                       WORK/PARAMREG                    09200017
RF       EQU   1                       WORK/PARAMREG                    09400017
RDCB     EQU   2                       DCB ADDRESS                      09600017
RBASE    EQU   3                       BASE REGISTER                    09800017
RCORE    EQU   4                       IOB ADDRESS                      10000017
RPAR     EQU   5                       START OF PARAMETER LIST          10200017
RWTG     EQU   6                       START OF WTG                     10400017
RPARC    EQU   7                       CURRENT ENTRY IN PARAMETER LIST  10600017
RWTGC    EQU   8                       CURRENT ENTRY IN WTG TABLE       10800017
RTIOT    EQU   9                       TIOT ADDRESS                     11000017
RUCB     EQU   10                      CURRENT UCB                      11200017
RDEB     EQU   11                      DEB ADDRESS                      11400017
RB       EQU   12                      WORK REG                         11600017
RC       EQU   13                      WORK REG                         11800017
RD       EQU   14                      WORK/PARAMREG                    12000017
RJ       EQU   15                      WORK/PARAMREG                    12200017
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 12400017
         USING IECTIOB,RCORE                                            12600017
         USING IHADCB,RDCB                                              12800017
         USING IECTDEB,RDEB                                             13000017
         EJECT                                                          13200017
         BALR  RBASE,0                                                  13400017
         USING *,RBASE                                                  13600017
         L     RDCB,0(RPARC)            DCB ADDRESSABILITY         000D 13800017
         L     RDEB,DCBDEBAD            LOAD DEB ADDRESS           000D 14000017
         L     RDEB,28(RDEB)            LOAD DEB START FOR DSECT   000D 14200017
         LA    RB,DEBUCBAD             LOAD UCB ADDRESS          A30780 14230020
         SR    RUCB,RUCB               CLEAR REGISTER            A30780 14260020
         IC    RUCB,DEBNMEXT           LOAD NO EXTENTS(UCB'S)    A30780 14290020
         SLL   RUCB,2                                            A30780 14320020
         AR    RUCB,RB                 ADD UCB SECTION SIZE      A30780 14350020
         SR    RTIOT,RTIOT             CLEAR REGISTER            A30780 14380020
         IC    RTIOT,DCBOFLGS          SAVE DCBOFLAGS            A30780 14410020
         ST    RUCB,DCBREAD            SAVE ACCESS METHOD ADRS   A30780 14440020
         STC   RTIOT,DCBOFLGS          RESTORE DCBOFLAGS         A30780 14470020
         IC    RTIOT,DEBAMLNG          LOAD ACCESS METHOD SIZE   A30780 14500020
         AR    RUCB,RTIOT              ADD TO GET SUB-ID AREA    A30780 14530020
         SR    RTIOT,RTIOT              CLEAR REGISTER             000E 14600017
         L     RCORE,DEBIRBAD-1         GET ADDRESS OF POINTERS    000E 14800017
         TM    DCBERROP,TRMTST          TEST FOR ONLINE-TEST       000D 15000017
         BO    ONLTST1                  IF SO, BRANCH TO SET UP    000E 15200017
TST2741  CLI   DCBDEVTP,INTR1                                      000I 15220018
         BE    INTERUPT                                            000I 15240018
         CLI   DCBDEVTP,INTR2                                      000I 15260018
         BNE   GRAPHICS                                            000I 15280018
INTERUPT LA    RB,BREAK41                                          000I 15300018
         BAL   RC,LOADROUT                                         000I 15320018
         BAL   RD,BLDIRB                                           000I 15340018
         ST    RF,8(RCORE)                                         000I 15360018
         SPACE 2                                                        15380018
GRAPHICS LA    RJ,DEBUCBAD         GET UCB TABLE ADDRESS           000E 15400017
         L     RJ,0(RJ)            GET UCB ADDRESS                 000E 15600017
         TM    19(RJ),X'90'        THIS DEVICE BISYNCH             000E 15800017
         BNO   LOADPCI             IF NOT, LOAD PCI APPEND         000E 16000017
         TM    DCBXCODE,GRAPHMSK   TEST FOR 1130/2250              000E 16200017
         BO    GRAPH1                   IF SO, BRANCH TO SET UP    000E 16400017
         B     LOADPCI                  GO LOAD PCI APPENDAGE      000E 16600017
INITIQE  SRL   RTIOT,1                  REDUCE TO NMBR OF EXTENTS  000E 16800017
         LA    RB,96(RF)                LOAD ADRS OF IQE POINTER   000D 17000017
         LA    RC,4(RB)                 START IQE'S IN NEXT WORD   000D 17200017
         L     RE,DEBTCBAD-1            LOAD ADDRESS OF TCB             17400018
IQEINIT  ST    RC,0(RB)                 STORE ADDRESS OF NEXT IQE  000D 17600017
         ST    RF,8(RC)                 STORE IRB ADDRESS IN IQE   000D 17800017
         ST    RE,12(RC)                STORE TCB ADDRESS               18000018
         MVI   12(RC),X'00'             ZERO OUT HIGH BYTE        23883 18100018
         LR    RB,RC                    SAVE ADDRESS OF THIS IQE   000D 18200017
         LA    RC,16(RC)                STEP TO NEXT               000D 18400017
         BCT   RTIOT,IQEINIT            DECREMENT AND TEST         000D 18600017
         ST    RTIOT,0(RB)              ZERO LAST POINTER          000D 18800017
         BR    RJ                       BRANCH                     000E 19000017
ONLTST1  IC    RTIOT,DCBDEVTP           LOAD DEVICE TYPE           000D 19200017
         LM    RB,RC,ONLTTMSK           LOAD ONLTST MASK           000D 19400017
         SLDL  RB,0(RTIOT)              SHIFT TO DEVICE BIT        000D 19600017
         LTR   RB,RB                    TEST FOR ONLTST SUPPORT    000D 19800017
         BM    TSTOK                    IF BIT=1, BRANCH           000D 20000017
         NI    DCBERROP,MASKALL-TRMTST  TURN OFF TEST BIT          000D 20200017
         B     TST2741                  GO TEST FOR 2741                20400018
TSTOK    LA    RB,ONLTST                LOAD ADDRESS OF MODULE NAME000D 20600017
         BAL   RC,LOADROUT              LINK TO LOAD ROUTINE       000D 20800017
         BAL   RD,BLDIRB                                                20830018
         ST    RF,0(RCORE)              STORE IRB ADRS IN QUEUE         20860018
         B     TST2741                                                  20890018
         SPACE 2                                                        20920018
BLDIRB   EQU   *                                                        20950018
         IC    RTIOT,DEBNMEXT      LOAD NUMBER OF EXTENTS          000E 21000017
         SLL   RTIOT,2                  MULTIPLY BY EIGHT          000D 21200017
         LA    RTIOT,1(RTIOT)           ADD 1 FOR SIZE OF WORKAREA 000D 21400017
         CIRB  EP=(RE),KEY=SUPR,MODE=SUPR,STAB=(RE),WKAREA=(RTIOT) 000D 21600017
         BAL   RJ,INITIQE          LINK TO IQE INIT                000E 21800017
         BR    RD                                                       22100018
GRAPH1   L     RE,12(RCORE)             GET IRB ROUTINE ADDRESS    000E 22400017
         IC    RTIOT,DEBNMEXT      LOAD NUMBER OFEXTENTS           000E 22600017
         SLL   RTIOT,2             MULTIPLY BY EIGHT               000E 22800017
         LA    RTIOT,1(RTIOT)      ADD 1 FOR WKAREA SIZE           000E 23000017
         CIRB  EP=(RE),KEY=SUPR,MODE=SUPR,STAB=(RE),WKAREA=(RTIOT),    X23200017
               SVAREA=YES                                          000E 23400017
         BAL   RJ,INITIQE          LINK TO INITIALIZE IQE          000E 23600017
         ST    RF,4(RCORE)         STORE IRB ADDRESS               000E 23800017
LOADPCI  TM    DCBBFTEK,DYNBUF          TEST FOR DYNAMIC BUFFERING 000E 24000017
         BZ    TESTBPM                                                  24200017
         LA    RB,PCIAPP                LOAD ADDRESS OF IDTTRL ENTRY.   24400017
         BAL   RC,LOADROUT              BRANCH TO LOAD PCI APPENDAGE.   24600017
         ST    RE,DEBPCIA               STORE ADDRESS IN APPENDAGE      24800017
*                                  TABLE.                               25000017
*                LINE 252000 REMOVED                             A66464 25200021
TESTBPM  CLI   DEBAMLNG,X'00'           TEST FOR AN ACCESS METHOD       25400017
*    SECTION.  IF NOT, DO NOT LOAD BUFFER ROUTINE.                      25600017
         BZ    LOADCEAP                                                 25800017
LOADBPMR LA    RB,BPMR                  POINT TO IDTTRL TABLE AND       26000017
         BAL   RC,LOADROUT         BRANCH TO LOAD BUFFER POOL           26200017
*                                  MANAGEMENT ROUTINE.                  26400017
         L     RTIOT,DCBREAD           LOAD ACCESS METHOD ADRS   A30780 26600020
         EJECT                                                          26800017
         ST    RE,0(RTIOT)              STORE ADDRESS OF BUFFER POOL    27000017
*    MANAGEMENT ROUTINE IN FIRST WORD OF ACCESS METHOD SECTION OF DEB.  27200017
LOADCEAP EQU   *                                                        27400017
         LA    RB,CHENDAPP             ID AND TTRL FLD NEEDED FOR LOAD  27600017
         BAL   RC,LOADROUT                                              27800017
         ST    RE,DEBCEA                STORE ADDRESS OF CHANNEL END -  28000017
         ST    RE,DEBXCEA          ABNORMAL END APPENDAGE IN APPENDAGE  28200017
*                                  TABLE.                               28400017
         CLI   DCBDEVTP,DEVWTTA         IS THE WORLD TRADE TELETYPE000G 28600017
         BNE   OTHERDEV                 BRANCH IF NOT              000G 28800017
         LA    RB,CEAPPWT               LOAD ADDRESS OF IDTTRL ENTRY00G 29000017
         BAL   RC,LOADROUT              BRANCH TO LOAD CEAPP FOR WTTA.G 29200017
         LR    RB,RE                    SAVE WTTA CE APP ADDRESS   000G 29400017
         MVC   8(8,RB),DEBPCIA          MOVE PCI AND CE APP. ADDRESSESG 29600017
*                                       IN WTTA CE APPENDAGE.      000G 29800017
         ST    RE,DEBPCIA               STORE CEAPP ADDR IN APP. TABLEG 30000017
         ST    RE,DEBCEA                STORE ADDRESS OF CHANNEL END -G 30200017
         ST    RE,DEBXCEA          ABNORMAL END APP IN APPENDAGE TABLEG 30400017
OTHERDEV EQU   *                                                   000G 30600017
         LA    RB,READWR               ID AND TTRL FLD NEEDED FOR LOAD  30800017
         BAL   RC,LOADROUT             RETURN LINKAGE ESTABLISHED       31000017
*        PROTECT DCBOFLGS FIELD FOR STORE OF READ/WRITE ADDRESS         31200017
*     WHICH DESTROYES HIGH ORDER BYTE-DCBOFLGS.                         31400017
         IC    RC,DCBOFLGS                                              31600017
         ST    0,DCBREAD               ADDRESS OF READ/WRITE MODULE     31800017
         STC   RC,DCBOFLGS                                              32000017
         SPACE 2                                                   000M 32040019
         USING WORKAREA,RD                                         000M 32080019
         L     RD,4(RWTGC)              ADDRESSABILITY FOR WORK ARE000M 32120019
         SPACE 1                                                   000M 32160019
         LR    RCORE,0                 RCORE USED FOR LOCATION OF VD    32200017
         AH    RCORE,VDOFFSET          LOCATE VECTOR DIRECTORY          32400017
         SR    RTIOT,RTIOT             REG USED FOR DEVICE CODE         32600017
         IC    RTIOT,WORKAREA           PICK UP DEVICE CODE STORED 000M 32800019
*                                            MODULE IGG0194N       000M 33000019
         STC   RTIOT,DCBDEVTP          STORE IN DCB                     33400017
         SR    RC,RC         USE LINKREG AS TEMP. COUNT                 33600017
*                                 USED AS A DEVICE COUNT.               33800017
RWVDLP   NC    0(4,RCORE),0(RCORE)     TEST FOR ZERO FIELD              34000017
         BNZ   VD1                     BRANCH IF NOT ZERO FIELD    000A 34200017
         MVI   3(RCORE),X'FF'          MAKE FIELD NON ZERO       A28605 34300019
RWVD1    EQU   *                                                   000M 34500019
         LA    RB,WORKTTRL                                         000M 34800019
         STC   RC,DCBDEVTP   STORE DEVICE COUNT                         35200017
         BAL   RC,LOADROUT                                              35400017
         DROP  RD                                                  000M 35500019
NEXTSP10 ST    0,0(RCORE)              STORE VECTOR LIST ADDRESS        35600017
         STC   RTIOT,0(RCORE)          STORE DEVICE CD IN HIGH ORDER    35800017
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 36000017
         MVC   22(7,RWTG),CONATB                                        36200017
         SPACE 2                                                        36400017
ENDLOD4  XC    0(2,RWTGC),0(RWTGC)      CLEAR ID TO INDICATE            36500018
*                                       COMPLETION                      36600018
         L     RJ,4(RWTGC)              LOAD ADDRESS OF WORK AREA.      36800017
*                                  OF EXECUTOR.                         37000017
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURRENT WTG REGISTER. 37200017
         LA    RPARC,PLOFF(0,RPARC)     INCREMENT CURRENT PARAMETER     37400017
*                                  LIST REGISTER TO NEXT ENTRY.         37600017
         CLC   0(2,RWTGC),AMIDCNST      IF THE NEXT WTG ENTRY CALLS FOR 37800017
         BCR   8,RBASE                                                  38000017
         CLC   0(2,RWTGC),OPIDCNST      IF NOT, TEST FOR END OF TABLE.  38200017
         BNE   RELOOP              NOT END OF TABLE, RETURN TO CHECK    38400017
*                                  NEXT ENTRY.                          38600017
         LR    RPARC,RPAR               REINITIALIZE CURRENT WTG REG    38800017
         LA    RWTGC,WAOFF(0,RWTG) AND CURRENT PARAMETER LIST REG.      39000017
ZCHECK   CLI   0(RWTGC),X'00'                                           39200017
         BNE   XCTLRTNE            IF NOT ZERO, GO TO TRANSFER CONTROL. 39400017
         LA    RWTGC,WGOFF(0,RWTGC) IF ZERO, GET NEXT ENTRY AND RETURN  39600017
         LA    RPARC,PLOFF(0,RPARC) TO ZCHECK.                          39800017
         B     ZCHECK                                                   40000017
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 40200017
XCTLRTNE EQU   *                                                        40400017
         LA    RJ,DXCCW12(RJ)           POINT TO DOUBLE WORD LIST.      40600017
         MVC   6(2,RWTG),0(RWTGC)       MOVE ID TO NAME FIELD.          40800017
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR TO WTG TABLE.          41000017
         XCTL  DE=(RWTG),SF=(E,(15))                                    41200017
         EJECT                                                          41400017
LOADROUT MVI   22(RWTG),LOADATB         SET STANDARD LOAD ATTRIBUTES.   41600017
         MVC   6(2,RWTG),0(RB)         MOVE ID OF LAST 2 BYTES OF NAME  41800017
         MVC   14(3,RWTG),2(RB)        MOVE TTR FROM TABLE              42000017
         SR    RE,RE                                                    42200017
         IC    RE,5(0,RB)               GET DOUBLE WORD LENGTH AND      42400017
         SLL   RE,3                CONVERT TO BYTES.                    42600017
         ST    RE,24(0,RWTG)            STORE LENGTH IN PARAMETER LIST. 42800017
         MVC   25(2,RWTG),26(RWTG)      MOVE LENGTH TO FIELD WHICH      43000017
*                             INDICATES TOTAL LENGTH OF MODULE.         43200017
         CLC   0(2,RB),ONLTST           ONLINE TEST ROUTINE       M3153 43220018
         BE    ADDEIGHT                 YES, ADD 800 TO SIZE      M3153 43240018
         CLC   0(2,RB),READWR           IS THIS READWRITE               43260018
         BE    ADDEIGHT                 IF SO ADD 800 TO TTR LENGTH     43320018
         CLC   0(2,RB),CHENDAPP         IS THIS LOAD FOR CHNL END A000B 43400017
         BNE   CMPL                     IF NOT USE TTR LENGTH      000B 43600017
         OI    25(RWTG),ONE000          ADD 1000 TO TTR LENGTH          43620019
         B     LONGLOAD                                                 43640019
         SPACE 1                                                        43660019
ADDEIGHT EQU   *                                                        43700018
         OI    25(RWTG),EIGHT00         IF SO ADD 800 TO TTR LNGTH 000B 43800017
         B     LONGLOAD                 GO TO LONG LOAD            000B 44000017
CMPL     CLI   5(RB),128                COMPARE LENGTH IN DOUBLE   000B 44200017
         BH    LONGLOAD       WORDS TO 128 (OR 1024 BYTES).  IF GREATER 44400017
*                             THAN 128, BRANCH TO SPECIAL ROUTINE.      44600017
         MVC   27(2,RWTG),25(RWTG)      MOVE LENGTH TO FIELD WHICH      44800017
*                             INDICATES LENGTH OF FIRST TEXT RECORD.    45000017
LOAD     LR    RE,RWTG                  POINT TO PARAMETER LIST.        45200017
         L     RF,16(0,0)               GET COMMUNICATION VECTOR TABLE  45400017
*                                  ADDRESS.                             45600017
         L     RF,84(0,RF)              GET ADDRESS OF DCB FOR SVC LIB. 45800017
*                                                                       46000017
         LOAD  DE=(0),DCB=(1)                                           46200017
*                                                                       46400017
         MVC   0(2,RUCB),0(RB)         MOVE ID TO DEB                   46600017
         LA    RUCB,2(0,RUCB)           UPDATE POINTER TO SUBROUTINE    46800017
*                                  ID SECTION IN DEB.                   47000017
         IC    RD,DEBNMSUB              GET NMBR ROUTINES LOADED   000E 47200017
         LA    RD,1(RD)                 ADD ONE                    000E 47400017
         STC   RD,DEBNMSUB              STORE COUNT IN DEB         000E 47600017
         BR    RC                       RETURN.                         47800017
LONGLOAD MVC   27(2,RWTG),CONATB+3      SET LENGTH OF FIRST TEXT RECORD 48000017
*                                  TO 1024 (400 HEX).                   48200017
         MVI   22(RWTG),LOADATB1        MODIFY ATTRIBUTES TO INDICATE   48400017
*                                  MORE THAN ONE TEXT RECORD.           48600017
         B     LOAD                                                     48800017
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 49000017
VD1      CLC   DCBDEVTP(1),0(RCORE)  TEST FOR EQUAL DEVICE CODE: DCBDV  49200017
         BE    RWVD1         VS. VECTOR DIREC. DEVICE TYPE.             49400017
*                                  DEVICE CODE AND VECTOR DIRECTORY TBL 49600017
         CLI   0(RCORE),X'FF'          TEST END OF TABLE           000A 49800017
         BE    VDOVFLER                                            000A 50000017
         LA    RCORE,4(0,RCORE)        BUMP TO GET NEXT VD FIELD        50200017
         AH    RC,ONE        BUMP DEVICE COUNT                          50400017
*                                 VECTOR LIST FIELD NOT ZERO OR EQUAL   50600017
*                                 TO DEVICE CODE TO LOAD PROGRAM.       50800017
         B     RWVDLP                                                   51000017
VDOVFLER L     1,ERR6                  VECTOR DIRECTOR OVERFLOW    000A 51200017
         ABEND (1)                                                 000A 51400017
         CNOP  0,4                                                      51600017
         EJECT                                                          51800017
ONLTTMSK DS    0F                                                  000D 52000017
       DC    BL.51'111111111111111111111111111000000011111111111111111' 52200019
*      1050        *****                                           000J 52400018
*      2740             ******************                         000J 52600018
*      1060                               **                       000J 52800018
*      1030                                 **                     000J 53000018
*      83B3                                   **                   000J 53200018
*      115A                                     **                 000J 53400018
*      TWX                                        ***              000J 53600018
*      2260/2848                                     *             000J 53800018
*      S360/1130/2780/2020                            ********     000J 54000018
*      2741                                                   **   000J 54200018
*      2740/2760                                                ** 000J 54400018
*      1050X                                                      **    54460019
*      2740X                                                        **  54520019
         DS    0F                                                       54600017
ERR6     DC    X'80097000'                                         000A 54800017
TRMTST   EQU   X'10'                    TERMINAL TEST BIT IN ERROP      55400017
         SPACE                                                          55600017
WAOFF    EQU   32                       OFFSET OF FIRST WTG ENTRY FROM  55800017
*                                  START OF WTG.                        56000017
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES.          56200017
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES.          56400017
OPIDCNST DC    C'0S'                    ID OF LAST OPEN LOAD.           56600017
AMIDCNST DC    C'3S'                    ID OF THIS MODULE.         000D 56800017
DXCCW12  EQU   X'1C8'                                                   57000017
DYNBUF   EQU   X'08'                    CODE FOR BFTEK=D IN THE DCB,    57200017
DEVWTTA  EQU   X'2A'                    WTTA OFFSET                000G 57400017
ONE      DC    H'01'                                                    57600017
VDOFFSET DC    H'12'                                                    57800017
CONATB   DC    X'C3780004000400'       XCTL ATTRIBUTES AND LENGTH       58200017
LOADATB  EQU   X'CB'                   STANDARD LOAD ATTRIBUTES    1266 58400018
*    REENTERABLE, ONLY LOADABLE, EXECUTABLE, ONLY ONE TEXT RECORD AND   58600017
*    NO RLD RECORD, ORIGIN IS ZERO, ENTRY POINT IS ZERO, AND CANNOT BE  58800017
*    REPROCESSED BY LINKAGE EDITOR.                                     59000017
LOADATB1 EQU   X'CA'                   LOAD ATTRIBUTES FOR MODS    1266 59200018
*    THAT ARE LARGER THAN 1024 BYTES - SAME AS LOADATB EXCEPT THAT MORE 59400017
*    THAN ONE TEXT RECORD IS SPECIFIED.                                 59600017
EIGHT00  EQU   X'08'                                               000B 59800017
ONE000   EQU   X'10'                                                    59900019
GRAPHMSK EQU   X'40'                                               000E 60000017
MASKALL  EQU   X'FF'                    ALL ONES                   000D 60200017
INTR1    EQU   X'2B'                                                    60260018
INTR2    EQU   X'2C'                                                    60320018
         SPACE 2                                                        63200017
*    THE FOLLOWING IS THE IDTTRL TABLE FOR ALL OF THE BTAM SUBROUTINES, 63400017
*    APPENDAGES, AND DEVICE I/O MODULES.  EACH ENTRY CONSISTS OF THE    63600017
*    LAST TWO CHARACTERS OF THE MODULE NAME, THE RELATIVE TRACK AND     63800017
*    RECORD ADDRESS OF THE CORRESPONDING LOAD MODULE ON SYS1.SVCLIB,    64000017
*    AND THE LENGTH OF THE MODULE IN NUMBER OF DOUBLE WORDS.  THE TTR   64200017
*    AND LENGTH ARE INSERTED IN THE TABLE BY THE IEHIOSUP UTILITY       64400017
*    PROGRAM, WHICH IS EXECUTED AUTOMATICALLY DURING STAGE 2 OF THE     64600017
*    SYSTEM GENERATION PROCESS.  IF ANY OF THESE MODULES ARE CHANGED,   64800017
*    REPLACED, OR MOVED, IEHIOSUP MUST BE EXECUTED AGAIN.               65000017
         SPACE 1                                                        65200017
NENT     EQU   7                        NUMBER OF IDTTR'S          000M 65400019
LENGTH   EQU   NENT*6+6                LENGTH OF IDTTR'S+2+4            65600017
NODBWDS  EQU   (LENGTH+7)/8            NO OF DBL WDS W/ PADDING         65800017
ORGIDTTR EQU   1024-NODBWDS*8          START OF IDTTR LIST              66000017
         SPACE 1                                                        66200017
         ORG   IGG0193S+ORGIDTTR                                        66400017
PCIAPP   DC    C'MC'                   PCI APPENDAGE                    66600017
         DC    XL4'0'                  TTRL FIELD                       66800017
ONLTST   DC    C'MR'                    ON-LINE TEST CONTROL MOD   000D 67000017
         DC    XL4'0'                        TTRL FIELD            000D 67200017
BPMR     DC    C'MS'                   BUFFER POOL MANAGEMENT ROUTINE   67400017
         DC    XL4'0'                  TTRL FIELD                       67600017
CHENDAPP DC    C'MB'                   CHANNEL END/ABNORMAL END         67800017
*                                 APPENDAGE                             68000017
         DC    XL4'0'                  TTRL FIELD                       68200017
CEAPPWT  DC    C'PD'                    CHANNEL END/ABNORMAL END   000G 68400017
*                                  APPENDAGE FOR WTTA.             000G 68600017
         DC    XL4'0'                   TTRL FIELD                 000G 68800017
READWR   DC    C'MA'                   READ/WRITE ROUTINE               69000017
         DC    XL4'0'                  TTRL FIELD                       69200017
BREAK41  DC    C'PK',XL4'0'            2741 BREAK MODULE                75200019
IDEND    DC    X'0000'                  END OF IDTTRL TABLE.            81800017
         SPACE 2                                                        82000017
         CNOP  4,8                     PADDING                          82200017
LOADID   DC    C'019'                  OPEN SVC CODE                    82400017
         DC    YL1(X'80'-NODBWDS)                                       82600017
*                                  IDTTRL TABLE.                        82800017
         DCBD  DSORG=BX,DEVD=BS                                    000E 83000017
        IECTIOBX                                                        83200017
        IECTDEBX                                                        83400017
         SPACE 2                                                   000M 83420019
         SPACE 2                                                   000M 83440019
WORK     DSECT                                                     000M 83460019
WORKAREA DS   0D                        WORK AREA PROVIDED FOR OPEN000M 83480019
         DS    XL1                      MODULE NUMBER              000M 83500019
         DS    XL1                                                 000M 83520019
WORKTTRL DS    XL6                                                 000M 83540019
         END                                                            83600017
