         TITLE 'IGG0194Q - BTAM OPEN LOAD 3 FOR LOCAL 3270'             00100021
IGG0194Q CSECT                                                          00200021
*                                                                       00400021
* STATUS - CHANGE LEVEL 000                                             00600021
*                                                                       00800021
* FUNCTION/OPERATION - THIS ROUTINE IS BROUGHT INTO CORE AND EXECUTED   01000021
*    WHEN THE BTAM OPEN LOAD 2 FOR 3270 ISSUES 'XCTL' TO IGG0194Q.      01200021
*    THIS ROUTINE LOADS THE REQUIRED MODULES, STORES THE ID'S OF THE    01400021
*    MODULES AND A COUNT OF MODULES LOADED INTO THE DEB, SETS UP 3270   01600021
*    ATTENTION HANDLING AND SETS UP OLT IF REQUIRED.                    01800021
*                                                                       02000021
* ENTRY POINT - ENTRY IS TO THE FIRST BYTE OF THE MODULE AS A RESULT OF 02200021
*    AN XCTL TO IGG0194Q.                                               02400021
*                                                                       02600021
* INPUT - REGISTERS 5, 6, 7, AND 8 ARE THE INPUT                        02800021
*    5 - BEGINNING OF THE DCB PARAMETER LIST                            03000021
*    6 - BEGINNING OF THE WHERE-TO-GO TABLE                             03200021
*    7 - ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST         03400021
*    8 - ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE.         03600021
*                                                                       03800021
* OUTPUT - THE REGISTERS WILL BE POSITIONED TO THE NEXT UNFINISHED      04000021
*    ENTRY IN THE WHERE-TO-GO TABLE.  THE REQUIRED BTAM MODULES ARE     04200021
*    LOADED.  IRB'S AND IQE'S ARE BUILT AS REQUIRED.                    04400021
*                                                                       04600021
* EXTERNAL ROUTINES - ABEND (SVC 13)                                    04800021
*         CIRB (SVC 43)                                                 05000021
*         LOAD (SVC 8)                                                  05200021
*         XCTL (SVC 7)                                                  05400021
*                                                                       05600021
* EXITS, NORMAL - THIS ROUTINE NORMALLY TERMINATES BY LOCATING THE NEXT 05800021
*    NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO   06000021
*    THAT ROUTINE.                                                      06200021
*                                                                       06400021
* EXITS, ERROR - IF THE VECTOR TABLE IN THE READ/WRITE ROUTINE          06600021
*    (IGG019MA) IS FULL AND ANOTHER ENTRY IS REQUIRED, THE TASK IS      06800021
*    ABENDED WITH A SYSTEM CODE OF 097.                                 07000021
*                                                                       07200021
* TABLES/WORK AREAS - THE DCB PARAMETER LIST CONTAINS THE ADDRESS OF    07400021
*    EACH DCB SPECIFIED IN THE OPEN MACRO.  THE WHERE-TO-GO TABLE       07600021
*    CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB   07800021
*    CORRESPONDING TO THIS ENTRY.  THE IDTTRL TABLE CONTAINS THE ID'S   08000021
*    REQUIRED TO LOAD THE REQUIRED BTAM MODULES.                        08200021
*                                                                       08400021
* ATTRIBUTES - THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS        08600021
*    ENABLED, PRIVELEDGED, AND REENTRANT.                               08800021
*                                                                       09000021
* NOTES - THIS ROUTINE COMPLETES THE OPEN PROCESSING FOR BTAM-SUPPORTED 09200021
*    3270'S.  THEREFORE, THE WHERE-TO-GO ENTRY WILL BE SET TO ZERO.     09400021
*                                                                       09600021
         EJECT                                                          09603021
