         TITLE 'IGG019UP - ASYNCHRONOUS READY PROCESSOR 05/01/73'       00004021
IGG019UP CSECT                                                          00010021
* /* START OF SPECIFICATIONS ****                                       00050021
*                                                                       00100021
*01*  MODULE-NAME = IGG019UP (OS/360 CQ513)                             00150021
*01*  COPYRIGHT = NONE                                                  00250021
*01*  STATUS = 00                                                       00300021
*01*  CHANGE-ACTIVITY = NONE                                            00350021
*01*  DESCRIPTIVE-NAME = LOCAL 3270 READY ROUTINE                       00400021
*01*  FUNCTION = PROCESS ASYNCHRONOUS DE INTERRUPTS FROM 3270 LOCAL     00450021
*     DEVICES. ROUTINE IS ASYNCHRONOUSLY SCHEDULED BY FIRST LEVEL       00460021
*     ATTENTION ROUTINE (IECTATEN) IF: 1) THE USER SPECIFIED 'READYQ=0' 00470021
*     IN A DCB MACRO INSTRUCTION FOR A LOCAL 3270 LINE GROUP, 2) THE    00480021
*     USER HAS ATTEMPTED TO OPEN THE PREVIOUSLY MENTIONED LINE GROUP,   00490021
*     3) AND THE DEVICE FROM WHICH AN UNSOLICITED DEVICE END INTERRUPT  00492021
*     IS RECEIVED WAS NOT READY (INTERVENTION REQUIRED) AT OPEN TIME;   00494021
*     OR AN INTERVENTION REQUIRED CONDITION HAS PREVIOUSLY BEEN         00496021
*     DETECTED BY LOCAL 3270 ERP'S FOR A DEVICE WHICH HAD BEEN IN USE   00498021
*     AND AN UNSOLICITED DEVICE END INTERRUPT IS RECEIVED.              00498421
*01*  NOTES = STANDARD CODING PRACTICES, AS DESCRIBED BY SDD            00500021
*     PROGRAMMING STANDARDS, ARE FOLLOWED.                              00510021
*02*    DEPENDENCIES = NONE                                             00550021
*02*    PERFORMANCE = NOT APPLICABLE                                    00600021
*02*    RESTRICTIONS = NONE                                             00650021
*02*    REGISTER-CONVENTIONS = SEE EQUATES IMMEDIATLY FOLLOWING THIS    00700021
*       PROLOG                                                          00710021
*02*    PATCH-LABEL = MAINPTCH                                          00750021
*01*  MODULE-TYPE = MODULE                                              00800021
*02*    PROCESSOR = ASSEMBLER                                           00810021
*02*    MODULE-SIZE = 200 BYTES                                         00830021
*02*    ATTRIBUTES = REENTERABLE                                        00840021
*01*  ENTRY = IGG019UP                                                  00844021
*02*    PURPOSE = ENTERED AT FIRST EXECUTABLE INSTRUCTION VIA           00846021
*       SCHEDULING OF IRB                                               00846421
*02*    LINKAGE = BALR                                                  00848021
*02*    INPUT = REGISTER ONE CONTAINS THE RLN OF THE DEVICE WHICH CAME  00848821
*       READY IN THE HIGH BYTE AND THE ADDRESS OF THE DEB FOR THE LINE  00848921
*       GROUP. THIS COMES FROM THE IQE PARAMETER FIELD WHERE IT WAS     00849021
*       PLACED BY IECTATEN BEFORE BRANCHING TO THE ASYNCHRONOUS EXIT    00849121
*       EFFECTOR STAGE 2 TO SCHEDULE THIS ROUTINE.                      00849221
*02*    OUTPUT = IF A READ INITIAL WAS PENDING FOR THE LINE GROUP, A    00849621
*       RESETPL WILL HAVE BEEN DONE. OTHERWISE, THE UCBGRAF FIELD WILL  00852421
*       HAVE BEEN SET SUCH THAT THE NEXT READ INITIAL FOR THIS LINE     00854421
*       GROUP WILL RESULT IN A RESETPL TYPE COMPLETION. THE DECB WILL   00854821
*       HAVE BEEN MODIFIED AS FOLLOWS (IN EITHER CASE): 1) DECFLAGS     00855221
*       WILL CONTAIN A X'F0', 2) DECPOLPT WILL CONTAIN THE RLN OF THE   00855321
*       DEVICE WHICH CAME READY. IN THE EVENT OF MULTIPLE DEVICES IN    00858321
*       THE SAME LINE GROUP COMING READY, THEY WILL BE PROCESSED        00860321
*       SIMILARLY TO ATTENTIONS. THAT IS TO SAY, ONE WILL BE PROCESSED  00860721
*       FOR EACH READ INITIAL ISSUED TO THE LINE GROUP, THE SEARCH FOR  00861121
*       A READY DEVICE BEGINNING WITH THE RLN SPECIFIED IN THE READ     00861521
*       INSTRUCTION.                                                    00862221
*02*    EXIT-NORMAL = BRANCH RETURN ON THE ENTRY CONTENTS OF REGISTER   00863821
*       14                                                              00865821
*02*    EXIT-ERROR = NONE                                               00867621
*01*  EXTERNAL-REFERENCES = SEE FOLLOWING:                              00873621
*02*    ROUTINES = NONE                                                 00876621
*02*    DATA-SETS = NONE                                                00880621
*02*    DATA-AREA = UCB, DEB, DCB, DECB, IOB                            00883021
*01*  TABLES = NONE                                                     00883221
*01*  MACROS = RESETPL IECTUCBX IECTIOBX IECTDEBX IECTDECB              00888821
*                                                                       00894421
**** END OF SPECIFICATIONS ***/                                         00900021
*                                                                       01050021
*              EQUATE THE GENERAL REGISTERS                             01100021
*                                                                       01150021
RPARM0   EQU   0                   PARAMETER REGISTER 0                 01200021
RPARM1   EQU   1                   PARAMETER REGISTER 1                 01250021
REVN     EQU   2                   EVEN OF ARITHMETIC PAIR              01300021
RODD     EQU   3                   ODD OF ARITHMETIC PAIR               01350021
RRLN     EQU   4                   RLN SAVE REGISTER                    01400021
RDEB     EQU   5                   DEB SAVE REGISTER                    01450021
RSAVE    EQU   6                   RETURN POINT SAVE REGISTER           01500021
RUCB     EQU   7                   UCB ADDRESS REGISTER                 01550021
RDECB    EQU   8                   DECB ADDRESS REGISTER                01600021
RWORK1   EQU   9                   WORK REGISTER                        01650021
RWORK2   EQU   10                  WORK REGISTER                        01700021
RIC      EQU   11                  CHARACTER REGISTER                   01750021
RBASE    EQU   12                  BASE REGISTER                        01800021
RWORKD   EQU   13                  UTILITY REGISTER                     01850021
RRTRN    EQU   14                  LINK REGISTER                        01900021
REP      EQU   15                  ENTRY POINT REGISTER                 01950021
RROUTE   EQU   15                  ROUTING REGISTER FOR SVC 116         02000021
*                                                                       02050021
         SPACE 3                                                        02100021
