         TITLE 'IGG019PD - CHANNEL END/ABNORMAL END APPENDAGE WTTA'     00200017
IGG019PD CSECT                                                          00400017
         SPACE 2                                                        00600017
* STATUS -          CHANGE LEVEL 000    MAY 10, 1968                    00800017
         SPACE 2                                                        01000017
* FUNCTION -        SERVICE BTAM DEPENDENT WTTA I/O INTERRUPTS          01200017
*                   AND PCI INTERRUPTIONS.                              01400017
*                        1. GIVE CONTROL TO THE PCI APPENDAGE           01600017
*                        2. PROCESS THE LAST CHARACTER OF THE           01800017
*                           MESSAGE AND GIVE CONTROL TO THE             02000017
*                           NORMAL CHANNEL END APPENDAGE.               02200017
*                        3. PROVIDE CHANNEL PROGRAM RESTARTS            02400017
         SPACE 2                                                        02600017
* ENTRY POINT -     ENTRY IS TO 1ST EXECUTABLE INSTRUCTION FROM IOS     02800017
         SPACE 2                                                        03000017
* INPUT -           REGISTER  2 - ADDRESS OF THE IOB                    03200017
*                   REGISTER  4 - ADDRESS OF THE DCB                    03400017
*                   REGISTER  7 - ADDRESS OF THE UCB                    03600017
*                   REGISTER 14 - RETURN ADDRESS                        03800017
         SPACE 2                                                        04000017
* OUTPUT -          1.  GIVE CONTROL TO THE PCI APPENDAGE               04200017
*                   2.  GIVE CONTROL TO THE NORMAL CHANNEL END APP.     04400017
*                   3.  CHANNEL PROGRAM RESTARTS                        04600017
         SPACE 2                                                        04800017
* EXTERNAL ROUTINES                                                     05000017
*                   NONE                                                05200017
         SPACE 2                                                        05400017
* EXIT -            RETURN TO IOS VIA REGISTER 14 + 8 FOR RESTART OF CP 05600017
*                                                 + 0 WHEN THERE IS PCI 05800017
*                   INTERRUPT WITH SPECIAL CONDITIONS                   06000017
*                   GIVE CONTROL TO THE NORMAL CE APPENDAGE             06200017
*                   GIVE CONTROL TO THE PCI APPENDAGE                   06400017
         SPACE 2                                                        06600017
* IN LINE ROUTINES -THE TP OP CODE IS USED AS AN INDEX TO BRANCH TO     06800017
*                        THE APPROPRIATE ROUTINE WITHIN THE CHANNEL     07000017
*                        END APPENDAGE. THE SEQUENCE OF PROCESSING      07200017
*                        IS INITIALIZATION AND CHECKING FOR ANY         07400017
*                        ERRORS, TP OP CODE ROUTINE, AND THEN EXITING.  07600017
*                        THE VARIOUS ROUTINES ARE -                     07800017
*                        1. TP01 - A PREPARE COMMAND HAS BEEN HALTED    08000017
*                            BY A HALT I/O AS A RESULT OF A RESETPL     08200017
*                            MACRO INSTRUCTION.                         08400017
*                        2. HIOREAD - A READ COMMAND HAS BEEN HALTED    08600017
*                            BY A HALT I/O AS A RESULT OF A RESETPL     08800017
*                            MACRO INSTRUCTION.                         09000017
*                        3. TP07 - THE RECEIVED AND EXPECTED TERMINAL   09200017
*                            IDENTIFICATION ARE COMPARED.               09400017
*                            IF THE COMPARISON IS CORRECT, THE NEXT     09600017
*                            READ CCW IS STARTED, OTHERWISE THE OPERA-  09800017
*                            TION IS STOPPED AND THE CONTROL WILL       10000017
*                            RETURN TO THE USER.                        10200017
*                        4. TP11 - A MESSAGE HAS BEEN RECEIVED OR SENT  10400017
*                        5. TPXX - CONTROL IS GIVEN TO THE NORMAL       10600017
*                            CHANNEL END APPENDAGE.                     10800017
         SPACE 2                                                        11000017