*/*IGG0194Q: CHART */                                                   09606021
*/* HEADER                                                              09609021
*/*BTAM OPEN LOAD 3 FOR LOCAL 3270 DEVICES                          */  09612021
*/*IGG0194Q: E ENTRY FROM IGG0194P VIA XCTL */                          09615021
*/* M ESTABLISH BASES FOR DCB AND DEB DSECTS */                         09618021
*/* D (NO,,YES,GETIOB) BUFFER POOL PROVIDED BY USER? */                 09621021
*/* D (YES,,NO,GETIOB) ANY BUFFERS REQUESTED? */                        09624021
*/* D (NO,,YES,GETIOB) IS BUFFER LENGTH ZERO? */                        09627021
*/* P ROUND BUFFER LENGTH TO NEXT FULL WORD AND STORE LENGTH IN DCB */  09630021
*/* P COMPUTE TOTAL SIZE OF BUFFERS PLUS BUFFER CONTROL BLOCK */        09633021
*/* L GETMAIN FOR BUFFER POOL */                                        09636021
*/* P STORE ADDRESS OF BUFFER CONTROL BLOCK IN DCB */                   09639021
*/* P INITIALIZE THE BUFFER CONTROL BLOCK AND LINK BUFFERS TOGETHER */  09642021
*/*GETIOB: M OBTAIN ADDRESS OF DEB SUBID FIELD */                       09645021
*/* D (YES,,NO,TESTBPM) OLT'S REQUIRED? */                              09648021
*/* S LOADRTN: LOAD LOCAL 3270 OLT CONTROL RTN */                       09651021
*/* S BLDIRB: BUILD IRB AND IQE'S FOR OLT */                            09654021
*/* P STORE IRB ADDRESS IN IRB POINTER AREA */                          09657021
*/*TESTBPM: D (YES,,NO,LOADCEA) BUFFER MANAGEMENT REQUIRED? */          09660021
*/* S LOADRTN: LOAD BUFFER MANAGEMENT ROUTINE */                        09663021
*/* P STORE ADDRESS OF BUFFER MANAGEMENT ROUTINE IN DEB */              09666021
*/*LOADCEA: S LOADRTN: LOAD LOCAL 3270 CEA/XEA RTN */                   09669021
*/* P STORE ADDRESS OF CEA/XEA IN DEB CEA AND XEA VECTORS */            09672021
*/* S LOADRTN: LOAD BTAM READ/WRITE ROUTINE */                          09675021
*/* P STORE ADDRESS OF READ/WRITE ROUTINE IN DCB */                     09678021
*/* M LOCATE DDM VECTOR TABLE */                                        09681021
*/*RWVDLP: D (YES,,NO,VDLPINDX) VECTOR TABLE ENTRY = ZERO? */           09684021
*/*DDMIN: P STORE INDEX TO VECTOR IN DCB */                             09687021
*/* S LOADRTN: LOAD LOCAL 3270 DDM */                                   09690021
*/* P STORE ADDRESS AND DEVICE CODE IN VECTOR TABLE */                  09693021
*/*ENBLATN: S LOADRTN: LOAD 2ND LEVEL ATTN RTN */                       09696021
*/* S BLDIRB: BUILD IRB & 1 IQE FOR ATTN HANDLING */                    09699021
*/* P STORE IRB ADDRESS IN ALL UCB'S OF LINE GROUP */                   09702021
*/* D (YES,,NO,NORDYQ) READYQ SPECIFIED IN DCB ? */                     09704021
*/* D (YES,BLDRDYRB,NO,) USER PROVIDE ROUTINE ? */                      09704421
*/* S LOADRTN: LOAD BTAM'S READY EXIT ROUTINE */                        09704821
*/* P FLAG USING BTAM'S ROUTINE IN DCB */                               09704921
*/* P STORE ADDRESS OF ROUTINE IN DCB */                                09708421
*/*BLDRDYRB: D (YES,USEUSER,NO,) USER PROVIDE ROUTINE ? */              09710421
*/* S (,RDYIRBDN) BLDIRB: BUILD IRB AND IQE'S FOR BTAM READY */         09712421
*/*USEUSER: S BLDPIRB: BUILD IRB AND IQE'S FOR USER READY */            09712921
*/*RDYIRBDN: P SET GRAF FLAGS AND STORE IRB ADDRESS IN ALL UCB'S */     09713321
*/*ENDLOAD: P CHECK ALL UCB'S FOR READY DURING OPEN */                  09715321
*/*NORDYQ: P CLEAR WHERE-TO-GO ID TO INDICATE END OF OPEN */            09715721
*/* R GO TO STANDARD WHERE-TO-GO CODE */                                09716021
*/*VDLPINDX: D (NO,,YES,DDMIN) VECTOR FOR LOCAL 3270? */                09719521
*/* D (NO,,YES,VDOVRFLO) END OF TABLE ENTRY? */                         09723021
*/* M (,RWVDLP) INCR INDICES FOR NEXT ENTRY */                          09726521
*/*VDOVRFLO: R ABEND WITH SYSTEM 097 CODE */                            09730021
*/*LOADRTN: E ENTRY */                                                  09733521
*/* P CONSTRUCT BLDL LIST ENTRY IN OPEN WORK AREA FROM IDTTRL ENTRY */  09737021
*/* D (NO,,YES,THREERCD) RTN REQUESTED = READ/WRITE RTN? */             09740521
*/*COMPL: D (NO,,YES,LONGLOAD) RTN SIZE EXCEEDS 1024 BYTES? */          09744021
*/* P LENGTH OF FIRST TEXT RCD = SIZE OF ROUTINE */                     09747521
*/*LOAD: L LOAD RTN FROM SYS1.SVCLIB */                                 09751021
*/* P STORE ID IN CURRENT DEB SUBID ENTRY */                            09754521
*/* M INCREMENT POINTER TO NEXT DEB SUBID ENTRY */                      09758021
*/* R RETURN */                                                         09761521
*/*THREERCD: P ADD X'800' TO RTN LENGTH DERIVED FROM IDTTRL*/           09765021
*/*LONGLOAD: P LENGTH OF FIRST TEXT RECORD = 1024 BYTES */              09768521
*/* P (,LOAD) MODIFY LOAD ATTRIBUTES FOR MULTIPLE TEXT RECORDS */       09772021
*/*BLDIRB: E ENTRY */                                                   09775521
*/* P COMPUTE LENGTH OF IRB WORKAREA */                                 09779021
*/* L INVOKE CIRB TO BUILD IRB */                                       09782521
*/*IQEINIT: P INITIALIZE IQE'S AND LINK THEM TOGETHER */                09786021
*/* P SET LINK OF LAST IQE = ZERO */                                    09789521
*/* R RETURN */                                                         09793021
*/*BLDPIRB: E ENTRY */                                                  09795021
*/* P COMPUTE LENGTH OF IRB WORKAREA */                                 09795421
*/* L (,IQEINIT) INVOKE CIRB TO BUILD PROB PROG IRB */                  09795821
         EJECT                                                          09796521