*                                                                       02150021
*              EQUATE THE CONSTANTS                                     02200021
*                                                                       02250021
ONE      EQU   1                   NUMBER 1                             02300021
TWO      EQU   2                   NUMBER 2                             02350021
THREE    EQU   3                   NUMBER 3                             02400021
FOUR     EQU   4                   NUMBER 4                             02450021
FIVE     EQU   5                   NUMBER 5                             02500021
SIX      EQU   6                   NUMBER 6                             02550021
SEVEN    EQU   7                   NUMBER 7                             02600021
EIGHT    EQU   8                   NUMBER 8                             02650021
NINE     EQU   9                   NUMBER 9                             02700021
TEN      EQU   10                  NUMBER 10                            02750021
*                                                                       02800021
*               GRAPHICS STATUS FIELD FLAGS                             02850021
*                                                                       02900021
OPENINIT EQU   X'80'               OPEN IS IN PROGRESS                  02950021
OPENRDY  EQU   X'40'               DEVICE CAME READY DURING OPEN        03000021
DVCRDY   EQU   X'20'               DEVICE CAME READY - NOT IN OPEN      03050021
BTAMROUT EQU   X'10'               USING IGG019UP                       03100021
USERROUT EQU   X'08'               USING USER WRITTEN EXIT              03150021
*                                  NOTE: THIS FLAG SHOULD NEVER BE      03200021
*                                  ON UPON ENTRY TO IGG019UP            03250021
RDYNDONE EQU   X'04'               PROCESSING OF 'DEVICE CAME READY     03300021
*                                  CONDITION' NOT COMPLETE              03350021
DVCNRDY  EQU   X'02'               DEVICE HAS RETURNED INTERVENTION     03400021
*                                  REQUIRED (SET BY IGG0194P IF         03450021
*                                  DETECTED DURING OPEN OR              03500021
*                                  IGE0210E IF SUBSEQUENT TO OPEN)      03550021
RSVED    EQU   X'01'               FLAG RESERVED FOR BTAM'S USE         03600021
*                                                                       03650021
*              GRAPHICS CONTROL BYTE FLAGS                              03700021
*                                                                       03750021
ONLINTST EQU   X'80'               ONLINE TEST CURRENTLY HAS THE        03800021
*                                  DEVICE                               03850021
DEERR    EQU   X'40'               DEVICE END WITH ERROR                03860021
*                                  IN IECTATEN                          03870021
RDTIACTV EQU   X'08'               READ TI ACTIVE FLAG (SET BY          03900021
*                                  IECTSVC FOR DURATION OF READ         03950021
*                                  INITIAL)                             04000021
RDTIPEND EQU   X'04'               READ TI PENDING (SET BY IECTSVC      04050021
*                                  IF NO ATTENTIONS AT INITIATION       04100021
*                                  OF READ INITIAL, RESET BY            04150021
*                                  IECTATEN WHEN IGG019PG IS            04200021
*                                  SCHEDULED TO ACTUALLY PERFORM        04250021
*                                  THE EXCP FOR THE READ)               04300021
SKIP     EQU   X'02'               DO NOT HONOR ATTENTIONS FROM         04350021
*                                  DEVICE FOR READ TI'S                 04400021
ATTEN    EQU   X'01'               ATTENTION RECEIVED FROM DEVICE       04450021
*                                                                       04500021
*              OTHER EQUATES                                            04550021
*                                                                       04600021
ALLON    EQU   X'FF'               ALL BITS IN A BYTE                   04610021
NOBITS   EQU   X'00'               ALL BITS OFF IN A BYTE               04620021
READY    EQU   X'F0'               DECFLAGS FOR READY DEVICE            04630021
SADENERR EQU   X'80'               IOBINCAM OPEN FAIL BIT               04640021
         EJECT                                                          04650021
         BALR  RBASE,0             ESTABLISH BASE REGISTER              04700021
         USING *,RBASE             AND ASSEMBLER ADDRESSABILITY         04750021
         B     PASTID              BRANCH AROUND ID           NOW       04760021
         DC    C'IGG019UP'         TO LOCATE IN DUMP                    04770021
