         TITLE 'IGG019PA - LOCAL 3270 CE/XCE APPENDAGE '                00200021
IGG019PA CSECT                                                          00400021
*********************************************************************** 00600021
*       LOCAL 3270 CHANNEL END/ABNORMAL CHANNEL END APPENDAGE         * 00900021
*********************************************************************** 01200021
* STATUS:                                                             * 01400021
*    CHANGE LEVEL 000         SEPTEMBER 2, 1971                       * 01600021
*                                                                     * 01800021
* FUNCTION:                                                           * 02000021
*    THIS MODULE WILL BE LOADED BY THE BTAM OPEN EXECUTOR WHEN THE    * 02200021
*    APPLICATION PROGRAM OPENS A LINE GROUP DCB THAT CONTAINS A LOCAL * 02400021
*    3270 DEVICE. THE ENTRY POINT ADDRESS WILL BE PLACED INTO THE DEB * 02600021
*    ASSOCIATED WITH THE LINE GROUP. WHEN IOS IS READY TO DO CHANNEL  * 02800021
*    END OR ABNORMAL CHANNEL END PROCESSING, IT WILL GET THE ADDRESS  * 03000021
*    AND GIVE IT CONTROL.                                             * 03200021
*                                                                     * 03400021
*    THIS MODULE HAS THE FOLLOWING RESPONSIBILITIES:                  * 03600021
*    1) CONTROL BLOCK CLEAN-UP AT THE END OF AN I/O REQUEST INITIATED * 03800021
*    BY THE BTAM READ/WRITE ROUTINE (IGG019MA) FOR THE APPLICATION    * 04000021
*    PROGRAM.                                                         * 04200021
*    2) RETRY CHANNEL PROGRAMS THAT WERE NOT RETRYABLE BY THE LOCAL   * 04400021
*    DEVICE ERP'S (IGE0010E, IGE0110E).                               * 04600021
*    3) RECOGNIZE REQUEST-FOR-TEST MESSAGES AND THE ON-LINE TEST IN   * 05200021
*    PROGRESS CONDITION AND SCHEDULE THE LOCAL ON-LINE TEST CONTROL   * 05400021
*    MODULE (IGG019PI).                                               * 05600021
*    4) RECOGNIZE THE OLTEP EXECUTING CONDITION AND SET THE OLTEP     * 05800021
*    IN CONTROL FLAG.                                                 * 06000021
*                                                                     * 06400021
* ENTRY:                                                              * 06600021
*         TO THE FIRST EXECUTABLE INSTRUCTION.                        * 06800021
*                                                                     * 07000021
* INPUT:                                                              * 07200021
*    REGISTER 1 - ADDRESS OF THE RQE.                                 * 07400021
*    REGISTER 2 - ADDRESS OF THE IOB.                                 * 07600021
*    REGISTER 3 - ADDRESS OF THE DEB.                                 * 07800021
*    REGISTER 4 - ADDRESS OF THE DCB.                                 * 08000021
*    REGISTER 6 - UNIT ADDRESS OF TARGET DEVICE OF I/O REQUEST.       * 08200021
*    REGISTER 7 - ADDRESS OF UCB.                                     * 08400021
*    REGISTER 14 - RETURN ADDRESS TO IOS.                             * 08600021
*    REGISTER 15 - ENTRY POINT ADDRESS.                               * 08800021
*    DECAREA - CONTAINS THE ADDRESS OF THE REQUEST-FOR-TEST MESSAGE   * 09000021
*    IF AN RFT WAS RECEIVED. THE 3270 RFT HAS THE FOLLOWING FORMAT:   * 09200021
*          +++++++++++++++++++++++++++++++++++++  SOH%/STX = HEADER   * 09400021
*          +     +     +     +     +     +     +  XX = TEST MSG NUMBER* 09600021
*    +0    + SOH +  %  +  /  + STX +  X  +  X  +  YY = NUMBER OF TIMES* 09800021
*          +     +     +     +     +     +     +       TEST MSG TO BE * 10000021
*          +++++++++++++++++++++++++++++++++++++       SENT           * 10200021
*          +     +     +     +     +     +     +  N = 3 (# OF CHARS IN* 10400021
*    +6    +  Y  +  Y  +  N  +  C  +  U  +  U  +       ADDRESS)       * 10600021
*          +     +     +     +     +     +     +  CUU = ADDRESS OF    * 10800021
*          +++++++++++++++++++++++++++++++++++++       TARGET DEVICE  * 11000021
*                                                                     * 11200021
* OUTPUT:                                                             * 11400021
*    ALL REGISTERS ARE THE SAME AS WHEN THE CE/XCE APPENDAGE WAS      * 11600021
*    ENTERED.                                                         * 11800021
*                                                                     * 11900021
*    CONTROL BLOCKS:                                                  * 12000021
*    DECCOUNT = RESIDUAL COUNT FROM IOBCSW                            * 12200021
*    DECCSWST = STATUS BITS FROM IOBCSW                               * 12400021
*    DECSENS0 = SENSE INFORMATION FROM IOBSENS0 (IF ABNORMAL CHANNEL  * 12600021
*    AND UNIT CHECK)                                                  * 12800021
*                                                                     * 12900021
*    NORMAL COMPLETION (IOBFLAG1, BITS 2 & 5 OFF) : IOBERRCT =0,      * 13000021
*    BUSY BIT OF IOBINCAM TURNED OFF (IF A READ INITIAL, THE BUSY BIT * 13200021
*    IN EVERY IOB IS TURNED OFF).                                     * 13400021
*                                                                     * 13500021
*    PERMANENT ERROR (IOBFLAG1, BIT 2 OFF AND BIT 5 ON; AND IOBERRCT, * 13600021
*    BYTE 2, BITS 5,6,&7 = 011) : SAME OUTPUT AS NORMAL COMPLETION.   * 13800021
*                                                                     * 14000021
*    USER CORRECTABLE ERROR (IOBFLAG1, BIT 2 OFF AND BIT 5 ON; AND    * 14200021
*    IOBERRCT, BYTE 2, BITS 5,6,&7 = 110) : SAME OUTPUT AS NORMAL     * 14400021
*    COMPLETION.                                                      * 14600021
*                                                                     * 14800021
*    INTERCEPT CONDITION (IOBFLAG1, BIT 5 ON AND IOBECBCC = X'44') :  * 15000021
*    SAME OUTPUT AS NORMAL COMPLETION.                                * 15200021
*                                                                     * 16000021
*    RECONSTRUCTION REQUIRED (IOBFLAG1, BIT 5 ON; AND IOBERRCT, BYTE  * 16200021
*    2, BITS 5,6,&7 = 010) : SAME OUTPUT AS NORMAL COMPLETION.        * 16400021
*                                                                     * 16600021
*    RETRY CHANNEL PROGRAM (IOBFLAG1, BIT 2 ON; AND IOBERRCT, BYTE 2, * 16800021
*    BITS 5,6,&7 = 111) : THE FOLLOWING FIELDS ARE RESET TO ZERO --   * 17000021
*    IOBFLAG1, IOBFLAG2, IOBSENS0, IOBSENS1, IOBFLAG3, IOBCSW.        * 17200021
*    IOBECBCC IS RESET TO X'7F' AND IOBERRCT, BYTE 2, IS SET TO X'05'.* 17400021
*                                                                     * 17600021
*    RETRY FAILURE (IOBFLAG1, BIT 5 ON; AND IOBERRCT, BYTE 2, BITS    * 17800021
*    5,6,&7 = 101) : SAME OUTPUT AS NORMAL COMPLETION.                * 18000021
*                                                                     * 18200021
*    OLTEP EXECUTING (IOBINCAM, BYTE 1 = X'02') : BUSY BIT OF IOB     * 18400021
*    PASSED BY IOS TURNED ON; DECFLAGS, BIT 7 (OLTEP IN CONTROL)      * 18600021
*    TURNED ON.                                                       * 18800021
*                                                                     * 19000021
*    REQUEST FOR TEST (FIRST 3 BYTES OF USER AREA = SOH%/) : CONVERT  * 19200021
*    TO STANDARD OS BTAM RFT --                                       * 19400021
*    +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++    * 19600021
*    +     +     +     +     +     +     +     +     +     +     +    * 19800021
*    + SOH +  %  +  X  +  X  +  Y  +  Y  +  N  +  C  +  U  +  U  +    * 20000021
*    +     +     +     +     +     +     +     +     +     +     +    * 20200021
*    +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++    * 20400021
*    AND SCHEDULE ON-LINE TEST.                                       * 20600021
* PUT ADDR OF RFT IN IOBERINF, AMD SCHEDULE ON-LINE TEST.             * 20800021
*    ON-LINE TEST IN PROGRESS (IOBINCAM, BYTE 1, BIT 7 ON) : SCHEDULE * 21000021
*    ON-LINE TEST.                                                    * 21200021
*                                                                     * 21400021
* EXTERNAL REFERENCES:                                                * 21600021
*         NONE                                                        * 21800021
*                                                                     * 22000021
* EXITS, NORMAL:                                                      * 22200021
*         POST COMPLETE OR ERP REQUIRED - RETURN TO IOS.              * 22400021
*         RETRY CHANNEL PROGRAM - RETURN TO IOS+8.                    * 22600021
*                                                                     * 22800021
* EXITS, ERROR:                                                       * 23000021
*         NONE                                                        * 23200021
*                                                                     * 23400021
* TABLES/WORK AREAS:                                                  * 23600021
*         NONE                                                        * 23800021
*                                                                     * 24000021
* ATTRIBUTES:                                                         * 24200021
*    RESIDENT, ENABLED, AND SERIALLY REUSABLE.                        * 24400021
*                                                                     * 24600021
* CHARACTER CODE DEPENDENCY:                                          * 24800021
*    NONE                                                             * 25000021
*                                                                     * 25200021
* NOTES:                                                              * 25250021
*    NONE                                                             * 25300021
*                                                                     * 25350021
*********************************************************************** 25400021
         EJECT                                                          25600021
