 TITLE 'IGG019MS - BTAM REQUEST/RELEASE BUFFER ROUTINE'                 00500013
IGG019MS CSECT                                                          01000013
*128200000008,00000282                                             0583 01500013
         SPACE 2                                                        02000013
*    STATUS         CHANGE LEVEL 001,   JUNE 2, 1967               0583 02500013
         SPACE 2                                                        03000013
* FUNCTION -                                                            03500013
*                   TO PROVIDE OR RELEASE A BUFFER FROM OR TO           04000013
*                   THE BUFFER POOL ASSOCIATED WITH A DESIGNATED DCB.   04500013
         SPACE 2                                                        05000013
* ENTRY POINT -                                                         05500013
*                   ENTRY IS TO THE 1ST EXECUTABLE INSTRUCTION          06000013
         SPACE 2                                                        06500013
* INPUT -                                                               07000013
*                   REQUEST                                             07500013
*                        REGISTER O CONTAINS THE REQUEST COUNT IN THE   08000013
*                   LEFTMOST BYTE WITH ZEROS IN THE RIGHT THREE BYTES   08500013
*                                                                       09000013
*                   RELEASE                                             09500013
*                        REGISTER O CONTAINS THE ADDRESS OF THE FIRST   10000013
*                        BUFFER BEING RELEASED BY THE CALLING PROGRAM.  10500013
*                                                                       11000013
*                   REGISTER 1 CONTAINS A POINTER TO THE CURRENT DCB    11500013
         SPACE 2                                                        12000013
* OUTPUT -                                                              12500013
*                   REQUEST                                             13000013
*                        REGISTER 15 WILL CONTAIN THE ADDRESS OF THE    13500013
*                        FIRST REQUESTED BUFFER IN THE THREE RIGHTHAND  14000013
*                        BYTES.                                         14500013
*                                                                       15000013
*                        THE LEFT BYTE WILL CONTAIN -                   15500013
*                        0 - IF ALL REQUESTED BUFFERS ARE AVAILABLE.    16000013
*                        4 - IF THE NUMBER OF AVAILABLE BUFFERS         16500013
*                            IS LESS THAN THE REQUESTED NUMBER. THOSE   17000013
*                            AVAILABLE WILL HAVE BEEN PROVIDED.         17500013
*                        8 - IF NO BUFFERS ARE AVAILABLE.               18000013
*                       12 - IF THE BUFFER CONTROL BLOCK ADDRESS IS     18500013
*                            INVALID (THE ADDRESS IS ZERO OR HAS        19000013
*                            IMPROPER BOUNDARY ALIGNMENT).              19500013
*                                                                       20000013
*                   RELEASE                                             20500013
*                        REGISTER 15 WILL CONTAIN ZEROS IN THE RIGHT    21000013
*                        HAND THREE BYTES.                              21500013
*                                                                       22000013
*                        THE LEFT BYTE WILL CONTAIN -                   22500013
*                        0 - IF ALL BUFFERS HAVE BEEN RETURNED.         23000013
*                        8 - IF NO BUFFERS WERE RETURNED BECAUSE THE    23500013
*                            THE FIRST BUFFER IN THE CHAIN HAD BEEN     24000013
*                            RETURNED PREVIOUSLY (IS THE FIRST BUFFER   24500013
*                            ON THE QUEUE OF AVAILABLE BUFFERS).        25000013
*                       12 - IF THE BUFFER CONTROL BLOCK ADDRESS IS     25500013
*                            INVALID (THE ADDRESS IS ZERO OR HAS        26000013
*                            IMPROPER BOUNDARY ALIGNMENT).              26500013
*                                                                       27000013
         SPACE 2                                                        27500013
* EXTERNAL -                                                            28000013
*                   NONE                                                28500013
         SPACE 2                                                        29000013
* EXIT -                                                                29500013
*                   RETURN IS TO THE CALLING ROUTINE, THE RETURN        30000013
*                   ADDRESS BEING IN REGISTER 14.                       30500013
         SPACE 2                                                        31000013