PASTID   EQU   *                   AROUND ID                            04780021
         LR    RSAVE,RRTRN         SAVE RETURN ADDRESS                  04800021
         XR    RRLN,RRLN           CLEAN RLN REGISTER                   04850021
         LR    RDEB,RPARM1         SAVE DEB AND RLN                     04900021
         SLDL  RRLN,EIGHT          PLUG RLN                             04950021
         SRL   RDEB,EIGHT          PUT DEB ADDRESS BACK                 05000021
         USING IECTDEB+36,RDEB     ESTABLISH DEB ADDRESSABILITY         05050021
         LR    RODD,RRLN           GET THE RLN                          05150021
         BCTR  RODD,0              REDUCE BY ONE                        05160021
         LA    REVN,FOUR           GET LENGTH OF EXTENT                 05200021
         MR    REVN,REVN           RODD CONTAINS DISPLACEMENT           05250021
*                                  FROM DEB EXTENT LIST TO              05300021
*                                  EXTENT FOR THIS DEVICE               05350021
         L     RUCB,DEBUCBAD(RODD) GET THE UCB ADRESS                   05400021
         LA    RUCB,0(RUCB)        INSURE HIGH BYTE CLEAR               05450021
         L     RWORK1,DEBUCBAD     GET MASTER UCB ADDRESS               05500021
         LA    RWORK1,0(RWORK1)    INSURE HIGH BYTE CLEAR               05550021
         USING UCB,RUCB            ESTABLISH UCB ADDRESSABILITY         05600021
         USING MSTRUCB,RWORK1      ESTABLISH MASTER ADDRESSABILITY      05650021
         TM    UCBGRAF,DVCRDY      THIS DEVICE COME READY ?             05700021
         BNO   CANTDO              NO, CAN'T PROCESS THIS DEVICE        05750021
         CLI   MTRINRLN,NOBITS     INITIALIZED ?                        05800021
         BE    CANTDO              NO, NO IOB TO USE                    05850021
         XR    RWORKD,RWORKD       CLEAR REG                            05860021
         IC    RWORKD,MTRINRLN     GET INIT RLN                         05870021
         L     RWORK2,MTRDEBAD     GET THE DEB ADDRESS                  05900021
         LA    RWORK2,0(RWORK2)    INSURE HIGH BYTE CLEAR               05950021
         CR    RDEB,RWORK2         DEB SAME AS PASSED ?                 06000021
         BNE   CANTDO              NO, CONTROL BLOCKS MESSED UP         06050021
         OI    MTRGRAF,RDYNDONE    SET READY NOT DONE                   06060021
         DROP  RWORK1              DON'T NEED MASTER ANY MORE           06100021
         L     RWORK1,DEBPROTG     GET THE DCB ADDRESS                  06150021
         LA    RWORK1,0(RWORK1)    INSURE HIGH BYTE CLEAR               06200021
         USING IHADCB,RWORK1       ESTABLISH DCB ADDRESSABILITY         06250021
         L     RWORK2,DCBIOBAD     GET ADDRESS OF IOB POOL              06300021
         LR    RODD,RWORKD         GET RLN                              06400021
         XR    REVN,REVN           CLEAN EVEN REGISTER                  06450021
         IC    REVN,DCBEIOBX       GET SIZE OF IOB                      06500021
         LR    RWORKD,RWORK1       SAVE DCB ADDRESS                     06510021
         DROP  RWORK1              DON'T NEED DCB ANYMORE               06550021
         MR    REVN,REVN           RODD CONTAINS DISPLACEMENT           06600021
