         TITLE 'IECKCPYT  QTAM COPY TERMINAL TABLE (COPYT)'             00700013
*********************************************************************** 01400013
*                                                                     * 02100013
*NAME-                                                                * 02800013
*   IECKCPYT    QTAM COPY TERMINAL TABLE (COPYT)                      * 03500013
*                                                                     * 04200013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04900013
*                                                                     * 05600013
*FUNCTION-                                                            * 06300013
*        IECKCPYT WILL COPY AN ENTRY FROM THE TERMINAL TABLE INTO A   * 07000013
*   SPECIFIED WORK AREA.                                              * 07700013
*        THE ROUTINE WILL GET THE ADDRESS OF THE COMMUNICATIONS       * 08400013
*   VECTOR TABLE, AND FROM THIS TABLE WILL GET THE ADDRESS OF THE     * 09100013
*   TERMINAL TABLE.  THE ADDRESS OF THE END OF THE TABLE IS RETRIEVED * 09800013
*   FROM THE FIRST ENTRY IN THE TABLE, AND THE MAXIMUM SIZE OF ANY    * 10500013
*   TERMID IS GAINED FROM THE SECOND ENTRY IN THE TERMINAL TABLE.     * 11200013
*        THE TERMINAL TABLE TERMID'S ARE SCANNED FOR THE DESTINATION  * 11900013
*   NAME WHICH MATCHES THE REQUESTED ENTRY NAME.  IF THE PROPER       * 12600013
*   ENTRY IS FOUND, IT IS COPIED INTO THE WORK AREA.  A NORMAL        * 13300013
*   COMPLETION CODE OF X'00' IS PLACED, RIGHT ADJUSTED, INTO          * 14000013
*   REGISTER 15.                                                      * 14700013
*        IF AN ENTRY IS FOUND WITH LENGTH ZERO, OR IF NO ENTRY OF     * 15400013
*   THE SPECIFIED LENGTH IS FOUND, AN ERROR CODE OF X'20' IS PLACED,  * 16100013
*   RIGHT ADJUSTED, IN REGISTER 15.                                   * 16800013
*        RETURN IS TO THE NEXT PROCESSING PROGRAM INSTRUCTION.        * 17500013
*                                                                     * 18200013
*ENTRY POINTS-                                                        * 18900013
*   IECKCPYT - EXPANSION OF THE COPYT MACRO GENERATES A BALR TO THIS  * 19600013
*        POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER, AND    * 20300013
*        REGISTER 14 AS THE RETURN ADDRESS REGISTER.                  * 21000013
*                                                                     * 21700013
*INPUT-                                                               * 22400013
*   REGISTER  0- PARAMETER REGISTER. POINTS TO THE WORK AREA INTO     * 23100013
*        WHICH THE TERMINAL TABLE ENTRY IS TO BE COPIED.              * 23800013
*   REGISTER  1- CONTAINS A POINTER TO THE NAME OF THE TERMINAL       * 24500013
*        TABLE ENTRY TO BE COPIED.                                    * 25200013
*   REGISTER 13- ADDRESS OF THE SAVE AREA.                            * 25900013
*   REGISTER 14- RETURN ADDRESS                                       * 26600013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 27300013
*                                                                     * 28000013
*OUTPUT-                                                              * 28700013
*   REGISTER 15- WILL RETURN ONE OF THE FOLLOWING CONDITION CODES,    * 29400013
*        RIGHT ADJUSTED:                                              * 30100013
*        X'00' INDICATES NO ERRORS                                    * 30800013
*        X'20' INDICATES EITHER INVALID TERMINAL TABLE ENTRY          * 31500013
*              SPECIFIED, OR AN ENTRY OF LENGTH ZERO.                 * 32200013
*   IF THERE WERE NO ERRORS, A COPY OF THE DESIRED TERMINAL TABLE     * 32900013
*        ENTRY WILL BE IN THE CALLING ROUTINE'S WORK AREA.            * 33600013
*                                                                     * 34300013
*EXTERNAL ROUTINES-                                                   * 35000013
*   NONE.                                                             * 35700013
*                                                                     * 36400013
*EXITS-                                                               * 37100013
*   NORMAL- REGISTERS ARE RESTORED AND CONTROL RETURNS TO THE         * 37800013
*        LOCATION HELD IN REGISTER 14.                                * 38500013
*   ERROR- SAME AS ABOVE.                                             * 39200013
*                                                                     * 39900013
*TABLES/WORK AREAS-                                                   * 40600013
*   NONE.                                                             * 41300013
*                                                                     * 42000013
*ATTRIBUTES-                                                          * 42700013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 43400013
*                                                                     * 44100013
*NOTES-                                                               * 44800013
*   REGISTER  0- WILL HOLD THE END OF TABLE ADDRESS DURING SCANNING   * 45500013
*        OF TERMINAL TABLE.                                           * 46200013
*   REGISTER  2- WORK REGISTER.  WILL HOLD THE ADDRESS OF THE         * 46900013
*        WORK AREA.                                                   * 47600013
*   REGISTER  3- WORK REGISTER.  WILL HOLD THE SIZE OF THIS TERMINAL  * 48300013
*        TABLE ENTRY DURING SCANNING OF TABLE.                        * 49000013
*   REGISTER  4- WORK REGISTER.  WILL HOLD THE LENGTH OF THE TERMID.  * 49700013
*   REGISTER  5- WORK REGISTER.  WILL HOLD THE ADDRESS OF THE         * 50400013
*        COMMUNICATIONS VECTOR TABLE.                                 * 51100013
*   REGISTER  6- WORK REGISTER.  WILL HOLD THE POINTER TO THE CURRENT * 51800013
*        POSITION IN THE TERMINAL TABLE.                              * 52500013
*                                                                     * 53200013
*********************************************************************** 53900013
IECKCPYT START                                                          54600013
R0       EQU   0                                                        55300013
PLREG    EQU   1                                                        56000013
WORKREG  EQU   2                                                        56700013
XREG     EQU   3                                                        57400013
WREG     EQU   4              WORKREG                                   58100013
RD       EQU   5                                                        58800013
TERMREG  EQU   6                                                        59500013
FLAG     EQU   7                                                        60200013
RETURN   EQU   14                                                       60900013
SREG     EQU   15                                                       61600013
         USING IECKTERM,TERMREG                                         62300013
         USING *,SREG                                                   63000013
         SAVE  (14,12)                                                  63700013
         SR    XREG,XREG           CLEAR WORKING REGISTER               64400013
         SR    WREG,WREG           CLEAR WORKING REGISTER               65100013
         SR    FLAG,FLAG           CLEAR ERROR FIELD                    65800013
         L     RD,CVTABLE(0,0)     GET THE ADDRESS OF THE               66500013
