 TITLE 'IGG019MC - BTAM PCI APPENDAGE'                                  00200013
IGG019MC CSECT                                                          00400013
*72430001012000,468000                                             000C 00700015
         SPACE 2                                                        01000013
* STATUS            CHANGE LEVEL  004   NOVEMBER 16, 1967               01200015
         SPACE 2                                                        01400013
* FUNCTION -                                                            01600013
*                   THE PROGRAM CONTROLLED INTERRUPT IS USED TO         01800013
*                   PROVIDE DYNAMIC BUFFERING (*) BY ASSIGNING BUFFER   02000013
*                   N+1  DURING THE TIME BUFFER N IS BEING READ INTO    02200013
*                   OR WRITTEN FROM.  ONLY THE CURRENT BUFFER AND 1     02400013
*                   SUCCEEDING BUFFER CAN BE MADE AVAILABLE AT ANY      02600013
*                   ONE TIME.                                           02800013
*                                                                       03000013
*                   *  SEE NOTE BELOW FOR BRIEF DESCRIPTION OF DYNAMIC  03200013
*                      BUFFERING.                                       03400013
         SPACE 2                                                        03600013
* ENTRY POINT -                                                         03800013
*                   ENTRY IS 1ST EXECUTIVE INSTRUCTION                  04000013
          SPACE 2                                                       04200013
* INPUT -                                                               04400013
*                   REGISTER 2 CONTAINS A POINTER TO THE PERTINENT IOB  04600013
*                   REGISTER 15 CONTAINS THE BASE ADDRESS               04800013
          SPACE 2                                                       05000013
* OUTPUT                                                                05200013
*                   NONE                                                05400013
         SPACE 2                                                        05600013
* EXTERNAL ROUTINE -                                                    05800013
*                   THE REQUEST-RELEASE BUFFER ROUTINE IS USED TO       06000013
*                   GET OR RELEASE BFRS FROM OR TO THE BUFFER POOL.     06200013
         SPACE 2                                                        06400013
* EXIT -                                                                06600013
*                   RETURN IS TO IOS AFTER ASSIGNING A BUFFER OR        06800013
*                   QUEUING A REQUEST FOR ONE                           07000013
         SPACE 2                                                        07200013
* IN LINE ROUTINES -                                                    07400013
*                   THE PCI OCCURS FOR ALL READ OR WRITE CHANNEL        07600013
*                   COMMANDS SET UP FOR DYNAMIC BUFFERING.              07800013
*                   READ                                                08000013
*                        READ OR READ-SKIP                              08200013
*                        READ                                           08400013
*                             AN ATTEMPT IS MADE TO ASSIGN A BUFFER     08600013
*                             TO THE NEXT READ CCW WHICH IS BLOCKED BY  08800013
*                             A READ-SKIP CCW UNTIL THE BFR IS ASSIGNED 09000013
*                             IF A BUFFER IS ASSIGNED THE READ-SKIP IS  09200013
*                             ALTERED TO A TIC TO THE BLOCKED READ CCW. 09400013
*                             AND THIS READ IS IN TURN BLOCKED BY ALTER 09600013
*                             ING THE FOLLOWING TIC CCW TO READ-SKIP    09800013
*                             IF NO BUFFER IS AVAILABLE TO BE ASSIGNED  10000013
*                             A REQUEST IS ADDED TO THE REQUEST QUEUE.  10200013
*                             POINTERS TO THE 1ST AND LAST ENTRIES IN   10400013
*                             THIS QUEUE ARE STORED IN THE DATA EXTENT  10600013
*                             BLOCK ASSOCIATED WITH THIS IOB.  THE      10800013
*                             CHAINING POINTERS ARE STORED IN THE READ  11000013
*                             CCW'S IN PLACE OF THE BUFFER ADDRESSES.   11200013
*                                                                       11400013
*                        READ-SKIP                                      11600013
*                             A BUFFER NEVER DID GET ASSIGNED.  THE     11800013
*                             PCI ON THE PREVIOUS READ WAS EITHER LOST  12000013
*                             OR HANDLED.  IF IT WAS LOST THE TWO       12200013
*                             PREVIOUS READ BUFFERS MUST BE POSTED,     12400013
*                             THE MOST RECENT WITH AN ERROR INDICATION, 12600013
*                             AND ANOTHER READ-SKIP COMMAND OVERLAYED   12800013
*                             IN THE NEXT CCW TO PERMIT COMPLETION OF   13000013
*                             THE READ.  IF THE PCI ON THE PREVIOUS     13200013
*                             READ WERE HANDLED THE BUFFER REQUEST WAS  13400013
*                             QUEUED.  THIS REQUEST MUST BE PURGED      13600013
*                             FROM THE QUEUE AND THE PREVIOUS READ      13800013
*                             BUFFER POSTED.  ANOTHER READ-SKIP COMMAND 14000013
*                             PLACED IN THE NEXT CCW TO ALLOW COMPLE-   14200013
*                             TION OF THE READ.                         14400013
*                             IF A BUFFER WERE ASSIGNED PRIOR TO HAND-  14600013
*                             LING THIS INTERRUPT, BUT AFTER FETCHING   14800013
*                             THE CCW COMMAND CODE IN STORAGE WILL      15000013
*                             BE A TIC.  IN THIS CASE THE BFR WILL BE   15200013
*                             RELEASED AND THE READ BFR WILL BE POSTED. 15400013
*                             IN EITHER CASE DATA WILL HAVE BEEN LOST   15600013
*                             AND THE POSTING WILL SO INDICATE.         15800013
*                   WRITE                                               16000013
*                        THE BUFFER CHAIN ADDRESS IS TESTED FOR 0 TO    16200013
*                        SEE IF THIS IS THE LAST BUFFER IN THE WRITE    16400013
*                        CHAIN.  IF IT IS THE BUFFER IS POSTED.  IF     16600013
*                        NOT THE NEXT BUFFER ADDRESS IS PLACED IN THE   16800013
*                        NEXT WRITE CCW, THE FOLLOWING TIC IS MADE      17000013
*                        VALID AND THE TIC TO THE CURRENT WRITE CCW     17200013
*                        IS INVALIDATED BY ORRING A 1 TO ITS TRANSFER   17400013
*                        ADDRESS.  SHOULD THE INVALID TIC ADDRESS BE    17600013
*                        FETCHED AN ABNORMAL END WOULD OCCUR.           17800013
         SPACE 2                                                        18000013
