         TITLE 'IGG019PG - BTAM LOCAL 3270 SECOND LEVEL ATTN RTN'       00700021
IGG019PG CSECT                                                          01400021
*                                                                       02100021
* STATUS - CHANGE LEVEL 000                                             02800021
*                                                                       03500021
* FUNCTION - STARTS A READ OF MODIFIED DATA TO A 3270 WHICH HAS GIVEN   04200021
*    AN ATTENTION INTERRUPT. SCHEDULED BY THE FIRST LEVEL ATTENTION     04900021
*    ROUTINE IF NEEDED.  ENTERED FROM THE THIRD STAGE OF THE            05600021
*    ASYNCHRONOUS EXIT EFFECTOR (AEE3).                                 06300021
*                                                                       07000021
* ENTRY POINT - THIS ROUTINE IS ENTERED AT IGG019PG FROM AEE3.          07700021
*                                                                       08400021
* INPUT - REGISTER 1 CONTAINS THE ADDRESS OF THE UCB OF THE DEVICED     09100021
*    WHICH CAUSED AN ATTENTION INTERRUPT.                               09800021
*                                                                       10500021
* OUTPUT - AN IOB IS INITIALIZED TO DO A READ MODIFIED AND EXCP IS      11200021
*    ISSUED.  THE UCB ATTENTION HANDLING FIELDS ARE UPDATED AS NEEDED.  11900021
*                                                                       12600021
* EXTERNAL ROUTINES - EXCP (SVC 0)                                      13300021
*                                                                       14000021
* EXITS, NORMAL - WHEN FINISHED, THIS ROUTINE RETURNS TO AEE3.          14700021
*                                                                       15400021
* EXITS, ERROR - RETURN TO AEE3 WITHOUT ISSUING EXCP.                   16100021
*                                                                       16800021
* TABLES/WORK AREAS - THE UCB EXTENSIONS OF THE INTERRUPTING DEVICE     17500021
*    AND RELATIVE LINE 1 OF THE LINE GROUP.  THE IOB INITIALIZED BY     18200021
*    READ INITIAL AND THE IOB FOR THE INTERRUPTING DEVICE.              18900021
*                                                                       19600021
* ATTRIBUTES - THIS ROUTINE IS LOADED BY OPEN. IT EXECUTES ENABLED,     20300021
*    SUPERVISOR PROTECT KEY, PRIVILEDGED, AND REENTRANT.                21000021
*                                                                       21700021
         EJECT                                                          22400021
*/*IGG019PG: CHART */                                                   22430021
*/* HEADER                                                              22460021
*/*BTAM SECOND LEVEL ATTENTION ROUTINE FOR 3270                     */  22490021
*/* E ENTRY FROM AEE3 */                                                22520021
*/* M ESTABLISH CSECT ADDRESSABILITY AND SAVE RETURN ADDR */            22550021
*/* M ESTABLISH BASES FOR DEVICE AND MASTER UCB DSECTS */               22580021
*/* M ESTABLISH ADDRESSABILITY FOR DEB AND DCB */                       22610021
*/* P OBTAIN ADDRESS OF INITIALIZED IOB */                              22640021
*/* D (YES,EXCP,NO,GETIOB) RLN OF DEVICE IS RLN OF INIALIZED IOB? */    22670021
*/*GETIOB: P OBTAIN ADDRESS OF DEVICE'S IOB */                          22700021
*/* P COPY ECB POINTER AND CHANNEL PROGRAM TO DEVICE'S IOB */           22730021
*/*EXCP: P SAVE ECB CONTENTS IN A NON-VOLATILE REGISTER */              22760021
*/* L INVOKE EXCP TO START I/O OPERATION ON DEVICE */                   22790021
*/* P CLEAR INITIALIZED RLN FIELD IN UCB */                             22820021
*/* D (YES,REPOST,NO,) HAS ECB BEEN POSTED */                    A61855 22830021
*/* D (NO,RESTORE,YES,) HAD WAIT BEEN ISSUED */                  A61855 22840021
*/* D (NO,RESTORE,YES,) IS RB WAIT COUNT ZERO */                 A61855 22842021
*/* P TURN OFF WAIT BIT IN ECB */                                A61855 22844021
*/*RESTORE: P RESTORE PRE-EXCP STATUS OF ECB */                  A61855 22850021
*/*RETURN: P MOVE RLN OF DEVICE BEING USED TO DECPOLPT */        A61855 22880021
*/* R RETURN TO AEE3 */                                                 22910021
*/*REPOST: P PUT COMP. CODE IN REG 0 & RESTORE ECB CONTENTS */   A61855 22920021
*/* P (,RETURN) REPOST ECB */                                    A61855 22930021
*/*IGG019PG: END */                                                     22940021
         EJECT                                                          22970021
