         TITLE 'IECKCHGT  QTAM CHANGE TERMINAL TABLE (CHNGT)'           00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-                                                                * 01600013
*   IECKCHGT   QTAM CHANGE TERMINAL TABLE (CHNGT)                     * 02000013
*                                                                     * 02400013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 02800013
*                                                                     * 03200013
*FUNCTION-                                                            * 03600013
*        IECHCHGT WILL REPLACE A TERMINAL TABLE ENTRY WITH A NEW      * 04000013
*   ENTRY SUPPLIED BY THE CALLING ROUTINE.                            * 04400013
*        AFTER THE REGISTERS ARE SAVED, THE ADDRESS OF THE TERMINAL   * 04800013
*   TABLE IS LOADED INTO A WORK REGISTER.  THE ADDRESS OF THE END     * 05200013
*   OF THE TABLE IS LOADED INTO ANOTHER WORK REGISTER, AND THE        * 05600013
*   ADDRESS OF THE FIRST ENTRY IN ANOTHER WORK REGISTER.  THE TERMINAL* 06000013
*   TABLE IS SEARCHED FOR THE PROPER TERMINAL ENTRY.  IF THE ENTRY    * 06400013
*   IS NOT FOUND, A CODE OF X'20' IS SET IN REGISTER 15 AND CONTROL   * 06800013
*   RETURNS TO THE NEXT MESSAGE PROCESSING PROGRAM INSTRUCTION.       * 07200013
*        IF THE ENTRY IS FOUND, THE LENGTH OF THE NEW INFORMATION     * 07600013
*   IS COMPARED WITH THAT TABLE ENTRY. IF NOT EQUAL, A CODE OF X'10'  * 08000013
*   IS PASSED BACK TO THE CALLING ROUTINE.                            * 08400013
*        IF THE QCB FOR THE TERMINAL TABLE IS NOT A DESTINATION       * 08800013
*   QUEUE, OR A STOPLN HAS BEEN ISSUED, THE CROSS PARTITION MOVE IS   * 09200013
*   EXECUTED TO ENTER THE NEW INFORMATION IN THE TERMINAL TABLE.      * 09600013
*        IF THE QCB IS A DESTINATION QUEUE, AND A STOPLN HAS NOT      * 10000013
*   BEEN ISSUED, THE MOVE IS MADE IN TWO OPERATIONS, PRESERVING THE   * 10400013
*   SEQUENCE NUMBER.                                                  * 10800013
*                                                                     * 11200013
*ENTRY POINTS-                                                        * 11600013
*   IECKCHGT - EXPANSION OF THE CHNGT MACRO GENERATES A BALR TO THIS  * 12000013
*        POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER, AND    * 12400013
*        REGISTER 14 AS THE RETURN ADDRESS REGISTER.                  * 12800013
*                                                                     * 13200013
*INPUT-                                                               * 13600013
*   REGISTER  0- CONTAINS THE ADDRESS OF THE CALLING ROUTINE'S WORK   * 14000013
*        AREA CONTAINING THE NEW TERMINAL TABLE ENTRY.                * 14400013
*   REGISTER  1- CONTAINS THE ADDRESS OF THE NAME OF THE TERMINAL     * 14800013
*        TABLE ENTRY TO BE CHANGED.                                   * 15200013
*   REGISTER 14- RETURN ADDRESS.                                      * 15600013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 16000013
*                                                                     * 16400013
*OUTPUT-                                                              * 16800013
*   IF NO ERRORS OCCUR, THE NEW ENTRY WILL BE IN THE TERMINAL         * 17200013
*   TABLE.                                                            * 17600013
*                                                                     * 18000013
*                                                                     * 18400013
*EXTERNAL ROUTINES-                                                   * 18800013
*   QPOST (IGG067 IN MODULE IECKQQ01).                                * 19200013
*   CROSS PARTITION MOVE (QMOVER + 6 IN MODULE IGG019NG).             * 19600013
*                                                                     * 20000013
*EXITS-                                                               * 20400013
*   NORMAL - RETURN IS TO THE NEXT PROCESSING PROGRAM INSTRUCTION,    * 20800013
*        WITH RETURN CODE OF X'00' IN LOW ORDER BYTE OF REGISTER 15.  * 21200013
*   ERROR - SAME AS ABOVE, BUT WITH ONE OF THE FOLLOWING ERROR CODES  * 21600013
*        IN REGISTER 15:                                              * 22000013
*        X'10'- INVALID COUNT SPECIFIED                               * 22400013
*        X'20'- INVALID TERMINAL TABLE ENTRY SPECIFIED.               * 22800013
*                                                                     * 23200013
*TABLES/WORK AREAS-                                                   * 23600013
*   NONE.                                                             * 24000013
*                                                                     * 24400013
*ATTRIBUTES-                                                          * 24800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 25200013
*                                                                     * 25600013
*NOTES-                                                               * 26000013
*   REGISTER  0- WORK REGISTER.  WILL CONTAIN THE ADDRESS OF THE END  * 26400013
*        OF THE TERMINAL TABLE.                                       * 26800013
*   REGISTER  1- WORK REGISTER.  WILL CONTAIN THE ADDRESS OF QMOVER.  * 27200013
*   REGISTER  2- WORK REGISTER.  WILL CONTAIN THE ADDRESS OF THE      * 27600013
*        CALLING ROUTINE'S NEW ENTRY.                                 * 28000013
*   REGISTER  3- WORK REGISTER.  WILL CONTAIN THE SIZE OF THE TERMINAL* 28400013
*        TABLE ENTRY.                                                 * 28800013
*   REGISTER  4- WORK REGISTER.  WILL CONTAIN THE LENGTH OF THE TERMID* 29200013
*        FIELD.                                                       * 29600013
*   REGISTER  5- WORK REGISTER.  WILL HOLD THE ADDRESS OF THE         * 30000013
*        COMMUNICATIONS VECTOR TABLE.                                 * 30400013
*   REGISTER  6- WORK REGISTER.  WILL HOLD THE ADDRESS OF THE         * 30800013
*        TERMINAL TABLE.                                              * 31200013
*   REGISTER  7- WORK REGISTER. WILL HOLD THE ADDRESS OF IGG019NG.    * 31600013
*   REGISTER  8- WORK REGISTER. WILL HOLD THE ERROR FLAG.             * 32000013
*                                                                     * 32400013
*********************************************************************** 32800013
IECKCHGT START                                                          33200013
R0       EQU   0                                                        33600013
PLREG    EQU   1                                                        34000013
WORKREG  EQU   2                                                        34400013
XREG     EQU   3                                                        34800013
WREG     EQU   4                                                        35200013
RD       EQU   5                                                        35600013
TERMREG  EQU   6                                                        36000013
NGQUE    EQU   7                                                        36400013
FLAG     EQU   8                                                        36800013
MREG     EQU   9                                                        37200013
LCBREG   EQU   9                                                        37600013
DCBREG   EQU   10                                                       38000013
RLNR     EQU   11                                                       38400013
QCBREG   EQU   12                                                       38800013
RETURN   EQU   14                                                       39200013
SREG     EQU   15                                                       39600013
QPOST    EQU   67                                                       40000013
         USING IECKTERM,TERMREG                                         40400013
         USING QBLOCK,QCBREG                                            40800013
         USING IHADCB,DCBREG                                            41200013
         USING LCB,LCBREG                                               41600013
         USING *,SREG                                                   42000013
         SAVE  (14,12)                                                  42400013
         SR    XREG,XREG           CLEAR WORKING REGISTER               42800013
         SR    FLAG,FLAG           CLEAR ERROR INDICATOR                43200013
         L     RD,CVTABLE(0,0)     GET ADDRESS OF THE COMMUNICATIONS    43600013