*              REGISTER EQUATES                                         09800021
RPARM2   EQU   0                   SECOND PARAMETER REGISTER            10000021
RPARM1   EQU   1                   FIRST PARAMETER REGISTER             10200021
REVN     EQU   2                   WORK REGISTER- EVEN                  10400021
RODD     EQU   3                   WORK REGISTER- ODD                   10600021
RCORE    EQU   4                   POINTER TO GETMAIN'ED CORE           10800021
RPAR     EQU   5                   START OF PARAMETER LIST              11000021
RWTG     EQU   6                   START OF WTG TABLE                   11200021
RPARC    EQU   7                   CURRENT ENTRY IN PARAMETER LIST      11400021
RWTGC    EQU   8                   CURRENT ENTRY IN WTG TABLE           11600021
RUCB     EQU   9                   POINTER TO UCB                       11800021
RDEB     EQU   10                  POINTER TO DEB                       12000021
RBASE    EQU   11                  BASE REGISTER FOR CSECT              12200021
RDCB     EQU   12                  POINTER TO DCB                       12400021
RW3      EQU   13                  WORK REGISTER                        12600021
RRTRN    EQU   14                  RETURN POINT REGISTER                12800021
RRTN     EQU   14                                                       13000021
REPR     EQU   15                  ENTRY POINT REG                      13200021
*                                                                       13400021
RW1      EQU   2                   ALTERNATE ASSIGNMENTS                13600021
RW2      EQU   3                       FOR WORK REGISTERS               13800021
RSUBID   EQU   9                   POINTER TO NEXT DEB SUB-ID FIELD     14000021
*                                                                       14200021
ANRDEVTP EQU   X'FE'               DCBDEVTP CODE FOR 3270               14400021
CVTAD    EQU   16                                                       14600021
DEBAVT   EQU   28                  DISP TO VECTOR TO DEB APPENDAGE TAB  14700021
EQ       EQU   8                   CC MASK = 8                          14800021
EIGHT    EQU   X'08'                                                    15000021
FIVE     EQU   5                                                        15060021
ONE28    EQU   128                                                      15120021
FOUR     EQU   4                                                        15200021
FREEPOOL EQU   X'04'                FLAG TO CLOSE TO RELEASE BUFFERS    15400021
GRAF     EQU   28                  OFFSET TO GRAPHICS STATUS  SB A57064 15450021
IQEIRB   EQU   8                   DISP TO IRB ADDR FIELD IN IQE        15600021
IQELNGTH EQU   16                  LENGTH OF AN IQE IN BYTES            15800021
IQELNK   EQU   0                   DISP TO LINK FIELD IN IQE            16000021
IQETCB   EQU   12                  DISP TO TCB ADDR FIELD IN IQE        16200021
IRBAD    EQU   28                  DISP TO IRB ADDR IN UCB EXTENSION    16400021
LOADATB  EQU   X'CB'               STANDARD LOAD ATTRIBUTES             16600021
*    REENTERABLE, ONLY LOADABLE, EXECUTABLE, ONLY ONE TEXT RECORD, NO   16800021
*    RLD RECORD, ORIGIN IS ZERO, ENTRY IS ZEROS EERO, AND CANNOT BE     17000021
*    REPROCESSED BY THE LINKAGE EDITOR.                                 17200021
LOADATB1 EQU   X'CA'               LOAD ATTRIBUTES FOR MODULES          17400021
*    LARGER THAN 1024 BYTES - SAME AS LOADATB BUT MORE THAN ONE         17600021
*    TEXT RECORD.                                                       17800021
NDVTRTBL EQU   X'FF'               END OF VECTOR TABLE CODE             18000021
OLT      EQU   X'10'               DCB OLT FLAG                         18200021
ONE      EQU   1                                                        18400021
PLOFF    EQU   4                   OFFSET IN PARM LIST                  18600021
RBNEXAV  EQU   96                  DISP TO IQE POINTER IN IRB           18800021
RDYOFF   EQU   X'EF'               TURN OFF READY IN OPEN FLG SB A57064 18810021
RDYQ     EQU   32                  UCB OFFSET TO READY IRB AD SB A57064 18850021
SEVEN    EQU   7                                                        18860021
SIX      EQU   6                                                        18920021
SVCDCB   EQU   84                  DISP TO DCB FOR SYS1.SVCLIB IN CVT   19000021
TENAND4  EQU   14                                                       19100021
THREE    EQU   3                                                        19200021
TWENTY2  EQU   22                                                       19230021
TWENTY4  EQU   24                                                       19260021
TWENTY5  EQU   25                                                       19290021
TWENTY6  EQU   26                                                       19320021
TWENTY7  EQU   27                                                       19350021
TWO      EQU   2                                                        19400021
VDOFFSET EQU   12                  DISP TO VECTOR TABLE IN READ/WRITE   19600021
*                                      RTN                              19800021
WAOFF    EQU   32                  OFFSET OF FIRST WTG ENTRY FROM       20000021
*                                      BEGINNING OF TABLE               20200021
DXCCW12  EQU   X'1C8'                                                   20400021
WGOFF    EQU   8                   OFFSET IN WTG TABLE                  20600021
ZERO     EQU   0                                                        20800021
*                                                                       21000021
*                                                                       21200021
         USING IHADCB,RDCB                                              21400021
         USING IECTDEB,RDEB                                             21600021
         BALR  RBASE,0             ESTABLISH ADDRESSABILITY FOR CSECT   21800021
         USING *,RBASE                                                  22000021
         L     RDCB,0(RPARC)       ADDRESSABILITY FOR DCB               22200021
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      22400021
         L     RDEB,DEBAVT(RDEB)   GET START OF APPENDAGE VECTOR TABLE  22600021
*                                                                       22800021
*                                                                       23000021
*              DETERMINE IF A BUFFER POOL MUST BE OBTAINED              23200021
         CLI   DCBBUFCB+3,ONE      BUFFER POOL PROVIDED BY USER         23400021
         BNE   GETIOB               YES, GO GET IOB'S                   23600021
         CLI   DCBBUFNO,ZERO        NO. ARE ANY BUFFERS REQUESTED       23800021
         BE    GETIOB               NO, BUFFER POOL NOT REQUIRED.       24000021
*                                   GO GET IOB'S                        24200021
         CLC   DCBBUFL(TWO),ZEROS  BUFFER LENGTH EQUAL TO ZERO          24400021
         BE    GETIOB               YES, GO GET IOB'S                   24600021