*                   CCW 1 ----------------------------------------      18200013
*                        IRD/WR CMD*   B U F F E R   A D D R E S S      18400013
*                        I---------------------------------------I      18600013
*                        I FLAGS   *T/P OP CD*    C O U N T      I      18800013
*                        -----------------------------------------      19000013
         SPACE 2                                                        19200013
*                   CCW 2-----------------------------------------      19400013
*                        IR-S / TIC* A D D R E S S  OF  C C W  3 I      19600013
*                        I---------------------------------------I      19800013
*                        I FLAGS   *T/P OP CD*    C O U N T      I      20000013
*                        -----------------------------------------      20200013
         SPACE 2                                                        20400013
*                   CCW 3-----------------------------------------      20600013
*                        IRD/WR CMD*  B U F F E R   A D D R E S S       20800013
*                        I---------------------------------------I      21000013
*                        I FLAGS   *T/P OP CD*    C O U N T      I      21200013
*                        -----------------------------------------      21400013
         SPACE 2                                                        21600013
*                   CCW 4-----------------------------------------      21800013
*                        IR-S / TIC* A D D R E S S  OF  C C W 1  I      22000013
*                        I---------------------------------------I      22200013
*                        I FLAGS   *T/P OP CD*    C O U N T      I      22400013
*                        -----------------------------------------      22600013
         SPACE 2                                                        22800013
* ATTRIBUTES -                                                          23000013
*                   THIS ROUTINE IS RUN IN SUPERVISOR MODE, DISABLED    23200013
         SPACE 2                                                        23400013
* NOTE -                                                                23600013
*                   'DYNAMIC BUFFERING' IS DEFINED AS THE ABILITY TO    23800013
*                   PROVIDE I/O BUFFERS JUST PRECEDING AN IMPENDING     24000013
*                   I/O OPERATION TO PERMIT MORE FLEXIBLE USE OF        24200013
*                   LIMITED STORAGE SPACE.                              24400013
*                                                                       24600013
         EJECT                                                          24800013
