         TITLE 'IGG019PI - LOCAL ON-LINE TEST CONTROL'                  00300021
IGG019PI CSECT                                                          00600021
*********************************************************************** 00603021
*                       LOCAL OLT CONTROL                             * 00606021
*********************************************************************** 00609021
*                                                                     * 00612021
* STATUS:                                                             * 00615021
*    CHANGE LEVEL 000         DECEMBER 14, 1971                       * 00618021
*                                                                     * 00621021
* FUNCTION:                                                           * 00624021
*    1. SERVICE ON-LINE TEST REQUESTS FOR THE LOCAL 3270.             * 00627021
*    2. VALIDITY CHECK RFT.                                           * 00630021
*    3. SERVICE I/O INTERRUPTS WHILE IN TEST.                         * 00633021
*    4. RETRY TESTS WITH ERROR-ENDING STATUS 3 TIMES BEFORE TERMIN-   * 00636021
*    ATING TEST.                                                      * 00639021
*    5. END TEST (RESTART READ INITIAL).                              * 00642021
*                                                                     * 00645021
* ENTRY:                                                              * 00648021
*         ENTRY IS TO THE FIRST EXECUTABLE INSTRUCTION VIA THE        * 00651021
*         ASYNCHRONOUS EXIT EFFECTOR SCHEDULED BY IGG019PA (CE/XCE    * 00654021
*         APPENDAGE).                                                 * 00657021
*                                                                     * 00660021
* INPUT:                                                              * 00663021
*    REG 1 - ADDRESS OF THE IOB.                                      * 00666021
*    REG 14 - ADDRESS OF THE ASYNCHRONOUS EXIT EFFECTOR.              * 00669021
*                                                                     * 00672021
*    IOBERINF - ADDRESS OF THE START OF THE RFT INSERTED BY IGG019PA. * 00675021
*                                                                     * 00678021
*    IOBINCAM, BYTE 0, BIT 6 - ERROR BIT TURNED ON BY IGC0E06F/       * 00681021
*    IGC0F06F/IGC1306F/IGC1406F (EBCDIC TEST MESSAGE MODULES) IF AN   * 00684021
*    ERROR WAS FOUND.                                                 * 00687021
*                                                                     * 00690021
*    IOBWORK+2 - BINARY YY VALUE COUNTER INSERTED BY IGC1206F (LOCAL  * 00693021
*    TEST CONTROL).                                                   * 00696021
*                                                                     * 00699021
* OUTPUT:                                                             * 00702021
*    IOBWORK - RLN OF THE DEVICE REQUESTING THE TEST (BYTE 0) AND     * 00705021
*    OF THE RFT TARGET (BYTE 1).                                      * 00708021
*                                                                     * 00711021
*    IOBINCAM, BYTE 0, BIT 7 (OLT IN PROGRESS) - TURNED ON FOR TEST   * 00714021
*    INITIALIZATION; TURNED OFF WHEN TEST IS ENDED.                   * 00717021
*                                                                     * 00720021
*    IOBWORK+4 - RETRY COUNTER.                                       * 00723021
*                                                                     * 00726021
*    IOBUCBX - DURING TEST, CONTAINS RLN OF RFT TARGET. AT END OF     * 00729021
*    TEST, CONTAINS RLN OF DEVICE THAT REQUESTED TEST.                * 00732021
*                                                                     * 00735021
*    UCBFL1, BIT 3 (INTERCEPT BIT) TURNED ON IN UCB OF RFT TARGET     * 00738021
*    IF IT IS NOT THE SOURCE TO INTERCEPT THE NEXT REQUEST TO THE DVC.* 00741021
*                                                                     * 00744021
* EXTERNAL REFERENCES:                                                * 00747021
*         SVC 0 - EXCP.                                               * 00750021
*         SVC 66 - GET ON LINE TEST TRANSIENTS.                       * 00753021
*         SVC 3 - RETURN TO IOS.                                      * 00756021
*         POST - POST USER COMPLETE.                                  * 00759021
*         GETMAIN - GET SAVE AREA.                                    * 00762021
*         FREEMAIN - RELEASE SAVE AREA.                               * 00765021
*                                                                     * 00768021
* EXITS, NORMAL:                                                      * 00771021
*         AT END OF TEST, IF USER HAD ISSUED RESETPL, POST IS ISSUED  * 00774021
*         TO POST USER COMPLETE WITH A X'48' COMPLETION CODE.         * 00777021
*                                                                     * 00780021
*         OTHERWISE, THIS MODULE BALR'S TO IGG019MA (READ/WRITE RTN)  * 00783021
*         TO RE-ISSUE THE READ INITIAL AND THEN RETURNS TO THE        * 00786021
*         ASYNCHRONOUS EXIT EFFECTOR VIA BR 14.                       * 00789021
*                                                                     * 00792021
*         DURING THE TEST, THIS MODULE IS EXITED AFTER SVC 0 BY A     * 00795021
*         SVC 3 - RETURN TO IOS.                                      * 00798021
*                                                                     * 00801021
* EXITS, ERROR:                                                       * 00804021
*         NONE                                                        * 00807021
*                                                                     * 00810021
* TABLES/WORK AREAS:                                                  * 00813021
*         NONE                                                        * 00816021
*                                                                     * 00819021
* ATTRIBUTES:                                                         * 00822021
*    RE-ENTRANT                                                       * 00825021
*                                                                     * 00828021
* CHARACTER CODE DEPENDENCY:                                          * 00831021
*    NONE                                                             * 00834021
*                                                                     * 00837021
* NOTES:                                                              * 00837121
*    NONE                                                             * 00837221
*                                                                     * 00837321
*********************************************************************** 00840021
         EJECT                                                          00870021
