         TITLE 'QTAM CLOSE ROUTINE (CLOSEMC)'                           00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKCLOS  QTAM CLOSE ROUTINE (CLOSEMC)                            * 03000013
*                                                                     * 03600013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04200013
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        IECKCLOS WILL CLOSE DOWN THE SYSTEM FOR INCOMING MESSAGES,   * 06000013
*   AND ALLOW THE REMAINING MESSAGES TO BE SENT.                      * 06600013
*        THE ADDRESS OF THE LPS ROUTINE IS OBTAINED THROUGH THE       * 07200013
*   COMMUNICATIONS VECTOR TABLE, TERMINAL TABLE, AND THE              * 07800013
*   IMPLEMENTATION MODULE.  THE ADDRESS OF THE MASTER RECEIVE SWITCH  * 08400013
*   IS GAINED FROM THE FIXED LOCATION PART OF IGG019NG.  THE QMOVE    * 09000013
*   ROUTINE IS USED TO TURN OFF THE MASTER RECEIVE SWITCH BY MOVING   * 09600013
*   A MASK INTO THE SWITCH.  THE SYSTEM WILL NOW ACCEPT NO MORE       * 10200013
*   INCOMING TRANSMISSIONS.                                           * 10800013
*        THE TCB FOR MESSAGE CONTROL IS USED TO OBTAIN THE ADDRESS    * 11400013
*   OF THE DEB CHAIN. FOR EACH DEB ON THE CHAIN. THE ASSOCIATED DCB   * 12000013
*   IS REFERENCED.  IF THE DCB IS NOT FOR A COMMUNICATION LINE, IT    * 12600013
*   IS IGNORED AND THE NEXT IS OBTAINED FROM THE CHAIN.               * 13200013
*        IF THE DEB IS FOR A LINE, EACH LCB IS ACCESSED.  IF THE LINE * 13800013
*   FOR THE LCB IS ACTIVE, THE ROUTINE ISSUES A STOPLN MACRO TO       * 14400013
*   STOP THE LINE.  THEN A STARTLN MACRO IS ISSUED TO PUT OUT ALL     * 15000013
*   MESSAGES FOR THAT LINE.  ONLY THE LINES FOR OUTPUT WILL BE        * 15600013
*   STARTED, AS THE MASTER RECEIVE SWITCH HAS BEEN TURNED OFF.        * 16200013
*        IF THE LINE IS NOT ACTIVE. THE NEXT LCB IS ACCESSED.         * 16800013
*   WHEN THE END OF THE DEB CHAIN IS REACHED, THE ROUTINE             * 17400013
*   RETURNS CONTROL TO THE NEXT MESSAGE PROCESSING PROGRAM INSTRUCT-  * 18000013
*   ION.                                                              * 18600013
*                                                                     * 19200013
*ENTRY POINTS-                                                        * 19800013
*   IECKCLOS - THE EXPANSION OF THE CLOSEMC MACRO GENERATES A BLAR    * 20400013
*        TO THIS POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER * 21000013
*        AND REGISTER 14 AS THE RETURN ADDRESS.                       * 21600013
*                                                                     * 22200013
*INPUT-                                                               * 22800013
*   REGISTER 14- RETURN ADDRESS.                                      * 23400013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 24000013
*                                                                     * 24600013
*OUTPUT-                                                              * 25200013
*   NONE.                                                             * 25800013
*                                                                     * 26400013
*EXTERNAL ROUTINES-                                                   * 27000013
*   QPOST (IGG067 IN MODULE IECKQQ01).                                * 27600013
*   LINE CHANGE ( IN MODULE IECKLNCH).                                * 28200013
*   CROSS PARTITION MOVE (QMOVER + 6 IN MODULE IGG019NG).             * 28800013
*                                                                     * 29400013
*EXITS-                                                               * 30000013
*   NORMAL - CONTROL RETURNS TO THE CALLING ROUTINE THRU THE ISSUING  * 30600013
*        OF A RETURN MACRO.                                           * 31200013
*   ERROR - NONE.                                                     * 31800013
*                                                                     * 32400013
*TABLES/WORK AREAS-                                                   * 33000013
*   AREA - 18 WORD SAVE AREA.                                         * 33600013
*                                                                     * 34200013
*ATTRIBUTES-                                                          * 34800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 35400013
*                                                                     * 36000013
*NOTES-                                                               * 36600013
*   REGISTER  1- ADDRESS OF QMOVER.                                   * 37200013
*   REGISTER  2- ADDRESS OF THE TERMINAL TABLE.                       * 37800013
*   REGISTER  3- SIZE OF AN LCB.                                      * 38400013
*   REGISTER  4- ADDRESS OF MASTER RECEIVE SWITCH.                    * 39000013
*   REGISTER  5- ADDRESS OF MASK TO TURN SWITCH OFF.                  * 39600013
*   REGISTER  6- COUNT OF CHARACTERS TO BE MOVED.                     * 40200013
*   REGISTER  7- BASE FOR DCB.                                        * 40800013
*   REGISTER  8- BASE FOR DEB.                                        * 41400013
*   REGISTER 12- BASE FOR THIS ROUTINE.                               * 42000013
*   REGISTER 13- POINTER TO THIS ROUTINES SAVE AREA.                  * 42600013
*                                                                     * 43200013
*********************************************************************** 43800013
IECKCLOS START                                                          44400013
*3160810000                                                        000A 44700018
FREG     EQU   1                                                        45000013
TREG     EQU   2                                                        45600013
RD       EQU   3                                                        46200013
RB       EQU   4                                                        46800013
RC       EQU   5                                                        47400013
RA       EQU   6                                                        48000013
RDCB     EQU   7                                                        48600013
RDEB     EQU   8                                                        49200013
RBASE    EQU   12                                                       49800013
RSAVE    EQU   13                                                       50400013
QPOST    EQU   67                                                       51000013
CVTABLE  EQU   16                                                       51600013
CVTTRMTB EQU   156                                                      52200013
TTQUES   EQU   4                                                        52800013
         USING IHADCB,RDCB                                              53400013
         USING IECTDEB+36,RDEB                                          54000013
         SAVE  (14,12)                                                  54600013
         BALR  RBASE,0                                                  55200013
         USING *,RBASE                                                  55800013
         ST    RSAVE,AREA+4            SAVE REGISTER 13                 56400013
         LA    RSAVE,AREA                 FOR THIS ROUTINE              57000013
         L     TREG,CVTABLE            ACCESS CVT                       57600013
         L     TREG,CVTTRMTB(0,TREG)   ACCESS QTAM TERMINAL TABLE       58200013
         L     RA,TTQUES(0,TREG)       ACCESS IMPLEMENTATION MODULE     58800013
         L     RA,0(0,RA)              ACCESS FIXED AREA                59400013