DEVTYPE  EQU   16                                                  000C 24860015
DCBBSENQ EQU   68                                                A27624 24930019
ZEROREG  EQU   0                        REGISTER ZERO                   25000013
PARREG   EQU   1                        PARAMETER REGISTER              25200013
IOBREG   EQU   2                        PTR TO INPUT OUTPUT BLOCK       25400013
DEBREG   EQU   3                        PTR TO DATA EXTENT BLOCK        25600013
DCBREG   EQU   4                        PTR TO DATA CONTROL BLOCK       25800013
BCBREG   EQU   5                        PTR TO BUFFER CONTROL BLOCK     26000013
QREG     EQU   6                        PTR TO REQ-REL BFR & REQ QUEUE  26200013
BUFREG   EQU   7                        PTR TO BUFFER                   26400013
BUF2REG  EQU   8                        PTR TO NEXT BUFFER              26600013
CCWREG   EQU   9                        PTR TO CHANNEL COMMAND WORD     26800013
CCW2REG  EQU   10                       PTR TO NEXT CH COMMAND WORD     27000013
WORKREG  EQU   11                       WORK REGISTER                   27200013
UCBREG   EQU   11                        UCB ADDRESS             A64655 27250021
BASEREG  EQU   12                       BASE REGISTER                   27400013
SAVEREG  EQU   13                       PTR TO SAVE AREA                27600013
RETREG   EQU   14                       RETURN ADDRESS REGISTER         27800013
BRREG    EQU   15                       PTR TO REQUESTED BFR OR ER IND  28000013
DEBNMEXT EQU   16                                                       28200013
DEBUCBAD EQU   32                                                       28400013
IOBUCBX  EQU   32                  OFFSET TO UCB POINTER         A64655 28450021
CVT0PT01 EQU   X'98'                                                    28600013
SIXTEEN  EQU   16                                                       28800013
DCBXMODE EQU   X'38'                                          SB A56746 28850021
DCBBSETX EQU   X'3F'                                          SB A56746 28900021
DCBBSETB EQU   X'46'                                          SB A56746 28950021
INTBLCHK EQU   X'40'                                          SB A56746 28960021
DCBBUFCB EQU   20                       OFFSET TO BCB ADDRESS           29000013
IOBECBPT EQU   4                        OFFSET TO ECB POINTER           29200013
DEBTCBAD EQU   0                        OFFSET TO TCB ADDRESS           29400013
DECTYPE  EQU   4                                                   000A 29600013
DECLNGTH EQU   6                        OFFSET TO LAST BFR LENGTH       29800013
DECAREA  EQU   12                                                  000A 30000013
DECPOLPT EQU   36                                                  000A 30200013
DECWLNG  EQU   42                                                  000B 30300014
DCBBUFCT EQU   34                                                  7752 30330017
DECBUFCT EQU   8                                                   7752 30360017
AUTOPOLL EQU   X'80'                                               000A 30400013
BISYNC   EQU   X'90'               BISYNC DEVICE                 A64655 30410021
FIRSTPCI EQU   X'40'                    FIRST TIME PCI FLAG        3712 30440016
RDCMND   EQU   X'02'                    READ COMMAND               3712 30480016
RSTICOP  EQU   X'12'                    READ SKIP/TIC TP OP CODE   3712 30520016
TICCMND  EQU   X'08'                    TIC COMMAND                3712 30560016
SKIP     EQU   X'10'                    SKIP FLAG                       30600013
PC       EQU   X'20'                   PROGRAM CHECK BIT                30800013
RRTXT    EQU   X'20'              READ RESP TO TXT CODE          A66407 30850021
         USING *,BASEREG                                                31000013
         STM   RETREG,CCWREG,SAVEIOS-*(BRREG)     SAVE REGISTERS        31200013
         LR    BASEREG,BRREG                                            31400013
         L     CCWREG,64                LOAD CCW ADDRESS           3712 31600016
         LA    CCWREG,0(CCWREG)         CLEAR HIGH ORDER BYTE           31700017
         SH    CCWREG,EIGHT             BACK UP TO INT CCW         3712 31800016
         CLC   68(2),STATUS             IS STATUS PCI ONLY         3712 32000016
         BE    CHKWRT                   IF SO, BRANCH            A49691 32200021
         CLI   0(CCWREG),RDCMND         IS COMMAND READ            3712 32400016
         BNE   PROGCK                  IF NO, IS THERE PROG CK   A28629 32460019
         CLI   5(CCWREG),RDPCI         IS THIS FIRST PCI         A28629 32520019
         BNE   EXIT                    IF NOT, EXIT              A28629 32580019
         TM    68,UCORUE               UNIT CHECK OR UNIT EXCP   A28629 32760019
         BNZ   EXIT                    IF SO, EXIT               A28629 32820019
         B     MOVEIND                 CHECK FOR AUTOPOLL        A28629 32880019
PROGCK   TM    69,PC                   WAS THERE PROG CHECK      A28629 32940019
         BZ    WRTIC                    IF NOT, GO TO WRITE ROUTINE3712 33000016
         TM    5(CCWREG),RSTICOP        IS TIC TPOP CODE PRESENT   3712 33200016
         BNO   EXIT                     IF NOT, EXIT               3712 33400016
         CLI   0(CCWREG),TICCMND        AND IS COMMAND TIC         3712 33600016
         BNE   EXIT                     IF NOT, EXIT               3712 33800016
         SH    CCWREG,EIGHT             IF SO BACK UP TO WRITE CMND3712 34000016
         B     WRTIC                    GO POST PREVIOUS BUFFER    3712 34200016
CHKWRT   EQU   *                                                 A49691 34250021
         CLI   0(CCWREG),TICCMND                                 A49691 34300021
         BNE   LBCB                                              A49691 34350021
         TM    3(CCWREG),X'01'                                   A49691 34360021
         BNO   EXIT                                              A49691 34370021
         CLI   5(CCWREG),X'21'    TPOP CODE,ALL RESET            A66407 34372021
         BE    EXIT               YES,EXIT                       A66407 34374021
         CLI   5(CCWREG),X'A1'    TPOP CODE,ALL RESET            A66407 34376021
         BE    EXIT               YES,EXIT                       A66407 34378021
         SH    CCWREG,EIGHT                                      A49691 34380021
         B     WRTIC                                             A49691 34390021