RZERO    EQU   0                   REGISTER ZERO                 A61855 23020021
PARMREG  EQU   1                   PARAMETER REGISTER                   23100021
REVN     EQU   2                   WORK REGISTERS- EVEN/ODD PAIR        23800021
RODD     EQU   3                       FOR MULTIPLICATION               24500021
ECBSAVE  EQU   4                   REG TO SAVE ECB CONTENTS             25200021
RW3      EQU   4                   WORK REGISTER                        25900021
MTRBASE  EQU   5                   ADDR OF UCB FOR RLN 1                26600021
UCBBASE  EQU   6                   ADDR OF UCB FOR INTERRUPTING DEVICE  27300021
IOBDVC   EQU   7                   ADDR OF IOB FOR DEVICE               28000021
IOBRDTI  EQU   8                   ADDR OF INITIALIZED IOB              28700021
DEBREG   EQU   9                   ADDRESS OF DEB                       29400021
DCBREG   EQU   10                  ADDRESS OF DCB                       30100021
SAVE14   EQU   11                  REGISTER TO SAVE RETURN PT.          30800021
BASEREG  EQU   12                  BASE REGISTER                        31500021
RTRNREG  EQU   14                  RETURN REGISTER                      32200021
*                                                                       32900021
ALLON    EQU   X'FF'                                                    33600021
CPA      EQU   X'40'               DISP TO START OF CPA IN IOB          34300021
CPALNGTH EQU   24                  LENGTH OF 3270 CPA                   35000021
DCBPT    EQU   X'14'               DISP TO DCB ADDR IN IOB              35700021
ECBPT    EQU   4                   DISP TO ECB ADDR IN IOB              36400021
FOUR     EQU   4                                                        37100021
INCAM    EQU   X'1C'               DISP TO IOBINCAM                     37800021
IOBBUSY  EQU   X'40'               IOBINCAM BUSY BIT                    38500021
ONE      EQU   X'01'                                                    39200021
POLPT    EQU   36                  DISP TO DECPOLPT FIELD IN DECB       39900021
START    EQU   X'10'               DISP OF PTR TO CPA IN IOB            40600021
TWO      EQU   2                                                        40900021
UCBX     EQU   X'20'               DISP TO UCB INDEX IN IOB             41300021
ZERO     EQU   0                                                        42000021
         USING MSTRUCB,MTRBASE                                          42700021
         USING UCB,UCBBASE                                              43400021
         USING IHADCB,DCBREG                                            44100021
         USING DEBNMSUB,DEBREG                                          44800021
         BALR  BASEREG,0           ESTABLISH ADDRESSABILITY FOR CSECT   45500021
         USING *,BASEREG                                                46200021
         LR    SAVE14,RTRNREG      SAVE REG 14 (RETURN ADDRESS)         46900021
         LR    UCBBASE,PARMREG     GET ADDRESS OF UCB IN DSECT BASE REG 47600021
         CLI   UCBRLN,ONE          RLN = 1                              48300021
         BE    RLN1                YES, BRANCH                          49000021
         L     MTRBASE,UCBCTLNK    NO, GET ADDRESS OF MASTER UCB        49700021
         B     GETDEB              BR TO GET ADDR OF DEB                50400021
*                                                                       51100021
RLN1     LR    MTRBASE,UCBBASE                                          51800021
GETDEB   L     DEBREG,MTRDEBAD     GET ADDR OF DEB FROM MASTER UCB      52500021
         L     DCBREG,DEBDCBAD-1   GET ADDR OF DCB FROM DEB             53200021
         L     IOBDVC,DCBIOBAD     GET BASE OF IOB POOL                 53900021
         SR    RW3,RW3                                                  54600021
         IC    RW3,DCBEIOBX        GET LENGTH OF IOB                    55300021
*                                                                       56000021
         SR    RODD,RODD                                                56700021
         IC    RODD,MTRINRLN       GET RLN OF INITIALIZED IOB           57400021
         MR    REVN,RW3            GET DISPLACEMENT INTO IOB POOL       58100021
         LA    IOBRDTI,0(RODD,IOBDVC)  ADD BASE TO GET ADDR OF          58800021
*                                  INITIALIZED IOB                      59500021
*                                                                       60200021
         CLC   UCBRLN(ONE),MTRINRLN  RLN FOR INITIALIZED IOB =          60900021
*                                  RLN OF INTERRUPTING DEVICE           61600021
         BNE   GETIOB              NO, GET ADDRESS OF OTHER IOB         62300021
         LR    IOBDVC,IOBRDTI      YES, IOB FOR DEVICE IS INITIALIZED   63000021
         B     EXCP                    IOB.  START I/O                  63700021