*                                    VECTOR TABLE (CVT)                 44000013
         L     TERMREG,CVTTRMTB(0,RD) GET TERMTBL ADDRESS FROM CVT      44400013
         LR    WORKREG,R0          GET THE WORKAREA ADDRESS             44800013
         L     R0,0(0,TERMREG)     GET END OF TABLE ADDRESS             45200013
         IC    WREG,4(0,TERMREG)   GET LENGTH OF TERMID FIELD           45600013
         L     NGQUE,4(TERMREG)        LOAD ADDRESS OF IGG019NG         46000013
         L     NGQUE,0(NGQUE)          ADDRESS OF QUEUES                46400013
         LA    TERMREG,8(0,TERMREG) BUMP TO 1ST ENTRY IN TERMTBL        46800013
         BCTR  WREG,0              DECREMENT BY ONE FOR EXECUTE         47200013
LOOKUP   EX    WREG,COMPID         CAUSE TERMNAME TO BE COMPARED        47600013
         IC    XREG,TNTRYSZE       GET SIZE OF TERMTBL ENTRY            48000013
         BNE   LAST                IF NOT EQUAL BRANCH                  48400013
         CLC   0(1,WORKREG),TNTRYSZE COMPARE ENTRY SIZES                48800013
         BE    LNGTHOK             BRANCH IF NEW LENGTH EQUAL TO OLD    49200013
         LA    FLAG,X'10'          ELSE SET ERROR FLAG                  49600013
         B     RET                 AND RETURN TO USER                   50000013
         SPACE                                                          50400013