LBCB     CLI   5(CCWREG),RRTXT  READ RESP TO TEXT?               A66407 34400021
         BE    EXIT                                              A66407 34450021
         L     BCBREG,DCBBUFCB(DCBREG)  PTR TO BCB               A66407 34500021
         SR    WORKREG,WORKREG          COMPUTE PTR TO REQUEST BFR Q    34600013
         IC    WORKREG,DEBNMEXT(DEBREG)                                 34800013
         SLL   WORKREG,2                                                35000013
         LA    QREG,DEBUCBAD(WORKREG,DEBREG)                            35200013
         MVC   BYTE(1),5(CCWREG)        IS T/P OP CODE READ-SKIP OR TIC 35400013
         NI    BYTE,X'3F'               TEST BITS 2-7 ONLY              35600013
         CLI   BYTE,X'12'               IS TP OP CODE 22                35800013
         BE    READSKIP                 YES                             36000013
WRTIC    L     CCW2REG,8(CCWREG)        LOAD ADRS OF PREVIOUS CCW       36200013
         N     CCW2REG,TICMASK          VALIDATE TIC ADDRESS IN REG     36400013
         MVC   SAVEBFR+1(3),1(CCW2REG)  SAVE ADRS OF PREVIOUS BUFFER    36600013
         L     BUFREG,0(CCWREG)         LOAD PTR TO THIS CCW BUFFER     36800013
         N     BUFREG,BUFMSK            ADJUST TO 1ST BYTE OF BFR       37000013
         SH    BUFREG,FOUR                                              37200013
         CLI   0(CCWREG),X'01'          IS COMMAND WRITE                37400013
         BE    WRPCI                    YES                             37600013
         SH    CCW2REG,EIGHT      PREV CCW                      A61827  37610021
         TM    5(CCW2REG),X'25'   CK RD RESP TO TXT             A61827  37612021
         BNO   NOT25              IF NOT BRANCH                 A61827  37614021
         L     WORKREG,8(CCW2REG) LOAD DATA ADD OF RD TXT       A61827  37616021
         SH    WORKREG,TWENTY     SUBT COUNT OF RD RESP CCW     A61827  37618021
         CLR   WORKREG,CCW2REG    EQ DATA ADREA OF RD RESP?     A61827  37618421
         BNE   NOT25              IF NOT BR                     A61827  37618821
         LA    WORKREG,0(WORKREG) CLEAR HI ORDER BYTE           A61827  37619221
         ST    WORKREG,SAVEBFR   STORE AS BFR PTR               A61827  37619621
NOT25    EQU   *                                                A61827  37619721
         AH    CCW2REG,EIGHT      RESTORE CCW                   A61827  37619821
         LH    PARREG,2(PARREG)                                    000C 37620015
         SR    WORKREG,WORKREG                                     000C 37640015
         IC    WORKREG,DEVTYPE+3(PARREG)                           000C 37660015
         SRL   WORKREG,4                                           000C 37680015
         EX    WORKREG,COMPARE                                     000C 37700015
         BNE   READPCI                                             000C 37720015
         CLC   4(1,BUFREG),DCBBSENQ(DCBREG)                        000C 37740015
         BE    EXIT                                                000C 37760015
         CLC   5(1,BUFREG),DCBBSENQ(DCBREG)                      A46838 37770021
         BE    EXIT                                              A46838 37772021
READPCI  EQU   *                                                   000C 37780015
         SR    UCBREG,UCBREG      CLEAR REGISTER                 A64655 37782021
         IC    UCBREG,32(IOBREG)  GET INDEX TO UCB               A64655 37784021
         SLL   UCBREG,2           MULTIPLY INDEX BY 4            A64655 37786021
         L     UCBREG,32(DEBREG,UCBREG)  GET UCB ADDR FOR LINE   A64655 37788021
         TM    19(UCBREG),BISYNC   BI-SYNC LINE?                 A64655 37788821
         BNO   CONTINU            NO,SKIP CHK                    A64655 37789221
*        THIS CHECK IS FOR BI-SYNC DEVICES ONLY                  A64655 37789621
         LH    WORKREG,6(CCW2REG)  COUNT OF PREVIOUS CCW      SB A56746 37790021
         A     WORKREG,0(CCW2REG)  ADD ADDRESS OF PREVIOUS CCWSB A56746 37792021
         BCTR  WORKREG,0           POINT TO LAST CHARACTER    SB A56746 37794021
         TM    DCBXMODE(DCBREG),INTBLCHK IS INT BLK CHK USED  SB A56746 37796021
         BZ    CHKETX              NO, CHK FOR ETX            SB A56746 37798021
         BCTR  WORKREG,0           YES, BACK UP ONE CHAR      SB A56746 37798421
CHKETX   EQU   *                   CHECK FOR ETX              SB A56746 37798821
         CLC   0(1,WORKREG),DCBBSETX(DCBREG) IS ETX ?         SB A56746 37799221
         BE    EXIT                YES, DON'T GET ANOTHER BUFFER A56746 37799621
         CLC   0(1,WORKREG),DCBBSETB(DCBREG) IS ETB ?         SB A56746 37799821
         BE    EXIT                YES, DON'T GET ANOTHER BUFFER A56746 37799921