*                                                                       24800021
*              CONSTRUCT BUFFER POOL                                    25000021
         SR    RW1,RW1                                                  25200021
         IC    RW1,DCBBUFNO         GET NUMBER OF BUFFERS               25400021
         LH    RW2,DCBBUFL          GET BUFFER LENGTH                   25600021
         LA    RW2,THREE(RW2)       ROUND TO                            25800021
         SRL   RW2,TWO                  NEXT HIGHEST                    26000021
         SLL   RW2,TWO                      FULL WORD                   26200021
         STH   RW2,DCBBUFL          STORE ROUNDED LENGTH IN DCB         26400021
         LR    RPARM1,RW1                                               26600021
         MR    RPARM2,RW2           COMPUTE SIZE OF BUFFER AREA         26800021
         LA    RPARM2,EIGHT(RPARM1) ADD 8 FOR BUFFER CONTROL BLOCK      27000021
         O     RPARM2,IOBPOOL       PLACE SUBPOOL NUMBER IN             27200021
*                                   HIGH-ORDER BYTE OF PARM REG         27400021
         GETMAIN  R,LV=(0)          GET CORE FOR BUFFER POOL            27600021
         ST    RPARM1,0(RPARM1)     STORE ADDRESS IN BUFCB              27800021
         MVC   DCBBUFCB+1(THREE),ONE(RPARM1)  STORE ADDR IN DCB         28000021
         STH   RW1,FOUR(RPARM1)    STORE NO. OF BUFFERS IN BUFCB        28200021
         STH   RW2,SIX(RPARM1)     STORE SIZE OF BUFFERS IN BUFCB       28400021
*              BUILD BUFFER CHAIN                                       28600021
         LR    RCORE,RPARM1                                             28800021
         LA    RPARM1,EIGHT(RPARM1) GET ADDRESS OF FIRST BUFFER         29000021
         ST    RPARM1,0(RCORE)      STORE ADDRESS OF FIRST BUFFER       29200021
*                                       IN BUFFER CONTROL BLOCK         29400021
TESTBUFC BCT   RW1,NEXTBUF          IF MORE BUFFERS, BRANCH             29600021
         ST    RW1,0(RPARM1)        ZERO LAST LINK FIELD                29800021
         OI    DCBMACRF,FREEPOOL    TELL CLOSE TO FREE BUFFER POOL      30000021
         B     GETIOB               GO GET THE IOB'S                    30200021
*                                                                       30400021
NEXTBUF  LR    RCORE,RPARM1         SAVE ADDRESS OF CURRENT BUFFER      30600021
         ALR   RPARM1,RW2           COMPUTE ADDRESS OF NEXT BUFFER      30800021
         ST    RPARM1,0(RCORE)      STORE ADDRESS OF NEXT BUFFER IN     31000021
*                                       LINK FIELD OF CURRENT BUFFER    31200021
         B     TESTBUFC            LOOP TO PROCESS NEXT BUFFER          31400021
*                                                                       31600021
GETIOB   EQU   *                                                        31800021
         SR    RSUBID,RSUBID                                            32000021
         IC    RSUBID,DEBNMEXT     GET NO. OF DEVICES IN THE LINE GROUP 32200021
         SLL   RSUBID,TWO          MULT BY 4 TO GET LENGTH OF UCB LIST  32400021
         LA    RSUBID,DEBUCBAD(RSUBID)  GET ADDRESS OF AM AREA          32600021
         IC REVN,DCBOFLGS          SAVE DCB OPEN FLAGS                  32800021
         ST    RSUBID,DCBREAD      SAVE ADDRESS OF ACCESS METHOD AREA   33000021
         STC   REVN,DCBOFLGS       RESTORE DCB OPEN FLAGS               33200021
*                                                                       33400021
         SR    REVN,REVN                                                33600021
         IC    REVN,DEBAMLNG       GET LENGTH OF ACCESS METHOD AREA     33800021
         AR    RSUBID,REVN         ADD TO GET ADDRESS OF SUB-ID'S       34000021
*                                                                       34200021
         TM    DCBERROP,OLT        ON-LINE TESTS REQUIRED               34400021
         BNO   TESTBPM             NO, TEST FOR BUFFER MANAGEMENT RTN   34600021
         L     RCORE,DEBIRBAD-1    GET ADDRESS OF DEB IRB POINTERS      34800021
         LA    RPARM1,OLTCTL       GET ADDRESS OF IDTTRL ENTRY          35000021
         BAL   RRTRN,LOADRTN       LOAD OLT CTL MODULE                  35200021
         SR    RPARM1,RPARM1                                            35400021
         IC    RPARM1,DEBNMEXT     NO. OF IQE'S = NO. OF DEVICES        35600021
         SLA   RPARM1,ONE               & MULTIPLY BY 2                 35800021
*                                  BECAUSE EXISTING BTAM EXPECTS IT     36000021
         BAL   RRTRN,BLDIRB        BUILD IRB AND IQE'S FOR OLT          36200021
         ST    RPARM1,0(RCORE)     STORE IRB ADDRESS IN POINTER         36400021
*                                                                       36600021
TESTBPM  CLI   DEBAMLNG,ZERO       BUFFER MANAGEMENT REQUIRED           36800021
         BZ    LOADCEA             NO, GO LOAD CEA/XEA                  37000021
         LA    RPARM1,BPMR         GET ADDRESS OF IDTTRL ENTRY          37200021
         BAL   RRTN,LOADRTN        LOAD BUFFER POOL MANAGEMENT ROUTINE  37400021
         L     REVN,DCBREAD        GET ADDRESS OF AM SECTION IN DEB     37600021
         ST    RPARM2,0(REVN)      STORE ADDR OF ROUTINE IN DEB         37800021
*                                                                       38000021
LOADCEA  LA    RPARM1,CHENDAPP     GET ADDRESS OF IDTTRL ENTRY          38200021
         BAL   RRTN,LOADRTN        LOAD CEA/XEA                         38400021
         ST    RPARM2,DEBCEA       STORE RTN ADDR IN DEB VECTOR TO CEA  38600021
         ST    RPARM2,DEBXCEA          AND XEA                          38800021