* ATTRIBUTES -      THIS ROUTINE IS RUN IN SUPERVISOR MODE, DISABLED.   11200017
         EJECT                                                          11400017
IOBREG   EQU   2                        INPUT/OUTPUT BLOCK ADDRESS      11600017
DCBREG   EQU   4                        DATA CONTROL BLOCK ADDRESS      11800017
UCBREG   EQU   7                        UNIT CONTROL BLOCK ADDRESS      12000017
WREG     EQU   8                        ADDRESS WORK REGISTER           12200017
W2REG    EQU   9                        ADDRESS WORK REGISTER           12400017
ECBREG   EQU   10                       EVENT CONTROL BLOCK ADDRESS     12600017
ICREG    EQU   11                       ADDRESS WORK REGISTER           12800017
BASEREG  EQU   12                       BASE REGISTER                   13000017
CCWREG   EQU   13                       CHANNEL COMMAND WORD ADDRESS    13200017
RETREG   EQU   14                       RETURN ADDRESS                  13400017
BRREG    EQU   15                       ENTRY POINT ADDRESS             13600017
         USING IECTDECB,ECBREG                                          13800017
         USING IECTIOB,IOBREG                                           14000017
         USING IHADCB,DCBREG                                            14200017
         USING *,BASEREG                                                14400017
         STM   RETREG,W2REG,SAVEIOS-*(BRREG) SAVE REGISTERS             14600017
         B     16(BRREG)                BRANCH TO 1ST EXECUTABLE STMT   14800017
MCPCIAPP DC    A(0)                     PCI APPENDAGE ADDRESS           15000017
MBENDAPP DC    A(0)                     CHANNEL END APPENDAGE ADDRESS   15200017
         LR    BASEREG,BRREG            LOAD BASE REGISTER              15400017
         L     CCWREG,64                LOAD CCW ADDRESS AND SUBTRACT   15600017
         SH    CCWREG,EIGHT             EIGHT TO POINT ON THE LAST USED 15800017
         CLC   68(2,0),STATUS           TEST FOR PCI ALONE              16000017
         BE    PCIAPP                   BRANCH IF YES                   16200017
         TM    69,PCI                   IS PCI BIT PRESENT              16400017
         BNO   CEAPPWT                  IF NOT, BRANCH TO CE.APP WTTA   16600017
         TM    69,PC                    IS PROGRAM CHECK FLAG PRESENT   16800017
         BO    PCIAPP                   BRANCH IF YES                   17000017
         CLI   0(CCWREG),X'01'          IS A COMMAND WRITE              17200017
         BNE   WTAPP00                  BRANCH IF NOT                   17400017
         CLC   6(2,CCWREG),H1           IS CCW COUNT EQUAL AT 1         17600017
         BE    CEAPPWT                  BRANCH IF YES                   17800017
WTAPP00  EQU   *                                                        18000017
         NI    69,MASKALL-PCI-IL        TURN OFF PCI AND IL FLAGS       18200017
         CLC   70(2,0),6(CCWREG)        TEST FOR RESIDUAL CNT=CCW COUNT 18400017
         BNE   EXIT                     BRANCH IF UNEQUAL               18600017
         TM    5(CCWREG),X'40'          IS THE FIRST PCI                18800017
         BO    EXIT                     BRANCH IF YES                   19000017
         XC    70(2,0),70(0)            CLEAR RESIDUAL COUNT            19200017
         MVC   SAVEKEY(1),64(0)         SAVE KEY OF THE CSW             19400017
         L     CCWREG,8(CCWREG)         LOAD THE PREVIOUS BUFFER ADDR   19600017
         LA    CCWREG,8(CCWREG)         INCREMENT THIS ADDR BY 8        19800017
         ST    CCWREG,64                STORE IT IN THE CSW             20000017
         MVC   64(1,0),SAVEKEY          RESTORE KEY OF THE CSW          20200017
         B     EXIT                                                     20400017
PCIAPP   L     BRREG,MCPCIAPP           LOAD PCI APPENDAGE ADDR         20600017
         BR    BRREG                    BRANCH TO PCI APPENDAGE         20800017
         EJECT                                                          21000017