* THE FOLLOWING CODE CAUSES THE QMOVE STCB TO TURN OFF THE              60000013
*   MASTER RECEIVE SWITCH                                               60600013
         L     TREG,284(0,RA)          SET UP QMOVE AS A QCB            61200013
         LR    FREG,TREG               SET UP QMOVE AS AN ELEMENT       61800013
         LA    RB,287(0,RA)            SET ADDRESS OF MASTER RECEIVE    62400013
*                                         SWITCH-1 AS PARAMETER IN REG4 63000013
         BAL   RC,*+6                  LOAD ADDRESS OF MASK TO CHANGE   63600013
*                                         SWITCH IN REG 5               64200013
         DC    X'0000'                 MASK USES BITS 4-7 ONLY          64800013
         SR    RD,RD                   COUNT=0 INDICATES HALF-BYTE CHNG 65400013
         SVC   QPOST                   POST QMOVE TO ITSELF             66000013
*  AT THIS POINT NO NEW RECEIVE OPERATIONS CAN BE STARTED               66600013
*  THE FOLLOWING CODE ISSUES A STOPLN MACRO AND THEN STRTLN MACRO TO    67200013
*    EACH ACTIVE COMMUNICATION LINE                                     67800013
         USING  IECKLCB0,RC                                             68400013
         L     RDEB,288(0,RA)          ACCESS TCB FOR MESSAGE CONTROL   69000013
         LA    RDEB,4(0,RDEB)          INITIALIZE FOR FIRST DEB         69600013
NEXTDEB  EQU   *                                                        70200013
         L     RDEB,4(0,RDEB)          ACCESS DEB                       70800013
         LA    RDEB,0(RDEB)       CLEAR THE HIGH ORDER BYTE             71400013
         LTR   RDEB,RDEB               END OF DEB CHAIN                 72000013
         BZ    CXEOL                     YES                            72600013
         L     RDCB,DEBDCBAD-1         NO,ACCESS RELATED DCB            73200013
         TM    DCBDSORG,X'10'          IS DATASET ORG FOR COMMUNICATION-73800013
               LINE                                                     74400013
         BZ    NEXTDEB                   NO                             75000013
         MVI   EXTCOMP,0               SET COUNT OF EXTENTS = 0         75600013
         L     RC,DCBLCBAD             START OF LCB AREA-SIZE OF LCB    76200013
NEXTEXT  EQU   *                                                        76800013
         IC    RD,DCBEIOBX             SIZE OF AN LCB                   77400013
         LA    RC,0(RD,RC)             START OF LCB AREA                78000013
         IC    RD,EXTCOMP              INCREMENT THE COUNT              78600013
         LA    RD,1(0,RD)                 OF EXTENTS (LCB'S)            79200013
         STC   RD,EXTCOMP                 FOR THIS DEB                  79800013
         CLI   LCBSTATE,0              IS LINE ACTIVE                   80400013
         BE    BYPASS              BRANCH IF NO                    000A 80700018
         TM    LCBSTATE,X'04'     IS LINE SENDING                  000A 81000018
         BO    BYPASS             BRANCH IF YES                    000A 81300018
         STOPLN (RDCB),(RD)            STOP THE LINE TRANSMISSION       81600013
*  AT THIS POINT BOTH INPUT AND OUTPUT OPERATIONS WILL BE STOPPED       82200013
         STARTLN  (RDCB),(RD)          RESTART THE LINE TRANSMISSION    82800013
*  ONLY OUTPUT OPERATIONS WILL BE RESTARTED                             83400013
BYPASS   EQU   *                                                        84000013
         CLC    EXTCOMP(1),DEBNMEXT    IS THIS THE LAST EXTENT          84600013
         BE    NEXTDEB                    YES                           85200013
         B     NEXTEXT                    NO                            85800013
CXEOL    EQU   *                                                        86400013
         L     RSAVE,AREA+4            RESTORE REGISTER 13              87000013
         RETURN (14,12)                                                 87600013
EXTCOMP  DC    X'00'                                                    88200013
AREA     DS    18F                                                      88800013
         EJECT                                                          89400013
         DCBD  DSORG=CX                                                 90000013
         EJECT                                                          90600013
         IECTDEBX                                                       91200013
         EJECT                                                          91800013
          LCBD                                                          92400013
         END                                                            93000013
