         TITLE 'BREAKOFF ROUTINE (BREAKOFF)'                            00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKBRKF   QTAM BREAKOFF ROUTINE  (BREAKOFF).                     * 03000013
*                                                                     * 03600013
*STATUS- CHANGE LEVEL= 17          JANUARY 1971                       * 04200021
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        IECKBRKF WILL KEEP TRACK OF THE TOTAL LENGTH OF A MESSAGE    * 06000013
*   AND TERMINATE THE MESSAGE IF IT EXCEEDS THE MAXIMUM LENGTH        * 06600013
*   SPECIFIED AS AN OPERAND OF THE BREAKOFF MACRO9  THE MESSAGE WILL  * 07200013
*   ALSO BE TERMINATED IF ALL THE CHARACTERS ARE IDENTICAL.           * 07800013
*        WHEN A SEGMENT IS RECEIVED. A TEST IS MADE TO SEE IF IT IS   * 08400013
*   A TEXT SEGMENT.  IF IT IS NOT A TEXT SEGMENT, THE LENGTH OF THE   * 09000013
*   PREFIX AND EXPANSION FIELDS ARE SUMMED.  THIS VALUE IS ADDED TO   * 09600013
*   THE ADDRESS OF THE BUFFER TO GIVE THE ADDRESS OF THE SECOND BYTE  * 10200013
*   OF THE HEADER.  IF THE SEGMENT WAS A TEXT SEGMENT, THEN THIS      * 10800013
*   ADDRESS WOULD ALREADY BE AVAILABLE.                               * 11400013
*        THE ADDRESS OF THE SECOND BYTE OF THE HEADER IS SUBTRACTED   * 12000013
*   FROM THE END OF SEGMENT ADDRESS TO YIELD THE LENGTH OF THE DATA   * 12600013
*   FIELD - 2 IN THIS SEGMENT9  IF THE RESULTING LENGTH IS NEGATIVE,  * 13200013
*   THE RECEIVE BIT AT LCBSTATE ( LCB + 0) IS SET.                    * 13800013
*        IF THE LENGTH WAS NON-NEGATIVE, THE CHARACTERS ARE COMPARED. * 14400013
*   IF THE CHARACTERS ARE ALL IDENTICAL, THE RECEIVE BIT AT LCBSTATE  * 15000013
*   IS TURNED OFF UNLESS A PROGRAM CHECK OCCURED.  IF A CHANNEL       * 15300021
*   PROGRAM CHECK OCCURED BECAUSE OF INSUFFICIENT BUFFERS, RETURN IS  * 15600021
*   MADE TO USER.                                                     * 15900021
*        IF THE CHARACTERS WERE NOT IDENTICAL, THE LENGTH OF THIS     * 16200013
*   SEGMENT IS ADDED TO THE MESSAGE SUBTOTAL AT LCBERRCT (LCB + 78).  * 16800013
*   THIS NEW SUBTOTAL IS COMPARED AGAINST THE MAXIMUM MESSAGE LENGTH  * 17400013
*   SUPPLIED BY THE USER.  IF THIS MESSAGE IS LONGER THAN THIS        * 18000013
*   MAXIMUM, THE RECEIVE BIT IS TURNED OFF.                           * 18600013
*        A TEST IS MADE FOR END OF MESSAGE CHARACTER. IF IT HAS NOT   * 19200013
*   BEEN RECEIVED, CONTROL RETURNS TO THE CALLING ROUTINE.  THIS      * 19800013
*   PORTION OF THE MODULE IS REPEATED UNTIL THE END OF MESSAGE        * 20400013
*   CHARACTER IS FOUND.                                               * 21000013
*        ONCE END OF MESSAGE IS FOUND, A TEST WILL BE MADE TO SEE     * 21600013
*   IF A PROGRAM CHECK HAS OCCURRED.  THIS WILL ARISE FROM HAVING     * 22200013
*   THE RECEIVE BIT OFF, THUS NOT ALLOWING A BUFFER TO BE ASSIGNED.   * 22800013
*   A PROGRAM CHECK WILL NOT OCCUR IF THE MESSAGE IS ACCEPTABLE.  IF  * 23400013
*   THE MESSAGE IS ACCEPTABLE, CONTROL RETURNS TO THE NEXT LPS        * 24000013
*   INSTRUCTION.                                                      * 24600013
*        IF A PROGRAM CHECK HAS OCCURRED, HOUSEKEEPING IS PERFORMED   * 25200013
*   TO SET UP FOR THE WRITING OF BREAKOFF CHARACTERS.  THE            * 25800013
*   UCB IS OBTAINED TO CHECK FOR 2848/2701.  A READ SKIP/WRITE BREAK  * 25900021
*   IS SET UP FOR 2848/2701. FOR DIAL LINES A WRITE BREAK/DISABLE     * 26000021
*   IS SET UP IN THE CCWS IN THE BREAK OFF ROUTINE. THE               * 26100021
*   CHARACTERS ARE WRITTEN AND CONTROL IS PASSED TO THE LPS CONTROL   * 26400013
*   ROUTINE.                                                          * 27000013
*                                                                     * 27600013
*ENTRY POINTS-                                                        * 28200013
*   IECKBRKF - CONTROL IS PASSED HERE BY THE CODE GENERATED BY THE    * 28800013
*        EXPANSION OF THE BREAKOFF MACRO.  REGISTER 15 HOLDS THE      * 29400013
*        ADDRESS OF THIS ENTRY POINT, AND REGISTER 14 HOLDS THE       * 30000013
*        RETURN ADDRESS.                                              * 30600013
*                                                                     * 31200013
*INPUT-                                                               * 31800013
*   REGISTER 11- ADDRESS OF END OF SEGMENT.                           * 32400013
*   REGISTER 14- RETURN ADDRESS REGISTER.                             * 33000013
*   REGISTER 14 SERVES AS THE PARAMETER REGISTER, POINTING TO THE     * 33600013
*        HALFWORD CONTAINING THE MAXIMUM MESSAGE LENGTH SPECIFIED IN  * 34200013
*        THE BREAKOFF MACRO.                                          * 34800013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 35400013
*                                                                     * 36000013
*OUTPUT-                                                              * 36600013
*   IF THE END OF MESSAGE HAS BEEN ENCOUNTERED, THE LCBERRCT FIELD    * 37200013
*        (LCB + 78) WILL HOLD THE TOTAL LENGTH OF THE MESSAGE.  IF    * 37800013
*        END OF MESSAGE HAS NOT BEEN FOUND, THIS FIELD WILL HOLD      * 38400013
*        THE SUBTOTAL.                                                * 39000013
*   IF THE MESSAGE IS LONGER THAN THE MAXIMUM ALLOWABLE, OR IF        * 39600013
*        ALL CHARACTERS IN THAT SEGMENT ARE IDENTICAL, THE RECEIVE    * 40200013
*        BIT IN THE LCBSTATE FIELD WILL BE SET TO OFF.                * 40800013
*        OTHERWISE IT IS ON.                                          * 41400013
*                                                                     * 42000013
*EXTERNAL ROUTINES-                                                   * 42600013
*   EXCP (SVC 0).                                                     * 43200013
*                                                                     * 43800013
*EXITS-                                                               * 44400013
*   NORMAL - RETURN IS TO THE NEXT LPS INSTRUCTION BY BRANCHING ON    * 45000013
*        REGISTER 14 AROUND THE MACRO GENERATED CONSTANT.             * 45600013
*   ERROR - CONTROL IS PASSED TO THE LPS CONTROL ROUTINE AFTER        * 46200013
*        BREAKOFF CHARACTERS ARE WRITTEN IF THE SEGMENT CONTAINS ALL  * 46800013
*        IDENTICAL CHARACTERS,OR IF THE TOTAL MESSAGE LENGTH IS       * 47400013
*        GREATER THAN THE MAXIMUM ALLOWABLE.                          * 48000013
*                                                                     * 48600013
*TABLES/WORK AREAS-                                                   * 49200013
*   NONE.                                                             * 49800013
*                                                                     * 50400013
*ATTRIBUTES-                                                          * 51000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 51600013
*                                                                     * 52200013
*NOTES-                                                               * 52800013
*   REGISTER  4- BASE REGISTER FOR LCB.                               * 53400013
*   REGISTER  9- WORK REGISTER.  ADDRESS OF BEGINNING OF SEGMENT.     * 54000013
*   REGISTER 10- LENGTH OF TEXT IN SEGMENT - 2.                       * 54600013
*                                                                     * 55200013
*********************************************************************** 55800013
IECKBRKF START                                                          56400013
*1171783000-792000                                                 00PS 56700016
*2540614000-616000,876700-880900,931000-934000                     7766 56800017
*0300881100-881700,934400-935600                                   00PS 56900017
*A042000,153000-159000,259000-261000                             S21016 56950021
         SPACE                                                          57000013