*                                    COMMUNICATIONS VECTOR TABLE (CVT)  67200013
         L     TERMREG,CVTTRMTB(0,RD) GET TERMTBL ADDRESS FROM CVT      67900013
         LR    WORKREG,R0          LOAD WORKAREA ADDRESS IN WORKREG     68600013
         L     R0,0(0,TERMREG)     GET END OF TABLE ADDRESS             69300013
         IC    WREG,4(0,TERMREG)   GET LENGTH OF TERMID FIELD           70000013
         BCTR  WREG,0              DECREMENT BY ONE FOR EXECUTE         70700013
         LA    TERMREG,8(0,TERMREG)  BUMP TO FIRST ENTRY IN TABLE       71400013
LOOKUP   EX    WREG,COMPID         CAUSE COMPARE FOR TABLE ENTRY        72100013
         BNE   LAST                BRANCH IF NOT EQUAL                  72800013
         IC    XREG,TNTRYSZE       GET SIZE OF ENTRY FROM ENTRY         73500013
         BCTR  XREG,0              DECREMENT FOR EXECUTE                74200013
         EX    XREG,MOVTERM        CAUSE ENTRY TO BE COPIED IN WORKAREA 74900013
         B     RET                 AND RETURN TO USER                   75600013
COMPID   CLC   0(1,PLREG),TERMID   COMPARE TERMNAME TO TERMID           76300013
LAST     CR    TERMREG,R0          IS IT LAST ENTRY                     77000013
         BNL   INVALID             BRANCH IF YES - ERROR                77700013
         CLI   TNTRYSZE,0          IS LENGTH OF ENTRY EQUAL ZERO        78400013
         BE    INVALID             BRANCH IF YES                        79100013
         IC    XREG,TNTRYSZE       ELSE GET LENGTH                      79800013
         LA    TERMREG,0(XREG,TERMREG) AND BUMP TO NEXT ENTRY           80500013
         B     LOOKUP              RELOOP TO LOOK AT NEXT ENTRY         81200013
INVALID  LA    FLAG,X'20'          SET ERROR INDICATOR FOR USER         81900013
RET      LR    SREG,FLAG           LOAD USER'S ERROR INDICATOR          82600013
         RETURN (0,12)             RETURN TO USER                       83300013
MOVTERM  MVC   0(1,WORKREG),TNTRYSZE COPY TABLE ENTRY INTO 1ST BYTE     84000013
*                                      OF WORKAREA                      84700013
CVTABLE  EQU   16                                                       85400013
CVTTRMTB EQU   156                                                      86100013
*  THE FOLLOWING ERROR FLAGS ARE PASSED TO THE USER IN REGISTER 15      86800013
*                  X'00'    NO ERRORS                                   87500013
*                  X'20'    INVALID TERMINAL TABLE ENTRY SPECIFIED      88200013
         EJECT                                                          88900013
         TERMTBLD                                                       89600013
         END                                                            90300013
