         TITLE 'IECKCHPL  QTAM CHANGE POLLING LIST (CHNGP)'             00500013
*********************************************************************** 01000013
*                                                                     * 01500013
*                                                                     * 02000013
*NAME-                                                                * 02500013
*   IECKCHPL   QTAM  CHANGE POLLING LIST (CHNGP)                      * 03000013
*                                                                     * 03500013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04000013
*                                                                     * 04500013
*FUNCTION-                                                            * 05000013
*       IECKCHPL WILL PLACE A NEW POLLING LIST INTO THE POLLING LIST  * 05500013
*   AREA SPECIFIED FOR THE LINE OR CHANGES THE LINE STATUS WITH       * 06000013
*   REGARD TO POLLING.                                                * 06500013
*        THE ADDRESS OF THE SPECIFIED DCB IS USED AS A BASE           * 07000013
*   REGISTER TO ALLOW SYMBOLIC REFERENCE TO FIELDS IN THAT DCB.       * 07500013
*   A TEST IS MADE TO SEE IF THAT DCB IS OPEN.  IF IT IS NOT OPEN,    * 08000013
*   AN ERROR INDICATOR OF X'01' IS RETURNED TO THE CALLING ROUTINE    * 08500013
*   IN REGISTER 15.  CONTROL IS PASSED TO THE NEXT MESAGE PROCESSING  * 09000013
*   PROGRAM INSTRUCTION.                                              * 09500013
*        IF THE DCB IS OPEN, THE SPECIFIED RLN (RELATIVE LINE         * 10000013
*   NUMBER) IS CHECKED AGAINST THE HIGHEST RLN FOR THAT DCB TO        * 10500013
*   BE SURE THAT THE LINE EXISTS.  IF THE SPECIFIED RLN IS TOO HIGH,  * 11000013
*   AN ERROR INDICATION OF X'08' IS RETURNED IN REGISTER 15. CONTROL  * 11500013
*   IS PASSED TO THE NEXT MESSAGE PROCESSING PROGRAM INSTRUCTION.     * 12000013
*        IF THE RLN IS VALID, THE ADDRESS OF THE DCB IS SHIFTED OUT   * 12500013
*   OF THE WORK REGISTER.  RLN IS MULTIPLIED BY 4 AND ADDED TO THE    * 13000013
*   DCB BASE REGISTER , THUS HAVING THE DCB BASE REGISTER POINT TO    * 13500013
*   THE NAME OF THE POLLING LIST.                                     * 14000013
*        A TEST IS MADE TO SEE IF ONLY THE STATUS BYTES ARE TO BE     * 14500013
*   CHANGED.  IF THE CALLING ROUTINE WANTS A NEW POLLING LIST, THE      15000013
*   LENGTH OF THE NEW LIST IS COMPARED WITH THE LENGTH OF THE OLD.    * 15500013
*   IF THEY ARE NOT EQUAL, AN ERROR INDICATION OF X'10' IS PASSED BACK* 16000013
*   IN THE LOW ORDER BYTE OF REGISTER 15.  CONTROL PASSES TO THE      * 16500013
*   NEXT MESSAGE PROCESSING PROGRAM INSTRUCTION.                      * 17000013
*        IF THE LENGTHS ARE EQUAL, OR IF MERELY THE STATUS CHARACTERS * 17500013
*   ARE TO BE MODIFIED, CONTROL IS SET UP FOR THE CROSS PARTITION     * 18000013
*   MOVE NECESSARY TO GET THE INFORMATION FROM THE MESSAGE PROCESSING * 18500013
*   PARTITION TO THE MESSAGE CONTROL.                                 * 19000013
*        AFTER THE MOVE IS COMPLETED, CONTROL IS RETURNED TO THE NEXT * 19500013
*   MESSAGE PROCESSING PROGRAM INSTRUCTION.                           * 20000013
*                                                                     * 20500013
*                                                                     * 21000013
*ENTRY POINTS-                                                        * 21500013
*   IECKCHPL - CONTROL IS PASSED HERE BY A BALR IN THE EXPANSION OF   * 22000013
*        THE CHNGP MACRO.  REGISTER 15 IS THE ENTRY POINT REGISTER    * 22500013
*        AND REGISTER 14 IS THE RETURN POINT REGISTER.                * 23000013
*                                                                     * 23500013
*INPUT-                                                               * 24000013
*   REGISTER  0- WILL CONTAIN THE ADDRESS OF THE DCB FOR THIS LINE    * 24500013
*        GROUP IN THE LOW ORDER THREE BYTES, AND THE RLN IN THE HIGH  * 25000013
*        ORDER BYTE.                                                  * 25500013
*   REGISTER 1- WILL POINT TO EITHER THE NEW POLLING LIST, IF THE     * 26000013
*        ENTIRE POLLING LIST IS TO BE CHANGED, OR TO THE NEW STATUS   * 26500013
*        BYTE WHICH IS TO BE INSERTED IN THE PRESENT POLLING LIST.    * 27000013
*   REGISTER 14- RETURN ADDRESS.                                      * 27500013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 28000013
*                                                                     * 28500013
*OUTPUT-                                                              * 29000013
*   THE POLLING LIST FOR THE LINE SPECIFIED WILL BE MODIFIED AS       * 29500013
*        HAS BEEN SPECIFIED.                                          * 30000013
*   IF ERRORS RESULT FROM IMPROPER INFORMATION, ONE OF THE            * 30500013
*        FOLLOWING ERROR FLAGS WILL BE SET IN THE LOW ORDER           * 31000013
*        BYTE OF REGISTER 15.                                         * 31500013
*              X'01'- DCB HAS NOT BEEN OPENED                         * 32000013
*              X'08'- INVALID RLN SPECIFIED                           * 32500013
*              X'10'- INVALID LENGTH SPECIFIED                        * 33000013
*        IF THERE WERE NO ERRORS, A CODE OF X'00' IS RETURNED.        * 33500013
*                                                                     * 34000013
*EXTERNAL ROUTINES-                                                   * 34500013
*   QPOST (IGG067 IN MODULE IECKQQ01).                                * 35000013
*   CROSS PARTITION MOVE (QMOVER+6 IN MODULE IGG019NG).               * 35500013
*                                                                     * 36000013
*EXITS-                                                               * 36500013
*   NORMAL - RETURN IS TO THE NEXT MESSAGE PROCESSING PROGRAM         * 37000013
*        INSTRUCTION WITH A X'00' IN REGISTER 15.  RETURN IS MADE VIA * 37500013
*        A RETURN MACRO.                                              * 38000013
*   ERROR - SAME AS ABOVE, BUT WITH ERROR INDICATION IN REGISTER 15.  * 38500013
*                                                                     * 39000013
*TABLES/WORK AREAS-                                                   * 39500013
*   NONE.                                                             * 40000013
*                                                                     * 40500013
*ATTRIBUTES-                                                          * 41000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 41500013
*                                                                     * 42000013
*NOTES-                                                               * 42500013
*   REGISTER  1- USED TO GET ADDRESS OF QMOVER.                       * 43000013
*   REGISTER  3- WORK REGISTER. WILL CONTAIN NUMBER OF CHARACTERS     * 43500013
*        TO BE MOVED.                                                 * 44000013
*   REGISTER  4- WORK REGISTER. WILL HOLD THE ADDRESS OF THE POLLING  * 44500013
*        LIST TO BE MODIFIED.                                         * 45000013
*   REGISTER  5- WORK REGISTER. WILL POINT TO NEW POLLING LIST OR     * 45500013
*              NEW STATUS CHARACTERS.                                 * 46000013
*   REGISTER  6- BASE REGISTER FOR DCB.                               * 46500013
*   REGISTER  7- WORK REGISTER. WILL HOLD THE CONDITION CODE FLAG.    * 47000013
*                                                                     * 47500013
*********************************************************************** 48000013
IECKCHPL START                                                          48500013
R0       EQU   0                                                        49000013
R1       EQU   1                                                        49500013
WREG     EQU   3                                                        50000013
POLLREG  EQU   4                                                        50500013
FROMREG  EQU   5                                                        51000013
DCBREG   EQU   6                                                        51500013
FLAG     EQU   7                                                        52000013
RETURN   EQU   14                                                       52500013
SREG     EQU   15                                                       53000013
DEBEXT   EQU   16                                                       53500013
QPOST    EQU   67                                                       54000013
CVTTRMTB EQU   156                                                      54500013
         USING IHADCB,DCBREG                                            55000013
         USING POLLIST,POLLREG                                          55500013
         USING *,SREG                                                   56000013
         SAVE  (14,12)                                                  56500013
         LR    DCBREG,0            REGISTER 0 HAS THE DCB ADDRESS WITH  57000013