LCBREG   EQU   4                                                        57600013
MSREG    EQU   6                                                        58200013
WREG1    EQU   9                                                        58800013
WREG2    EQU   10                                                       59400013
EOSREG   EQU   11                                                       60000013
RREG1    EQU   14                                                       60600013
SREG     EQU   15                                                       61200013
DCBDEBAD EQU   44                                                  7766 61400017
DEBUCBAD EQU   32                                                  7766 61600017
         SPACE                                                          61800013
         USING IECKLCB0,LCBREG                                          62400013
         USING IECKPREF,MSREG                                           63000013
         USING *,SREG                                                   63600013
         SPACE                                                          64200013
         LA    WREG1,TXSTRT+1      SET REGISTER TO START OF TEXT PLUS 1 64800013
         TM    MSTATUS,1           IS THIS A TEXT SEGMENT               65400013
         BNZ   TEXT                BRANCH IF YES                        66000013
         LH    WREG1,LCBTRST       GET PREFIX SIZE PLUS ANY EXPANSION   66600013
*                                    FOR TIME AND DATE STAMP            67200013
         LA    WREG1,MSEGSZE+1(WREG1)  USING BASE OF MSREG GET ADDRESS  67800013
*                                    OF 2ND BYTE IN HEADER FOLLOWING    68400013
*                                    PREFIX AND ANY EXPANSION           69000013
TEXT     LR    WREG2,EOSREG        GET END OF SEGMENT ADDRESS           69600013
         SR    WREG2,WREG1         COMPUTE LENGTH OF DATA MINUS TWO     70200013
         BM    TESTLNG             IF NEGATIVE DONT COMPARE             70800013
         BCTR  WREG1,0             SET TO START OF DATA AFTER PREFIX    71400013
         EX    WREG2,COMPARE       COMPARE EACH CHARACTER WITH PRECEDNG 72000013
         BE    ERROR               BRANCH IF ALL CHARACTERS ARE EQUAL   72600013
         SPACE                                                          73200013