*/*IGG019PA: CHART*/                                                    25800021
*/* E IGG019PA*/                                                        26000021
*/* P MOVE RESIDUAL COUNT INTO DECCOUNT*/                               26200021
*/* P MOVE STATUS BITS INTO DECCSWST*/                                  26400021
*/* D (YES,,NO,TESTXCE) IS COMPLETION CODE A X'7E'*/                    26460021
*/* M TURN ON IOB EXCEPTION BIT*/                                       26520021
*/*TESTXCE: D (YES,,NO,TSTRDTI) IS IT ABNORMAL CHANNEL END APPENDAGE*/  26620021
*/* D (NO,,YES,NOTUC) UNIT CHECK IN CSW STATUS*/                        26800021
*/* P MOVE SENSE INFO INTO DECSENS0*/                                   27000021
*/*NOTUC: D (NO,,YES,TESTIOB) HAS ERP BEEN ENTERED*/                    27200021
*/* D (YES,,NO,NORETRY) CHANNEL RETRY BY CE/XCE APPENDAGE*/             27400021
*/* M (,TSTRDTI) SET PERMANENT ERROR COMPLETION CODE*/                  27600021
*/*NORETRY: M TURN ON ERP HAS BEEN ENTERED BIT*/                        27800021
*/* R RETURN TO IOS*/                                                   28000021
*/*TESTIOB: D (NO,,YES,TSTRDTI) WAS THE IOB INTERCEPTED*/               28200021
*/* D (YES,,NO,TSTRECON) IS ERROR PERMANENT*/                           28400021
*/* D (YES,,NO,TSTRDTI) OPERATIONAL SIO*/                               28600021
*/* P (,TSTRDTI) SET SIOCC=3 ERROR FLAG*/                               28800021
*/*TSTRECON: D (NO,,YES,RECON) IS RECONSTRUCT REQUIRED*/                29000021
*/* D (YES,,NO,TSTRDTI) SHOULD REQUEST BE RETRIED*/                     29200021
*/* M RESET IOBFLAG1 FIELD TO ZERO*/                                    29400021
*/* M RESET IOBFLAG2 FIELD TO ZERO*/                                    29600021
*/* M RESET IOBFLAG3 FIELD TO ZERO*/                                    29800021
*/* M RESET IOBSENS0 AND IOBSENS1 TO ZERO*/                             30000021
*/* M RESET IOBCSW TO ZERO*/                                            30200021
*/* M SET IOBERRCT TO SHOW CE/XCE RETRY*/                               30400021
*/* M RESET IOBECBCC TO X'7F'*/                                         30600021
*/* R RETURN TO IOS+8*/                                                 30800021
*/* RECON: M SET RECONSTRUCTION REQUIRED FLAG*/                         31000021
*/*TSTRDTI: M RESET IOBERRCT FIELD TO ZERO*/                            31200021
*/* D (NO,,YES,ALLIOBS) WAS COMMAND A READ INITIAL*/                    31400021
*/* P GET ADDR OF MASTER UCB*/                                          31460021
*/* D (NO,,YES,TSTOLTEP) READ INITIAL PENDING ON LINE GROUP*/           31520021
*/* M (,TSTOLTEP) TURN OFF BUSY BIT IN IOB PASSED BY IOS*/              31600021
*/*ALLIOBS: P TURN OFF BUSY BIT IN ALL IOB'S*/                          31800021
*/*TSTOLTEP: D (YES,,NO,TSTOLT) IS OLTEP EXECUTING*/                    32000021
*/* M TURN ON BUSY BIT IN IOB PASSED BY IOS*/                           32200021
*/* M SET OLTEP IN CONTROL FLAG*/                                       32400021
*/*RESTREG: R RETURN TO IOS*/                                           32600021
*/*TSTOLT: D (NO,,YES,SCHEDOLT) IS OLT IN PROGRESS*/                    32800021
*/* D (YES,,NO,RESTREG) SOH%/ MESSAGE*/                                 33000021
*/* P CONVERT TO BTAM RFT*/                                             33200021
*/*SCHEDOLT: P SCHEDULE ON-LINE TEST*/                                  33400021
*/* R RETURN TO IOS+4*/                                                 33600021
*/*IGG019PA: END*/                                                      33800021
         EJECT                                                          34000021
         SPACE 2                                                        34200021