CEAPPWT  L     ECBREG,IOBECBPT          LOAD ADDRESS OF DECB            21200017
         L     CCWREG,IOBCSW            LOAD CCW ADDRESS                21400017
         SR    ICREG,ICREG              CLEAR ICREG REGISTER            21600017
         TM    IOBFLAG1,IOBEXE          IS ERP IN CONTROL               21800017
         BO    EXIT                     BRANCH IF YES                   22000017
         SH    CCWREG,EIGHT             SUBTRACT 8 TO LAST CCW          22200017
         BP    WTAPP01                                                  22400017
         TM    IOBSIOCC,X'30'           TEST FOR OPERATIONAL SIO        22600017
         BO    SIOCC1                   IF NOT,BRANCH                   22800017
         OI    DECERRST,SNO             SET ON SHOULD NOT OCCUR BIT     23000017
         B     CSWADR                                                   23200017
WTAPP01  EQU   *                                                        23400017
         TM    IOBCSW+4,X'F0'           TEST FOR ERROR IN CSW STATUS    23600017
         BNZ   SIOCC                    BRANCH IF YES                   23800017
         TM    IOBCSW+5,X'3F'           TEST CSW CHANNEL STATUS         24000017
         BZ    NORMAL                   BRANCH IF NO ERRORS             24200017
SIOCC    TM    IOBSIOCC,X'30'           TEST SIO COMPLETION CODE        24400017
         BNO   SIOCC10                  BRANCH IF OPERATIONAL SIO       24600017
SIOCC1   OI    DECERRST,X'80'           SET ON BIT 0 ERROR STATUS       24800017
         B     CSWADR                                                   25000017
SIOCC10  TM    IOBSIOCC,X'10'           TEST FOR CSW STORED             25200017
         BZ    TPXX                     BRANCH IF NOT                   25400017
CSWADR   MVC   IOBCSW+1(3),IOBSTART+1   MOVE START ADDRESS              25600017
         L     WREG,IOBCSW              LOAD IT,                        25800017
         LA    WREG,8(WREG)             ADD 8                           26000017
         ST    WREG,IOBCSW              AND STORE                       26200017
         L     CCWREG,IOBSTART          LOAD START ADDRESS              26400017
         B     TPXX                                                     26600017
NORMAL   MVC   TPCODE,5(CCWREG)         MOVE TPOP CODE                  26800017
         NI    TPCODE,TPMSK             SET OFF BITS 0-1 OF TPOP CODE   27000017
         CLI   TPCODE,X'04'             DETERMINE BRANCH TABLE FOR      27200017
         BE    TPRDWR                   NORMAL ENTRIES-DEPENDS UPON OF  27400017
         CLI   TPCODE,X'07'             IS READ TERMINAL ID             27600017
         BE    TPTERMID                 BRANCH IF YES                   27800017
         CLI   TPCODE,X'01'             THE TP CODE                     28000017
         BE    PREPASNS                                                 28200017
         CLI   TPCODE,X'11'                                             28400017
         BE    TPRDWR                                                   28600017
         CLI   TPCODE,TPBRK             IS A WRITE BREAK                28800017
         BE    TPBREAK                  BRANCH IF YES                   29000017
         B     TPXX                                                     29200017
TPBREAK  LA    ICREG,4(ICREG)           ADD 4 TO ICREG                  29400017
TPRDWR   LA    ICREG,4(ICREG)           ADD 4 TO ICREG                  29600017
TPTERMID LA    ICREG,4(ICREG)           ADD 4 TO ICREG                  29800017
PREPASNS LA    ICREG,0(ICREG)           ICREG KEEPS ITS VALUE           30000017
         B     TPOP(ICREG)                                              30200017
TPOP     B     TP01                     PREPARE-SENSE     01            30400017
         B     TP07                     READ TERM. ID.    07            30600017
         B     TP11                     READ/WRITE TEXT   11            30800017
         B     TP23                     WRITE BREAK       23            31000017
         EJECT                                                          31200017