*/*IGG019PI: CHART*/                                                    00900021
*/* E IGG019PI*/                                                        01200021
*/* D (NO,,YES,ERRTEST) IS ON-LINE TEST IN PROGRESS*/                   01500021
*/* D (YES,,NO,INVALID) ARE THE XX & YY FIELDS NUMERIC*/                01800021
*/* D (YES,,NO,INVALID) IS XX VALUE VALID (23-28)*/                     02100021
*/* D (NO,,YES,INVALID) IS YY COUNT ZERO*/                              02400021
*/* D (YES,,NO,INVALID) DOES N=3*/                                      02700021
*/* D (NO,,YES,INVALID) IS BUFFER LESS THAN 300 BYTES*/                 03000021
*/* D (YES,,NO,INVALID) WAS OPERATION A READ INITIAL*/                  03300021
*/* D (YES,,NO,INVALID) RFT TARGET ADDR FOUND IN UCB'S*/                03600021
*/* P SAVE RLNS OF REQUESTOR AND TARGET*/                               03900021
*/* D (YES,,NO,INVALID) IS DEVICE A LOCAL 3270*/                        04200021
*/* M TURN ON ON-LINE TEST IN PROGRESS BIT*/                            04500021
*/* M PUT RLN OF TARGET DEVICE IN IOBUCBX*/                             04800021
*/* P ZERO RETRY COUNT*/                                                05100021
*/* P GET NAME OF FIRST SVC LOAD*/                                      05400021
*/* L SVC 66 - GO BUILD TESTS*/                                         05700021
*/* R RETURN TO AEE*/                                                   06000021
*/*INVALID: D (NO,,YES,POST48) WAS RESETPL ISSUED*/                     06300021
*/* P SAVE THE ECB*/                                                    06600021
*/* L BALR TO READ/WRITE ROUTINE*/                                      06900021
*/* P RESTORE THE ECB*/                                                 07200021
*/* R RETURN TO AEE*/                                                   07500021
*/*POST48: P SET COMPLETION CODE TO X'48'*/                             07800021
*/* L POST*/                                                            08100021
*/* R RETURN TO AEE*/                                                   08400021
*/*ERRTEST: D (NO,,YES,EXCEPOFF) IS THE ERROR FLAG ON*/                 08700021
*/* D (NO,,YES,GOAHEAD) CHAN END, DVC END ALONE*/                       09000021
*/* D (NO,,YES,GOAHEAD) DVC END ALONE*/                                 09300021
*/* D (NO,,YES,EXCEPOFF) RETRY COUNT = 3*/                              09600021
*/* P (,STARTRFT) ADD ONE TO RETRY COUNT*/                              09900021
*/*EXCEPOFF: M TURN OFF IOB EXCEPTION BIT*/                             10200021
*/*RESTRLN: D (YES,,NO,RESTORE) IS SOURCE OF RFT = TARGET*/             10300021
*/* M TURN ON INTERCEPT BIT IN TARGET*/                                 10400021
*/*RESTORE: M RESTORE REQUESTOR'S RLN IN IOBUCBX*/                      10600021
*/* M (,INVALID) TURN OFF OLT IN PROGRESS BIT*/                         10800021
*/*GOAHEAD: P DECREMENT YY COUNT*/                                      11100021
*/* D (NO,,YES,RESTRLN) IS YY COUNT ZERO*/                              11400021
*/* P CLEAR RETRY COUNT*/                                               11700021
*/*STARTRFT: P SAVE THE ECB*/                                           12000021
*/* L SVC 0*/                                                           12300021
*/* P RESTORE THE ECB*/                                                 12600021
*/* R SVC 3*/                                                           12900021
*/*IGG019PI: END*/                                                      13200021
         EJECT                                                          13300021
         SPACE 2                                                        13500021