* IN-LINE ROUTINES -                                                    31500013
*                   ENTRY IS FOR A REQUEST OR RELEASE OF A BUFFER.      32000013
*                   WHICH ONE IS DETERMINED BY LOOKING AT THE           32500013
*                   INPUT IN REGISTER O, (SEE INPUT ABOVE)              33000013
*                                                                       33500013
*                   RELEASE                                             34000013
*                        THE BUFFER REQUEST QUEUE (BUILT IN THE PCI     34500013
*                        APPENDAGE) IS FIRST SATISFIED AND THEN ANY     35000013
*                        LEFT OVER BUFFERS ARE RETURNED TO THE BUFFER   35500013
*                        POOL.                                          36000013
*                   REQUEST                                             36500013
*                        BUFFERS ARE ASSIGNED TO THE REQUEST IF THEY    37000013
*                        ARE AVAILABLE.  A COUNT OF THE NUMBER OF       37500013
*                        AVAILABLE BUFFERS IS MAINTAINED IN THE 5TH &   38000013
*                        6TH BYTES OF THE BUFFER CONTROL BLOCK.         38500013
         SPACE 2                                                        39000013
* ATTRIBUTES -                                                          39500013
*                   THIS ROUTINE IS RUN IN SUPERVISOR MODE, DISABLED    40000013
         EJECT                                                          40500013
ZEROREG  EQU   0                        CNT OR PTR TO BFR PASSED AS PAR 41000013
DCBREG   EQU   1                        PTR TO DATA CONTROL BLOCK       41500013
DEBREG   EQU   3                        PTR TO DATA EXTENT BLOCK        42000013
CNTREG   EQU   4                        WORK REGISTER                   42500013
BCBREG   EQU   5                        PTR TO BUFFER CONTROL BLOCK     43000013
QREG     EQU   6                        PTR TO QUEUE                    43500013
BUFREG   EQU   7                        PTR BUFFER                      44000013
BUF2REG  EQU   8                        PTR TO NEXT BUFFER              44500013
CCWREG   EQU   9                        PTR TO CHANNEL COMMAND NORD     45000013
CCW2REG  EQU   10                       PTR TO NEXT CHANNEL COMMAND WD  45500013
WORKREG  EQU   11                       WORK REGISTER                   46000013
BASEREG  EQU   12                       BASE REGISTER                   46500013
SAVEREG  EQU   13                       PTR TO PASSING RTN SAVE AREA    47000013
RETREG   EQU   14                       RETURN ADDRESS                  47500013
BRREG    EQU   15                                                       48000013
DEBNMEXT EQU   16                       OFFSET TO NUMBER OF IOB         48500013
DEBUCBAD EQU   32                       OFFSET TO PTR TO UCB ADRS       49000013
DCBBUFCB EQU   20                       OFFSET TO BCB ADRS              49500013
DCBBFTEK EQU   32                       OFFSET TO BUFFER TECHNIQUE CODE 50000013
DCBDEBAD EQU   44                       OFFSET TO DEB ADDRESS           50500013
BCB      EQU   X'03'                                                    51000013
         USING *,BASEREG                                                51500013
         STM   RETREG,BASEREG,SAVEAREA-*(BRREG)   SAVE REGISTERS        52000013
         LR    BASEREG,BRREG            LOAD BASE REGISTER              52500013
         TM    DCBBUFCB+3(DCBREG),BCB   TEST FOR VALID BCB ADDRESS      53000013
         BNZ   NOBCB                    IF NOT VALID BRANCH             53500013
         L     BCBREG,DCBBUFCB(DCBREG)   LOAD PTR TO BUFFER CTRL BLOCK  54000013
         LA    BCBREG,0(BCBREG)         CLEAR HIGH ORDER BYTE.          54500013
         LTR   BCBREG,BCBREG            TEST FOR BUFFER CONTROL BLOCK   55000013
         BZ    NOBCB               ADDRESS OF ZERO.  IF SO, EXIT.       55500013
         SR    BRREG,BRREG                                              56000013
         LR    BUFREG,ZEROREG           LOAD PTR TO BFR                 56500013
         LA    BUFREG,0(BUFREG)         ZERO OUT LEFT BYTE              57000013
         LTR   BUFREG,BUFREG            TEST BUFFER ADDRESS             57500013
         BZ    BUFREQ                   IF REQUEST                      58000013
         LH    CNTREG,4(BCBREG)         LOAD AVAILABLE BUFFER COUNT     58500013
         TM    DCBBFTEK(DCBREG),X'08'   IF NO DYNAMIC BUFFERING DO NOT  59000013
         BZ    NOQUEUE                  TEST REQUEST QUEUE              59500013
         L     DEBREG,DCBDEBAD(DCBREG)  LOAD DEB ADDRESS                60000013
         SR    WORKREG,WORKREG          COMPUTE LOCATION OF PTR TO      60500013
         IC    WORKREG,DEBNMEXT(DEBREG) REQUEST QUEUE                   61000013
         SLL   WORKREG,2                                                61500013
         LA    QREG,DEBUCBAD(WORKREG,DEBREG)                            62000013
         L     CCW2REG,4(QREG)          LOAD PTR TO 1ST CCW IN THE QUEU 62500013