COMPID   CLC   0(1,PLREG),TERMID   COMPARE TERMNAME TO TABLE TERMID     50800013
LAST     CR    TERMREG,R0          IS IT LAST ENTRY                     51200013
         BE    INVALID             BRANCH IF YES                        51600013
         CLI   TNTRYSZE,0          IS SIZE EQUAL ZERO                   52000013
         BE    INVALID             BRANCH IF YES                        52400013
         LA    TERMREG,0(XREG,TERMREG) ELSE BUMP TO NEXT ENTRY          52800013
         B     LOOKUP              RELOOP TO LOOK AT NEXT ENTRY         53200013
         SPACE                                                          53600013
LNGTHOK  LR    WREG,TERMREG        SET THE ADDRESS TO BE ALTERED        54000013
         LR    RD,WORKREG          SET THE WORKAREA ADDRESS             54400013
         L     PLREG,284(NGQUE)    LOAD ADDRESS OF QMOVE                54800013
         LA    PLREG,0(PLREG)      CLEAR THE HIGH ORDER BYTE            55200013
         LR    WORKREG,PLREG       LOAD QCB ADDRESS                     55600013
         L     QCBREG,TQCBADDR-1   GET ADDRESS OF DESTINATION QUEUE QCB 56000013
         CLI   8(QCBREG),X'68'     IS THIS A DESTINATION QUEUE          56400013
*                                    (MAY BE PROCESS QUEUE OR MESSAGE   56800013
*                                    RESPONSE TRANSFER QUEUE)           57200013
         BNE   INACTIVE        BRANCH IF NOT TERMINAL DESTINATION QUEUE 57600013
         L     DCBREG,QRLN         GET RELATIVE LINE NUMBER (RLN) AND   58000013
*                                    DCB ADDRESS FROM QCB               58400013
         LR    RLNR,DCBREG         LOAD RLN REGISTER                    58800013
         SRL   RLNR,24             AND SHIFT RLN TO LOW ORDER BYTE      59200013
         SR    MREG,MREG           CLEAR WORK REGISTER                  59600013
         IC    MREG,DCBEIOBX       GET LCB/IOB SIZE FROM DCB            60000013
         MR    FLAG,RLNR           GET LCB/IOB SIZE TIMES RLN           60400013
         L     FLAG,DCBLCBAD       GET THE LCB ADDRESS                  60800013
         LA    LCBREG,0(FLAG,MREG)     ADD IN START OF LCB'S            61200013
         SR    FLAG,FLAG           RESTORE ERROR REGISTER               61600013
         CLI   LCBSTATE,0          IS THE LINE ACTIVE                   62000013
