         TITLE 'IGG0194P - BTAM OPEN LOAD 2 FOR LOCAL 3270'             00100021
IGG0194P CSECT                                                          00200021
*                                                                       00400021
* STATUS - CHANGE LEVEL 000                                             00600021
*                                                                       00800021
* FUNCTION/OPERATION - THIS MODULE VERIFIES THAT ALL DEVICES IN THE     01000021
*    LINE GROUP ARE LOCAL 3270 DEVICES.  A BUFFER POOL WILL BE OBTAINED 01200021
*    AND INITIALIZED IF REQUESTED.  IOB'S WILL BE OBTAINED AND          01400021
*    INITIALIZED.  AN ERASE WRITE WILL BE DONE TO EACH DEVICE IN THE    01600021
*    LINE GROUP TO INITIALIZE IT.  THE CONTROL BLOCK CHAINS REQUIRED    01800021
*    FOR ATTENTION HANDLING WILL BE INITIALIZED.                        02000021
*                                                                       02200021
* ENTRY POINTS - THIS ROUTINE IS ENTERED AT IGG0194P VIA AN XCTL FROM   02400021
*    IGG0193M, THE FIRST BTAM OPEN LOAD.  IT MAY ALSO BE RE-ENTERED     02600021
*    FROM THE RELOOP PORTION OF THIS ROUTINE IF IT DETERMINES THAT      02800021
*    THERE IS ANOTHER DATA CONTROL BLOCK TO BE OPENED.                  03000021
*                                                                       03200021
* INPUT - THE REGISTERS 5, 6, 7, AND 8 ARE THE INPUT, AS FOLLOWS:       03400021
*    5 - THE ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST       03600021
*    6 - THE ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE          03800021
*    7 - THE ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST     04000021
*    8 - THE ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO 04200021
*        TABLE                                                          04400021
*                                                                       04600021
* OUTPUT - THE REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES 04800021
*    IN THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.               05000021
*        SOME OF THE DCB AND UCB EXTENSION FIELDS WILL HAVE BEEN        05200021
*    INITIALIZED.                                                       05400021
*        THIS EXECUTOR'S ENTRY (OR ENTRIES) IN THE WHERE-TO-GO TABLE    05600021
*    WILL HAVE BEEN UPDATED TO IDENTIFY LOAD 3 FOR 3270 (IGG0194Q).     05800021
*                                                                       06000021
* EXTERNAL ROUTINES - GETMAIN, REGISTER FORM (SVC 10)                   06200021
*    FREEMAIN, REGISTER FORM (SVC 10)                                   06400021
*    ABEND (SVC 13)                                                     06600021
*    EXCP (SVC 0)                                                       06800021
*    WAIT (SVC 1)                                                       07000021
*    DOM (SVC 87)                                                       07100021
*    PURGE (SVC 16)                                                     07200021
*    WTOR (SVC 35)                                                      07400021
*    XCTL (SVC 7)                                                       07600021
*                                                                       07800021
* EXITS, NORMAL - THIS ROUTINE EXITS VIA XCTL TO THE MODULE IDENTIFIED  08000021
*    BY THE NEXT NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE, NAMELY        08200021
*    IGG0194Q (BTAM OPEN EXECUTOR - LOAD 3 FOR 3270).                   08400021
*                                                                       08600021
* EXITS, ERROR - THIS ROUTINE EXITS VIA ABEND FOR THE FOLLOWING ERROR   08800021
*    CONDITIONS:                                                        09000021
*    00095000  INCOMPATIBLE DEVICES ARE DEFINED ARE DEFINED TO BE ON    09200021
*              THE SAME LINE GROUP.                                     09400021
*                                                                       09600021
* TABLE/WORK AREAS - THE WHERE-TO-GO TABLE CONTAINS THE ID AND TTR OF   09800021
*    OPEN EXECUTOR LOAD 3 FOR 3270.  THE DCB PARAMETER LIST CONTAINS    10000021
*    THE ADDRESS OF EACH DCB SPECIFIED IN THE OPEN MACRO.               10200021
*                                                                       10400021
* ATTRIBUTES - THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS        10600021
*    ENABLED, PRIVILEDGED, AND REENTRANT.                               10800021
*                                                                       11000021
         EJECT                                                          11003021