*        ESTABLISH ADDRESSABILITY                                       34400021
         SPACE                                                          34600021
         USING IECTIOB,IOBREG                                           34800021
         USING IHADCB,DCBREG                                            35000021
         USING IECTDECB,ECBREG                                          35200021
         USING IECTDEB,DEBREG                                           35400021
         USING *,BASEREG                                                35600021
         STM   ZEROREG,BRREG,SAVEIOS-*(BRREG) SAVE REGISTERS            35800021
         LR    BASEREG,BRREG       SET UP BASE REG                      36000021
         B     LOADECB             BRANCH AROUND SAVE AREA              36200021
SAVEIOS  DC    16F'0'                   SAVE AREA                       36400021
         SPACE 2                                                        36600021
*        ADDRESS CONTROL BLOCKS                                         36800021
         SPACE                                                          37000021
LOADECB  L     ECBREG,IOBECBPT     LOAD ADDR OF DECB                    37200021
         L     DEBREG,PREFIX(DEBREG)  LOAD ADDR OF START OF DEB         37400021
         SPACE 2                                                        37600021
*        SAVE RESIDUAL COUNT AND STATUS                                 37800021
         SPACE                                                          38000021
         MVC   DECCOUNT(CNTLNGTH),IOBCSW+6  MOVE INTO DECB - RESIDUAL   38100021
         MVC   DECCSWST(STATLNG),IOBCSW+4   COUNT AND STATUS BITS OF    38200021