*                                                                       39000021
         LA    RPARM1,RDWRTRTN     GET ADDRESS OF IDTTRL ENTRY          39200021
         BAL   RRTN,LOADRTN        LOAD READ/WRITE ROUTINE              39400021
         IC    REVN,DCBOFLGS       SAVE DCBOFLAGS                       39600021
         ST    RPARM2,DCBREAD      STORE ADDRESS OF READ/WRITE RTN      39800021
         STC   REVN,DCBOFLGS       RESTORE OPEN FLAGS DESTROYED BY      40000021
*                                      PREVIOUS STORE.                  40200021
*                                                                       40400021
         LR    RCORE,RPARM2        GET ADDR OF READ/WRITE RTN           40600021
         LA    RCORE,VDOFFSET(RCORE)    GET BEGINNING OF VECTOR TABLE   40800021
         SR    REVN,REVN           INITIALIZE INDEX COUNTER             41000021
         SR    RODD,RODD           INITIALIZE COMPARAND OF ZERO         41200021
*                                                                       41400021
RWVDLP   C     RODD,0(RCORE)       VECTOR TABLE ENTRY EQUAL ZERO        41600021
         BNZ   VDLPINDX            BRANCH IF FIELD NON-ZERO             41800021
         MVI   TWO(RCORE),ANRDEVTP MAKE FIELD NON-ZERO                  42000021
DDMIN    STC   REVN,DCBDEVTP       STORE INDEX TO VECTOR IN DCB         42200021
         LA    RPARM1,DDM          GET ADDRESS OF IDTTRL ENTRY          42400021
         BAL   RRTN,LOADRTN        LOAD 3270 LOCAL DDM                  42600021
         ST    RPARM2,0(RCORE)     STORE ADDRESS IN VECTOR TABLE        42800021
         MVI   0(RCORE),ANRDEVTP   STORE DEVICE TYPE CODE IN HIGH-ORDER 43000021
*                                      BYTE                             43200021
         B     ENBLATN             BRANCH TO LOAD 2ND LEVEL ATTN RTN    43400021
*                                                                       43600021
VDLPINDX CLI   0(RCORE),ANRDEVTP   VECTOR FOR ANR                       43800021
         BE    DDMIN               YES, USE IT                          44000021
         CLI   0(RCORE),NDVTRTBL   END OF TABLE                         44200021
         BE    VDOVRFLO            YES, GIVE ABEND                      44400021
         LA    RCORE,FOUR(RCORE)   INCR TO NEXT ENTRY                   44600021
         LA    REVN,ONE(REVN)      BUMP INDEX                           44800021
         B     RWVDLP              CHECK NEXT ENTRY                     45000021
*                                                                       45200021
VDOVRFLO L     RPARM1,ERR6         VECTOR DIRECTORY OVERFLOW ERROR      45400021
         ABEND (1)                                                      45600021
*                                                                       45800021
ENBLATN  LA    RPARM1,ATNRTN2      GET IDTTRL ENTRY                     46000021
         BAL   RRTN,LOADRTN        LOAD SECOND LEVEL ATTN RTN           46200021
         LA    RPARM1,TWO          NO. OF IQE'S = TWO            A68754 46400021
         BAL   RRTN,BLDIRB         BUILD IRB AND IQE FOR ATTENTION      46600021
*                                  HANDLING                             46800021
         LR    RW3,RSUBID          SAVE SUB ID PTR            SB A57064 46850021
         SR    REVN,REVN           INITIALIZE UCB LIST INDEX            47000021
         SR    RODD,RODD                                                47200021
         IC    RODD,DEBNMEXT       INITIALIZE LOOP COUNTER              47400021
ATNIRBLP L     RUCB,DEBUCBAD(REVN) GET UCB ADDRESS                      47600021
         LA    RPARM1,0(RPARM1)    INSURE HIGH BYTE CLEAR     SB A57064 47650021
         IC    RPARM2,IRBAD(RUCB)  PICK UP GRAF FLAGS         SB A57064 47700021
         SLL   RPARM2,TWENTY4      PUT IN HIGH BYTE           SB A57064 47750021
         OR    RPARM1,RPARM2       SAVE GRAF FLAGS            SB A57064 47760021
         ST    RPARM1,IRBAD(RUCB)  STORE IRB ADDR IN UCB EXTENSION      47800021
         LA    REVN,FOUR(REVN)     INDEX TO NEXT UCB ADDRESS            48000021
         BCT   RODD,ATNIRBLP       LOOP IF NOT FINISHED                 48200021
*                                                                       48400021
         TM    DCBLERB,X'02'       ADDRESS VIA READYQ ?       SB A57064 48400121
         BNO   NORDYQ              NO, DON'T SETUP IRB        SB A57064 48400221
         L     REVN,52(RDCB)       PICK POINTER TO USER       SB A57064 48450021
*                                  SUPPLIED READY ROUTINE     SB A57064 48500021
         LA    REVN,0(REVN)        CLEAR HIGH BYTE            SB A57064 48550021
         LTR   REVN,REVN           ADDRESS SUPPLIED ?         SB A57064 48560021
         BNZ   BLDRDYRB            YES, USE IT                SB A57064 48570021
         LR    RSUBID,RW3          RESTORE SUB ID PTR         SB A57064 48571621
         OI    DCBLERB,X'01'       FLAG USING BTAM'S          SB A57064 48574021
         LA    RPARM1,READYM       POINT TO IDTTRL            SB A57064 48575621
         BAL   RRTN,LOADRTN        LOAD READYQ - IGG019UP     SB A57064 48577221
         LR    REVN,RPARM2         GET ENTRY POINT            SB A57064 48578821
         LA    REVN,0(REVN)        CLEAR HIGH BYTE            SB A57064 48580421
         O     REVN,DCBLERB        PICK UP FLAGS              SB A57064 48582021
         ST    REVN,DCBLERB        SAVE THE ADDRESS           SB A57064 48583621
         LA    REVN,0(REVN)        CLEAR HIGH BYTE            SB A57064 48585221