TESTLNG  LA    WREG2,2(WREG2)      BUMP BY 2 TO GET DATA LENGTH         73800013
         AH    WREG2,LCBERCCW+6         ADD IN PREVIOUS MESSAGE COUNT   74400013
         STH   WREG2,LCBERCCW+6    TO ACCUMULATIVE LENGTH AND RESTORE   75000013
         LH    WREG1,0(0,RREG1)    GET MAXIMUM LENGTH FROM THE USER     75600013
         N     WREG1,MASK          IF MAXIMUM IS ZERO DO NOT COMPARE    76200013
         BZ    TESTPRCK            BRANCH IF PASSED LENGTH IS ZERO      76800013
         CLR   WREG2,WREG1         HAS MAXIMUM LENGTH BEEN EXCEEDED     77400013
         BNH   TESTPRCK            BRANCH IF NOT EXCEEDED               78000013
ERROR    TM    LCBSTART+2,1       HAS PROGRAM CHECK OCCURED  DUE   OOPS 78300016
         BO    2(0,RREG1)         TO INSUF BUFFERS.  IF SO,RETURN  OOPS 78600016
         NI    LCBSTATE,247       TURN OFF RECEIVE BIT TO STOP     OOPS 78900016
*                                 FURTHER BUFFER ASSIGNMENTS       OOPS 79200016
*    RELATED TO TEST FOR SEND IN LPSTART TO FORCE REENTRY TO BREAKOFF   79800013
         SPACE                                                          80400013
