         TITLE 'IECKCPYQ  QTAM COPY QUEUE STATUS (COPYQ)'               00800013
*********************************************************************** 01600013
*                                                                     * 02400013
*NAME-                                                                * 03200013
*   IECKCPYQ   QTAM  COPY QUEUE STATUS (COPYQ)                        * 04000013
*                                                                     * 04800013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 05600013
*                                                                     * 06400013
*FUNCTION-                                                            * 07200013
*        IECKCPYQ PLACES INFORMATION CONCERNING THE STATUS OF A       * 08000013
*   SPECIFIED MESSAGE QUEUE INTO THE CALLING ROUTINE'S WORK AREA.     * 08800013
*        THE ADDRESS OF THE TERMINAL TABLE IS RETRIEVED FROM THE      * 09600013
*   COMMUNICATIONS VECTOR TABLE.  THE TERMINAL TABLE IS SCANNED       * 10400013
*   TO FIND THE DESIRED ENTRY.  IF THE DESTINATION CODE IS NOT        * 11200013
*   FOUND, AN ERROR CODE OF X'20' IS RETURNED TO THE CALLING ROUTINE. * 12000013
*   CONTROL PASSES BACK TO THE CALLING ROUTINE.                       * 12800013
*        IF THE TERMINAL ENTRY IS FOUND, THE CONTENTS OF THE QCB      * 13600013
*   IS MOVED TO THE WORK AREA.  CONTROL RETURNS TO THE NEXT           * 14400013
*   LPS INSTRUCTION BY ISSUING A RETURN MACRO.                        * 15200013
*                                                                     * 16000013
*ENTRY POINTS-                                                        * 16800013
*   IECKCPYQ - EXPANSION OF THE COPYQ MACRO GENERATES A BALR TO THIS  * 17600013
*        POINT, WITH REGISTER 15 AS THE ENTRY POINT REGISTER, AND     * 18400013
*        REGISTER 14 AS THE RETURN REGISTER.                          * 19200013
*                                                                     * 20000013
*INPUT-                                                               * 20800013
*   REGISTER  0 - ADDRESS OF THE CALLING ROUTINE'S WORK AREA          * 21600013
*   REGISTER  1 - ADDRESS OF THE LOCATION WHICH POINTS TO THE         * 22400013
*        TERMINAL NAME.                                               * 23200013
*   REGISTER 14- RETURN ADDRESS REGISTER.                             * 24000013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 24800013
*                                                                     * 25600013
*OUTPUT-                                                              * 26400013
*   REGISTER 15- RETURN CODE                                          * 27200013
*              X'00' NO ERRORS                                        * 28000013
*              X'20' TERMINAL TABLE ENTRY NOT FOUND.                  * 28800013
*                                                                     * 29600013
*EXTERNAL ROUTINES-                                                   * 30400013
*   NONE.                                                             * 31200013
*                                                                     * 32000013
*EXITS-                                                               * 32800013
*   NORMAL - RETURN IS TO THE NEXT MESSAGE PROCESSING PROGRAM         * 33600013
*        INSTRUCTION, ACCOMPLISHED BY EXECUTING A RETURN MACRO.       * 34400013
*        RETURN CODE IN REGISTER 15 IS X'00'.                         * 35200013
*   ERROR - SAME AS ABOVE BUT WITH ERROR CODE OF X'20', TERMINAL      * 36000013
*        TABLE ENTRY NOT FOUND.                                       * 36800013
*                                                                     * 37600013
*TABLES/WORK AREAS-                                                   * 38400013
*   NONE.                                                             * 39200013
*                                                                     * 40000013
*ATTRIBUTES-                                                          * 40800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 41600013
*                                                                     * 42400013
*NOTES-                                                               * 43200013
*   REGISTER  0- ADDRESS OF END OF TERMINAL TABLE.                    * 44000013
*   REGISTER  2- ADDRESS OF CALLING ROUTINE'S WORK AREA.              * 44800013
*   REGISTER  3- INCREMENT VALUE OF 8.                                * 45600013
*   REGISTER  4- SIZE OF TERMID -1.                                   * 46400013
*   REGISTER  5- ADDRESS OF COMMUNICATIONS VECTOR TABLE.              * 47200013
*   REGISTER  6- BASE REGISTER FOR TERMINAL TABLE.                    * 48000013
*   REGISTER  7- BASE REGISTER FOR QUEUE CONTROL BLOCK.               * 48800013
*   REGISTER  8- WILL HOLD THE ERROR FLAGS UNTIL RETURN.              * 49600013
*                                                                     * 50400013
*********************************************************************** 51200013
IECKCPYQ START                                                          52000013
R0       EQU   0                                                        52800013
PLREG    EQU   1                                                        53600013
WORKREG  EQU   2                                                        54400013
XREG     EQU   3                                                        55200013
WREG     EQU   4              WORKREG                                   56000013
RD       EQU   5                                                        56800013
TERMREG  EQU   6                                                        57600013
QREG     EQU   7                                                        58400013
FLAG     EQU   8                                                        59200013
RETURN   EQU   14                                                       60000013
SREG     EQU   15                                                       60800013
         USING IECKTERM,TERMREG                                         61600013
         USING QBLOCK,QREG                                              62400013
         USING *,SREG                                                   63200013
         SAVE  (14,12)                                                  64000013
         SR    FLAG,FLAG           CLEAR ERROR INDICATOR                64800013
         LR    WORKREG,R0          GET WORKAREA ADDRESS FOR MOVE        65600013
         L     RD,CVTABLE(0,0)     GET ADDRESS OF THE COMMUNICATIONS    66400013