*        ESTABLISH ADDRESSABILITY                                       13800021
         SPACE 1                                                        14100021
         BALR  BASEREG,ZEROREG     SET UP BASE REG                      14400021
         USING *,BASEREG                                                14700021
         USING IECTIOB,IOBREG      IOB                                  15000021
         USING IHADCB,DCBREG       DCB                                  15300021
         USING UCBDSECT,UCBREG     UCB                                  15600021
         USING RFTMSG,RFTREG       REQUEST FOR TEST MSG                 15900021
         USING IECTDEB,DEBREG      DEB                                  16200021
         USING IECTDECB,DECBREG    DECB                                 16500021
         B     OLTCTL              BRANCH AROUND ID USED TO             16800021
         DC    C'IGG019PI'         LOCATE MODULE IN DUMP                17100021
OLTCTL   L     DCBREG,IOBDCBPT     GET ADDR OF DCB                      17400021
         L     RFTREG,IOBERINF     GET ADDR OF RFT MSG                  17700021
         L     DEBREG,DCBDEBAD     GET ADDR OF DEB                      18000021
         L     DEBREG,PREFIX(DEBREG) POINT PAST PREFIX                  18300021
         L     DECBREG,IOBECBPT    GET ADDR OF DECB                     18600021
         SPACE 2                                                        18900021
*        TEST FOR OLT IN PROGRESS - IF SO, NO NEED TO                   19200021
*        VALIDITY CHECK RFT                                             19500021
         TM    IOBINCAM,ONLIN      IS OLT IN PROGRESS                   19800021
         BO    ERRTEST             YES, GO CHECK FOR ERRORS             20100021
         SPACE 2                                                        20400021
*        VALIDITY TEST THE XX, YY, AND N FIELDS OF THE RFT              20700021
         SPACE                                                          21000021
         LA    WORKREG2,XXYYLNG    SET CTR TO 4                         21300021
         LA    WORKREG1,TESTNUMB   GET ADDR OF XX FIELD                 21600021
NUMLOOP  TM    0(WORKREG1),NUMERIC TEST EACH BYTE OF XX&YY              21900021
*                                   FIELDS FOR NUMERIC COUNT            22200021
         BNO   INVALID             NOT NUMERIC, GET OUT                 22500021
         LA    WORKREG1,INCRBY1(WORKREG1) INCREMENT POINTER             22800021
         BCT   WORKREG2,NUMLOOP    IF NOT ALL CHECKED, LOOP             23100021
         CLC   TESTNUMB(XXLNG),TEST23  TEST # (XX) TOO LOW ?            23400021
         BL    INVALID             YES, GET OUT                         23700021
         CLC   TESTNUMB(XXLNG),TEST28  TEST # TOO HIGH ?                24000021
         BH    INVALID             YES, GET OUT                         24300021
         CLC   PASSCNT(YYLNG),ZERO     IS # OF TESTS (YY) ZERO ?        24600021
         BE    INVALID             NO, GET OUT                          24900021
         CLI   ADBYTCNT,THREE      DOES THE COUNT FOR = OF CHARS        25200021
*                                   IN ADDR (N) = 3                     25500021
         BNE   INVALID             NO GET OUT                           25800021
         SPACE 2                                                        26100021
         SPACE 2                                                        27600021