*                                                                       64400021
GETIOB   SR    RODD,RODD           GET RLN OF INTERRUPTING DEVICE       65100021
         IC    RODD,UCBRLN                                              65800021
         MR    REVN,RW3            GET DISP INTO IOB POOL               66500021
         AR    IOBDVC,RODD         ADD BASE OF POOL TO GET ADDRESS OF   67200021
*                                      IOB                              67900021
         MVC   ECBPT(FOUR,IOBDVC),ECBPT(IOBRDTI)  MOVE ECB ADDR         68600021
         MVC   CPA(CPALNGTH,IOBDVC),CPA(IOBRDTI)  MOVE CHANNEL PROGRAM  69300021
         LA    REVN,CPA(IOBDVC)    GET ADDR OF CPA                      70000021
         ST    REVN,START(IOBDVC)  AND STORE IN IOB                     70700021
*                                                                       72100021
EXCP     LR    PARMREG,IOBDVC      GET IOB ADDR FOR EXCP                72800021
         L     ECBSAVE,ECBPT(IOBDVC) GET ADDR OF ECB                    73500021
         L     ECBSAVE,0(ECBSAVE)  GET CONTENTS OF ECB                  74200021
*                                                                       74900021
*        NOTE-- EXCP DESTROYS THE CONTENTS OF THE ECB.  SINCE WAIT MAY  75600021
*    HAVE BEEN ISSUED, THE ECB CONTENTS MUST BE SAVED IF THE WAIT IS    76300021
*    TO BE SATISFIED.                                                   77000021
*                                                                       77700021
         MVI   MTRINRLN,ZERO      CLEAR INIT RLN                 A68754 77750021
         EXCP  (1)                 START I/O OPERATION                  78400021
*                                                                       79100021
         L     REVN,ECBPT(IOBDVC)  GET ADDR OF DECB                     80500021
         TM    0(REVN),X'40'       HAS ECB BEEN POSTED ?         A61855 80550021
         BO    REPOST              YES-GO REPOST IT              A61855 80600021
         SR    RODD,RODD           CLEAR REG 3                   A61855 80650021
         IC    RODD,WAITBIT        INSERT WAIT BIT IN REG 3      A61855 80700021
         SLL   RODD,24             SHIFT IT TO HI ORDER BYTE     A61855 80750021
         NR    RODD,ECBSAVE        HAD WAIT BEEN ISSUED ?        A61855 80800021
         BZ    RESTORE             NO-RESTORE AND RETURN         A61855 80850021
         CLI   28(ECBSAVE),X'00'   IS RB WAIT COUNT ZERO         A61855 80900021
         BNE   RESTORE             NO-RESTORE AND RETURN         A61855 80950021
         N     ECBSAVE,WAITOFF     TURN OFF WAIT BIT             A61855 81000021
RESTORE  EQU   *                                                 A61855 81050021
         ST    ECBSAVE,0(REVN)     RESTORE PRE-EXCP STATUS OF ECB       81200021
RETURN   EQU   *                                                 A61855 81250021
         XC    POLPT(FOUR,REVN),POLPT(REVN)  CLEAR POLPT FIELD          81900021
         MVC   POLPT+3(ONE,REVN),UCBRLN MOVE RLN OF DEVICE BEING USED   82600021
*                                  INTO DECB                            83300021
*                                                                       84000021
         LR    RTRNREG,SAVE14      GET RETURN ADDR BACK IN REG 14       84700021
         BR    RTRNREG             RETURN TO AEE3                       85400021
*                                                                       86100021
REPOST   EQU   *                                                 A61855 86150021
         L     RZERO,0(REVN)       PUT COMP CODE IN REG 0        A61855 86200021
         ST    ECBSAVE,0(REVN)     RESTORE ECB CONTENTS          A61855 86250021
         POST  (REVN),(RZERO)      REPOST ECB WITH SAME CODE     A61855 86300021
         B     RETURN              RETURN                        A61855 86350021
*                                                                       86800021
*                                                                       87500021
         DS    0F                  GET ON WORD BOUNDRY           A61855 87550021
WAITOFF  DC    X'7FFFFFFF'         ALL F'S-WAIT BIT              A61855 87600021
WAITBIT  DC    X'80'               WAIT BIT                      A61855 87650021
*                                                                       87700021
*                                                                       87750021
         IECTUCBX                                                       87850021
         DCBD  DSORG=BX,DEVD=BS                                         88200021
         IECTDEBX                                                       88900021
         IECTIOBX                                                       89600021
*                                                                       91000021
         END                                                            91700021
