         TITLE 'IECKCNCL  QTAM CANCEL MESSAGE (CANCELM)'                00800013
*********************************************************************** 01600013
*                                                                     * 02400013
*NAME-                                                                * 03200013
*STATUS-  CHANGE LEVEL= 19         JANUARY 1971                       * 04000021
*                                                                     * 04800013
*FUNCTION-                                                            * 05600013
*        CAUSES A MESSAGE TO BE CANCELLED WHEN ANY OF THE ERROR       * 06400013
*   CONDITIONS SPECIFIED IN THE CALLING ROUTINES ERROR MASK IS        * 07200013
*   INDICATED IN THE ERROR HALF WORD AT LCBERRST (LCB+40), OR IF THE  * 08000013
*   MASK IS ZERO. IF THE MASK IS NOT ZERO AND NONE OF THE ERROR       * 08800013
*   CONDITIONS SPECIFIED BY THE MASK ARE INDICATED, RETURN IS TO THE  * 09600013
*   NEXT LPS INSTRUCTION.                                             * 10400013
*        IF THE ERROR MASK WAS ZERO, OR ANY OF THE SPECIFIED ERRORS   * 11200013
*   WERE DETECTED, AND IF THERE WAS NOT A DESTINATION ERROR CODE SET  * 12000013
*   IN LCBERRST, THEN LINKAGE IS MADE TO THE RECALL ROUTINE TO OBTAIN * 12800013
*   THE HEADER.  THEN THE CANCEL BIT IS SET TO A ONE IN THE MSTATUS   * 13600013
*   FIELD OF THE HEADER PREFIX (PREFIX + 12 IS OR'ED WITH A X'80').   * 14400013
*   IF THE INVALID DESTINATION BIT IS ON IN THE ERROR HALFWORD, THE   * 14500021
*   CANCEL BIT IS NOT SET BUT THE SERVICE BIT IS SET (X'10 IN         * 14600021
*   MSTATUS).                                                         * 14700021
*       IF THE SERVICE BIT IS SET IN MSTATUS, QSIZE IS NOT ADJUSTED.  * 14800021
*   OTHERWISE, THE QCB ADDRESS IS OBTAINED FROM THE TERMINAL TABLE    * 14900021
*   ENTRY SPECIFIED IN TTDKEY.  QSIZE IN THE QCB IS DECREMENTED BY    * 15000021
*   ONE.                                                              * 15100021
*        AFTER THE CANCEL BIT IS SET OR IF THERE WAS A DESTINATION    * 15200013
*   ERROR, THE PREVIOUS SEQUENCE NUMBER IS OBTAINED FROM MSNUMIN      * 16000021
*   (BUFFER + 28) AND IS STORED IN THE TSEQUIN FIELD OF               * 16800021
*   THE TERMINAL TABLE AT THE TABLE ENTRY + 4 UNLESS IT IS ZERO.      * 17600013
*   THE LCBMPLRT FIELD AT LCB + 32 IS MADE ZERO TO CANCEL THE         * 18400013
*   MULTIPLE ROUTING OPTION AND THE CONVERSATIONAL MODE BIT IN THE    * 19200013
*   LCB IS SET TO ZERO (LCBSTATE AT LCB + 0 IS AND'ED WITH A X'DF')   * 20000013
*   BEFORE RETURNING TO THE NEXT LPS INSTRUCTION.                     * 20800013
*                                                                     * 21600013
*ENTRY POINTS-                                                        * 22400013
*   IECKCNCL - EXPANSION OF THE CANCELM MACRO GENERATES A BALR TO     * 23200013
*              THIS POINT USING REGISTER 15 AS THE ENTRY POINT        * 24000013
*              REGISTER AND REGISTER 14 AS THE RETURN REGISTER.       * 24800013
*                                                                     * 25600013
*INPUT-                                                               * 26400013
*   REGISTER  4- ADDRESS OF THE LCB.                                  * 27200013
*   REGISTER  6- BUFFER ADDRESS.                                      * 28000013
*   REGISTER  8- TERMINAL TABLE SOURCE ENTRY.                         * 28800013
*   REGISTER 14- RETURN ADDRESS.                                      * 29600013
*              REGISTER 14 ALSO SERVES AS A PARAMETER LIST REGISTER.  * 30400013
*              THE PARAMETER LIST CONSISTS OF A HALF WORD ERROR MASK  * 31200013
*              SPECIFIED AS AN OPERAND IN THE CANCELM MACRO.          * 32000013
*   REGISTER 15- ENTRY POINT.                                         * 32800013
*                                                                     * 33600013
*OUTPUT-                                                              * 34400013
*   THE CANCEL BIT IN THE PREFIX WILL BE SET TO A ONE UNLESS THERE    * 35200013
*              WAS A DESTINATION ERROR.  THE SEQUENCE NUMBER WILL BE  * 36000013
*              STORED IN THE TSEQUIN FIELD OF THE TERMINAL TABLE ENTRY* 36800013
*              UNLESS IT IS ZERO.  THE MULTIPLE ROUTING BYTE WILL BE  * 37600013
*              SET TO ZERO IN THE LCB.  THE CONVERSATIONAL MODE FLAG  * 38400013
*              OF THE LCB WILL BE SET TO ZERO.                        * 39200013
*                                                                     * 40000013
*EXTERNAL ROUTINES-                                                   * 40800013
*   IECKRC - RECALL ROUTINE OF IGG019NG TO OBTAIN THE HEADER.         * 41600013
*                                                                     * 42400013
*EXITS-                                                               * 43200013
*   NORMAL- RETURN IS TO THE NEXT LPS INSTRUCTION VIA A BRANCH ON     * 44000013
*              REGISTER 14.                                           * 44800013
*   ERROR- NONE.                                                      * 45600013
*                                                                     * 46400013
*TABLES/WORK AREAS-                                                   * 47200013
*   NONE.                                                             * 48000013
*                                                                     * 48800013
*ATTRIBUTES-                                                          * 49600013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 50400013
*                                                                     * 51200013
*NOTES-                                                               * 52000013
*   REGISTER  3- SECOND LEVEL RETURN REGISTER TO RECALL ROUTINE.      * 52800013
*   REGISTER  9- SECOND LEVEL ENTRY POINT REGISTER TO THE RECALL      * 53600013
*              ROUTINE AND WORK REGISTER.                             * 54400013
*                                                                     * 55200013
*********************************************************************** 56000013
IECKCNCL START                                                          56800013
*1210760700-767000,912000                                          00PS 57200016
*90381704000-728000,800000,810000                                       57400017
* 612000,739000-757000                                           A28764 57500019
*A040000,145000-151000,157000-168000                             S21016 57550021
RREG2    EQU   3                                                        57600013
LCBREG   EQU   4                                                        58400013
MSREG    EQU   6                                                        59200013
TCREG    EQU   8                                                        60000013
WREG1    EQU   9                                                        60800013
WREG2    EQU   10                                                       61200019
RREG1    EQU   14                                                       61600013
SREG     EQU   15                                                       62400013
         USING *,SREG                                                   63200013
         USING IECKPREF,MSREG                                           64000013
         USING IECKLCB0,LCBREG                                          64800013
         USING IECKTERM,TCREG                                           65600013
         LH    WREG1,0(0,RREG1)    LOAD ERROR HALF WORD FROM USER       66400013
         SLA   WREG1,16            SHIFT TO HIGH ORDER PART OF REGISTER 67200013
         BC    8,ERRACT            BRANCH IF MASK IS ZERO               68000013
         N     WREG1,LCBERRST      TEST FOR DESIGNATED ERRORS           68800013
         BC    8,2(0,RREG1)        RETURN IF NO ERRORS                  69600013
ERRACT   MVC   LCBCECB+1(3),LCBCHDR  MAKE HEADER ADDRESS AVAILABLE      73600013
         L     WREG2,0(0,13)      GET LPS QUE ADDR FROM IGG019NG A28764 73900019
         BAL   RREG2,240(0,WREG2) BRANCH TO RECALL SUBR FOR HEADER28764 74200019
         LTR   WREG1,WREG1        IS INVALID DESTINATION BIT ON  A28764 74500019
         BNM   CANCEL             BRANCH IF NO                   A28764 74800019
         OI    MSTATUS,X'10'      SET SERVICED BIT               A28764 75100019
         B     ERRRET             BYPASS CANCEL BIT              A28764 75400019
CANCEL   OI    MSTATUS,X'80'      TURN ON CANCEL BIT IN PREFIX   A28764 75700019
         TM    MSTATUS,X'10'      IS MESSAGE SERVICED              00PS 76070016
         BO    ERRRET             BRANCH IS YES                    00PS 76140016
         LH    WREG1,TTDKEY       GET DESTINATION OFFSET           00PS 76210016
         LTR   WREG1,WREG1        IS OFFSET VALID                  00PS 76280016
         BZ    ERRRET             BRANCH IF NO                     00PS 76350016
         A     WREG1,=V(TERMTBL)  ADD IN TERMTBL ADDRESS           00PS 76420016
         L     WREG1,TQCBADDR-1-IECKTERM(WREG1)  LOAD DEST QCB ADDR00PS 76490016
         LH    RREG2,QSIZE-QBLOCK(WREG1)  LOAD CURRENT SIZE        00PS 76560016
         BCTR  RREG2,0            DECREMENT FOR CANCELED MESSAGE   00PS 76630016
         STH   RREG2,QSIZE-QBLOCK(WREG1)   AND RESTORE             00PS 76700016
ERRRET   LA    TCREG,0(TCREG)     CLEAR THE HIGH ORDER BYTE             76800013
         L     WREG1,16           ADDRESS OF THE CVT                    77600013
         C     TCREG,156(WREG1)   IS TCREG EQUAL TERM TABLE START       78400013
         BE    NOUPDATE           BRANCH YES                            79200013
         LH    WREG1,MSNUMIN       GET SEQUENCE NO. OF LAST MESSAGE00PS 80000017
         LTR   WREG1,WREG1         IS IT ZERO                           80800013
         BE    NOUPDATE            BRANCH IF YES                   00PS 81000017
         STH   WREG1,TSEQUIN       ELSE RESET SEQUENCE NUMBER           82400013
NOUPDATE EQU   *                                                        83200013
         MVI   LCBMPLRT,X'00'      AND ZERO MULTIPLE ROUTE BYTE IN LCB  84000013
         XC    LCBDLPTR(2),LCBDLPTR    ZERO DISTRIBUTION LIST BYTE      84800013
         NI    LCBSTATE,X'DF'      CLEAR CONVERSATIONAL MODE FLAG       85600013
         B     2(0,RREG1)          RETURN TO USER                       86400013
         EJECT                                                          87200013
         PREFIXD                                                        88000013
         EJECT                                                          88800013
         LCBD                                                           89600013
         EJECT                                                          90400013
         TERMTBLD                                                       91200013
         QCBD                                                           91600016
         END                                                            92000013