*/*IGG0194P: CHART */                                                   11006021
*/* HEADER                                                              11009021
*/*BTAM OPEN LOAD 2 FOR LOCAL 3270 DEVICES                          */  11012021
*/*IGG0194P: E ENTRY FROM IGG0193M VIA XCTL */                          11015021
*/* M ESTABLISH ADDRESSABILITY FOR DCB AND DEB DSECTS */                11018021
*/*GETUCB: D (YES,,NO,ABEND95) ALL DVCS IN LINE GROUP 3270 DVCS */      11021021
*/* M SUPPRESS DYNAMIC BUFFERING */                                     11024021
*/*GETIOB: P STORE IOB SIZE IN DCB */                                   11027021
*/* P COMPUTE SIZE OF IOB POOL */                                       11030021
*/* L GETMAIN FOR IOB'S */                                              11033021
*/* P STORE IOB POOL BASE ADDRESS IN DCB */                             11036021
*/* M SET UCB INDEX VALUE TO ZERO */                                    11039021
*/*INITIOBS: P CLEAR CORE FOR ONE IOB */                                11042021
*/* P INITIALIZE IOBFLAG1, IOBSTART, IOBDCBPT, AND IOBUCBX */           11045021
*/* M INCREMENT THE UCB INDEX VALUE BY 1 */                             11048021
*/* D (YES,,NO,INITIOBS) ALL IOB'S INITIALIZED? */                      11051021
*/* D (YES,,NO,INITERMS) OLT REQUESTED? */                              11054021
*/* P GET IRB POINTER AREA AND STORE ADDRESS IN DEBIRBAD */             11057021
*/*INITERMS: M GET NUMBER OF DVCS, ADDR OF DEB UCB LIST AND IOB POOL */ 11060021
*/*INITLP: M GET ADDRESS OF UCB */                                      11063021
*/* P SAVE OLTEP EXECUTING FLAG FROM GCB */                             11066021
*/* P CLEAR ATTENTION HANDLING FIELDS IN UCB EXTENSION */               11069021
*/* P CLEAR THE GRAPHICS STATUS BYTE IN THE UCB */                      11071021
*/* D (NO,,YES,RLN1) IOBUCBX = 0? */                                    11072021
*/* P STORE POINTER TO MASTER UCB */                                    11075021
*/*STRLN: P INCREMENT UCB INDEX BY 1 TO OBTAIN RLN AND STORE IN UCB */  11078021
*/* D (NO,,YES,BYPASSIO) OLTEP EXECUTING ON DEVICE? */                  11081021
*/* P CREATE ERASE WRITE CHANNEL PROGRAM IN IOB CPA */                  11084021
*/* L GETMAIN FOR WTOR AREA AND ECB */                                  11087021
*/* P STORE ADDRESS OF ECB IN IOB */                                    11090021
*/*EXCP: L ISSUE EXCP TO DO WRITE */                                    11093021
*/* M CLEAR TIMER LOOP COUNTER */                                       11096021
*/*TIMELOOP: L STIMER WAIT FOR 1/2 SECOND */                            11099021
*/* D (YES,,NO,TIMLPCHK) ECB POSTED COMPLETE? */                        11102021
*/*CHKECB: D (NO,,YES,RLSECORE) COMP CODE = X'7F'? */                   11105021
*/* D (YES,,NO,CHKERR) COMP CODE = X'44'? */                            11108021
*/* M (,EXCP) CLEAR ECB */                                              11111021
*/*TIMLPCHK: D (NO,,YES,PURGE) HAVE WAITED FOR 30 SEC */                11114021
*/* M (,TIMELOOP) INCR TIMER LOOP COUNTER BY 1 */                       11117021
*/*PURGE: P BUILD PURGE PARM LIST IN WTOR AREA */                       11120021
*/* L PURGE I/O OPERATION REQUEST */                                    11123021
*/* D (YES,,NO,WRTMSG) REQUEST QUIESCING? */                            11126021
*/* L (,CHKECB) WAIT FOR OPERATION TO COMPLETE */                       11129021
*/*CHKERR: D (YES,WRTMSG,NO,) ERROR WAS SIO CC=3? */                    11131021
*/* D (YES,,NO,SETERR) ERROR WAS INTERVENTION REQUIRED ? */             11133021
*/* P SET OPEN FAILED FLAG IN GRAPHICS STATUS BYTE IN UCB */            11133421
*/*DVCIRMSG: M INITIALIZE WTOR PARM LIST, ECB, AND REPLY AREA */        11133821
*/* P STORE DEVICE NAME IN MESSAGE */                                   11134221
*/* L ISSUE WTOR */                                                     11134621
*/* P SAVE MESSAGE ID FROM WTOR */                                      11134721
*/* L WAIT FOR REPLY */                                                 11134821
*/* L RELEASE MESSAGE */                                                11134921
*/* D (YES,SETERR,NO,) IS REPLY POST ? */                               11145921
*/* D (YES,,NO,SPECCHK) IS REPLY CONT ? */                              11155921
*/* M (,EXCP) CLEAR COMPLETION CODE IN ECB */                           11157921
*/*SPECCHK: D (YES,,NO,DVCIRMSG) IS REPLY DROP ? */                     11158221
*/* P (,SETERR) SET FORCE BRANCH TO SETERR ON INTERVENTION REQUIRED */  11158621
*/*WRTMSG: M INITIALIZE WTOR PARM LIST, ECB, AND REPLY AREA */          11159021
*/* P STORE DEVICE NAME IN MESSAGE */                                   11169021
*/* L ISSUE WTOR */                                                     11180021
*/* P SAVE MESSAGE ID FROM WTOR */                                      11191021
*/* L WAIT FOR REPLY */                                                 11202021
*/* L RELEASE MESSAGE */                                                11213021
*/* D (NO,,YES,SETERR) IS REPLY 'POST'? */                              11224021
*/* D (YES,,NO,WRTMSG) IS REPLY 'CONT'? */                              11235021
*/* M (,EXCP) CLEAR COMPLETION CODE IN ECB */                           11246021
*/*BYPASSIO: P SET OLTEP EXECUTING FLAG IN IOB */                       11257021
*/*SETERR: P FLAG INITIALIZATION FAILURE IN IOB */                      11268021
*/*RLSECORE: L FREEMAIN WTOR AREA */                                    11279021
*/* M CLEAR POINTER TO WTOR AREA AND TIMER LOOP COUNT */                11290021
*/* M INCR POINTERS TO NEXT IOB AND UCB POINTER */                      11301021
*/* D (YES,,NO,INITLP) ALL TERMINALS DONE? */                           11312021
*/* R GO TO END-OF-LOAD CODE */                                         11323021
*/*RLN1: P STORE ADDRESS OF DEB IN UCB */                               11334021
*/* P (,STRLN) SAVE ADDRESS OF MASTER UCB */                            11345021
*/*ABEND95: R ABEND WITH SYSTEM 095 CODE */                             11356021
*/*IGG0194P: END */                                                     11367021
         EJECT                                                          11378021