*                                   LAST CCW EXECUTED                   38300021
         CLI   IOBECBCC,X'7E'      IOB COMPLETION CODE A '7E'           38400021
         BNE   TESTXCE             NO , GO CHECK FOR ABNORMAL CE        38500021
         OI    IOBFLAG1,IOBEXC     TURN ON IOB EXCEPTION                38600021
         SPACE 2                                                        38800021
         CLI   IOBSENS0,ZEROS      ANY INTERCEPT SENSE LEFT      A68753 38850021
         BE    RETURN              NO, GO TO ERPS                A68753 38900021
         MVI   IOBCSW+4,X'82'      YES, MUST HAVE BEEN ATTN,UC   A68753 38950021
         B     RETURN              GO TO ERPS                    A68753 39000021
TESTXCE  DS    0H                  CHECK FOR ABNORMAL ENTRY      A68753 39050021
         TM    IOBFLAG1,IOBEXC     ABNORMAL ?                    A68753 39100021
         BNO   TSTRDTI             NO, GOOD COMPLETION           A68753 39150021
         CLI   IOBECBCC,NORMAL     FIRST ENTRY                   A68753 39200021
         BE    RETURN              YES, GO TO ERP                A68753 39250021
         TM    IOBCSW+4,X'02'      UNIT CHECK                    A68753 39300021
         BNO   TESTIOB             NO , DON'T REPOINT DECB       A68753 39350021
         MVC   DECSENS0(1),IOBSENS0  UPDATE SENSE IN DECB        A68753 39400021
         SPACE 2                                                        43400021