TP01     CLI   IOBECBPT,CCHIO           IS LINE STOPPED BY HALT I/O     31400017
         BNE   TP01A                    BRANCH IF NOT                   31600017
         NI    IOBFLAG1,MASKALL-IOBEX   SET OFF IOB EXCEPTION FLAG      31800017
         NI    4(UCBREG),MASKALL-HIOFLAG RESET HALT I/O FLAG IN UCB     32000017
         CLI   IOBCSW+4,CEDEUE          TEST FOR CE-DE UNIT EXCEPTION   32200017
         BNE   REXITA                   BRANCH TO RESTART               32400017
         OI    DECFLAGS,EOTWTFLG        SET ON EOT FLAG                 32600017
         NI    DECRESPN,MASKALL-MASKALL RESET DECRESPN                  32800017
         B     TP11G                                                    33000017
TP01A    TM    IOBSENS0,TIMOUT+INTREQ   IS TIME OUT OR INTERVENTION     33200017
*                                       REQUIRED PRESENT                33400017
         BM    TP11G                                                    33600017
         B     TP11E                    SHOULD NOT OCCUR                33800017
         SPACE 3                                                        34000017
HIOREAD  NI    4(UCBREG),MASKALL-HIOFLAG RESET HALT I/O FLAG IN UCB     34200017
         L     ICREG,0(CCWREG)          LOAD BUFFER OR AREA ADDRESS     34400017
         AH    ICREG,6(CCWREG)          ADD CCW COUNT                   34600017
         SH    ICREG,0(CCWREG)          SUBTRACT RESIDUAL COUNT         34800017
         ST    ICREG,0(CCWREG)          AND STORE IN AREA CCW ADDRESS   35000017
         MVC   6(2,CCWREG),IOBCSW+6     MOVE RESIDUAL CNT AS CCW CNT    35200017
         B     REXIT                    BRANCH TO RESTART               35400017
         SPACE 3                                                        35600017
TP07     NI    IOBFLAG1,MASKALL-IOBEX   SET OFF IOB EXCEPTION FLAG      35800017
         LH    ICREG,6(CCWREG)          LOAD IDENT COUNT                36000017
         LA    ICREG,1(ICREG)           INCREMENT BY 1                  36200017
         L     WREG,0(CCWREG)           LOAD ADDR OF IDENT CHAR         36400017
         LA    W2REG,0(WREG,ICREG)      LOAD ADDR OF COMPARE CHAR       36600017
         BCTR  ICREG,0                  DECREMENT COUNT BY 1            36800017
         BCTR  ICREG,0                  DECREMENT COUNT BY 1            37000017
         EX    ICREG,IDCMP              COMPARE IDENTIFICATION          37200017
         BE    IDGOOD                   IF GOOD, BRANCH                 37400017
         OI    DECFLAGS,NOCOMPAR        SET FLAG FOR BAD COMPARISON     37600017
         B     TPXX                                                     37800017
IDGOOD   NI    DECFLAGS,MASKALL-NOCOMPAR RESET FLAG FOR BAD COMPARISON  38000017
         B     REXITA                   EXECUTE NEXT CCW                38200017
IDCMP    CLC   0(0,WREG),0(W2REG)       COMPARE IDENT INSTRUCTION       38400017
         EJECT                                                          38600017
TP11     NI    IOBFLAG1,MASKALL-IOBEX   SET OFF IOB EXCEPTION FLAG      38800017
         TM    4(UCBREG),HIOFLAG        IS OPERATION STOPPED BY HALT IO 39000017
         BO    HIOREAD                  BRANCH IF YES                   39200017
         CLI   0(CCWREG),X'01'          IS COMMAND WRITE                39400017
         BE    WRITE                    BRANCH IF YES                   39600017
         CLC   6(2,CCWREG),IOBCSW+6     TEST FOR CCW CNT=RESIDUAL COUNT 39800017
         BE    TP11C                    BRANCH IF YES                   40000017
         L     ICREG,0(CCWREG)          LOAD BUFFER OR AREA ADDRESS     40200017
         LA    ICREG,0(ICREG)           CLEAR TOP REGISTER              40400017
         ST    ICREG,SAVEAREA           SAVE LAST BUFFER ADDRESS        40600017
         AH    ICREG,6(CCWREG)          ADD CCW COUNT                   40800017
         SH    ICREG,IOBCSW+6           SUBTRACT RESIDUAL COUNT         41000017
         BCTR  ICREG,0                  DECREMENT BY 1                  41200017
         CLI   0(ICREG),WRU             TEST FOR LAST CHAR.=WRU         41400017
         BNE   TP11B                    BRANCH IF NOT                   41600017
         TM    DCBBQFLG,IAMYES          TEST FOR IAM=YES IN DCB         41800017
         BNO   TP11B                    BRANCH IF NOT                   42000017
         OI    DECFLAGS,WRUWTFLG        SET ON WRU FLAG                 42200017