BLDRDYRB EQU   *                   BUILD THE IRB              SB A57064 48586821
         LR    RPARM2,REVN         SET EP ADDRESS             SB A57064 48588421
         SR    RPARM1,RPARM1       CLEAR IQE COUNT REG        SB A57064 48590021
         IC    RPARM1,DEBNMEXT     GET NUMB IQE'S - ONE / UCB SB A57064 48592021
         TM    DCBLERB,X'01'       USING BTAM'S ?             SB A57064 48592121
         BNO   USEUSER             NO, BUILD PP IRB           SB A57064 48592221
         BAL   RRTN,BLDIRB         BUILD A SUPR IRB           SB A57064 48592321
         B     RDYIRBDN            GO SET UP UCB'S            SB A57064 48592421
USEUSER  EQU   *                   BUILD USER IRB             SB A57064 48592521
         BAL   RRTN,BLDPIRB        GO BUILD THE READY QUEUE   SB A57064 48594021
RDYIRBDN EQU   *                   IRB IS BUILT               SB A57064 48594121
         SR    REVN,REVN           CLEAR A WORK REGISTER      SB A57064 48596021
         SR    RODD,RODD           CLEAR A WORK REGISTER      SB A57064 48598021
         IC    RODD,DEBNMEXT       INITIALIZE LOOP COUNTER    SB A57064 48598421
RDYIRBLP L     RUCB,DEBUCBAD(REVN) GET UCB ADDRESS            SB A57064 48598821
         ST    RPARM1,RDYQ(RUCB)   STORE IRB ADDRESS IN UCB   SB A57064 48599221
         TM    DCBLERB,X'01'       USING BTAM'S ?             SB A57064 48599621
         BZ    SETUSER             NO, FLAG USER              SB A57064 48599721
         OI    GRAF(RUCB),X'10'    SAY BTAM                   SB A57064 48599821
         B     TYPESET             CONTINUE                   SB A57064 48599921
SETUSER  EQU   *                   INDICATE USER ROUTINE      SB A57064 48600021
         OI    GRAF(RUCB),X'08'    SAY USER                   SB A57064 48600121
TYPESET  EQU   *                   TYPE OF ROUTINE FLAGGED    SB A57064 48600221
         LA    REVN,FOUR(REVN)     INDEX TO NEXT UCB ADDRESS  SB A57064 48600321
         BCT   RODD,RDYIRBLP       LOOP IF NOT FINISHED       SB A57064 48600421
ENDLOAD  EQU   *                   BTAM OPEN DONE             SB A57064 48600521
         SR    RODD,RODD           CLEAR A WORK REGISTER      SB A57064 48650021
         SR    REVN,REVN           CLEAR A WORK REGISTER      SB A57064 48700021
         IC    RODD,DEBNMEXT       INITIALIZE LOOP COUNTER    SB A57064 48750021
CHKOPRDY EQU   *                   CHECK FOR READY DURING OPENSB A57064 48760021
         L     RUCB,DEBUCBAD(REVN) GET UCB ADDRESS            SB A57064 48770021
         NI    GRAF(RUCB),X'7F'    TURN OPEN IN PROGRESS      SB A57064 48780021
         TM    GRAF(RUCB),X'40'    READY DURING OPEN ?        SB A57064 48780121
         BNO   SCHEDRET            NO, CONTINUE               SB A57064 48780221
         NI    GRAF(RUCB),X'BF'    TURN OFF OPEN READY        SB A57064 48780321
         SR    RDCB,RDCB           CLEAR EVEN REG             SB A57064 48780421
         LA    RW3,X'58'           PICK UP IOB LENGTH         SB A57064 48780521
         IC    RDCB,36(RUCB)       GET RLN FOR DEVICE         SB A57064 48780621
         MR    RDCB,RDCB           DISP INTO IOB POOL         SB A57064 48780721
         L     RDCB,0(RPARC)       GET DCB ADDRESS            SB A57064 48780821
         L     RDCB,28(RDCB)       GET ADDRESS OF IOB POOL    SB A57064 48780921
         LA    RDCB,0(RW3,RDCB)    POINT TO THIS RLN'S IOB    SB A57064 48781021
         NI    28(RDCB),X'7F'      TURN OFF OPEN FAILED       SB A57064 48781121
         L     RDCB,0(RPARC)       RESTORE DCB ADDRESS        SB A57064 48781221
SCHEDRET LA    REVN,FOUR(REVN)     INDEX TO NEXT UCB          SB A57064 48796021
         BCT   RODD,CHKOPRDY       LOOP IF NOT FINISHED       SB A57064 48798021
NORDYQ   EQU   *                   THIS LOAD FINISHED         SB A57064 48798121
         XC    0(TWO,RWTGC),0(RWTGC) CLEAR ID TO INDICATE DONESB A57064 48798421
         L     REVN,FOUR(RWTGC)    GET ADDR OF EXECUTOR'S WORK AREA     48800021
*                                                                       49000021
RELOOP   LA    RWTGC,WGOFF(RWTGC)  INCR CURRENT WTG REGISTER            49200021
         LA    RPARC,PLOFF(RPARC)  INCR CURRENT PARM LIST REGISTER      49400021
         CLC   0(TWO,RWTGC),AMIDCNST   IF THE NEXT WTG ENTRY REQUIRES   49600021
         BCR   EQ,RBASE            THIS EXECUTOR, EXEC MODULE AGAIN     49800021
         CLC   0(TWO,RWTGC),OPIDCNST   END OF TABLE                     50000021
         BNE   RELOOP              NO, CHECK NEXT ENTRY IN TABLE        50200021
*                                                                       50400021
         LR    RPARC,RPAR          REINITIALIZE CURRENT PARM LIST REG   50600021
         LA    RWTGC,WAOFF(RWTG)       AND WTG REGISTER                 50800021