*        INTERCEPTED IOB                                                43600021
         SPACE                                                          43800021
TESTIOB  EQU   *                                                        44000021
         CLI   IOBECBCC,INTRCEPT   WAS THE IOB INTERCEPTED              44200021
         BE    TSTRDTI             YES, TEST FOR RD INIT & CONTINUE     44400021
         SPACE 2                                                        44600021
*        TEST FOR PERMANENT ERROR FOUND BY ERP                          44800021
         SPACE                                                          45000021
         TM    IOBERRCT+1,USERCORR IS ERROR USER CORRECTABLE            45200021
         BO    TSTRECON            YES, TEST FOR RECONSTRUCTION         45400021
         TM    IOBERRCT+1,USERETRY IS ERROR PERMANENT OR USER RETRYABLE 45600021
         BNO   TSTRECON            NO, TEST FOR RECONSTRUCTION          45800021
         SPACE 2                                                        46000021
*        TEST FOR OPERATIONAL SIO                                       46200021
         SPACE                                                          46400021
         TM    IOBSIOCC,OPERSIO    TEST FOR OPERATIONAL SIO             46600021
         BNO   TSTRDTI             BRANCH IF OPERATIONAL                46800021
         OI    DECERRST,SIOCC3     SET SIOCC=3 ERROR FL AG              47000021
         B     TSTRDTI             GO TEST FOR READ INITIAL             47200021
         SPACE 2                                                        47400021
*        USER CORRECTABLE ERROR - CHECK FOR RECONSTRUCTION OR RETRY     47600021
         SPACE                                                          47800021
TSTRECON EQU   *                                                        48000021
         TM    IOBERRCT+1,NORECON  IS RECONSTRUCTION REQUIRED           48200021
         BNO   RECON               YES, SET RECON REQUIRED BIT          48400021
         TM    IOBERRCT+1,RTRYREQ  SHOULD REQUEST BE RETRIED            48600021
         BM    TSTRDTI             NO, TEST FOR READ INITIAL            48800021
         XC    IOBFLAG1(TOSENS1),IOBFLAG1   RESET IOBFLAG1, IOBFLAG2,   49000021
*                                           IOBSENS0, IOBSENS1 TO ZERO  49200021
         MVI   IOBFLAG1,X'42'      INITIALIZE FLAG               A68749 49250021
         XC    IOBFLAG3(TOCSW),IOBFLAG3     RESET IOBFLAG3, IOBCSW TO 0 49400021
         MVI   IOBERRCT+1,RETRY    SET IOBERRCT TO SHOW CE/XCE RETRY    49600021
         MVI   IOBECBCC,NORMAL     RESET IOBECBCC TO X'7F'              49800021
         LM    ZEROREG,BRREG,SAVEIOS RESTORE REGS                       50000021
         B     EIGHT(RETREG)       RETURN TO IOS+8                      50200021
RECON    EQU   *                                                        50400021
         MVI   DECERRST,RECONREQ   SET RECONSTRUCTION REQUIRED FLAG     50600021
         SPACE 2                                                        50800021
*        CHECK FOR READ INITIAL - IF SO, TUR OFF ALL BUSY BITS. IF NOT, 51000021
*        TURN OFF BUSY BIT OF IOB PASSED BY IOS                         51200021
         SPACE                                                          51400021
TSTRDTI  EQU   *                                                        51600021
         XC    IOBERRCT(CNTLNG),IOBERRCT  RESET IOBERRCT TO 0           51800021
         USING UCB,UCBREG               ADDRESSABILITY           A55715 51850021
         CLI   UCBRLN,MASTER       IS UCB MASTER UCB FOR LINE    A55715 51900021
         BE    RLNISONE            YES, BRANCH                   A55715 51950021
         L     UCBMSTR,UCBCTLNK    GET ADDR OF MASTER UCB        A55715 51960021
         B     BSYTST              GO TEST FOR READ TI PENDING   A55715 51970021