CONTINU  CLI   5(BCBREG),0        ANY BUFFERS AVAILABLE          A64655 37849921
         BE    QUEUE                    NO                              38000013
         L     PARREG,IOBECBPT(IOBREG)  GET POINTER TO DECB        7752 38020017
         CLC   DECBUFCT(1,PARREG),DCBBUFCT(DCBREG) ALL BUFFERS USED7752 38040017
         BNL   QPCI                     IF SO, BRANCH              7752 38060017
         IC    WORKREG,DECBUFCT(PARREG) PICKUP BUFFER COUNT        7752 38080017
         LA    WORKREG,1(WORKREG)       BUMP BY ONE                7752 38100017
         STC   WORKREG,DECBUFCT(PARREG) STORE BUFFER COUNT         7752 38120017
         L     ZEROREG,ZEROE            SETUP PARAM TO REQUEST 1 BUFFER 38200013
         LR    PARREG,DCBREG            LOAD PTR TO DCB INTO REG 1      38400013
         L     BRREG,0(QREG)            LOAD PTR TO REQ BFR ROUTINE     38600013
         BALR  RETREG,BRREG             LINK TO REQUEST BUFFER ROUTINE  38800013
         LA    BRREG,4(BRREG)           INCR BY 4 TO 1ST DATA BYTE      39000013
         ST    BRREG,0(CCW2REG)         STORE BUFFER ADRS IN CCW        39200013
         LH    WORKREG,6(BCBREG)        LOAD BFR LENGTH                 39400013
         SH    WORKREG,FOUR                                             39600013
         STH   WORKREG,6(CCW2REG)       STORE AS COUNT                  39800013
         MVI   0(CCW2REG),X'02'         RESTORE READ COMMAND CODE       40000013
         MVI   8(CCW2REG),X'02'         MAKE TIC COMMAND A READ SKIP    40200013
         SPACE 2                                                   000A 40400013
         BCR   15,0                     THIS INSTRUCTION IS        000A 40600013
*    REQUIRED FOR MODEL 91 SUPPORT TO ENSURE THAT THE FOLLOWING    000A 40800013
*    INSTRUCTION (WHICH CHANGES THE READ-SKIP TO A TIC) WILL BE    000A 41000013
*    EXECUTED IN SEQUENCE.                                         000A 41200013
         MVI   8(CCWREG),X'08'          MAKE THIS READ-SKIP A TIC       41400013
         SPACE 2                                                   000A 41600013
         B     QPCI                                                     41800013
READSKIP CLI   0(CCWREG),X'08'          IS THE CMND CODE TIC            42000013
         BE    TIC                      YES                             42200013
         L     CCWREG,0(CCWREG)         LOAD PTR TO NEXT READ CCW       42400013
         C     CCWREG,4(QREG)           IS CCW TO BE PURGED 1ST         42600013
         BNE   NOT1ST                                                   42800013
         MVC   4(4,QREG),0(CCWREG)      MAKE 2ND CCW 1ST NOW            43000013
         B     SETUPRS                                                  43200013
NOT1ST   L     CCW2REG,4(QREG)          LOAD PTR TO 1ST INTO REG        43400013
NXTCMP   C     CCW2REG,ZERO             IS THIS THE END OF THE QUEUE    43600013
         BE    NOTINQ                   YES, NOT IN QUEUE               43800013
         C     CCWREG,0(CCW2REG)        COMPARE CCW PTR TO NEXT CCW PTR 44000013
         BE    FOUND                                                    44200013
         L     CCW2REG,0(CCW2REG)       LOAD PTR TO NEXT CCW PTR IN CHN 44400013
         B     NXTCMP                                                   44600013
FOUND    MVC   0(4,CCW2REG),0(CCWREG)   CHAIN FRONT & BACK BFRS TOGETHR 44800013
LAST     C     CCWREG,8(QREG)           IS PURGED CCW LAST ONE IN QUEUE 45000013
         BNE   SETUPRS                                                  45200013
         ST    CCW2REG,8(QREG)          UPDATE PTR TO LAST CCW IN CHAIN 45400013
         B     SETUPRS                                                  45600013
NOTINQ   L     CCW2REG,8(CCWREG)        LOAD PTR TO PREVIOUS READ       45800013
         TM    5(CCW2REG),X'40'         IS THIS FIRST PCI               46000013
         BZ    NOTINQ1                  IF NOT, BRANCH             000A 46200013
         L     PARREG,IOBECBPT(IOBREG)  LOAD PTR TO DECB           000A 46400013
         TM    DECTYPE(PARREG),AUTOPOLL IS AN AUTOPOLL OPERATION   000A 46600013
         BZ    SETUPRS    IN PROGRESS.  IF NOT, BRANCH             000C 46800015
         L     WORKREG,DECAREA(PARREG)  LOAD BUFFER ADDRESS        000A 47000013
         MVC   DECPOLPT(1,PARREG),4(WORKREG) MOVE INDEX BYTE FROM  000A 47200013