*                                    THE RELATIVE LINE NUMBER (RLN) IN  57500013
*                                    THE HIGH ORDER BYTE                58000013
         LA    FLAG,X'01'          LOAD USER'S NOT OPEN ERROR FLAG      58500013
         TM    DCBOFLGS,X'10'      HAS THE DCB BEEN OPENED              59000013
         BNO   RET                 BRANCH IF NO                         59500013
*                                    RETURN SINCE NO DEB AVAILABLE      60000013
         SR    FLAG,FLAG           CLEAR ERROR INDICATOR                60500013
OPND     L     WREG,DCBDEBAD       GET DEB ADDRESS FROM THE DCB         61000013
         CLC   20(1,13),DEBEXT(WREG)   IS PASSED RLN TOO HIGH           61500013
         BNH   NORLNERR            BRANCH IF NO                         62000013
         LA    FLAG,X'08'          SET INVALID RLN ERROR FLAG           62500013
         B     RET                 RETURN TO USER                       63000013
*                                    RLN IS IN HIGH ORDER BYTE OF R0    63500013
NORLNERR SRL   R0,24               SHIFT OUT DCB ADDRESS                64000013
         SLL   R0,2                R0 HAS 4(RLN)                        64500013
         AR    DCBREG,R0           GET DCB+4(RLN) IN DCBREG             65000013
         L     POLLREG,DCBCPOLL-4  GET THE ADDRESS OF THE POLLING LIST  65500013