*    IF STOPLINE HAS BEEN ISSUED FOR THIS LINE THEN THE MESSAGE         62400013
*    SEQUENCE NUMBERS IN THE TERMTBL ENTRY WILL NOT HAVE BEEN           62800013
*    INCREMENTED SINCE THE ENTRY WAS COPIED INTO THE WORKAREA.          63200013
*    THEREFORE THE ENTIRE ENTRY CAN BE CHANGED WITH ONE MOVE.  IF       63600013
*    STOPLINE HAS NOT BEEN ISSUED THE SEQUENCE NUMBERS MAY HAVE         64000013
*    BEEN INCREMENTED SINCE THE ENTRY WAS COPIED INTO THE WORKAREA,     64400013
*    SO THE MOVE MUST NOT DESTROY THE NEW SEQUENCE NUMBERS.  THEREFORE  64800013
*    THE CHANGE IS MADE IN 2 MOVES LEAVING THE SEQUENCE NUMBERS INTACT. 65200013
         BE    INACTIVE            BRANCH IF LINE NOT ACTIVE            65600013
         LA    XREG,2              GET LENGTH-2 FOR EXECUTE MOVE        66000013
*                                    (THE LENGTH BYTE IS NOT MOVED      66400013
*                                    THEREFORE THE FOLLOWING RESULTS    66800013
*                                    IN TQCBADDR BEING CHANGED)         67200013
         SVC   QPOST               POST QCB TO ITSELF RESULTING IN MOVE 67600013
         LA    RD,7(RD)            BYPASS SEQUENCE NUMBERS IN WORKAREA  68000013
         LA    WREG,7(WREG)        BYPASS SEQUENCE NUMBERS IN ENTRY     68400013
         IC    XREG,TNTRYSZE       GET SIZE OF TABLE ENTRY              68800013
         LA    XREG,256+TNTRYSZE-TERMID(XREG)  SUBTRACT 9 FOR REMAINDER 69200013
         SVC   QPOST               POST QCB TO ITSELF RESULTING IN MOVE 69600013
         B     RET                 RETURN TO USER                       70000013
INACTIVE IC    XREG,TNTRYSZE       GET ENTRY SIZE                       70400013
         BCTR  XREG,0              DECREMENT LENGTH FOR EXECUTE MOVE    70800013
         BCTR  XREG,0              DECREMENT SO THAT TNTRYSZE (LENGTH)  71200013
*                                    IS NOT DISTURBED                   71600013
         SVC   QPOST               POST QCB TO ITSELF RESULTING IN MOVE 72000013
         B     RET                 RETURN TO USER                       72400013
         SPACE                                                          72800013
INVALID  LA    FLAG,X'20'          SET ERROR FOR INVALID TERMINAL       73200013
*                                    TABLE ENTRY                        73600013
RET      LR    SREG,FLAG           SET USER'S ERROR INDICATOR           74000013
         RETURN (0,12)             AND RETURN TO THE USER               74400013
         SPACE                                                          74800013
CVTABLE  EQU   16                                                       75200013
CVTTRMTB EQU   156                                                      75600013
         SPACE 2                                                        76000013
*  THE FOLLOWING ERROR INDICATORS ARE SET FOR THE USER IN THIS ROUTINE  76400013
*    AND ARE RIGHT ADJUSTED IN REGISTER 15                              76800013
*                  X'00'    NO ERRORS                                   77200013
*                  X'10'    INVALID COUNT SPECIFIED IN WORKAREA         77600013
*                  X'20'    INVALID TERMINAL TABLE ENTRY SPECIFIED      78000013
         EJECT                                                          78400013
         TERMTBLD                                                       78800013
         EJECT                                                          79200013
         QCBD                                                           79600013
         EJECT                                                          80000013
         DCBD  DSORG=(QX)                                               80400013
         EJECT                                                          80800013
         LCBD                                                           81200013
         END                                                            81600013