*    INPUT AREA TO HIGH ORDER BYTE OF DECPOLPT.                    000A 47400013
         B     SETUPRS                                             000A 47600013
NOTINQ1  L     WORKREG,SIXTEEN          LOAD ADDRESS OF CVT        000A 47800013
         L     BRREG,CVT0PT01(WORKREG)  LOAD PTR TO SUPERVISOR POST RT  48000013
         L     WORKREG,0(CCWREG)        LOAD PTR TO COMPLETED BFRA38554 48200020
         N     WORKREG,BUFMSK           ADJUST TO 1ST BYTE OF BFR       48400013
         SH    WORKREG,FOUR                                             48600013
         L     CCW2REG,0(CCW2REG)       SET UP PARM FOR SV POST  A38554 48700020
         N     CCW2REG,BUFMSK           ADJUST TO 1ST BYTE OF BFRA38554 48800020
         SH    CCW2REG,FOUR             BACK UP TO LINK FIELD    A38554 48900020
         O     CCW2REG,POSTMSK          OR IN COMPLETION CODE           49000013
         LR    ZEROREG,BASEREG          SAVE BASE                A38541 49200020
         STM   ZEROREG,BRREG,SAVEAREA   SAVE REGISTERS                  49400013
         L     BASEREG,DEBTCBAD(DEBREG) LOAD PTR TO TASK CONTROL BLOCK  49600013
         BALR  RETREG,BRREG             LINK TO SPVSR POST ROUTINE      49800013
         LR    BASEREG,ZEROREG          RESTORE BASE             A38541 50000020
         LM    ZEROREG,BRREG,SAVEAREA   RESTORE REGISTERS               50200013
SETUPRS  MVC   1(3,CCWREG),RS2+1        MOVE ADRS OF 4 TO READ CCW 0583 50400013
         L     CCW2REG,8(CCWREG)        LOAD PTR TO PREVIOUS READ       50600013
         MVC   16(8,CCW2REG),RS2        OVERLAY R-S IN CCW 3 OR 5       50800013
         OI    12(CCW2REG),X'80'        TURN ON DATA CHAIN BIT   A32459 50830020
         L     PARREG,IOBECBPT(IOBREG)  GET POINTER TO DECB      A32452 50860020
         CLC   DECBUFCT(1,PARREG),DCBBUFCT(DCBREG) ALL BUFS USED A32452 50890020
         BL    EXIT                     IF NOT, BRANCH           A32452 50920020
         MVC   22(2,CCW2REG),CCWCOUNT   MAKE COUNT 'C0'          A32452 50950020
         B     EXIT                                                     51000013
QUEUE    L     CCW2REG,8(CCWREG)        LOAD PTR TO NEXT CCW            51200013
         OI    15(CCWREG),X'01'        TURN ON PCI ENTRANCE BIT    1265 51260018
         NI    15(CCW2REG),X'FE'       TURN OFF PREVIOUS PCI     A27624 51330019
         L     WORKREG,4(QREG)          LOAD PTR TO 1ST CCW IN QUEUE    51400013
         C     WORKREG,ZERO             IS THIS FIRST ENTRY TO QUEUE    51600013
         BE    QIST                                                     51800013
         L     WORKREG,8(QREG)          LOAD PTR TO LAST CCW IN QUEVE   52000013
         ST    CCW2REG,0(WORKREG)       STORE CHAIN ADRS IN LAST ENTRY  52200013
         B     STLAST                                                   52400013
QIST     ST    CCW2REG,4(QREG)                                          52600013
STLAST   ST    CCW2REG,8(QREG)          ST PTR OF CCW AS LAST IN QUEUE  52800013
         MVC   0(4,CCW2REG),ZERO        ZERO IN CCW                     53000013
QPCI     TM    5(CCWREG),X'40'          IS T/P OP CODE 2ND PCI          53200013
         BZ    POSTBUF                  YES                             53400013
         NI    5(CCWREG),X'BF'          CHANGE T/P OP CODE PCI BIT      53600013
MOVEIND  L     PARREG,IOBECBPT(IOBREG) LOAD PTR TO DECB          A28629 53800019
         TM    DECTYPE(PARREG),AUTOPOLL IS AN AUTOPOLL OPERATION   000A 54000013
         BZ    EXIT                IN PROGRESS?  IF NOT, BRANCH    000A 54200013
         L     WORKREG,DECAREA(PARREG)  LOAD BUFFER ADDRESS        000A 54400013
         MVC   DECPOLPT(1,PARREG),4(WORKREG) MOVE INDEX BYTE FROM  000A 54600013
*    INPUT AREA TO HIGH ORDER BYTE OF DECPOLPT                     000A 54800013
         B     EXIT                                                     55000013