DEQUEUE  LR    CCWREG,CCW2REG                                           63000013
         C     CCWREG,ZERO              IS IT ZERO                      63500013
         BE    ENDQUEUE                 YES, END OF QUEUE               64000013
         L     CCW2REG,0(CCWREG)        LOAD PTR TO NEXT CCW IN QUEUE   64500013
         ST    CCW2REG,4(QREG)          UPDATE PTR TO 1ST CCW IN QUEUE  65000013
         LA    WORKREG,4(BUFREG)        INCREMENT BUFFER ADDRESS BY 4   65500013
         ST    WORKREG,0(CCWREG)        STORE AS READ ADDRESS IN CCW    66000013
         LH    WORKREG,6(BCBREG)        LOAD BFR LENGTH                 66500013
         SH    WORKREG,FOUR                                             67000013
         STH   WORKREG,6(CCWREG)        STORE AS COUNT                  67500013
         MVI   0(CCWREG),X'02'          SET READ COMMAND CODE           68000013
         MVI   8(CCWREG),X'02'          SET READ SKIP COMMAND CODE      68500013
         L     WORKREG,8(CCWREG)        LOAD PTR TO 2ND CCW IN IOB      69000013
         MVI   8(WORKREG),X'08'         MAKE READ SKIP A TIC            69500013
         CLC   1(3,BUFREG),ZERO         IS BFR LINK FIELD ZERO          70000013
         BE    EXIT                     YES, NO MORE BFRS               70500013
         L     BUF2REG,0(BUFREG)        LOAD ADDRESS OF NEXT BFR   0583 71000013
         MVC   1(3,BUFREG),ZERO         ZERO LINK ADDRESS          0583 71500013
         LR    BUFREG,BUF2REG           LOAD ADDRESS INTO BUFREG   0583 72000013
         B     DEQUEUE                                                  72500013
ENDQUEUE ST    CCW2REG,4(QREG)          UPDATE PTR TO 1ST CCW IN QUEUE  73000013
NOQUEUE  L     BUF2REG,0(BCBREG)        LOAD PTR TO 1ST AVAIL BFR       73500013
         CR    BUFREG,BUF2REG           WAS BUFFER ALREADY RETURNED     74000013
         BE    PARTIAL                  YES - ERROR                7660 74500017
         ST    BUFREG,0(BCBREG)         STORE PTR OF 1ST BFR RETURNED   75000013
         LA    WORKREG,255        SET MAX LOOP COUNT             A46852 75200021
NXTBUF   LA    CNTREG,1(CNTREG)         ADD ONE TO BUFFER COUNT         75500013
         CLC   1(3,BUFREG),ZERO         IS CHAIN ADRS ZERO              76000013
         BE    LASTBUF                                                  76500013
         L     BUFREG,0(BUFREG)         LOAD ADDRESS OF NEXT BUFFER     77000013
         NC    0(4,BUFREG),BUFMASK      ZERO LEFT BYTE             8280 77500017
         BCT   WORKREG,NXTBUF     LOOP                           A46852 78000021
         ST    BUF2REG,0(BCBREG)  RESTORE BUFF PTR IN BCB        A46852 78100021
         O     BRREG,INVBUF       INSERT RETURN CODE             A46852 78200021
         B     EXIT                                              A46852 78300021