RLNISONE LR    UCBMSTR,UCBREG      UCB IS MASTER UCB             A55715 51980021
         USING MSTRUCB,UCBMSTR     ADDRESSABILITY                A55715 51990021
BSYTST   EQU   *                                                 A55715 51992021
TSTOLT   EQU   *                                                 A61871 51994021
         TM    IOBINCAM,OLT            IS OLT IN PROGRESS        A61871 51996021
         BO    SCHEDOLT                YES BRANCH                A61871 51998021
         CLI   DECTYPE+1,RDTI      WAS COMMAND A READ INITIAL           52000021
         BE    TESTRFT                 YES GO TEST FOR RFT       A61871 52200021
         TM    MTRGCB,RDTIACTV      READ INITIAL REQUEST         A55715 52250021
*                                    OUTSTANDING?                A55715 52260021
         BO    TSTOLTEP            YES, LEAVE BUSY BIT ON               52290021
         NI    IOBINCAM,BUSY       TURN OFF BUSY BIT OF IOB PASSED BY   52400021
*                                   IOS                                 52600021
         B     TSTOLTEP            GO TEST FOR OLTEP EXECUTING          52800021
ALLIOBS  L     WREG,DCBIOBAD       GET INITIAL IOB BASE                 53000021
         SR    ICREG,ICREG         CLEAR REG                            53200021
         IC    ICREG,DEBNMEXT      LOOP COUNT                           53400021
         SR    ICSREG,ICSREG       CLEAR REG                            53600021
         IC    ICSREG,DCBEIOBX     = INCREMENT                          53800021
         LA    BRREG,DEBUCBAD-FOUR GET START OF UCB LIST         A55053 53850021
NEXTIOB  LA    WREG,0(ICSREG,WREG) GET ADDR OF IOB                      54000021
         LA    BRREG,FOUR(BRREG)                                 A55053 54050021
         L     UCBMSTR,0(BRREG)     GET UCB ADDR                 A55053 54100021
         NI    MTRGCB,ALLON-RDTIACTV   SIGNAL END OF READ INIT   A55715 54110021
         TM    6(UCBMSTR),X'E0'     OUTSTANDING I/O ?            A55053 54150021
         BNZ   ALLIOBLP                                          A55053 54160021
         NI    INCAM(WREG),BUSY    TURN OF IOB                          54200021
ALLIOBLP  BCT  ICREG,NEXTIOB     GO TO NEXT IOB-                 A55053 54400021
         SPACE 2                                                        54600021
*        TEST FOR OLTEP EXECUTING                                       54800021
         SPACE                                                          55000021
TSTOLTEP EQU   *                                                        55200021
         TM    UCBGCB,OLTEP        IS OLTEP EXECUTING                   55400021
         BNO   RESTREG                 NO RETURN                 A61871 55800021
         OI    DECFLAGS,OLTEPCTL   TURN ON OLTEP IN CONTROL BIT         56200021
RESTREG  EQU   *                                                        56400021
         CLI   DECTYPE+1,RDTI      READ INITIAL?                 A62682 56450021
         BE    RETURN                                            A62682 56500021
         MVC   LOCALRLN(ONE,ECBREG),RLN(ECBREG)                  A62682 56550021
* MOVE RLN INTO DECPOLPT                                         A62682 56560021
RETURN   EQU   *                                                 A62682 56570021
         LM    ZEROREG,BRREG,SAVEIOS RESTORE REGS                       56600021
         BR    RETREG              RETURN TO IOS                        56800021
         SPACE 2                                                        57000021
         SPACE 2                                                        58200021
*        TEST FOR RFT                                                   58400021
TESTRFT  EQU   *                                                 A61871 58500021
         TM    IOBECBCC,X'20'      PERMANENT ERROR               A66469 58550021
         BZ    ALLIOBS             YES, DON'T CHECK BUFFER       A66469 58560021
         SPACE                                                          58600021
         L     WREG,DECAREA        LOAD ADDR OF AREA                    58800021
         CLC   0(HDRLNGTH,WREG),SOHMSG  ARE 1ST 3 CHARS SOH%/           59000021
         BNE   ALLIOBS                 NO BRANCH                 A61871 59200021
         TM    DCBERROP,ONLT       ARE TERMINAL TESTS SPECIFIED  A56047 59230021
         BZ    ALLIOBS                 NO BRANCH                 A61871 59260021
         CLC   DECLNGTH(CNTLNGTH),MINBUFF  IS BUFF LONG ENOUGH   A60458 59270021
         BL    ALLIOBS                 NO BRANCH                 A61871 59280021
         MVC   STDHDR(RFTLNGTH,WREG),HDR3270(WREG) CONVERT TO STD       59300021