*        TEST FOR READ INITIAL                                          27900021
         SPACE                                                          28200021
         CLI   DECTYPE+1,RDINIT    WAS OPERATION A READ INIT            28500021
         BNE   INVALID             NO, GET OUT                          28800021
         SPACE 2                                                        29100021
*        GO TO EACH UCB AND COMPARE ADDRESS WITH ADDRESS                29400021
*        OF RFT TARGET DEVICE. IF THE ADDRESS IS FOUND AND              29700021
*        THE DEVICE IS A LOCAL 3270, CONTINUE. IF NOT, GO               30000021
*        END TEST (IE., REISSUE USER'S READ INITIAL).                   30300021
         SPACE                                                          30600021
         SR    WORKREG1,WORKREG1   CLEAR REG                            30900021
         SR    WORKREG2,WORKREG2   CLEAR REG                            31200021
         IC    WORKREG2,DEBNMEXT   GET = OF UCB ADDRS                   31500021
UCBLOOP  L     UCBREG,DEBUCBAD(WORKREG1) GET ADDR OF NEXT UCB           31800021
         CLC   CHARADDR(ADDRLNG),CUUADDR  COMPARE ADDRESSES             32100021
         BE    UCBFOUND            IF SAME, SEE IF LOCAL 3270           32400021
         LA    WORKREG1,NEXTADDR(WORKREG1)  POINT TO NEXT ADDR          32700021
         BCT   WORKREG2,UCBLOOP    IF NOT ALL, GO CHECK NEXT            33000021
         B     INVALID             ADDR NOT FOUND, GET OUT              33300021
UCBFOUND MVC   IOBWORK(RLNLNG),IOBUCBX  SAVE RLN OF REQUESTOR           33600021
         SR    WORKREG1,WORKREG1   CLEAR REG                            33900021
         IC    WORKREG1,DEBNMEXT   GET = OF LINES                       34200021
         SR    WORKREG1,WORKREG2   GET RLN OF RFT TARGET                34500021
         STC   WORKREG1,IOBWORK+1  SAVE RLN OF RFT TARGET               34800021
         CLI   DVCLASS,GRAPHIC     IS DVC A GRAPHIC                     35100021
         BNE   INVALID             NO, GET OUT                          35400021
         CLI   UNITYPE,A3277       IS DVC A 3277                        35700021
         BE    DVCOK               YES, SET UP FOR SVC 66               36000021
         CLI   UNITYPE,A3284       IS DVC A 3284                        36300021
         BE    DVCOK               YES, SET UP FOR SVC 66               36600021
         CLI   UNITYPE,A3286       IS DVC A 3286                        36900021
         BNE   INVALID             NO, NOT A LOCAL 3270 - GET OUT       37200021
         SPACE 2                                                        37500021
*        PREPARE TO ISSUE SVC 66                                        37800021
DVCOK    EQU   *                                                 A61871 37870021
         BAL   WORKREG2,GETIOB                                   A61871 37940021
         OI    ONE(WORKREG1),ONLIN     TURN ON OLT IN PROGRESS   A61871 38010021
         SPACE                                                          38100021
         OI    IOBINCAM,ONLIN    TURN ON OLT IN PROGRESS BIT     A61871 38400021
         MVC   IOBUCBX(RLNLNG),IOBWORK+1  SET UP IOB                    38700021
         XC    IOBWORK+4(RETRYLNG),IOBWORK+4 ZERO RETRY COUNT           39000021
         MVC   IOBERCCW(NAMELNG),SVCNAME  GET NAME OF 1ST SVC LOAD      39300021
         SPACE 2                                                        39600021
*        GET ON-LINE TEST TRANSIENTS                                    39900021
         SPACE                                                          40200021
         SVC   OLTRANS             GO BUILD TESTS                       40500021
         BR    AEEREG              RETURN TO AEE                        40800021
         SPACE 2                                                        41100021
*        THE RFT WAS FOUND TO BE INVALID. IF RESETPL WAS                41400021
*        ISSUED, POST. OTHERWISE, GO TO READ/WRITE ROUTINE              41700021
*        TO RE-ISSUE USER'S READ INITIAL.                               42000021
         SPACE                                                          42300021
INVALID  EQU   *                                                 A61871 42600021
         L     IOBREG,DCBIOBAD         GET BASE IOB ADDR         A61871 42630021
         SR    WORKREG2,WORKREG2       CLEAR REG.                A61871 42660021
         IC    WORKREG2,DEBNMEXT       GET # OF DEB EXTENTS      A61871 42690021
         SR    ICREG,ICREG             CLEAR REG.                A61871 42720021
         IC    ICREG,DCBEIOBX           GET SIZE OF IOB          A61871 42750021
         LA    WORKREG1,DEBUCBAD-FOUR  GET START OF UCB'S        A61871 42780021
NEXTIOB  LA    IOBREG,0(ICREG,IOBREG)  POINT TO EACH IOB         A61871 42810021
         LA    WORKREG1,FOUR(WORKREG1) BUMP UCBLIST POINTER      A61871 42840021
         L     UCBREG,0(WORKREG1)      GET NEXT UCB ADDR         A61871 42870021
         TM    6(UCBREG),X'E0'         OUTSTANDING I/O ?         A61871 42900021
         BNZ   ALLLOOP                 YES BRANCH                A61871 42930021
         NI    IOBINCAM,BUSY           TURN OFF BUSY             A61871 42960021
ALLLOOP  BCT   WORKREG2,NEXTIOB        LOOP UNTIL FINISHED       A61871 42990021
         BAL   WORKREG2,GETIOB         GET IOB ADDR              A61871 43020021
         TM    ONE(WORKREG1),RESETPL   RESETPL ISSUED ?          A66480 43050021
         BZ    REISSUE                 NO BRANCH                 A61871 43080021
         NI    ONE(WORKREG1),REPLOFF    SET OFF RESETPL FLAG     A66480 43110021
         B     POST48                  GO POST WITH 48           A61871 43140021
REISSUE  EQU   *                                                 A61871 43170021
         LR    SAVE14,AEEREG       SAVE REG 14 PRIOR TO BALR            43200021
         GETMAIN R,LV=72           GET SAVE AREA                        43500021
         LR    SAVEREG,IOBREG      PUT ADDR OF AREA IN REG 13           43800021
         LR    IOBREG,DECBREG                                           44100021
         L     RWROUT,DCBOFLGS     GET ADDR OF R/W ROUTINE              44400021
         L     WORKREG1,DECSDECB   SAVE ECB                             44700021
         BALR  AEEREG,RWROUT       GO TO READ/WRITE RTN                 45000021
         ST    WORKREG1,DECSDECB   REXTORE ECB                          45300021
         LR    IOBREG,SAVEREG      PUT ADDR OF AREA IN REG 1            45600021
         FREEMAIN R,LV=72,A=(1)    RELEASE SAVE AREA                    45900021
         LR    AEEREG,SAVE14       RESTORE REG 14                       46200021
         BR    AEEREG              RETURN TO AEE                        46500021
POST48   LR    IOBREG,DECBREG      PUT ADDR OF ECB IN REG 1             46800021
         LA    ZEROREG,CC48        SET COMPLETION CODE TO               47100021
         SLL   ZEROREG,24          X'48'                                47400021
         POST  (1),(0)             GO TO POST                           47700021
         BR    AEEREG              RETURN TO AEE                        48000021
         SPACE 2                                                        48300021
*        TEST THE ERROR BIT OF IOBINCAM (SET BY OLT TRANSIENTS          48600021
*        IF AN ERROR WAS FOUND). IF ON, GO END TEST.                    48900021
         SPACE                                                          49200021
ERRTEST  EQU   *                                                        49500021
         TM    IOBINCAM,ERRORBIT   WAS AN ERROR FOUND                   49800021
         BO    EXCEPOFF            YES, GO END TEST                     50100021
         SPACE 2                                                        50400021
*        TEST IOBCSW FOR ERRORS. IF FOUND, GO TO RETRY LOGIC.           50700021
*        IF NO ERRORS, GO ON.                                           51000021
         SPACE                                                          51300021
         CLI   IOBCSW+4,CEDE       CHAN END, DVC END ALONE              51600021
         BE    GOAHEAD             YES, GO ON                           51900021
         CLI   IOBCSW+4,DE         DVC END ALONE                        52200021
         BE    GOAHEAD             YES, GO ON                           52500021
         SPACE 2                                                        52800021
*        RETRY LOGIC  RETRY UP TO THREE TIMES AND IF THERE              53100021
*        IS STILL AN ERROR, GO END TEST.                                53400021
         SPACE                                                          53700021
         SR    WORKREG1,WORKREG1   CLEAR REG                            54000021
         IC    WORKREG1,IOBWORK+4  GET RETRY COUNT                      54300021
         CH    WORKREG1,RETRY3     IS COUNT = 3                         54600021
         BE    EXCEPOFF            YES, GO END TEST                     54900021
         LA    WORKREG1,INCRBY1(WORKREG1) ADD ONE TO COUNT              55200021
         STC   WORKREG1,IOBWORK+4  RETURN NEW COUNT                     55500021
         B     STARTRFT            GO TRY AGAIN                         55800021
         SPACE 2                                                        56100021
*        TO END TEST, TURN OFF IOB EXCEPTION FLAG (IF AN ERROR          56400021
*        WAS FOUND), TURN OFF OLT IN PROGRESS FLAG, SET UP IOB          56700021
*        FOR USER'S CHANNEL PROGRAM, AND BRANCH TO READ/WRITE           57000021
*        ROUTINE.                                                       57300021
         SPACE                                                          57600021
EXCEPOFF EQU   *                                                        57900021
         NI    IOBFLAG1,IOBEXCEP   TURN OFF IOB EXCEPTION BIT           58200021
         NI    IOBINCAM,ERRBIT     TURN OFF EROR BIT                    58500021
RESTRLN  EQU   *                                                        58800021
         CLC   IOBWORK(RLNLNG),IOBWORK+1  COMPARE RLNS OF SOURCE        58806021
*                                         AND TARGET                    58812021
         BE    RESTORE             IF SAME, DON'T TURN ON INTERCEPT     58820021
         SR    WORKREG1,WORKREG1   CLEAR REG                            58840021
         IC    WORKREG1,IOBUCBX    GET RLN OF TARGET DEVICE             58880021
         SLA   WORKREG1,MULTBY4    MULT BY 4 TO GET UCB ADDR            58920021
         L     UCBREG,DEBUCBAD(WORKREG1) BY INDEXING INTO DEB.          58960021
         TM    UCBFL1,UCBPST       CHECK FOR VALID RQE           A68753 58970021
*        SHOULD NEVER BE AN RQE, BUT CHECK TO PREVENT AN         A68753 58980021
*         EXPOSURE TO SYSTEM INTEGRITY                           A68753 58990021
         BO    RESTORE             DON'T MESS WITH UCB IF        A68753 58992021
*                                   VALID RQE                    A68753 58994021
         SR    WORKREG2,WORKREG2   CLEAR REG                     A68753 58996021
         ST    WORKREG2,UCBLTS     ZERO SENSE/STATUS FOR         A68753 58998021
*                                   INTERCEPT                    A68753 58998421
         OI    UCBFL1,INTRCEPT     TURN ON IOB INTERCEPT BIT TO         59000021
*                                  INTERCEPT NEXT REQUEST TO DVC.       59040021
RESTORE  EQU   *                                                        59070021
         MVC   IOBUCBX(RLNLNG),IOBWORK  PUT REQUESTOR'S RLN BACK        59170021
         NI    IOBINCAM,ONLINOFF   TURN OFF OLT IN PROGRESS             59400021
         BAL   WORKREG2,GETIOB                                   A61871 59500021
         NI    INCAM(WORKREG1),ONLINOFF TURN OFF OLT             A61871 59600021
         B     INVALID             GO END TEST                          59700021
         SPACE 2                                                        60000021
*        DECREMENT YY COUNT AND IF ZERO, END TEST. OTHERWISE,           60300021
*        KEEP GOING.                                                    60600021
         SPACE                                                          60900021
GOAHEAD  EQU   *                                                        61200021
         SR    WORKREG1,WORKREG1   CLEAR REG                            61500021
         IC    WORKREG1,IOBWORK+2  GET YY COUNT                         61800021
         BCT   WORKREG1,AGAIN      IF NOT ZERO, GO AGAIN                62100021
         B     RESTRLN             IF ZERO, GO END TEST                 62400021
AGAIN    STC   WORKREG1,IOBWORK+2  RETURN NEW COUNT                     62700021
         XC    IOBWORK+4(RETRYLNG),IOBWORK+4  CLEAR RETRY COUNT         63000021
STARTRFT EQU   *                                                        63300021
         L     WORKREG1,DECSDECB   SAVE ECB                             63600021
         SVC   EXCP                EXCP                                 63900021
         ST    WORKREG1,DECSDECB   RESTORE ECB                          64200021
         SVC   RETURN              RETURN                               64500021
*                                                                       64540021
*                                                                       64580021
GETIOB   EQU   *                                                 A61871 64620021
         L     WORKREG1,DCBIOBAD       GET BASE IOB ADDR         A61871 64660021
         LA    WORKREG1,88(WORKREG1)   ADJUST TO 1ST IOB         A61871 64700021
         BR    WORKREG2                RETURN                    A61871 64740021
         SPACE 2                                                        64800021
*        REGISTER EQUATES                                               65100021
         SPACE                                                          65400021
ZEROREG  EQU   0                   REGISTER 0                           65500021
IOBREG   EQU   1                   ADDR OF IOB                          65700021
DCBREG   EQU   2                   ADDR OF DCB                          66000021
UCBREG   EQU   3                   ADDR OF UCB (USED IN UCB LOOK-UP)    66300021
DEBREG   EQU   4                   ADDR OF DEB                          66600021
RFTREG   EQU   5                   ADDR OF RFT MSG                      66900021
ICREG    EQU   5                   INSERT CHAR. REG.             A61871 67000021
WORKREG1 EQU   6                   WORK REG                             67200021
WORKREG2 EQU   7                   WORK REG                             67500021
DECBREG  EQU   8                   ADDR OF DECB                         67800021
SAVE14   EQU   11                  USED TO SAVE REG 14 CONTENTS         68100021
BASEREG  EQU   12                  BASE REGISTER                        68400021
SAVEREG  EQU   13                  ADDR OF SAVE AREA                    68700021
AEEREG   EQU   14                  ADDR OF ASYNCH EXIT EFFECTOR         69000021
RWROUT   EQU   15                  ADDR OF READ/WRITE ROUTINE           69300021
         SPACE 2                                                        69600021
*        BIT SETTINGS                                                   69900021
         SPACE                                                          70200021
ONLIN    EQU   X'01'               OLT IN PROGRESS                      70500021
NUMERIC  EQU   X'F0'               FIRST 4 BYTES OF CHARACTER           70800021
*                                   NUMBER = 'F'                        71100021
RESETPL  EQU   X'01'               RESETPL ISSUED BIT                   71400021
ERRORBIT EQU   X'02'               ERROR BIT                            71700021
CEDE     EQU   X'0C'               CHAN END, DVC END ALONE              72000021
DE       EQU   X'04'               DVC END ALONE                        72300021
IOBEXCEP EQU   X'FB'               IOB EXCEPTION BIT                    72600021
RESTART  EQU   X'FE'               RESTART FLAG                         72900021
ONLINOFF EQU   X'FE'               OLT IN PROGRESS                      73200021
REPLOFF  EQU   X'FE'                   RESETPL BIT               A61871 73300021
ERRBIT   EQU   X'FD'               ERROR BIT                            73500021
UCBPST   EQU   X'20'               VALID RQE                     A68753 73550021
         SPACE 2                                                        73800021
*        DISPLACEMENTS INTO CONTROL BLOCKS                              74100021
         SPACE                                                          74400021
FSTUCB   EQU   32                  DISP OF UCB ADDRS IN DEB             74700021
OPTYPE   EQU   5                   DISP IN DECB OF OP TYPE              75000021
*        MISCELLANEOUS EQUATES                                          75300021
         SPACE                                                          75600021
THREE    EQU   X'F3'               = OF CHARS IN ADDR MUST = 3          75900021
GRAPHIC  EQU   X'10'               DEVICE CLASS - GRAPHICS              76200021
A3277    EQU   X'09'               3277 DEVIDE TYPE                     76500021
A3284    EQU   X'0A'               3284 DEVIDE TYPE                     76800021
A3286    EQU   X'0B'               3284 DEVIDE TYPE                     77100021
RDINIT   EQU   X'01'               READ INIT OPERATION VALUE            77400021
INTRCEPT EQU   X'10'               UCB IOB INTERCEPT BIT                77500021
PREFIX   EQU   28                  LENGTH OF DEB PREFIX                 77510021
XXYYLNG  EQU   4                   LENGTH OF XX & YY FIELDS             77520021
INCRBY1  EQU   1                   USED TO ADD 1 TO A CTR               77530021
XXLNG    EQU   2                   LENGTH OF XX FIELD                   77540021
YYLNG    EQU   2                   LENGTH OF YY FIELD                   77550021
BUFFLNG  EQU   2                   LENGTH OF DECLNGTH FIELD             77560021
ADDRLNG  EQU   3                   LENGTH OF CUU ADDR                   77570021
NEXTADDR EQU   4                   LENGTH OF UCB ADDRS IN DEB           77580021
RLNLNG   EQU   1                   LENGTH OF RLN                        77590021
RETRYLNG EQU   1                   LENGTH OF RETRY COUNTER              77600021
OLTRANS  EQU   66                  SVC TO GET OLT TRANSIENTS            77610021
CC48     EQU   X'48'               CONDITION CODE SET IF RESETPL        77620021
*                                   WAS ISSUED                          77630021
MULTBY4  EQU   2                   USED IN SLA INSTR TO MULT BY 4       77640021
EXCP     EQU   0                   EXCP SVC                             77650021
RETURN   EQU   3                   RETURN SVC                           77660021
NAMELNG  EQU   8                   # OF CHARS IN SVC LOAD NAME          77680021
FOUR     EQU   4                       FOUR                      A61871 77684021
BUSY     EQU   X'FF'-X'40'             BUSY BIT                  A61871 77688021
INCAM    EQU   28                      IOBINCAM DISPLACEMENT     A61871 77692021
ONE      EQU   1                       ONE                       A61871 77696021
         SPACE 2                                                        77700021
*        STORAGE                                                        78000021
         SPACE                                                          78300021
SVCNAME  DC    C'IGC0006F'         NAME OF FIRST SVC LOAD               78600021
TEST23   DC    X'F2F3'             TEST 23                              78900021
TEST28   DC    X'F2F8'             TEST 28                              79200021
MINBUF   DC    X'012C'             MINIMUM BUFFER SIZE = 300 BYTES      79500021
ZERO     DC    X'F0F0'             YY VALUE CANT BE 0                   79800021
RETRY3   DC    X'0003'             MAXIMUM NUMBER OF RETRIES            80100021
         ORG   IGG019PI+1024       MAKE MODULE 1024 BYTES LONG          80200021
*        CONTROL BLOCK DSECTS                                           80400021
         SPACE                                                          80700021
UCBDSECT DSECT                     UCB DSECT                            81000021
         DS    0F                                                       81300021
         ORG   UCBDSECT+6          ORG TO UCBFL1                        81400021
UCBFL1   DS    CL1                 UCB FLAG BYTE 1                      81500021
         ORG   UCBDSECT+13         ORG TO UNIT ADDR                     81700021
CHARADDR DS    CL3                 UNIT ADDR (EBCDIC)                   81900021
         ORG   UCBDSECT+18         ORG TO DVC CLASS AND UNIT TYPE       82200021
DVCLASS  DS    CL1                 DEVICE CLASS                         82500021
UNITYPE  DS    CL1                 UNIT TYPE                            82800021
UCBLTS   DS    CL1                                               A68753 82850021
         ORG   UCBDSECT+36         ORG TO RELATIVE LINE NUMBER          83100021
RLN      DS    CL1                 RELATIVE LINE NUMBER                 83400021
         DCBD  DSORG=BX,DEVD=BS                                         83700021
         IECTDEBX                                                       84000021
         IECTIOBX                                                       84300021
         IECTDECB                                                       84600021
RFTMSG   DSECT                                                          84900021
SOHPERC  DS    CL2                 SOH% HEADER                          85200021
TESTNUMB DS    CL2                 XX VALUE                             85500021
PASSCNT  DS    CL2                 YY VALUE                             85800021
ADBYTCNT DS    CL1                 N VALUE                              86100021
CUUADDR  DS    CL3                 CUU ADDRESS                          86400021
         END                                                            86700021
