         TITLE 'IECKCPPL  QTAM COPY POLLING LIST (COPYP)'               00800013
*********************************************************************** 01600013
*                                                                     * 02400013
*NAME-                                                                * 03200013
*   IECKCPPL  COPY POLLING LIST (COPYP)                               * 04000013
*                                                                     * 04800013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 05600013
*                                                                     * 06400013
*FUNCTION-                                                            * 07200013
*        IECKCPPL IS USED TO COPY A POLLING LIST INTO A WORK AREA     * 08000013
*   IN THE CALLING ROUTINE.  THE REGISTERS ARE SAVED AND A TEST IS    * 08800013
*   MADE TO DETERMINE IF THE DCB IS OPEN.  IF IT IS NOT, AN ERROR CODE* 09600013
*   OF X'01' IS PLACED INTO REGISTER 15, REGISTERS ARE RESTORED,      * 10400013
*   AND CONTROL IS RETURNED TO THE LOCATION IN REGISTER 14.           * 11200013
*        IF THE DCB IS OPEN, THE RELATIVE LINE NUMBER GIVEN BY THE    * 12000013
*   CALLING ROUTINE IS COMPARED WITH THE MAXIMUM RLN FOR THIS DCB.    * 12800013
*   IF THE SPECIFIED RLN IS TOO HIGH, INDICATING A LINE THAT DOES NOT * 13600013
*   EXIST IN THIS DCB, AN ERROR CODE OF X'08' IS RETURNED IN REG 15.  * 14400013
*        IF THE RLN IS VALID, THE PROPER POLLING LIST IS SELECTED     * 15200013
*   AND THE POLLING LIST SIZE IS RETRIEVED FROM THE FIRST BYTE OF     * 16000013
*   THE POLLING LIST.  THIS NUMBER OF BYTES IS MOVED FROM THE POLLING * 16800013
*   LIST TO THE SPECIFIED WORK AREA.  IN THIS CASE, A X'00',          * 17600013
*   INDICATING NO ERRORS, IS RETURNED IN REGISTER 15.  THE REGISTERS  * 18400013
*   ARE RESTORED AND CONTROL IS RETURNED TO THE MESSAGE PROCESSING    * 19200013
*   PROGRAM.                                                          * 20000013
*                                                                     * 20800013
*ENTRY POINTS-                                                        * 21600013
*   IECKCPPL - EXPANSION OF THE COPYP MACRO GENERATES A BALR TO THIS  * 22400013
*        POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER, AND    * 23200013
*        REGISTER 14 AS THE RETURN ADDRESS REGISTER.                  * 24000013
*                                                                     * 24800013
*INPUT-                                                               * 25600013
*   REGISTER  0- WILL CONTAIN THE ADDRESS OF THE DCB SPECIFIED IN     * 26400013
*        THE MACRO.  THE RELATIVE LINE NUMBER WILL BE IN THE HIGH     * 27200013
*        ORDER BYTE.                                                  * 28000013
*   REGISTER  1- CONTAINS THE ADDRESS OF THE WORK AREA INTO           * 28800013
*        WHICH THE POLLING LIST IS TO BE COPIED.                      * 29600013
*   REGISTER 13- ADDRESS OF THE SAVE AREA.                            * 30400013
*   REGISTER 14- RETURN ADDRESS.                                      * 31200013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 32000013
*                                                                     * 32800013
*OUTPUT-                                                              * 33600013
*   REGISTER 15- ONE OF THE FOLLOWING CODES WILL BE RETURNED,         * 34400013
*        RIGHT ADJUSTED, IN THIS REGISTER.                            * 35200013
*              X'00'  NO ERRORS.                                      * 36000013
*              X'01'  THE DCB HAS NOT BEEN OPENED.                    * 36800013
*              X'08'  THE PASSED RELATIVE LINE NUMBER IS TOO HIGH.    * 37600013
*                                                                     * 38400013
*EXTERNAL ROUTINES-                                                   * 39200013
*   NONE.                                                             * 40000013
*                                                                     * 40800013
*EXITS-                                                               * 41600013
*   NORMAL-RETURN IS TO THE NEXT MESSAGE CONTROL PROGRAM INSTRUCTION  * 42400013
*        BY ISSUING RETURN MACRO.                                     * 43200013
*   ERROR- ERROR RETURN CODE IS PLACED IN REGISTER 15, AND RETURN IS  * 44000013
*        AS ABOVE.                                                    * 44800013
*                                                                     * 45600013
*TABLES/WORK AREAS-                                                   * 46400013
*   NONE.                                                             * 47200013
*                                                                     * 48000013
*ATTRIBUTES-                                                          * 48800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 49600013
*                                                                     * 50400013
*NOTES-                                                               * 51200013
*   REGISTER  5- WORK REGISTER.                                       * 52000013
*   REGISTER  7- WORK REGISTER.                                       * 52800013
*   REGISTER  3- BASE REGISTER FOR IHADCB.                            * 53600013
*   REGISTER  6- BASE REGISTER FOR POLLIST.                           * 54400013
*                                                                     * 55200013
*********************************************************************** 56000013
IECKCPPL START                                                          56800013
R0       EQU   0                                                        57600013
R1       EQU   1                                                        58400013
DCBREG   EQU   3                                                        59200013
R5       EQU   5                                                        60000013
POLLREG  EQU   6                                                        60800013
FLAG     EQU   7                                                        61600013
RETURN   EQU   14                                                       62400013
SREG     EQU   15                                                       63200013
DEBEXT   EQU   16                                                       64000013
         USING IHADCB,DCBREG                                            64800013
         USING POLLIST,POLLREG                                          65600013
         USING *,SREG                                                   66400013
         SAVE  (14,12)                                                  67200013
         LR    DCBREG,R0           REGISTER 0 HAS THE DCB ADDRESS WITH  68000013