LASTBUF  ST    BUF2REG,0(BUFREG)        STORE PTR TO PREV 1ST AVAIL BFR 78500013
         STH   CNTREG,4(BCBREG)         STORE BFR COUNT                 79000013
         B     EXIT                                                     79500013
BUFREQ   LH    CNTREG,4(BCBREG)         LOAD COUNT OF BFRS AVAILABLE    80000013
         SRL   ZEROREG,24               SHIFT REQUEST COUNT             80500013
         LTR   ZEROREG,ZEROREG          ARE ANY BUFFERS REQUESTEDA30753 80600020
         BZ    EXITA                    NO, NONE MADE AVAILABLE  A30753 80700020
         SR    CNTREG,ZEROREG           SUB TO SEE IF ANY BFRS AVAIL    81000013
         L     BUF2REG,0(BCBREG)        LOAD PTR TO 1ST AVAIL BFR       81500013
         BM    NOTENUF                                                  82000013
         STH   CNTREG,4(BCBREG)         ST NEW AVAIL COUNT              82500013
         LA    BRREG,0(BUF2REG)         LOAD ADRS OF BFR INTO RET RGG   83000013
         B     DECR                                                     83500013
NEXT     L     BUF2REG,0(BUF2REG)       LOAD PTR TO NEXT BFR IN CHAIN   84000013
DECR     BCT   ZEROREG,NEXT             DECR AND TEST COUNT             84500013
         MVC   1(3,BCBREG),1(BUF2REG)   MOVE PTR TO NEXT AVAIL BFR      85000013
         ST    BUFREG,0(BUF2REG)        ZERO CHAIN ADRS IN LAST BFR     85500013
         B     EXIT                                                     86000013
NOTENUF  AR    CNTREG,ZEROREG           ADD BACK TO RESTORE AVAIL CNT   86500013
         BZ    EXITA                    NONE AVAIL IF ZERO              87000013
         SR    ZEROREG,CNTREG           INDICATE NUMBERS BFRS NOT AVAIL 87500013
         LA    BRREG,0(BUF2REG)         LOAD ADRS OF BFR INTO RET REG   88000013
         ST    BUFREG,0(BCBREG)         ZERO PTR TO 1ST AVAIL IN BCB    88500013
         STH   BUFREG,4(BCBREG)         ZERO AVAIL CNT IN BCB           89000013
PARTIAL  O     BRREG,PARTMASK           CODE PARTIAL               7660 89500017
         B     EXIT                                                     90000013
NOBCB    O     BRREG,NOBCBMSK           NO BUFFER CONTROL BLOCK         90500013
         B     EXIT                                                     91000013
EXITA    O     BRREG,NONEMASK           CODE NONE AVAILABLE             91500013
EXIT     LM    DEBREG,BASEREG,SAVEAREA+20    RESTORE REGISTERS          92000013
         BR    RETREG                                                   92500013
SIXTEEN  DC    H'16'                                                    93000013
FOUR     DC    H'4'                                                     93500013
ZERO     DC    F'0'                                                     94000013
SAVEAREA DS    15F'0'                   SAVE AREA FOR REGISTERS         94500013
PARTMASK DC    X'04000000'              RETURN CODE FOR SOME BUFFERS    95000013
*                                  AVAILABLE.                           95500013
NONEMASK DC    X'08000000'              RETURN CODE FOR NO BUFFERS      96000013
*                                  AVAILABLE.                           96500013
NOBCBMSK DC    X'0C000000'              RETURN CODE FOR INVALID BUFFER  97000017
*                                  CONTROL BLOCK ADDRESS.               97500013
INVBUF   DC    X'14000000'        RTN CODE FOR INV BUFFER ADDR   A46852 97600021
*                                 SPECIFIED IN RELBUF            A46852 97700021
BUFMASK  DC    X'00FFFFFC'                                              98000013
         CNOP  0,8                                                      98500013
         END                                                            99000013