RPARM2   EQU   0                    PARAMETER REGISTER                  11389021
RPARM1   EQU   1                    PARAMETER REGISTER                  11400021
RW1      EQU   2                    WORK REGISTER                       11600021
RCORE    EQU   3                    ADDRESS OF GETMAIN CORE             11800021
RUCB     EQU   4                    UCB ADDRESS                         12000021
RPAR     EQU   5                    ADDRESS OF DCB PARAMETER LIST       12200021
RWTG     EQU   6                    ADDRESS OF WTG TABLE                12400021
RPARC    EQU   7                    ADDRESS OF CURRENT DCB ENTRY        12600021
RWTGC    EQU   8                    ADDRESS OF CURRENT WTG ENTRY        12800021
RTIOT    EQU   9                    ADDRESS OF THE TASK I/O TABLE       13000021
RDCB     EQU   10                   DCB ADDRESS                         13200021
RDEB     EQU   11                   DEB ADDRESS                         13400021
RBASE    EQU   12                   BASE REGISTER                       13600021
RW2      EQU   13                   WORK REGISTER                       13800021
RPARM4   EQU   14                   PARAMETER REGISTER                  14000021
RPARM3   EQU   15                   PARAMETER REGISTER                  14200021
*                                                                       14400021
RW3      EQU   RTIOT                ALTERNATE                           14600021
RW4      EQU   RPARM3                   ASSIGNMENTS                     14800021
RW5      EQU   RDCB                         FOR WORK REGISTERS          15000021
*                                                                       15200021
*                                                                       15400021
ALLON    EQU   X'FF'                MASK OF ALL ONE'S                   15600021
ANRIOBSZ EQU   88                   3270 IOB SIZE                       15800021
ATNCNT   EQU   26                   DISP TO ATTN CNT FIELD IN UCB       16000021
ATNXTNSN EQU   14                   LENGTH OF ATTN HANDLING SECTION     16200021
*                                      OF UCB EXTENSION                 16400021
COMPOK   EQU   X'7F'                NORMAL COMPLETION CODE              16600021
DEBATV   EQU   28                  DISP TO DEB VECTOR TO APPNDG TAB     16700021
DVC3277  EQU   X'09'                DEVICE TYPE FOR 3277 DISPLAY        16800021
DVC3286  EQU   X'0B'                DEVICE TYPE FOR 3286 PRINTER        17000021
*              DEVICE TYPE FOR 3284 PRINTER IS X'0A'                    17200021
DXCCW12  EQU   X'1C8'                                                   17400021
DYNBUF   EQU   X'08'                DCB DYNAMIC BUFFERING FLAG          17600021
EIGHT    EQU   8                                                        17800021
EQ       EQU   8                    BC MASK FOR EQUALITY                18000021
ERROR    EQU   X'41'                PERMANENT ERROR OCCURED             18200021
FIVE     EQU   5                                                        18400021
FLAG1    EQU   X'42'               IOB IOS FLAGS - CMND CHAINING        18460021
*                                       I/O REQUESTS UNRELATED          18520021
FORCEBR  EQU   X'F0'               UNCOND BR CONDITION        SB A57064 18570021
FOUR     EQU   4                    ADDR INCR OF 4                      18600021
GCB      EQU   27                   DISP TO GCB FIELD IN UCB            18800021
GRAF     EQU   28                  DISP TO GRAPHICS STATUS    SB A57064 18800121
GRPHCDVC EQU   X'10'                GRAPHIC DEVICE CLASS                19000021
INITERR  EQU   X'80'                INITIALIZATION ERROR FLAG IN IOB    19200021
INTERCPT EQU   X'44'                IOB INTERCEPTED                     19400021
INTREQ   EQU   X'40'               INTERVENTION REQUIRED SENS SB A57064 19450021
IOBOLTEP EQU   X'42'                SECONDARY OLTEP EXECUTING FLAGS     19600021
LINK     EQU   36                   DISP TO CONTROL BLOCK LINK-1        19800021
NINE     EQU   9                                                 A66398 19850021
MAXINTVL EQU   59                  MAX VALUE OF TIME LOOP CTR           20000021
MSGDVCAD EQU   21                   DISP TO DEVICE ADDRESS IN WTOR      20200021
*                                      EXPASION                         20400021
OLT      EQU   X'10'                DCB BIT FOR EROPT=T                 20600021
OLTEP    EQU   X'80'                PRIMARY OLTEP EXECUTING FLAG        20800021
ONE      EQU   1                                                        21000021
OPENINIT EQU   X'80'               OPEN IN PROGRESS FLAG      SB A57064 21050021
OPENFAIL EQU   X'02'               OPEN FAILED GRAF FLAG      SB A57064 21120021
OPENMSG  EQU   X'08'               FLAG BYPASS INT REQ MSG    SB A57064 21170021
PLOFF    EQU   4                    OFFSET OF DCB ENTRIES               21200021
POSTBIT  EQU   X'40'               ECB POST BIT                         21400021
PTRSZ    EQU   16                  SIZE OF IRB POINTER AREA             21500021
PRGCTL   EQU   X'94'               PURGE CONTROL BYTE                   21600021
PURGESVC EQU   16                  PURGE SVC NUMBER                     21700021
RLN      EQU   36                   DISP TO RLN FIELD IN UCB            21800021
SIOCC3   EQU   X'30'                MASK TO TEST SIO CC = 3 IN IOB      22000021
SIX      EQU   6                                                        22200021
TENAND4  EQU   14                                                       22300021
THREE    EQU   3                                                        22400021
TWELVE   EQU   12                                                       22600021
TWO      EQU   2                                                        22800021
UCBDVCLS EQU   18                   DISP TO DEVICE CLASS FIELD IN UCB   23000021
UCBDVCTP EQU   19                   DISP TO DEVICE TYPE FIELD IN UCB    23200021
UCBNAME  EQU   13                   DISP TO DEVICE NAME IN UCB          23400021
WAOFF    EQU   32                   OFFSET OF FIRST WTG ENTRY FROM      23600021
*                                       BEGINNING OF TABLE              23800021
WGOFF    EQU   8                    OFFSET OF WTG ENTRIES               24000021
WTGPATH  EQU   30                  OFFSET TO PATH BITS        SB A57064 24050021
ZERO     EQU   X'00'                                                    24200021
*              ENTRY AND ADDRESSABILITY CODE                            24400021
         BALR  RBASE,0              ESTABLISH BASE REGISTER             24600021
         USING *,RBASE                                                  24800021
         USING IHADCB,RDCB                                              25000021
         USING IECTDEB,RDEB                                             25200021