*                                      FROM THE DCB USING DCBREG AS THE 66000013
*                                      BASE FOR DCBCPOLL                66500013
         SR    WREG,WREG           CLEAR WORKING REGISTER               67000013
         TM    0(R1),X'F0'             TEST FOR CHANGE STATUS ONLY      67500013
*                                      IF CHANGE STATUS INDICATED, R1   68000013
*                                      POINTS TO THE STATUS BYTE        68500013
         BO    GO                      BRANCH IF STATUS CHANGE          69000013
         SPACE                                                          69500013
*                                      IF NOT STATUS CHANGE, R1 POINTS  70000013
*                                      TO SIZE OF NEW LIST              70500013
CHANGE   CLC   POLLSZE,0(R1)       IS NEW LIST LENGTH EQUAL TO OLD      71000013
         BNE   ERR                 BRANCH IF NO                         71500013
         IC    WREG,0(R1)          ELSE GET SIZE OF LIST FOR MOVE       72000013
*                 (THE LENGTH BYTE WILL NOT BE DISTURBED IN THE MOVE)   72500013
         BCTR  WREG,0              DECREMENT FOR EXECUTE                73000013
         BCTR  WREG,0              DECREMENT TO START IN 2ND POSITION   73500013
GO       LR    FROMREG,R1              SET THE FROM ADDRESS FOR MOVE    74000013
         L     R1,16                   LOAD COMM. VECTOR TABLE ADDRESS  74500013
         L     R1,CVTTRMTB(R1)         ADDRESS OF TERM TABLE            75000013
         L     R1,4(R1)                ADDRESS OF IGG019NG              75500013
         L     R1,0(R1)                ADDRESS OF QUEUES IN NG          76000013
         L     R1,284(R1)              ADDRESS OF QMOVE                 76500013
         LA    R1,0(R1)                CLEAR HIGH ORDER                 77000013
         LR    2,R1                    SET MOVE DATA QCB ADDRESS        77500013
         SVC   QPOST               POST QMOVER QCB TO ITSELF THUS       78000013
*                                    CAUSING MOVE TO BE EXECUTED        78500013
         B     RET                 RETURN TO USER                       79000013
         SPACE                                                          79500013
ERR      LA    FLAG,X'10'(FLAG)    INDICATE INVALID LENGTH              80000013
RET      LR    15,FLAG             LOAD ERROR INDICATOR                 80500013
         RETURN (0,12)             RETURN TO USER                       81000013
         SPACE 2                                                        81500013
*  THE FOLLOWING ERROR INDICATORS ARE SET FOR THE USER IN THIS ROUTINE  82000013
*    AND ARE RIGHT ADJUSTED IN REGISTER 15                              82500013
*                  X'00'    NO ERRORS                                   83000013
*                  X'01'    DCB HAS NOT BEEN OPENED                     83500013
*                  X'08'    PASSED RELATIVE LINE NUMBER TOO HIGH        84000013
*                  X'10'    INVALID LENGTH SPECIFIED                    84500013
         EJECT                                                          85000013
         DCBD  DSORG=(QX)                                               85500013
         EJECT                                                          86000013
POLLIST  DSECT                                                          86500013
POLLSZE  DS    FL1                 INDICATES POLLING LIST LENGTH        87000013
POLLSTAT DS    FL1                 INDICATES STATUS OF POLLING LIST     87500013
         END                                                            88000013