TP11A    LH    WREG,IOBCSW+6            LOAD RESIDUAL COUNT             42400017
         LA    WREG,1(WREG)             INCREMENT IT BY 1               42600017
         CH    WREG,6(CCWREG)           TEST FOR RESIDUAL CNT=CCW CNT   42800017
         BNE   TP11A1                   BRANCH IF INEQUAL               43000017
         L     ICREG,DECAREA            LOAD FIRST BUFFER ADDRESS       43200017
         TM    DCBBFTEK,DYNBF           IS DYNAMIC BUFFERING SPECIFIED  43400017
         BZ    TP11A1                   BRANCH IF NOT                   43600017
         LA    ICREG,4(ICREG)           POINT ON DATA AREA ADDRESS      43800017
         C     ICREG,SAVEAREA           IS LAST BUFFER THE 1ST BUFFER   44000017
         BE    TP11A1                   BRANCH IF YES                   44200017
         L     ICREG,SAVEAREA           LOAD THE LAST BUFFER ADDRESS    44400017
         MVI   0(ICREG),X'1F'           MOVE A LETTER SHIFT AS 1ST CHAR 44600017
         BCTR  WREG,0                   DECREMENT RESIDUAL CNT BY 1     44800017
TP11A1   EQU   *                                                        45000017
         STH   WREG,IOBCSW+6            AND STORE IN RESIDUAL COUNT     45200017
         B     TP11C                                                    45400017
TP11B    CLC   0(1,ICREG),DCBWTEOM      TEST FOR LAST CHAR.=EOM         45600017
         BE    TP11A                    BRANCH IF YES                   45800017
         CLC   0(1,ICREG),DCBWTEOT      TEST FOR LAST CHAR.=EOT         46000017
         BNE   TP11C                    BRANCH IF NOT                   46200017
         OI    DECFLAGS,EOTWTFLG        SET ON FLAG                     46400017
         B     TP11A                                                    46600017
TP11C    TM    IOBCSW+4,UC              TEST FOR UNIT CHECK             46800017
         BNO   TPXX                     BRANCH IF NOT                   47000017
         TM    IOBSENS0,TIMOUT          TEST FOR TIME OUT BIT IN SENSE  47200017
         BNO   TP11D                    BRANCH IF NOT                   47400017
         OI    DECFLAGS,EOTWTFLG        SET ON EOT FLAG                 47600017
         B     TPXX                                                     47800017
TP11D    TM    IOBSENS0,LOSTDATA        TEST FOR LOST DATA BIT IN SNS   48000017
         BNO   TP11D1                   BRANCH IF BIT ABSENT            48200017
         NI    IOBSENS0,MASKALL-LOSTDATA TURN OFF LOST DATA BIT         48400017
         B     TPXX                                                     48600017
TP11D1   TM    IOBSENS0,DATACHK+OVERRUN IS DATA CHECK OR OVERRUN BIT    48800017
         BM    TP11E+4                  BRANCH IF YES                   49000017
TP11E    OI    DECERRST,SNO             SET ON SHOULD NOT OCCUR BIT     49200017
         OI    IOBFLAG1,IOBEX           SET ON IOB EXCEPTION FLAG       49400017
         B     TPXX                                                     49600017
         EJECT                                                          49800017
WRITE    TM    DECFLAGS,X'02'           THRESH RETURN AFTER CONTENTION  50000017
         BNO   WRITE1                   BRANCH IF NOT                   50200017
         MVI   IOBECBPT,CCNORM          YES, SET NORMAL COMPLETION      50400017
         NI    DECFLAGS,X'FD'           RESET TEMPORARY FLAG            50600017
         B     TPXX                     AND EXIT                        50800017