TIC      L     CCWREG,0(CCWREG)         LOAD ADRS OF NEXT READ CCW 0583 55200013
         L     BUFREG,0(CCWREG)         LOAD PTR TO BUFFER              55400013
         N     BUFREG,BUFMSK            ADJUST TO 1ST BYTE OF BFR       55600013
         SH    BUFREG,FOUR                                              55800013
         LA    ZEROREG,0(BUFREG)        PLACE BFR PTR IN REG 0          56000013
         LR    PARREG,DCBREG            LOAD PTR TO DCB INTO REG 1      56200013
         L     BRREG,0(QREG)            LOAD PTR TO RELEASE BFR ROUTINE 56400013
         BALR  RETREG,BRREG             LINK TO RELEASE BFR             56600013
         B     SETUPRS                  GO TO SETUP READ-SKIP      0583 56800013
WRPCI    CLC   1(3,BUFREG),ZERO+1       IS CHAIN ADRS IN BFR ZERO       57000013
         BE    LASTWR                   YES, LAST BUFFER, POST ONLY     57200013
         OI    11(CCW2REG),X'01'        INVALIDATE FOLLOWING TIC ADRS   57400013
         TM    5(CCWREG),FIRSTPCI       IS THIS FIRST PCI INT      3712 57470016
         BZ    WRB                      IF NOT, BRANCH             3712 57540016
         L     BUF2REG,16(CCWREG)       LOAD NEXT BUFFER ADDRESS   3712 57610016
         SH    BUF2REG,FOUR             BACK UP TO LONK FIELD      3712 57680016
         B     WRC                                                 3712 57750016
WRB      L     BUF2REG,0(BUFREG)        LOAD NEXT BUFFER ADDRESS   3712 57820016
WRC      CLC   1(3,BUF2REG),ZERO+1      IS THE NEXT BUFFER THE LAST3712 57890016
         BNE   QWPCI                                                    58000013
         L     PARREG,IOBECBPT(IOBREG)  LOAD PTR TO ECB                 58200013
         TM    DECTYPE+1(PARREG),X'0D'  IS OPERATION CONVERSATIONAL000B 58260014
         BO    WRWL                     YES, BRANCH                000B 58320014
         LH    WORKREG,DECLNGTH(PARREG) LOAD LAST BFR COUNT             58400013
WRL      SH    WORKREG,FOUR             ADJUST COUNT               000B 58600014
         STH   WORKREG,6(CCW2REG)       STORE IN CCW                    58800013
         LA    WORKREG,0(CCWREG,CCW2REG) ADD TWO WRITE ADRS TOGETHER    59000013
         SRL   WORKREG,1                DIVIDE BY 2, RESULT = 1ST TIC   59200013
         NI    4(CCW2REG),X'BF'                                  A65143 59250021
         TM    21(WORKREG),X'80'        IS NEXT TIC CMND LAST CCW       59400013
         BO    NODC                     IF SO, BYPASS SET UP CHAINING   59600013
         OI    4(CCW2REG),X'40'                                  A65143 59650021
         A     WORKREG,TICCHN           ADD CMND AND DIFFERENCE TO CCW  59800013
         ST    WORKREG,8(CCW2REG)           BEYOND 2ND TIC AND STORE    60000013
         OI    11(CCW2REG),X'01'    INVALIDATE TIC            SB P25004 60050021
         OI    4(CCW2REG),X'20'         LEAVE SLI FLG ON           3712 60200016
NODC     NI    4(CCW2REG),X'7F'         AND OFF DATA CHAIN      A65143  60400021
QWPCI    TM    5(CCWREG),X'40'          IS T/P OP CODE FOR 2ND PCI      60600013
         BZ    MOVEPTR                                                  60800013
         NI    5(CCWREG),X'BF'          ZERO T/P OP CODE BIT  1         61000013
         SPACE 2                                                   000A 61200013
         BCR   15,0                     THIS INSTRUCTION IS        000A 61400013
*    REQUIRED FOR MODEL 91 SUPPORT TO ENSURE THAT THE FOLLOWING    000A 61600013
*    INSTRUCTION (WHICH VALIDATES THE ADDRESS IN THE NEXT TIC      000A 61800013
*    COMMAND) WILL BE EXECUTED IN SEQUENCE.                        000A 62000013
         NI    11(CCWREG),X'FE'         VALIDATE NEXT TIC ADDRESS  000A 62200013
         SPACE 2                                                   000A 62400013
         B     EXIT                                                     62600013
WRWL     LH    WORKREG,DECWLNG(PARREG)  LOAD COUNT                 000B 62660014
         B     WRL                                                 000B 62720014
MOVEPTR  MVC   1(3,CCW2REG),1(BUFREG)   MOVE PTR TO NXT BFR TO CCW      62800013
         L     WORKREG,0(CCW2REG)       ADD 4 TO CCW BFR ADRS FOR       63000013
         AH    WORKREG,FOUR                                             63200013
         ST    WORKREG,0(CCW2REG)                                       63400013
         SPACE 2                                                   000A 63600013
         BCR   15,0                     THIS INSTRUCTION IS        000A 63800013