*                                                                       25400021
         L     RDCB,0(RPARC)        GET DCB ADDRESS                     25600021
         L     RDEB,DCBDEBAD        GET DEB ADDRESS                     25800021
         L     RDEB,DEBATV(RDEB)   GET ADDR OF APPENDAGE TABLE          26000021
*                                   FOR BASE OF DSECT                   26200021
*                                                                       26400021
*              CHECK ALL UCB'S IN LINE GROUP FOR 3270 DEVICES           26600021
         SR    RW1,RW1                                                  26800021
         IC    RW1,DEBNMEXT         GET NUMBER OF DEVICES IN LINE GROUP 27000021
         SR    RW2,RW2              INITIALIZE UCB TABLE INDEX TO ZERO  27200021
*                                                                       27400021
GETUCB   L     RUCB,DEBUCBAD(RW2)   GET ADDRESS OF UCB                  27600021
         CLI   UCBDVCLS(RUCB),GRPHCDVC  DEVICE A GRAPHICS DEVICE        27800021
         BNE   ABEND95              NO, ABEND                           28000021
         CLI   UCBDVCTP(RUCB),DVC3277   DEVICE A 3270 DEVICE            28200021
         BL    ABEND95              NO, ABEND                           28400021
         BE    NEXTUCB              YES, CHECK NEXT UCB                 28600021
         CLI   UCBDVCTP(RUCB),DVC3286   MAYBE                           28800021
         BH    ABEND95              NO, ABEND                           29000021
*                                                                       29200021
NEXTUCB  LA    RW2,FOUR(RW2)        INCR TO NEXT ADDRESS IN TABLE       29400021
         BCT   RW1,GETUCB           CHECK NEXT IF ALL NOT CHECKED       29600021
*                                                                       29800021
         NI    DCBBFTEK,ALLON-DYNBUF  SUPRESS DYNAMIC BUFFERING         30000021
*                                                                       30200021
*              CONSTRUCT THE IOB POOL                                   30400021
GETIOB   LA    RW1,ANRIOBSZ         GET THE IOB SIZE                    30600021
         STC   RW1,DCBEIOBX         STORE IOB SIZE IN DCB               30800021
         LR    RPARM1,RW1                                               31000021
         SR    RW2,RW2                                                  31200021
         IC    RW2,DEBNMEXT         GET NUMBER OF IOB'S                 31400021
         MR    RPARM2,RW2           GET TOTAL CORE REQUIRED             31600021
         LR    RPARM2,RPARM1        LOAD PRODUCT INTO REG 0             31800021
         O     RPARM2,IOBPOOL       OR IN SUBPOOL NUMBER                32000021
         GETMAIN  R,LV=(0)          GET CORE FOR THE IOB'S              32200021
*                                                                       32400021
         USING IECTIOB,RCORE                                            32600021
         LR    RCORE,RPARM1         GET ADDRESS OF IOB POOL             32800021
         SR    RCORE,RW1            SUBTRACT IOB SIZE                   33000021
         ST    RCORE,DCBIOBAD       STORE BASE FOR IOB POOL IN DCB      33200021
         LA    RDCB,0(RDCB)         CLEAR HIGH BYTE OF DCB ADDRESS      33400021
         SR    RW3,RW3              INITIALIZE COUNTER FOR UCB INDEX    33600021