*                                                  BTAM RFT             59400021
         ST    WREG,IOBERINF            SAVE ADDR OF AREA               59500021
         SPACE 2                                                        59600021
*        SCHEDULE ON LINE TEST                                          59800021
         SPACE                                                          60000021
SCHEDOLT EQU   *                                                        60200021
         L     UCBREG,DEBOFLGS     GET ADDR OF PTR TO IRB               60400021
         L     UCBREG,0(UCBREG)    GET OLT IRB ADDR                     60600021
         L     ICREG,IQEADDR(UCBREG)  LOAD 1ST IQE ADDR                 60800021
         MVC   IQEADDR(ADDRLNG,UCBREG),0(ICREG)  DEQUEUE                61000021
         XC    0(ADDRLNG,ICREG),0(ICREG)  ZERO LINK FIELD               61200021
         ST    IOBREG,ADDRLNG(ICREG)  STORE IOB ADDR AS PARM            61400021
         LA    ICREG,0(ICREG)      CLEAR HIGH ORDER BYTE                61600021
         LCR   IQEREG,ICREG             COMPLEMENT ADDR & PUT IN REG1   61800021
         L     BRREG,SIXT          LOAD CVT ADDR                        62000021
         L     BRREG,CVT0EF00(BRREG)  LOAD ASYNCH RT ADDR               62200021
         BALR  RETREG,BRREG        LINK TO SCHEDULE ROUTINE             62400021
         LM    ZEROREG,BRREG,SAVEIOS RESTORE REGS                       62600021
         B     FOUR(RETREG)        RETURN TO IOS+4                      62800021
         SPACE 2                                                        63000021
*        REGISTER EQUATES                                               63200021
         SPACE                                                          63400021
ZEROREG  EQU   0                                                        63600021
RQEREG   EQU   1                   ADDR OF RQE ASSOC WITH I/O REQUEST   63800021
IOBREG   EQU   2                   ADDR OF IOB                          64000021
DEBREG   EQU   3                   ADDR OF DEB                          64200021
DCBREG   EQU   4                   ADDR OF DCB                          64400021
ECBREG   EQU   5                   ECB ADDR                             64600021
UNITADRG EQU   6                   UNIT ADDR OF DVC I/O REQUEST WAS FOR 64800021
UCBREG   EQU   7                   UCB ADDR                             65000021
ICSREG   EQU   8                   WORK REG                             65200021
ICREG    EQU   9                   WORK REGISTER                        65400021
WREG     EQU   10                  WORK REG                             65600021
UCBMSTR  EQU   11                  ADDR OF MASTER UCB                   65700021
BASEREG  EQU   12                  BASE REGISTER                        65800021
RETREG   EQU   14                  RETURN ADDR TO IOS                   66000021
BRREG    EQU   15                  ENTRY POINT ADDRESS                  66200021
IQEREG   EQU   1                        ADDR OF IQE                     66300021
         SPACE                                                          66400021
         SPACE                                                          66600021
*        CONTROL BLOCK BIT SETTINGS                                     66800021
         SPACE                                                          67000021