*                                    THE RELATIVE LINE NUMBER (RLN) IN  68800013
*                                    THE HIGH ORDER BYTE                69600013
         LA    FLAG,X'01'          LOAD USER'S ERROR FLAG               70400013
         TM    DCBOFLGS,X'10'      HAS THE DCB BEEN OPENED              71200013
         BNO   RET                 BRANCH IF NO                         72000013
*                                    RETURN SINCE NO DEB AVAILABLE      72800013
         SR    FLAG,FLAG           CLEAR ERROR INDICATOR                73600013
OPND     L     R5,DCBDEBAD         GET DEB ADDRESS FROM THE DCB         74400013
         CLC   20(1,13),DEBEXT(R5)   IS PASSED RLN TOO HIGH             75200013
         BNH   NORLNERR            BRANCH IF NO                         76000013
         LA    FLAG,X'08'          SET INVALID RLN ERROR FLAG           76800013
         B     RET                 AND RETURN                           77600013
NORLNERR SRL   R0,24               SHIFT OUT DCB ADDRESS                78400013
         SLL   R0,2                R0 HAS 4(RLN)                        79200013
         AR    DCBREG,R0           GET DCB+4(RLN) IN DCBREG             80000013
         L     POLLREG,DCBCPOLL-4  GET THE ADDRESS OF THE POLLING LIST  80800013
*                                    FROM THE DCB USING DCBREG AS THE   81600013
*                                    BASE FOR DCBCPOLL                  82400013
         SR    R5,R5               CLEAR WORKING REGISTER               83200013
         IC    R5,POLLSZE          INSERT POLLING LIST SIZE             84000013
         BCTR  R5,0                DECREMENT FOR EXECUTE                84800013
         EX    R5,MOVPL            COPY POLLING LIST                    85600013
RET      LR    15,FLAG             LOAD ERROR FLAG FOR USER             86400013
         RETURN (0,12)             RESTORE AND RETURN TO USER           87200013
         SPACE                                                          88000013
MOVPL    MVC   0(1,R1),POLLIST       COPY POLLIST INTO WORKAREA         88800013
         SPACE 2                                                        89600013
*  THE FOLLOWING ERROR INDICATORS ARE SET FOR THE USER IN THIS ROUTINE  90400013
*    AND ARE RIGHT ADJUSTED IN REGISTER 15                              91200013
*                  X'00'    NO ERRORS                                   92000013
*                  X'01'    THE DCB HAS NOT BEEN OPENED                 92800013
*                  X'08'    PASSED RELATIVE LINE NUMBER TOO HIGH        93600013
         EJECT                                                          94400013
         DCBD  DSORG=QX                                                 95200013
         EJECT                                                          96000013
POLLIST  DSECT                                                          96800013
POLLSZE  DS    FL1                 INDICATES POLLING LIST LENGTH        97600013
         END                                                            98400013