*                                                                       33800021
INITIOBS LA    RCORE,0(RCORE,RW1)   STEP TO BEGINNING OF IOB            34000021
         XC    0(ANRIOBSZ,RCORE),0(RCORE)  CLEAR IOB                    34200021
         MVI   IOBFLAG1,FLAG1      SET IOS FLAGS                        34400021
         LA    RW4,IOBCPA           GET ADDR OF CHANNEL PROG AREA       34600021
         ST    RW4,IOBSTART             & STORE IT IN IOBSTART          34800021
         ST    RDCB,IOBDCBPT        STORE ADDRESS OF DCB                35000021
         STC   RW3,IOBUCBX          STORE UCB INDEX                     35200021
         LA    RW3,ONE(RW3)        INCR UCB INDEX BY 1                  35400021
         BCT   RW2,INITIOBS         DECR & TEST IOB COUNT               35600021
*                                   LOOP IF NOT FINISHED                35800021
*                                                                       36000021
*              GET POINTERS FOR IRB IF ON-LINE TEST REQUESTED           36200021
         TM    DCBERROP,OLT         OLT REQUESTED                       36400021
         BNO   INITERMS             NO, GO TO INITIALIZE TERMINALS      36600021
         LA    RPARM2,PTRSZ        NUMBER OF BYTES FOR POINTERS         36800021
         O     RPARM2,IOBPOOL       OR IN SUBPOOL NUMBER                37000021
         GETMAIN  R,LV=(0)          GET CORE FOR POINTERS               37200021
         ST    RPARM1,DEBIRBAD-1    STORE ADDRESS IN DEB                37400021
         XC    0(PTRSZ,RPARM1),0(RPARM1)  CLEAR AREA                    37600021