*                                  FROM TOP OF IOB POOL TO              06650021
*                                  IOB FOR THIS DEVICE                  06700021
         LA    RWORK1,0(RODD,RWORK2) GET IOB ADDRESS                    06750021
         USING IECTIOB,RWORK1      ESTABLISH IOB ADDRESSABILITY         06800021
         L     RWORK2,IOBECBPT     GET DECB ADDRESS                     06850021
         LA    RWORK2,0(RWORK2)    INSURE HIGH BYTE CLEAR               06900021
         USING IECTDECB,RWORK2     ADDRESS DECB                         06902021
         STC   RRLN,DECRLN         UPDATE RLN TO READY DEVICE           06910021
         DROP  RWORK2              DON'T NEED DECB UNTIL AFTER RESETPL  06920021
         DROP  RWORK1              DON'T NEED IOB ANYMORE               06950021
         RESETPL (RWORK2),ATTENT                                        07000021
         LTR   REP,REP             RETURN ZERO ?                        07050021
         BNZ   OPENOF              NO, DON'T RESET FLAGS                07100021
         USING IECTDECB,RWORK2     ESTABLISH DECB ADDRESSABILITY        07250021
         NI    DECFLAGS,NOBITS     RESET THE FLAGS                      07300021
         OI    DECFLAGS,READY      SET DEVICE CAME READY                07350021
         STC   RRLN,DECPOLPT+THREE    PLUG THE RLN              SA68748 07400021
OPENOF   EQU   *                   RESET SAD/ENABLE FAILED IN IOB       07402021
         USING IHADCB,RWORKD       ESTABLISH DCB ADDRESSABILITY         07410021
         L     RWORK2,DCBIOBAD     GET ADDRESS OF IOB POOL              07420021
         LR    RODD,RRLN           GET RLN                              07430021
         XR    REVN,REVN           CLEAR EVEN REG                       07440021
         IC    REVN,DCBEIOBX       GET SIZE OF IOB                      07442021
         DROP  RWORKD              DON'T NEED DCB ANY MORE              07444021
         MR    REVN,REVN           RODD CONTAINS DISPLACEMENT           07446021
*                                  FROM TOP OF IOB POOL TO              07448021
*                                  IOB FOR THIS DEVICE                  07448421
         LA    RWORK1,0(RODD,RWORK2) GET IOB ADDRESS                    07448821
         USING IECTIOB,RWORK1      ESTABLISH IOB ADDRESSABILITY         07449221
         NI    IOBINCAM,ALLON-SADENERR TURN OFF SAD ENABLE FAILED       07449621
         DROP  RWORK1              DON'T NEED IOB ANYMORE               07449721
CANTDO   EQU   *                   PROCESSING COMPLETE                  07450021
         LR    RRTRN,RSAVE         PICK UP RETURN POINT                 07500021
         BR    RRTRN               RETURN TO AEE2                       07550021
MAINPTCH DS    50F                 DEFINE A PATCH AREA                  07560021
         ORG   IGG019UP+1024                                            07570021
         EJECT                                                          07600021
         IECTUCBX                                                       07650021
         IECTIOBX                                                       07700021
         IECTDEBX                                                       07750021
         IECTDECB                                                       07800021
         DCBD  DSORG=BX                                                 07850021
         END   IGG019UP                                                 07900021