ZEROS    EQU   X'00'               BYTE OF ZEROS                        67200021
ALLON    EQU   X'FF'               BYTE OF ONES                  A55715 67250021
IOBEXC   EQU   X'04'               EXCEPTIONAL CONDITION BIT            67400021
RECONSTR EQU   X'02'               RECONSTRUCT BUFFER IMAGE BIT         67600021
INTRCEPT EQU   X'44'               COMPLETION CODE - IOB INTERCEPTED    67800021
OPERSIO  EQU   X'30'               OPERATIONAL SIO CODE                 68000021
SIOCC3   EQU   X'10'               SIOCC=3 ERROR BIT                    68200021
RETRY    EQU   X'05'               RETRY CHAN PGM SETTING               68400021
ERP      EQU   X'02'               ERP HAS BEEN ENTERED BIT             68600021
ERROR    EQU   X'41'               PERMANENT ERROR COMPLETION CODE      68800021
USERCORR EQU   X'04'               USER CORRECTABLE BIT                 69000021
USERETRY EQU   X'01'               PERMANENT OR USER RETRYABLE          69200021
*                                   ERROR BIT                           69400021
NORECON  EQU   X'05'               RECONSTRUCTION NOT REQUIRED SETTING  69600021
RTRYREQ  EQU   X'07'               RETRY CHAN PGM SETTING               69800021
RECONREQ EQU   X'10'               RECONSTRUCTION REQUIRED FLAG         70000021
NORMAL   EQU   X'7F'               NORMAL COMPLETION CODE               70200021
RDTI     EQU   X'01'               VALUE OF READ INITIAL                70400021
BUSY     EQU   X'FF'-X'40'         BUSY BIT                             70600021
OLTEP    EQU   X'80'               OLTEP EXECUTING BIT                  70700021
MASTER   EQU   X'01'               MASTER UCB BIT                       70800021
RDTIPEND EQU   X'04'               READ INIT PENDING BIT                70900021
RDTIACTV EQU   X'08'               READ INITIAL OUTSTANDING FLAG A55715 70950021
OLTEPCTL EQU   X'01'               OLTEP IN CONTROL BIT                 71000021
SIXT     EQU   X'10'               CVT ADDR                             71200021
OLT      EQU   X'01'               OLT IN PROGRESS BIT                  71400021
ONLT     EQU   X'10'               EROPT = T IN DCB, IE. TERM TESTS     71460021
*                                   ARE SPECIFIED                       71520021
         SPACE                                                          71600021
         SPACE                                                          71800021
*        DISPLACEMENTS EQUATES                                          72000021
         SPACE                                                          72200021
TOSENS1  EQU   4                   LENGTH OF ZERO-OUT FOR RETRY         72400021
TOCSW    EQU   8                   LENGTH OF ZERO-OUT                   72600021
INCAM    EQU   28                  DISP OF IOBINCAM                     72800021
CVT0EF00 EQU   4                   OFFSET TO ASYNCH SCHEDULER           73000021
PREFIX   EQU   28                  LENGTH OF DEB PREFIX                 73010021
CNTLNGTH EQU   2                   LENGTH OF DECCOUNT                   73020021
STATLNG  EQU   2                   LENGTH OF DECCSWST                   73030021
SENSELNG EQU   1                   LENGTH OF DECSENS0                   73040021
EIGHT    EQU   8                   DISP INTO IOS                        73050021
CNTLNG   EQU   2                   LENGTH OF IOBERRCT                   73060021
HDRLNGTH EQU   3                   FIRST 3 CHARS OF 3270 RFT - SOH%/    73070021
STDHDR   EQU   2                   LENGTH OF STD BTAM RFT HEADER        73080021
RFTLNGTH EQU   10                  LENGTH OF STD BTAM RFT (3270)        73090021
HDR3270  EQU   4                   LENGTH OF 3270 RFT HEADER            73100021
IQEADDR  EQU   96                  DISP PAST UCB OF 1ST IQE ADDR        73110021
ADDRLNG  EQU   4                   LENGTH OF IQE ADDR                   73120021
FOUR     EQU   4                   DISP INTO IOS                        73130021
ONE      EQU   1                                                 A62682 73180021
LOCALRLN EQU   39                  DISP OF DECPOLPT LOCALRLN     A62682 73192021
RLN      EQU   25                  DISP OF DECB RLN FIELD        A62682 73194021
         SPACE 2                                                        73200021
*        STORAGE                                                        73400021
         SPACE                                                          73600021
SOHMSG   DC    X'016C61'           SOH HEADER SEQUENCE                  73800021
MINBUFF  DC    X'012C'             MIN BUFF LENGTH FOR RFT       A60458 73850021
         IECTUCBX                                                       74000021
         IECTDEBX                                                       74200021
         DCBD  DSORG=BX,DEVD=BS                                         74400021
         IECTIOBX                  UCB DSECTS                           74500021
         IECTDECB                                                       74600021
         END                                                            74800021