*    REQUIRED FOR MODEL 91 SUPPORT TO ENSURE THAT THE FOLLOWING    000A 64000013
*    INSTRUCTION (WHICH VALIDATES THE ADDRESS IN THE NEXT TIC      000A 64200013
*    COMMAND) WILL BE EXECUTED IN SEQUENCE.                        000A 64400013
         NI    11(CCWREG),X'FE'         VALIDATE NEXT TIC ADDRESS  000A 64600013
         SPACE 2                                                   000A 64800013
         B     ZEROCC                                                   65000013
LASTWR   EQU   *                                              SB P25004 65200021
         NI    11(CCWREG),X'FE'     VALIDATE TIC              SB P25004 65250021
         TM    13(CCWREG),X'80'     IS NEXT CCW THE LAST ?    SB P25004 65300021
         BO    ZEROCC                   IF SO, NO SWEAT, ADRS O.K.      65400013
         TM    21(CCWREG),X'2E'        IS FOLLOWING CCW DATA     A26889 65460019
         BNZ   SUB32                   NO, BRANCH                A26889 65520019
         TM    21(CCWREG),X'10'         IS FOLLOWING CCW A DATA CCW     65600013
         BO    MVCSAVE                  IF SO, BRANCH                   65800013
SUB32    SH    CCWREG,THIRTY2          SUBTRACT 32               A26889 66000019
MVCSAVE  MVC   SAVEBFR+1(3),17(CCWREG)  MOVE BUFFER ADRS TO SAVE AREA   66200013
ZEROCC   MVI   0(BUFREG),X'00'          ZERO COMPLETION CODE IN THIS BF 66400013
POSTBUF  L     WORKREG,SIXTEEN          LOAD OFFSET FOR POST ROUTINE    66600013
         L     BRREG,CVT0PT01(WORKREG)  LOAD PTR TO SUPERVISOR POST RT  66800013
         ST    BUFREG,BUFPOST           STORE BUFFER ADDRESS            67000013
         MVC   BUFPOST(1),POSTCODE      MOVE IN WRROR CODE IF ANY       67200013
         L     CCW2REG,BUFPOST          LOAD BFR ADRS AS ECB CODE       67400013
         NI    SAVEBFR+3,X'FC'                                          67600013
         L     WORKREG,SAVEBFR          LOAD PTR TO COMPLETED BFR       67800013
         SH    WORKREG,FOUR             ADJUST TO 1ST BYTE OF BFR       68000013
POSTIT   LR    ZEROREG,BASEREG          SAVE BASE REGISTER         3712 68200016
         L     BASEREG,DEBTCBAD(DEBREG) LOAD PTR TO TASK CONTROL BLOCK  68400013
         BALR  RETREG,BRREG                                             68600013
        LR    BASEREG,ZEROREG          RESTORE BASREG             2414  68800014
         MVI   POSTCODE,X'7F'           RESET POSTING CODE              69000013
EXIT     LM    RETREG,CCWREG,SAVEIOS                                    69200013
         BR    RETREG                                                   69400013
COMPARE  CLI   NINE,0                                                   69500015
EIGHT    DC    H'8'                                                     69600013
FOUR     DC    H'4'                                                     69800013
THIRTY2  DC    H'32'                                                    70000013
ZERO     DC    F'0'                                                     70200013
TWENTY   DC    H'20'                                             A61827 70250021
SAVEBFR  DC    F'0'                     PREVIOUS BUFFER ADDRESS         70400013
BUFPOST  DC    F'0'                     BUFFER AS ECB ADDRESS           70600013
BYTE     DC    X'12'                                                    70800013
POSTCODE DC    X'7F'                    POSTING CODE                    71000013
NINE     DC    X'09'                                               000C 71100015
SAVEIOS  DC    16F'0'                   SAVE AREA FOR REGISTERS         71200013
SAVEAREA DC    16F'0'                   SAVE AREA                       71400013
POSTMSK  DC    X'7F000000'              COMPLETION CODE MASK            71600013
ZEROE    DC    X'01000000'                                              71800013
TICCHN   DC    X'08000018'                                              72000013
TICMASK  DC    X'FFFFFFFE'              TIC MASK FOR VALIDATING ADRS    72200013
BUFMSK   DC    X'00FFFFFC'                                         3712 72400016
RS2      DC    X'02'                    COMMAND - READ                  72600013
         DC    X'000004'                AREA                            72800013
         DC    X'30'                    FLAGS - SLI,SKIP                73000013
         DC    X'12'                    T/P OP CODE                     73200013
         DC    X'7FFD'                  COUNT                           73400013
CCWCOUNT DC    X'00C0'                                           A32452 73500020
STATUS   DC    X'0080'                                                  73600013
CEDEPCI  DC    X'0C80'                  CHAN/DEVICE END PCI        3712 73700016
RDPCI    EQU   X'51'                                             A28629 73730019
UCORUE   EQU   X'03'                                             A28629 73760019
         CNOP  0,8                                                      73800013
         END                                                            74000013