*                                    VECTOR TABLE (CVT)                 67200013
         L     TERMREG,CVTTRMTB(0,RD) GET TERMTBL ADDRESS FROM CVT      68000013
         L     R0,0(0,TERMREG)     GET END OF TABLE ADDRESS             68800013
         SR    WREG,WREG           CLEAR WORKING REGISTER               69600013
         IC    WREG,4(0,TERMREG)   GET TERMID SIZE                      70400013
         BCTR  WREG,0              DECREMENT SIZE FOR COMPARE           71200013
         LA    XREG,8              INITIALIZE FOR LATER ADDITION        72000013
LAST     CR    TERMREG,R0          IS THIS LAST ENTRY                   72800013
         BE    ERROR               BRANCH IF YES                        73600013
         AR    TERMREG,XREG        ELSE ACCESS NEXT ENTRY               74400013
         IC    XREG,TNTRYSZE       INSERT SIZE OF TERMINAL ENTRY        75200013
         EX    WREG,COMPID         IS THIS SPECIFIED ENTRY              76000013
         BNE   LAST                BRANCH IF NO                         76800013
         L     QREG,TNTRYSZE       ELSE LOAD QCBADDR FROM TERMTBL       77600013
*                                    THE QCB SIZE IS 32 BYTES FOR BOTH  78400013
*                                    PROCESS AND DESTINATION QUEUES     79200013
*                                    WHICH ARE ON THE DASD              80000013
         MVC   0(32,WORKREG),COREQ MOVE QCB TO WORKAREA                 80800013
         B     RET                 RETURN TO USER                       81600013
ERROR    LA    FLAG,X'20'          INDICATE TERMINAL NAME NOT FOUND     82400013
RET      LR    SREG,FLAG           LOAD USER'S ERROR INDICATOR          83200013
         RETURN (0,12)             AND RETURN TO USER                   84000013
         SPACE                                                          84800013
COMPID   CLC   0(1,PLREG),TERMID   COMPARE TERMINAL NAME TO TABLE ENTRY 85600013
         SPACE                                                          86400013
CVTABLE  EQU   16                                                       87200013
CVTTRMTB EQU   156                                                      88000013
*  THE FOLLOWING ERROR FLAGS ARE PASSED TO THE USER IN THIS ROUTINE     88800013
*                  X'00'    NO ERRORS                                   89600013
*                  X'20'    INVALID TERMINAL TABLE ENTRY                90400013
         EJECT                                                          91200013
         TERMTBLD                                                       92000013
         EJECT                                                          92800013
* DEFINE QCB                                                            93600013
QBLOCK   DSECT                                                          94400013
COREQ    DS    0F                  QCB ADDRESS FOR DASD QUEUES          95200013
         END                                                            96000013