*                                                                       51000021
ZCHECK   CLI   0(RWTGC),ZERO       IF ENTRY NON-ZERO,                   51200021
         BNE   XCTLRTNE                GO TO TRANSFER CONTROL           51400021
         LA    RWTGC,WGOFF(RWTGC)  IF ZERO, GET NEXT ENTRY              51600021
         LA    RPARC,PLOFF(RPARC)                                       51800021
         B     ZCHECK                  AND CHECK IT                     52000021
*                                                                       52200021
XCTLRTNE LA    REPR,DXCCW12(REVN)  POINT TO DOUBLE WORD LIST            52400021
         MVC   SIX(TWO,RWTG),0(RWTGC)  MOVE ID TO NAME FIELD            52500021
         MVC   TENAND4(THREE,RWTG),TWO(RWTGC)  MOVE TTR TO WTG FIELD    52600021
         MVC   TWENTY2(SEVEN,RWTG),CONATB  RESTORE XCTL ATTRIBUTES      52700021
*                                  & LENGTH                             52800021
         XCTL  DE=(RWTG),SF=(E,(15))                                    53200021
*                                                                       53400021
*                                                                       53600021
*        THIS SUBROUTINE IS USED TO LOAD ROUTINES FOR OPEN              53800021
*  INPUT - REGISTER 1 - ADDR OF IDTTRL ENTRY OF MODULE TO BE LOADED     54000021
*  OUTPUT - REGISTER 0 - ADDR OF THE LOADED ROUTINE                     54200021
*  RETURN ADDR IN REGISTER 14                                           54400021
LOADRTN  MVI   TWENTY2(RWTG),LOADATB  SET STANDARD LOAD ATTRIBUTES      54500021
         MVC   SIX(TWO,RWTG),0(RPARM1)  MOVE ID TO LAST 2 BYTES OF      54600021
*                                  NAME                                 54700021
         MVC   TENAND4(THREE,RWTG),TWO(RPARM1)  MOVE TTR FROM TABLE     54800021
         SR    REVN,REVN                                                55200021
         IC    REVN,FIVE(RPARM1)   GET LENGTH IN DOUBLE WORDS           55400021
         SLL   REVN,3                  AND CONVERT TO BYTES             55600021
         ST    REVN,TWENTY4(RWTG)  STORE LENGTH IN PARM LIST            55800021
         MVC   TWENTY5(TWO,RWTG),TWENTY6(RWTG)  MOVE LENGTH             56000021
         CLC   0(TWO,RPARM1),RDWRTRTN  MOD REQUESTED = READ/WRITE RTN   56200021
         BE    THREERCD            YES, ADJUST LENGTH TO THREE RECORDS  56400021
*                                      TOTAL LENGTH OF MODULE           56600021
CMPL     CLI   FIVE(RPARM1),ONE28  IF MOD MORE THAN 128 DOUBLE WORDS    56800021
         BH    LONGLOAD                (1024 BYTES)  LONG, GO TO        57000021
*                                       SET UP LONG LOAD                57100021
         MVC   TWENTY7(TWO,RWTG),TWENTY5(RWTG)  MOVE LENGTH TO FIELD    57200021
*                                       WHICH INDICATES LENGTH OF       57300021
*                                       FIRST TEXT RECORD               57400021
LOAD     LR    RPARM2,RWTG         POINT TO PARAMETER LIST              57600021
         L     RPARM1,CVTAD        GET ADDRESS OF CVT                   57800021
         L     RPARM1,SVCDCB(RPARM1)   GET ADDR OF DCB FOR SYS1.SVCLIB  58000021
         LR    RODD,RRTN           SAVE RETURN ADDRESS                  58200021
         LOAD  DE=(0),DCB=(1)                                           58400021
         MVC   0(TWO,RSUBID),SIX(RWTG)  MOVE ID TO DEB                  58600021
         LA    RSUBID,TWO(RSUBID)  INCR TO NEXT SUB-ID IN DEB           58800021
         SR    REVN,REVN                                                59000021
         IC    REVN,DEBNMSUB       GET NO. OF SUBROUTINES LOADED        59200021
         LA    REVN,ONE(REVN)      ADD ONE                              59400021
         STC   REVN,DEBNMSUB       STORE UPDATED COUNT IN DEB           59600021
         BR    RODD                RETURN TO NSI                        59800021
*                                                                       60000021
THREERCD OI    TWENTY5(RWTG),EIGHT ADD X'800' TO TTR LENGTH             60200021
LONGLOAD MVC   TWENTY7(TWO,RWTG),CONATB+3  SET LENGTH OF FIRST TEXT     60400021
*                                  RECORD TO 1024 (X'400') BYTES        60600021
         MVI   TWENTY2(RWTG),LOADATB1  MODIFY ATTRIBUTES FOR MORE       60800021
*                                      THAN ONE TEXT RECORD             61000021
         B     LOAD                                                     61200021
*                                                                       61400021
*        THIS SUBROUTINE IS USED TO BUILD AN IRB AND REQUIRED IQE'S     61600021
*        FOR OPEN                                                       61800021
* INPUT - REGISTER 0 - ADDRESS OF THE ROUTINE ENTRY POINT TO BE USED    62000021
*         REGISTER 1 - NUMBER OF IQE'S TO BE BUILT                      62200021
*                                                                       62400021
* OUTPUT - REGISTER 1 - ADDRESS OF THE INITIALIZED IRB                  62600021
*                                                                       62800021
* RETURN ADDRESS PASSED IN REGISTER 14                                  63000021
*                                                                       63200021
BLDPIRB  EQU   *                   BUILD PP IRB               SB A57064 63250021
         LR    REVN,RPARM1         SAVE NO. IQE'S             SB A57064 63300021
         SLL   REVN,1              MULTIPLY BY TWO            SB A57064 63350021
         LA    REVN,ONE(REVN)      ADD ONE FOR LNGTH OF WKAREASB A57064 63360021
         LR    RW3,RRTN            SAVE RETURN PTR            SB A57064 63370021
         CIRB  EP=(RPARM2),KEY=PP,MODE=PP,STAB=(RE),WKAREA=(REVN),     X63372021
               SVAREA=YES                                     SB A57064 63374021
         B     IRBSETUP            GO SET IT UP               SB A57064 63376021