WRITE1   CLI   IOBECBPT,CCNORM          TEST FOR NORMAL COMPLETION      51000017
         BNE   TPXX                     BRANCH IF NOT                   51200017
         TM    IOBCSW+4,UE              TEST FOR UNIT EXCEPTION         51400017
         BNO   TP11F                    BRANCH IF NOT                   51600017
         B     TP11I                                                    51800017
TP11F    TM    IOBCSW+4,UC              TEST FOR UNIT CHECK             52000017
         BNO   TPXX                     BRANCH IF NOT                   52200017
         TM    IOBSENS0,DATACHK         TEST FOR DATA CHECK IN SENSE    52400017
         BNO   TP11E                    BRANCH IF NOT                   52600017
         B     TP11I                                                    52800017
TP11G    EQU   *                                                        53000017
         TM    DCBERROP,LERCNT          ARE LINE ERROR COUNTS SPECIFIED 53200017
         BZ    TPXX                     IF NOT, EXIT                    53400017
         SR    ICREG,ICREG              CLEAR ICREG REGISTER            53600017
         IC    ICREG,IOBUCBX            LOAD LINE NUMBER                53800017
         LA    W2REG,20                 MULTIPLY BY SIZE OF ERROR BLOCK 54000017
         MR    WREG,ICREG                                               54200017
         A     W2REG,DCBLERB            ADD ERROR BLOCK START ADDRESS   54400017
         CLI   IOBECBPT,CCHIO           IS LINE STOPPED BY HALT I/O     54600017
         BE    TP11H                    BRANCH IF YES                   54800017
         IC    ICREG,CDC(W2REG)         LOAD DATA CHECK COUNTER         55000017
         LA    ICREG,1(ICREG)           INCREMENT BY 1                  55200017
         STC   ICREG,CDC(W2REG)         AND STORE IT IN DATA CHECK CNT  55400017
         IC    WREG,CDCT(W2REG)         LOAD THRESHHOLD DATA CHECK CNT  55600017
         CR    ICREG,WREG               COMPARE THESE COUNTS            55800017
         BNE   TPXX                                                     56000017
         OI    IOBFLAG1,IOBEX           SET ON IOB EXCEPTION FLAG       56200017
         BCTR  ICREG,0                  DECREMENT BY 1                  56400017
         STC   ICREG,CDC(W2REG)         AND STORE IT IN DATA CHECK CNT  56600017
         OI    DECFLAGS,X'02'           SET TEMPORARY FLAG              56800017
         B     TPXX                                                     57000017
TP11H    IC    ICREG,CNT(W2REG)         LOAD TRANSMISSION COUNT         57200017
         BCTR  ICREG,0                  DECREMENT BY 1                  57400017
         STC   ICREG,CNT(W2REG)         UPDATE TRANSMISSION COUNT       57600017
         SPACE 3                                                        57800017
TPXX     LM    WREG,W2REG,SAVEIOS+40    RESTORE REGISTERS               58000017
         L     BRREG,MBENDAPP           LOAD NORMAL END APPENDAGE ADDR  58200017
         BR    BRREG                    AND BRANCH                      58400017
         EJECT                                                          58600017
TP11I    EQU   *                                                        58800017
         MVC   IOBERINF(1),IOBSENS0     SAVE SENSE DATA                 59000017
         MVC   IOBERINF+1(7),IOBCSW+1   SAVE CSW DATA                   59200017
         MVC   IOBERINF+8(8),0(CCWREG)  SAVE FAILING CCW                59400017
         LA    CCWREG,IOBCPA            LOAD CHANNEL PROGRAM ADDRESS    59600017
         MVC   0(8,CCWREG),WRITEBRK     MOVE WRITE BREAK CCW            59800017
         B     REXIT                                                    60000017
         SPACE 3                                                        60200017