TESTPRCK TM    MSTATUS,2           IS THIS END OF MESSAGE               81000013
         BZ    2(0,RREG1)          RETURN TO USER IF NO                 81600013
         TM    LCBCSW+5,X'20'      HAS INVALID TIC ADDRESS AS THE       82200013
*                                    RESULT OF NO BUFFER CAUSED A       82800013
*                                    PROGRAM CHECK                      83400013
         BZ    2(0,RREG1)          RETURN TO USER IF NO                 84000013
*    CONTINUE TO RETURN TO USER UNTIL PROGRAM CHECK OCCURS              84600013
         MVI   LCBCECB,0           CLEAR READ INITIAL OP CODE           85200013
         OI    LCBERRST+1,X'20'    SET BREAKOFF ERROR BIT               85800013
         OI    MSTATUS,32          SET EOB NOT LAST CHARACTER IN BUFFER 86400013
         MVC   LCBTRST,MSEGSZE     GET MESSAGE SIZE TO EOB FOR TEXT     87000013
         MVC   LCBSTART,CCW+1      SET BREAK CCW ADDRESS INTO LCBSTART  87600013
         L     WREG1,LCBDCBPT      OBTAIN DCB ADDRESS              7766 87670017
         L     WREG1,DCBDEBAD(WREG1)  OBTAIN DEB ADDRESS           7766 87740017
         L     WREG1,DEBUCBAD(WREG1) GET UCB ADDR FOR LINE GROUP   7766 87810017
         CLI   19(WREG1),X'82'    IS THIS A 2848/2701              7766 87880017
         BNE   EXCP               NO,CHANNEL PROGRAM OK            7766 87950017
         MVC   LCBSTART,CCW28+1      INDICATE SPECIAL BREAK FOR    7766 88020017
EXCP     EQU   *                     INTERRUPT HANDLING            7766 88090017
         TM    17(WREG1),X'90'     IS THIS A DIAL LINE             00PS 88110017
         BZ    SVC0                NO, CHANNEL PROGRAM OK          00PS 88130017
         MVC   LCBSTART,CCWTWX+1   ELSE DO WRITE BREAK, DISABLE    00PS 88150017
SVC0     EQU   *                                                   00PS 88170017
         LA    1,LCBFLAG1          SET IOB ADDRESS IN REGISTER 1        88200013
         SVC   0                   EXCP TO CAUSE BREAKOFF CHARACTERS    88800013
*                                    TO BE WRITTEN                      89400013
         L     WREG1,0(0,13)       GET ADDRESS OF LPS QUEUE IN IGG019NG 90000013
         B     232(0,WREG1)        BRANCH TO LPS CONTROL ROUTINE        90600013
         SPACE                                                          91200013
COMPARE  CLC   0(1,WREG1),1(WREG1) COMPARE SUCCESSIVE CHARACTERS        91800013
MASK     DC    A(65535)                                                 92400013
CCW      CCW   13,CCW,0,21         CCW TO WRITE BREAK CHARACTERS        93000013
CCW28    DC    X'42'                                               7766 93100017
         DC    AL3(CCW28)                                          7766 93200017
         DC    X'700003C0'         READ SKIP FOR 2848              7766 93300017
         DC    X'41000001200003E8' WRITE BREAK FOR 2848            7766 93400017
CCWTWX   DC    X'0D'                                               00PS 93440017
         DC    AL3(CCWTWX)                                         00PS 93480017
         DC    X'40000015'                                         00PS 93520017
         DC    X'2F00000020000002'                                 00PS 93560017
         EJECT                                                          93600013
         LCBD  QTAM=3                                                   94200013
         EJECT                                                          94800013
         PREFIXD                                                        95400013
         END                                                            96000013