*                                                             SB A57064 63380021
BLDIRB   LR    REVN,RPARM1         SAVE NO. OF IQE'S                    63400021
         SLL   REVN,1              MULTIPLY BY TWO                      63600021
         LA    REVN,ONE(REVN)      ADD ONE TO GET LENGTH OF WORKAREA    63800021
         LR    RW3,RRTN                IN DOUBLE WORDS                  64000021
         CIRB  EP=(RPARM2),KEY=SUPR,MODE=SUPR,STAB=(RE),WKAREA=(REVN)   64200021
*                                                                       64400021
IRBSETUP EQU   *                                              SB A57064 64450021
         SRL   REVN,1              GET NUMBER OF IQE'S                  64600021
         LA    RODD,RBNEXAV(RPARM1)    GET ADDR OF IRB'S IQE POINTER    64800021
         LR    RRTN,RW3            RESTORE RETURN ADDRESS               65000021
         L     RPARM2,DEBTCBAD-1   GET TCB ADDRESS                      65200021
         LA    RW3,FOUR(RODD)                                           65400021
IQEINIT  ST    RW3,IQELNK(RODD)    STORE ADDR OF NEXT IQE IN CURRENT    65600021
*                                      LINK                             65800021
         ST    RPARM1,IQEIRB(RW3)  STORE IRB ADDR IN IQE                66000021
         ST    RPARM2,IQETCB(RW3)  STORE TCB ADDR IN IQE                66200021
         MVI   IQETCB(RW3),ZERO    CLEAR HIGH ORDER BYTE                66400021
         LR    RODD,RW3            SAVE ADDR OF THIS IQE                66600021
         LA    RW3,IQELNGTH(RW3)   STEP TO NEXT                         66800021
         BCT   REVN,IQEINIT        LOOP IF MORE TO DO                   67000021
         ST    REVN,IQELNK(RODD)   ZERO LINK FIELD OF LAST IQE          67200021
*                                                                       67400021
         BR    RRTN                RETURN TO CALLING POINT              67600021
*                                                                       67800021
*                                                                       68149721
AMIDCNST DC    C'4Q'               ID OF THIS EXECUTOR                  68200021
OPIDCNST DC    C'0S'               ID OF LAST OPEN LOAD                 68400021
         DS    0F                  FORCE FULL WORD ALIGNMENT            68600021
ZEROS    DC    F'0'                WORD OF ZEROS                        68800021
IOBPOOL  DC    X'FA000000'         SUBPOOL NO. FOR IOB'S AND BUFFERS    69000021
ERR6     DC    X'80097000'         ABEND CODE FOR VECTOR TABLE OVERFLOW 69200021
CONATB   DC    X'C3780004000400'   XCTL ATTRIBUTES AND LENGTH           69400021
*                                                                       69600021
*        IDTTRL TABLE FOR THE BTAM ROUTINES USED FOR THE LOCAL 3270.    69800021
*    EACH ENTRY CONSISTS OF THE LAST TWO CHARACTERS OF THE MODULE NAME, 70000021
*    THE RELATIVE TRACK AND RECORD ADDRESS OF THE CORRESPONDING LOAD    70200021
*    MODULE ON SYS1.SVCLIB, AND THE LENGTH OF THE MODULE IN DOUBLE      70400021
*    WORDS. THE TTR AND LENGTH ARE INSERTED BY THE IEHIOSUP UTILITY     70600021
*    DURING STAGE 2 OF SYSGEN. IF ANY OF THESE MODULES ARE CHANGED,     70800021
*    REPLACED, OR MOVED, IEHIOSUP MUST BE EXECUTED AGAIN.               71000021
*                                                                       71200021
NENT     EQU   7                   NUMBER OF IDTTRL'S                   71400021
LENGTH   EQU   NENT*6+6            LENGTH OF IDTTRL'S +2+4              71600021
NODBWDS  EQU   (LENGTH+7)/8        NO. OF DBL WORDS WITH PADDING        71800021
ORGIDTTR EQU   1024-NODBWDS*8      START OF IDTTRL LIST                 72000021
*                                                                       72200021
         ORG   IGG0194Q+ORGIDTTR   BEGINNING OF IDTTRL TABLE            72400021
RDWRTRTN DC    C'MA',XL4'0'        READ/WRITE RTN                       72600021
BPMR     DC    C'MS',XL4'0'        BUFFER POOL MANAGEMENT RTN           72800021
CHENDAPP DC    C'PA',XL4'0'        LOCAL 3270 CEA/XEA RTN               73000021
ATNRTN2  DC    C'PG',XL4'0'        LOCAL 3270 SECOND LEVEL ATTN RTN     73200021
DDM      DC    C'PH',XL4'0'        LOCAL 3270 DEVICE DEPENDENT MODULE   73400021
OLTCTL   DC    C'PI',XL4'0'        LOCAL 3270 OLT CONTROL RTN           73600021
READYM   DC    C'UP',XL4'0'        LOCAL 3270 READY ROUTINE   SB A57064 73600121
*                                                                       73800021
IDEND    DC    XL2'0'              END OF IDTTRL TABLE                  74000021
         CNOP  4,8                 PADDING                              74200021
LOADID   DC    C'019'              OPEN SVC CODE                        74400021
         DC    YL1(X'80'-NODBWDS)  POINTER FOR IEHIOSUP                 74600021
*                                                                       74800021
*        END OF IDTTRL TABLE                                            75000021
*                                                                       75200021
         DCBD  DSORG=BX,DEVD=BS                                         75400021
         IECTDEBX                                                       75600021
         IECTIOBX                                                       75800021
         END                                                            76000021