TP23     EQU   *                                                        60400017
         TM    IOBCSW+4,UC              TEST FOR UNIT CHECK             60600017
         BO    TP11E                    BRANCH IF PRESENT               60800017
         MVC   IOBSENS0(1),IOBERINF     RESTORE SENSE DATA              61000017
         MVC   IOBCSW+1(7),IOBERINF+1   RESTORE CSW DATA                61200017
         L     CCWREG,IOBCSW            PICK UP CCW POINTER             61400017
         SH    CCWREG,EIGHT             ADJUST TO FAILING CCW           61600017
         MVC   0(8,CCWREG),IOBERINF+8   RESTORE FAILING CCW             61800017
         OI    DECFLAGS,CONTFLG         SET ON CONTENTION FLAG          62000017
         TM    IOBCSW+4,UC              TEST FOR UNIT CHECK             62200017
         BO    TP11G                    BRANCH IF YES                   62400017
         B     TPXX                                                     62600017
         EJECT                                                          62800017
REXITA   LA    CCWREG,8(CCWREG)         UPDATE CCW POINTER              63000017
REXIT    ST    CCWREG,IOBSTART          STORE CCW START ADDRESS         63200017
         NI    IOBFLAG1,MASKALL-IOBEX   SET OFF IOB EXCEPTION FLAG      63400017
         LM    RETREG,W2REG,SAVEIOS     RESTORE REGISTERS               63600017
         B     8(RETREG)                RETURN TO IOS+8                 63800017
         SPACE 3                                                        64000017
EXIT     LM    RETREG,W2REG,SAVEIOS     RESTORE REGISTERS               64200017
         BR    RETREG                   RETURN TO IOS                   64400017
         EJECT                                                          64600017
WRITEBRK DC    XL8'0D00000020230004'                                    64800017
SAVEIOS  DC    12F'0'                                                   65000017
SAVEAREA DC    F'0'                                                     65200017
EIGHT    DC    H'8'                                                     65400017
H1       DC    H'1'                                                     65600017
TPCODE   DC    X'00'                                                    65800017
SAVEKEY  DC    X'00'                                                    66000017
STATUS   DC    XL2'0080'                                                66200017
PCI      EQU   X'80'                                                    66400017
IL       EQU   X'40'                    INCORRECT LENGTH                66600017
PC       EQU   X'20'                                                    66800017
UE       EQU   X'01'                                                    67000017
UC       EQU   X'02'                                                    67200017
CEDE     EQU   X'0C'                                                    67400017
CEDEUE   EQU   X'0D'                                                    67600017
CEDEUC   EQU   X'0E'                                                    67800017
COMREJ   EQU   X'80'                                                    68000017
INTREQ   EQU   X'40'                                                    68200017
BUSOUT   EQU   X'20'                                                    68400017
EQUCHK   EQU   X'10'                                                    68600017
DATACHK  EQU   X'08'                                                    68800017
OVERRUN  EQU   X'04'                                                    69000017
LOSTDATA EQU   X'02'                                                    69200017
TIMOUT   EQU   X'01'                                                    69400017
DYNBF    EQU   X'08'                                                    69600017
CNT      EQU   10                       NUMBER OF TRANSMISSIONS         69800017
CDC      EQU   11                                                       70000017
CDCT     EQU   15                                                       70200017
LERCNT   EQU   X'08'                                                    70400017
WRU      EQU   X'32'                                                    70600017
EOTWTFLG EQU   X'04'                                                    70800017
WRUWTFLG EQU   X'01'                                                    71000017
CONTFLG  EQU   X'10'                                                    71200017
TPBRK    EQU   X'23'                                                    71400017
NOCOMPAR EQU   X'10'                                                    71600017
HIOFLAG  EQU   X'80'                                                    71800017
MASKALL  EQU   X'FF'                                                    72000017
IAMYES   EQU   X'20'                                                    72200017
SNO      EQU   X'40'                                                    72400017
CCNORM   EQU   X'7F'                    NORMAL COMPLETION CODE          72600017
CCHIO    EQU   X'48'                                                    72800017
IOBEX    EQU   X'04'                                                    73000017
IOBEXE   EQU   X'24'                                                    73200017
TPMSK    EQU   X'3F'                                                    73400017
         CNOP  0,8                                                      73600017
         IECTDECB                                                       73800017
         IECTIOBX                                                       74000017
         DCBD  DSORG=BX,DEVD=WT                                         74200017
         END                                                            74400017