*                                                                       37800021
*              INITIALIZE THE ATTENTION FIELDS IN THE UCB (EXCEPT THE   38000021
*              IRB ADDRESS AND UNLOCK AND CLEAR THE TERMINALS           38200021
INITERMS SR    RW3,RW3                                                  38400021
         IC    RW3,DEBNMEXT         GET NO. OF DEVICES IN  LINE GROUP   38600021
         LA    RDEB,DEBUCBAD        GET ADDR OF DEB UCB LIST            38800021
         DROP  RDEB                END DEB ADDRESSABILITY               39000021
         L     RCORE,DCBIOBAD       GET BASE ADDR OF IOB POOL           39200021
INITLP   EQU   *                                                        39400021
         L     RUCB,0(RDEB)         GET ADDR OF UCB FOR DEVICE          39600021
         LA    RCORE,ANRIOBSZ(RCORE)  GET ADDR OF IOB FOR DEVICE        39800021
         IC    RW1,GCB(RUCB)          SAVE GCB FIELD                    40000021
         XC    ATNCNT(ATNXTNSN,RUCB),ATNCNT(RUCB)  CLEAR ATTN-HANDLING  40200021
*                                         FIELDS IN UCB EXTENSION       40400021
         STC   RW1,GCB(RUCB)          RESTORE GCB TO UCB                40600021
         NI    GCB(RUCB),OLTEP     CLEAR ALL GCB EXCEPT OLTEP-EXEC      40800021
*                                         FLAG                          41000021
         NI    GRAF(RUCB),ZERO     RESET GRAPHICS STATUS      SB A57064 41000121
         OI    GRAF(RUCB),OPENINIT FLAG OPEN IN PROGRESS      SB A57064 41000221
         SR    RW1,RW1                                                  41200021
         IC    RW1,IOBUCBX            GET UCB INDEX FROM IOB            41400021
         LTR   RW1,RW1                IS IT 0, I.E. IS RLN = 1          41600021
         BZ    RLN1                   YES, SET UP MASTER UCB PTR TO DEB 41800021
         ST    RDCB,LINK(RUCB)        NO, STORE POINTER TO MASTER UCB   42000021
STRLN    LA    RW1,ONE(RW1)           COMPUTE RLN FROM UCB INDEX        42200021
         STC   RW1,RLN(RUCB)          AND STORE IN UCB                  42400021
*                                                                       42600021
         TM    GCB(RUCB),OLTEP        OLTEP EXECUTING ON DEVICE         42800021
         BO    BYPASSIO               YES, DO NOT DO INITIALIZATION     43000021
*                                                                       43200021
         MVC   IOBCPA(NINE),WRTCCW   MOVE ERASE WR CCW INTO IOB  A66398 43400021
         LA    RW1,IOBCPA+EIGHT      GET ADDRESS OF DATA STREAM  A66398 43600021
         O     RW1,IOBCPA             ADD COMMAND CODE TO HIGH BYTE     43800021
         ST    RW1,IOBCPA                                               44000021
         LA    RPARM2,WTOARLNG        GET LENGTH OF WTOR AREA           44200021
         O     RPARM2,POOLNUM         SET POOL NUMBER                   44400021
         GETMAIN  R,LV=(0)          GET CORE FOR IT                     44600021
         ST    RPARM1,IOBECBPT      STORE ADDRESS IN IOB                44800021
         XC    0(WTOARLNG,RPARM1),0(RPARM1)  CLEAR AREA                 45000021
*                                                                       45200021
EXCP     LA    RPARM1,IOBFLAG1      GET ADDRESS OF IOB                  45400021
         EXCP  (1)                  DO I/O OPERATION                    45600021
*                                                                       45800021
         MVI   IOBINCAM+1,ZERO     CLEAR LOOP CTR                       46000021
         MVC   IOBERINF(TIMELNG),TIME                            A62752 46060021
*                  MOVE TIMER OUT OF TRANSINET AREA              A62752 46120021
TIMELOOP STIMER WAIT,BINTVL=IOBERINF  WAIT FOR 1/2 SECOND        A62752 46170021
         L     RW1,IOBECBPT        GET ADDR OF ECB                      46400021
         TM    0(RW1),POSTBIT      HAS ECB BEEN POSTED                  46600021
         BZ    TIMLPCHK            NO, SEE IF TIME INTERVAL UP          46800021
*                                                                       47000021
CHKECB   EQU   *                                                        47200021
         L     RW1,IOBECBPT         GET ADDRESS OF ECB                  47400021
         CLI   0(RW1),COMPOK        NORMAL COMPLETION                   47600021
         BE    RLSECORE             YES, RELEASE GETMAIN AREA           47800021
*                                                                       48000021
         CLI   0(RW1),INTERCPT      IOB INTERCEPTED                     48200021
         BNE   CHKERR               NO, CHECK CAUSE OF ERROR            48400021
         MVI   0(RW1),ZERO          YES, CLEAR COMPLETION CODE          48600021
         B     EXCP                 RE-ISSUE OPERATION                  48800021
*                                                                       49000021
TIMLPCHK CLI   IOBINCAM+1,MAXINTVL LOOP CTR AT MAX VALUE                49200021
         BE    CHKERR              YES, CHECK CAUSE OF ERROR  SB A57064 49400021
         SR    RW1,RW1                                                  49600021
         IC    RW1,IOBINCAM+1      GET LOOP CTR                         49800021
         LA    RW1,ONE(RW1)        INCR CTR BY 1                        50000021
         STC   RW1,IOBINCAM+1      AND STORE BACK IN IOB                50200021
         B     TIMELOOP            WAIT FOR 0.5 SEC MORE                50400021
*                                                                       50600021
CHKERR   EQU   *                   CHECK CAUSE OF I/O FAILURE SB A57064 50650021
         TM    IOBSIOCC,SIOCC3     WAS ERROR SIO CC = 3 (CU   SB A57064 50700021
*                                  NOT OPERATIONAL)           SB A57064 50750021
         BO    WRTMSG              YES, TELL OPERATOR         SB A57064 50800021
         TM    IOBSENS0,INTREQ     INTERVENTION REQUIRED ?    SB A57064 50850021
         BNO   SPECBR              NO, GO FLAG OPEN ERROR     SB A57064 50860021
         OI    GRAF(RUCB),OPENFAIL FLAG OPEN FAILED           SB A57064 50870021
SPECBR   EQU   *                   TEST TO SEE IF BYPASS MSG  SB A57064 50880021
         TM    WTGPATH(RWTG),OPENMSG BYPASS MSG SET ?         SB A57064 50900021
         BO    SETERR              YES, BYPASS INT REQ MSG    SB A57064 50950021
         L     RW1,IOBECBPT        GET ADDR OF GETMAINED AREA SB A57064 51250021
DVCIRMSG EQU   *                   PUT OUT DEVICE NOT OPER    SB A57064 51300021
         XC    0(EIGHT,RW1),0(RW1) CLEAN ECB AND REPLY AREA   SB A57064 51350021
         LA    RPARM2,FOUR(RW1)    GET ADDRESS OF REPLY AREA  SB A57064 51400021
         MVC   EIGHT(WTODVLNG-EIGHT,RW1),WTODEV MOVE DEV MSG  SB A57064 51450021
         MVC   MSGDVCAD+EIGHT(THREE,RW1),UCBNAME(RUCB) PUT    SB A57064 51500021
*                                  UCB NAME IN MESSAGE        SB A57064 51550021
         LA    RPARM1,EIGHT(RW1)   GET BEGINNING OF WTOR EXP  SB A57064 51600021
         WTOR  ,(RPARM2),,(RW1),MF=(E,(1)) WRITE MESSAGE      SB A57064 51650021
         XR    RPARM1,RW1          EXCHANGE CONTENTS          SB A57064 51700021
         XR    RW1,RPARM1          OF REGISTERS               SB A57064 51750021
         XR    RPARM1,RW1          RPARM1 AND RW1             SB A57064 51800021
         WAIT  ECB=(1)             WAIT FOR REPLY             SB A57064 51850021
         DOM   MSG=(2)             RELEASE MESSAGE            SB A57064 51900021
         L     RW1,IOBECBPT        GET ADDRESS OF WTOR AREA   SB A57064 51950021
         CLC   FOUR(FOUR,RW1),POST IS REPLY 'POST' ?          SB A57064 52000021
         BE    SETERR              YES, FLAG ERROR            SB A57064 52050021
         CLC   FOUR(FOUR,RW1),CONT IS REPLY 'CONT' ?          SB A57064 52100021
         BNE   SPECCHK             NO, CHECK SPECIAL REPLY    SB A57064 52150021
         MVI   0(RW1),ZERO         YES, CLEAR COMPLETION CODE SB A57064 52200021
         NI    GRAF(RUCB),ALLON-OPENFAIL TURN OFF OPEN  FLAG  SB A57064 52210021
         B     EXCP                AND RETRY I/O              SB A57064 52250021
SPECCHK  EQU   *                   CHECK FOR BYPASS FUTURE    SB A57064 52300021
         CLC   FOUR(FOUR,RW1),DROP IS REPLY 'DROP' ?          SB A57064 52700021
         BNE   DVCIRMSG            NO, INVALID - REISSUE MSG  SB A57064 52750021
         OI    WTGPATH(RWTG),OPENMSG SET BYPASS INT REQ MSG   SB A57064 52800021
         B     SETERR              AND GO SET OPEN ERROR      SB A57064 52900021
*                                                                       55000021
WRTMSG   XC    0(EIGHT,RW1),0(RW1)  YES, CLEAR ECB AND REPLY AREA       55200021
         LA    RPARM2,FOUR(RW1)     GET ADDRESS OF REPLY AREA           55400021
         MVC   EIGHT(WTOARLNG-EIGHT,RW1),WTOBASE  MOVE SKELETON MSG     55600021
*                                   INTO GETMAIN AREA                   55800021
         MVC   MSGDVCAD+EIGHT(THREE,RW1),UCBNAME(RUCB)  PUT DEVICE      56000021
*                                   NAME INTO MESSAGE                   56200021
         LA    RPARM1,EIGHT(RW1)    GET BEGINNING OF WTOR EXPASION      56400021
         WTOR  ,(RPARM2),,(RW1),MF=(E,(1))   WRITE MESSAGE              56600021
         XR    RPARM1,RW1           EXCHANGE CONTENTS                   56800021
         XR    RW1,RPARM1               OF REGISTERS                    57000021
         XR    RPARM1,RW1                   RPARM1 AND RW1              57200021
*                                                                       57400021
         WAIT  ECB=(1)              WAIT FOR REPLY                      57600021
*                                                                       57800021
         DOM   MSG=(2)              RELEASE MESSAGE                     58000021
*                                                                       58200021
         L     RW1,IOBECBPT         GET ADDRESS OF WTOR AREA            58400021
         CLC   FOUR(FOUR,RW1),POST  REPLY IS 'POST'                     58600021
         BE    SETERR               YES, FLAG ERROR                     58800021
*                                                                       59000021
         CLC   FOUR(FOUR,RW1),CONT  REPLY IS 'CONT'                     59200021
         BNE   WRTMSG               NO, INVALID REPLY - REWRITE MESSAGE 59400021
         MVI   0(RW1),ZERO          CLEAR COMPKETION CODE               59600021
         B     EXCP                 RETRY INITIALIZATION                59800021
*                                                                       60000021
BYPASSIO OI    IOBINCAM,IOBOLTEP    SET OLTEP EXECUTING FLAGS IN IOB    60200021
SETERR   TM    IOBSENS0,INTREQ     INTERVENTION REQ?            A66419  60400021
         BO    NOSETERR           YES,DON'T SET OPEN FLAG        A66419 60410021
         OI    IOBINCAM,INITERR   FLAG OPEN FAILURE IN IOB       A66419 60420021
NOSETERR EQU   *                                                 A66419 60430021
         TM    GCB(RUCB),OLTEP      OLTEP IN CONTROL ?          A57374  60450021
         BO    DONORLSE             YES, NO CORE TO RELEASE     A57374  60500021
RLSECORE LR    RPARM1,RW1           ADDRESS OF AREA TO BE FREED         60600021
         LA    RPARM2,WTOARLNG      LENGTH OF AREA                      60800021
         O     RPARM2,POOLNUM       POOL NUMBER                         61000021
         FREEMAIN  R,LV=(0),A=(1)   FREE AREA                           61200021
DONORLSE EQU   *                    GOTTEN CORE HAS BEEN FREED  A57374  61250021
         XC    IOBECBPT(FOUR),IOBECBPT  CLEAR POINTER TO AREA           61400021
         MVI   IOBINCAM+1,ZERO                                          61600021
         LA    RDEB,FOUR(RDEB)      GET POINTER TO NEXT UCB ADDRESS     61800021
         BCT   RW3,INITLP           LOOP IF MORE TERMS TO INITIALIZE    62000021
         B     ENDLOAD              END-OF-LOAD CODE                    62200021
*                                                                       62400021
RLN1     L     RPARM1,DCBDEBAD      GET ADDRESS OF DEB                  62600021
         ST    RPARM1,LINK(RUCB)    STORE IN LINK FIELD                 62800021
         LR    RDCB,RUCB            SAVE ADDRESS OF MASTER UCB          63000021
         B     STRLN                STORE RLN                           63200021
*                                                                       63400021
*              END-OF-LOAD CODE                                         63600021
ENDLOAD  MVC   0(FIVE,RWTGC),LD3F3270   SET UP IDTTR FOR NEXT LOAD      63800021
         L     RW1,FOUR(RWTGC)                                          64000021
*                                                                       64200021
RELOOP   LA    RWTGC,WGOFF(RWTGC)   INCR CURRENT WTG REGISTER           64400021
         LA    RPARC,PLOFF(RPARC)   INCR CURRENT PARM LIST REG TO NEXT  64600021
*                                       ENTRY                           64800021
         CLC   0(TWO,RWTGC),AMIDCNST  IF NEXT WTG ENTRY REQUIRES THIS   65000021
         BCR   EQ,RBASE             EXECUTOR, RETURN TO BEGINNING       65200021
         CLC   0(TWO,RWTGC),OPIDCNST   IF NOT, TEST FOR END OF TABLE    65400021
         BNE   RELOOP               NOT END, CHECK NEXT ENTRY           65600021
*                                                                       65800021
         LR    RPARC,RPAR           REINITIALIZE CURRENT PARM REG       66000021
         LA    RWTGC,WAOFF(RWTG)    AND CURRENT WTG REG                 66200021
ZCHECK   CLI   0(RWTGC),ZERO        IF FIRST BYTE OF CURRENT WTG ENTRY  66400021
         BNE   XCTLRTNE             NON-ZERO, GO TO TRANSFER CONTROL    66600021
         LA    RWTGC,WGOFF(RWTGC)   IF NOT, GET NEXT ENTRY              66800021
         LA    RPARC,PLOFF(RPARC)                                       67000021
         B     ZCHECK               AND CHECK IT                        67200021
*                                                                       67400021
*                                                                       67600021
XCTLRTNE EQU   *                                              SB A57064 67650021
         NI    WTGPATH(RWTG),ALLON-OPENMSG TURN OFF BYPASS    SB A57064 67700021
         LA    RPARM3,DXCCW12(RW1)      POINT TO DOUBLE WORD LIST       67800021
         MVC   SIX(TWO,RWTG),0(RWTGC)   MOVE ID TO NAME FIELD           68000021
         MVC   TENAND4(THREE,RWTG),TWO(RWTGC)  MOVE TTR TO WTG TABLE    68200021
         XCTL  DE=(RWTG),SF=(E,(15))                                    68400021
*                                                                       68600021
ABEND95  L     RPARM1,ERRCODE                                           68800021
         ABEND (1)                 INCOMPATIBLE DEVICES ON LINE GROUP   69000021
*                                     RESET KEYBOARD                    69400021
*                                     RESET MODIFIED DATA TAGS          69600021
OPIDCNST DC    C'0S'                ID OF LAST OPEN LOAD                69800021
AMIDCNST DC    C'4P'                ID OF THIS MODULE                   70000021
TIME     DC    F'50'               TIME INTERVAL OF .50 SEC             70200021
ERRCODE  DC    X'80095000'         ABEND CODE                           70400021
IOBPOOL  DC    X'FA000000'          SUBPOOL NUMBER FOR IOB'S            70600021
POOLNUM  DC    X'FE000000'          SUBPOOL FOR WTOR AREA               71200021
WRTCCW   DC    XL9'0500000020240001C3'  ERASE WRIT CCW SKELETON  A66398 71400021
*                                   COMMAND = ERASE WRITE               71600021
*                                   FLAGS = SLI                         71800021
*                                   TP OP CODE = OPEN WRITE             72000021
*                                   BYTE CNT = 1                        72200021
WTOBASE  WTOR  'IEC804A  000 CONTROL UNIT NOT OPER. REPLY CONT OR POST'*72400021
               ,,4,,ROUTCDE=(1,8,10),DESC=2,MF=L                        72600021
WTOARLNG EQU   (*-WTOBASE+8+7)/8*8  LENGTH OF GETMAIN AREA FOR WTOR     72800021
*****************************************************************       72810021
* IF THE WTOR MACRO CHANGES OR IF THE MSG CHANGES THEN THE NEXT THREE   72820021
* EQUTES MUST ALSO BE CHANGED                                           72830021
WTODEV   WTOR  'IEC804A  000 DEVICE NOT OPER. REPLY CONT, POST OR DROP'*72850021
               ,,4,,ROUTCDE=(1,8,10),DESC=2,MF=L              SB A57064 72900021
WTODVLNG EQU   (*-WTODEV+8+7)/8*8  LENGTH OF GETMAINED AREA   SB A57064 72950021
NENT     EQU   1                    NUMBER OF IDTTR'S                   73000021
LENGTH   EQU   NENT*6+6             LENGHT OF IDTTR'S+2+4               73200021
NODBWDS  EQU   (LENGTH+7)/8         NO. OF DBL WDS WITH PADDING         73400021
ORGIDTTR EQU   1024-NODBWDS*8       START OF IDTTR LIST                 73600021
         ORG   IGG0194P+ORGIDTTR   BEGINNING OF IDTTRL TABLE            73800021
LD3F3270 DC    C'4Q'                ID FOR THIRD LOAD OF BTAM OPEN      74000021
*                                       FOR 3270                        74200021
         DC    X'00000000'          TTR AND L                           74400021
IDEND    DC    X'0000'              END OF IDTTRL TABLE                 74600021
         CNOP  4,8                  PADDING                             74800021
LOADID   DC    C'019'               OPEN SVC CODE                       75000021
         DC    YL1(X'80'-NODBWDS)  POINTER FOR IEHIOSUP                 75200021
*                                                                       75400021
TIMELNG  EQU   4                       LENGTH OF TIMER           A62752 75500021
CONT     EQU   WTODEV+48            CHAR FOR CONT COMPARE               75550021
POST     EQU   WTODEV+54           CHARS. FOR POST COMPARE              75560021
DROP     EQU   WTODEV+62           CHARS. DOR DROP COMPARE              75570021
         DCBD  DSORG=BX,DEVD=BS                                         75600021
         IECTDEBX                                                       75800021
         IECTIOBX                                                       76000021
         END                                                            76200021
